Excel-də doğum günündən yaşı necə hesablamaq olar (8 asan üsul) -

Hugh West

16-10-2023 Excel düsturları
  • Bunu Paylaş
Hugh West

Məqalə Excel-də doğum günündən yaşı hesablamaq üçün bəzi heyrətamiz üsulları nümayiş etdirir. Siz yaşı tam illər kimi hesablamaq üçün bir neçə düstur öyrənəcəksiniz, həmçinin bugünkü tarixdə və ya müəyyən bir tarixdə illər, aylar və günlərlə faktiki yaş əldə edəcəksiniz. İndi biz sizə Excel-də doğum günündən yaşın hesablanması ilə bağlı asan və rahat üsullardan keçəcəyik.

Təcrübə İş Kitabını endirin

Daha yaxşı başa düşmək və özünüzü məşq etmək üçün aşağıdakı Excel iş kitabını yükləyə bilərsiniz. .

Ad günündən Yaşın Hesablanması.xlsm

Excel-də Ad Günündən Yaşın Hesablanması üçün 8 Metod

“Hey, neçə yaşın var ? “ Çox verilən sual. Uşaqlıqdan hamımız bu sualı tez-tez eşitmişik. Ancaq bu nə deməkdir? Bu, adətən, nə qədər yaşadığınızı ifadə edən cavabı bildirir.

Excel-də doğum günündən yaşı hesablamaq üçün heç bir xüsusi funksiya olmasa da, Doğum tarixini yaşa çevirməyin bir neçə alternativ yolu.

Bizdə 10 nəfərdən ibarət Ad günləri siyahısı var.

Burada bu anda biz onların yaşlarını Excel-də ad günlərindən hesablayacağıq.

1. Excel-də Ad günündən Yaşı Hesablamaq üçün Əsas Düsturdan istifadə

İlk olaraq biz ən ənənəvi yolu öyrənəcəyik. Excel-də yaşı illərlə hesablamaq. Bir insanın yaşını təyin etmək üçün ən ümumi üsul hansıdır? Sadəcə olaraqcari tarixdən doğum tarixi. Yaşın hesablanması üçün bu ümumi düstur Excel-də də istifadə edilə bilər. Addımları diqqətlə edin.

Addımlar:

  • İlk , D5 xanasını seçin, aşağıdakı düsturu daxil edin , və ENTER düyməsini basın.
=(TODAY()-C5)/365.25

Burada C5 <-in başlanğıc xanasıdır. 8>Ad günü sütun.

TODAY funksiyası bu günün tarixini qaytarır. Təbii ki, 1 il 365 gündən ibarətdir. Ancaq sıçrayış ili hər 4 ildən bir gəlir, ona görə də tarix fərqlərini 365,25-ə bölürük. Doldurma Dəstəyi Alətindən istifadə edin və D sütununu tamamlamaq üçün onu aşağı dartın.

  • Sonra, nəticələri tam illərdə göstərmək istəyirsinizsə, istifadə edin INT funksiyası .
=INT(D5)

Qeyd: D5:D14 xanalarının Nömrə və ya Ümumi formatında olduğundan əmin olun.

Ətraflı oxu: Excel-də Orta Yaşı Necə Hesablamaq olar (7 Asan Metod)

2. IF, YEAR, MONTH və NOW Funksiyasının Formula Kombinasiyasının Tətbiqi

Bu üsul düsturu tətbiq edir bəzi fərqli funksiyaları birləşdirir. IF , YEAR , MONTH və NOW funksiyalarının burada öz əməliyyatları var. Lütfən, aşağıdakı addımları yerinə yetirin.

Addımlar:

  • İlk olaraq D5 xanasını seçin və aşağıdakı düsturu yazın və<üzərinə toxunun. 6> ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo")

Formula Dağılımı

Burada, MONTH və YEAR funksiyalar həmin tarixin ay və ilini ədəd kimi qaytarır. Biz məntiqi test daxil etmək üçün ƏGƏR funksiyasından istifadə etdik ki, əgər indiki tarix ayı doğum tarixi ayından böyükdürsə, o zaman formula işləyir :

YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo"

Əks halda düsturun qalan hissəsi işləyəcək:

YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo"

Qeyd: Bu metodun çatışmazlığı ondan ibarətdir ki, 1 il əlavə etmək əvəzinə 12 ayı qaytarır. Bunu Cons vəziyyətində görə bilərik.

3. Fərqli Hüceyrələrdə Doğum İli, Ay və Gündən Yaşın Hesablanması

Burada doğum tariximizi aldıq. müxtəlif hüceyrələrdə onları İl , Ay, və Gün -ə bölməklə.

Bu cədvəldən , biz onların indiki yaşını hesablamaq istəyirik. İş addımlarımızı diqqətlə izləyin.

Addımlar:

  • İlk olaraq, TARİX və istifadə edərək doğum tarixini almalıyıq. DATEVALUE funksiyaları. Bunun üçün biz bu düsturdan istifadə etdik:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5)

Bu düstur müxtəlif illəri, ayları və günləri bir xanada birləşdirdi.

  • G5 xanasını seçin və aşağıdakı düsturu yerləşdirin.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "&  DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days"

Ətraflı oxuyun: Excel-də Yaşı İllər və Aylarla Necə Hesablamaq olar (5 Asan Yol)

4. Həyata keçirmə YEARFRAC Funksiyası

İlin bir hissəsini qaytaran YEARFRAC funksiyasından istifadə də ad günlərindən yaşı hesablamaq üçün etibarlı bir yanaşmadır.Excel. Aşağıdakı addımları yerinə yetirin.

Addımlar:

  • D5 xanasını seçin və aşağıdakı düsturu yazın.
=YEARFRAC(C5,TODAY(),1)

Bu funksiya ad günü ilə bugünkü tarix arasındakı fərqi hesabladı. Burada biz basis -i 1 kimi qəbul edirik, bu da faktiki deməkdir.

  • Yaş göstəricisini tam illərdə göstərmək üçün INT funksiyasından istifadə edin.

5. Excel-də doğum günündən yaşın hesablanması üçün DATEDIF funksiyasının qəbul edilməsi

Yaşın hesablanması üçün ən rahat və lazımlı funksiya DATEDIF funksiyasıdır . Addımları diqqətlə izləyin.

Addımlar:

  • Əvvəlcə D5 xanasını seçin və aşağıdakı düsturu yapışdırın və basın ENTER .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days"

Formula Dağılımı

Yaşları il, ay və günlərlə almaq üçün biz “Y” , “YM” və “MD” arqumentlərindən istifadə etdik ardıcıl olaraq DATEDIF funksiyasında . Yuxarıdakı düstur birləşdirilən 3 dəyər (illər, aylar və günlər) olan tək mətn sətrini qaytarır.

6. Yalnız Sıfırdan Qeyri Dəyərləri Göstərmək üçün IF-in DATEDIF Funksiyasının Birləşdirilməsi

Əvvəlki məqaləmizdə metodu istifadə etsəniz, bəzi xanalarda 0 ay və 0 gün görünməsi ilə bağlı problem görə bilərsiniz.

Bu problemdən qaçmaq və sıfırdan fərqli dəyərlər göstərmək üçün biz bunu edə bilərik. ƏGƏR funksiyasını birləşdirərək əvvəlki düsturumuzu bir qədər yeniləmək. Yeni formula ilə yenilənmək üçün,diqqətlə müşahidə edin.

Addımlar:

  • Əvvəlcə D5 xanasını seçin və düsturu aşağıdakı kimi yazın və düyməsini basın. ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days")

Bu düstur əvvəlki düsturumuza bənzəyir, lakin yeganə fərq ondan ibarətdir ki, il, ay və ya günlərdə hər hansı sıfır dəyər varsa, bu şərtlər buraxılacaq. ƏĞƏR funksiyasından istifadə edərək biz bu şərti sadəcə sıfırdan fərqli dəyərləri göstərmək üçün tətbiq etdik.

7. Müəyyən bir tarixdə yaşın hesablanması

Əvvəlki üsullarımızda biz bunun necə edildiyini öyrəndik. doğum günündən indiki yaşı hesablamaq. İndi biz müəyyən bir tarixdə yaşın müəyyən edilməsi prosedurunu öyrənəcəyik.

Müəyyən bir tarixdə yaşı proqnozlaşdırmaq üçün biz DATEDIF funksiyası yenidən. Buradan açıq şəkildə bu funksiyadan istifadənin rahatlığını başa düşə bilərsiniz. Aşağıdakı addımları yerinə yetirin.

Addımlar:

  • E5 xanasını seçin və aşağıdakı düsturu yazın və ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days"

Əvvəlki üsullarımızdan fərqi ondadır ki, biz orada indiyə qədər yaşı hesablamışıq. Tarix. Beləliklə, biz TODAY funksiyasından istifadə etdik. Amma biz burada yaşı indiki yaşı deyil, konkret bir tarixdə işlədirik. Beləliklə, biz Son Tarix üçün başqa xana istinadından istifadə edirik.

Ətraflı oxuyun: Excel-də İki Tarix Arasında Yaşı Necə Hesablamaq olar (6 Faydalı Metod)

8. Doğum günündən yaşı hesablamaq üçün VBA tətbiqiExcel

Excel-də yaşı ad günlərindən hesablamağın başqa bir yolu VBA kodundan istifadə etməkdir. Bu metoddan istifadə edərək yaşı hesablamaq üçün aşağıdakı addımları izləyə bilərsiniz.

Addımlar:

  • Cədvəlin adı üzərinə sağ klikləyin və Koda Baxın seçin.

  • Dərhal Proqramlar üçün Microsoft Visual Basic pəncərəsi açılır. Cədvəl9 (VBA) üzərinə sağ klikləyin > Daxil et > Modulu seçin.

  • Bu kod modulunu açır, burada aşağıdakı kodu yapışdırın aşağı salın və Çalışdır düyməsini basın və ya F5 düyməsini basın. 
3612
  • İndi kod modulunu bağlayaraq iş vərəqinə qayıdın. Siz görə bilərsiniz ki, D5:D14 hüceyrələr avtomatik olaraq illərlə yaşla doldurulur. Düstur panelində biz VBA kodumuzda istifadə etdiyimiz DATEDIF funksiyasını görə bilərik.

İnsanın Müəyyən Yaşa çatdığı Tarixin Tapılması

Deyək ki, Robinin doğum tarixi 13-08-1996-cı ildir. O, nə vaxt 50 yaşına çatacaqdı? Bunu hardan bilirsiniz? Əvvəllər bunu bilmirsinizsə, narahat olmaq üçün heç bir şey yoxdur. Sadəcə addımlarımızı diqqətlə izləyin.

Addımlar:

  • İlk olaraq D5 xanasını seçin və düsturu aşağıdakı kimi yazın, sonra basın. ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5))

Burada il ilə 50 əlavə etdik doğum tarixi. Nəhayət, 50 Yaşa çatma tarixinə qayıdırYaş .

Nəticə

Bu məqaləni oxuduğunuz üçün təşəkkür edirik, ümid edirik ki, bu faydalı oldu. Hər hansı bir sualınız və ya təklifiniz varsa, şərh bölməsində bizə bildirin. Ətraflı araşdırmaq üçün Exceldemy saytımıza daxil olun.

Əvvəlki yazı Excel-də çarpaz cədvəli necə etmək olar (3 uyğun nümunə)
Növbəti yazı Excel-də tarixi ilə necə çevirmək olar (3 sürətli üsul)

Hugh West sənayedə 10 ildən çox təcrübəyə malik yüksək təcrübəli Excel təlimçisi və analitikidir. Mühasibat uçotu və maliyyə üzrə bakalavr dərəcəsi və Biznesin idarə edilməsi üzrə magistr dərəcəsinə malikdir. Hugh tədrisə həvəslidir və izləmək və başa düşmək asan olan unikal tədris yanaşması işləyib hazırlayıb. Onun Excel üzrə ekspert biliyi bütün dünyada minlərlə tələbə və mütəxəssisə öz bacarıqlarını təkmilləşdirməyə və karyeralarında üstün olmağa kömək etmişdir. Hugh öz bloqu vasitəsilə biliklərini dünya ilə bölüşür, fərdlərə və müəssisələrə öz potensiallarını tam şəkildə çatdırmaq üçün pulsuz Excel dərsləri və onlayn təlimlər təklif edir.