Sådan bruger du FILTER-funktionen i Excel (10 ideelle eksempler)

Hugh West

16-10-2023 Excel-formler
  • Del Dette
Hugh West

Excel 365 giver os en kraftfuld funktion til automatisk filtrering af vores datasæt, kaldet FILTER funktionen. Det gør vores opgave lettere ved at bruge denne funktion i Excel-formler. Denne artikel vil dele den komplette idé om, hvordan funktionen FILTER funktionen fungerer i Excel uafhængigt og derefter sammen med andre Excel-funktioner. Hvis du også er nysgerrig, kan du downloade vores øvelsesarbejdsbog og følge os.

Download arbejdsbog til øvelser

Download denne arbejdsbog til øvelse, så du kan øve dig, mens du læser denne artikel.

Anvendelse af FILTER-funktionen.xlsx

Introduktion til FILTER-funktionen i Excel

Funktion Målsætning:

Filtrere nogle bestemte celler eller værdier i henhold til vores krav.

Syntaks:

=FILTER (array, include, [if_empty])

Argumenter Forklaring:

Argument Krævet eller valgfri Værdi

array Påkrævet Et array, en arrayformel eller en henvisning til en række celler, som vi har brug for antallet af rækker for.
omfatter Påkrævet Dette fungerer som et boolsk array; det indeholder betingelsen eller kriterierne for filtrering.
[if_empty] Valgfrit Overfør den værdi, der skal returneres, når der ikke returneres nogen resultater.

Returparameter:

Funktionen returnerer et dynamisk resultat. Når værdierne i kildedataene ændres, eller når kildedataarrayet ændres i størrelse, opdateres resultaterne fra FILTER automatisk.

10 egnede eksempler på brug af FILTER-funktionen i Excel

For at demonstrere eksemplerne tager vi et datasæt med 10 Studerende på en institution. Deres ID, navn, afdeling, indskrevet semester og CGPA-værdi er i intervallet af cellerne B5:F14 .

📚 Bemærk:

Alle operationer i denne artikel udføres ved hjælp af Microsoft Office 365 ansøgning.

1. Udførelse af AND-operation med FILTER-funktionen for flere kriterier

I det første eksempel vil vi udføre den OG af FILTER Vores ønskede betingelser ligger inden for området celler C5:C6 .

Trinene for at gennemføre dette eksempel er angivet nedenfor:

📌 Trin:

  • Først og fremmest skal du vælge celle B10 .
  • Skriv nu følgende formel ned i cellen.

=FILTER(Dataset!B5:F14,(Dataset!D5:D14=C5)*(Dataset!F5:F14>=C6), "ingen resultater")

  • Derefter skal du trykke på Indtast .

  • Du får det filtrerede resultat i området af celler B10:F11 .

Vi kan således sige, at vi er i stand til at anvende FILTER funktion for OG drift.

2. Anvendelse af OR-operation med FILTER-funktion til flere kriterier

I det andet eksempel skal vi bruge FILTER funktion for den ELLER Her har vi nævnt betingelserne i intervallet af celler C5:C6 .

Trinene for at afslutte dette eksempel er angivet som følger:

📌 Trin:

  • Først skal du vælge celle B10 .
  • Skriv herefter følgende formel i cellen.

=FILTER(Dataset!B5:F14,(Dataset!D5:D14=OR!C5)+(Dataset!F5:F14>=OR!C6), "ingen resultater")

  • Tryk på Indtast .

  • Du vil finde det filtrerede resultat i de ønskede celler.

Vi kan derfor bruge den FILTER fungerer perfekt for den ELLER drift.

3. Kombination af AND- og OR-logik med FILTER-funktion

Nu vil vi bruge FILTER funktion for en kombineret OG og ELLER operationen. Betingelserne ligger i intervallet af celler C5:C7 .

Trinene til at udføre dette eksempel er angivet nedenfor:

📌 Trin:

  • Først skal du vælge celle B11 .
  • Skriv derefter følgende formel ned i cellen.

=FILTER(Dataset!B5:F14,(Dataset!F5:F14>=Combine!C7)*((Dataset!D5:D14=Combine!C5)+(Dataset!D5:D14=Combine!C6)), "Ingen resultater")

  • Tryk på Indtast .

  • Du vil bemærke, at det filtrerede resultat vil være tilgængeligt i cellerne.

Derfor fungerer vores formel effektivt, og vi er i stand til at udføre den OG og ELLER operationer samtidig af den FILTER funktion.

4. Filtrering af dubletter ved hjælp af FILTER-funktionen

I dette eksempel vil vi filtrere de duplikerede enheder fra vores datasæt. Vores datasæt indeholder 2 dublerede enheder.

Trinene i dette eksempel er angivet nedenfor:

📌 Trin:

  • I begyndelsen skal du vælge celle H5 .
  • Skriv derefter følgende formel i cellen.

=FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16)>1,"No result")

  • Tryk således på Indtast .

  • Du vil se, at alle duplikerede værdier er opført separat.

Til sidst kan vi sige, at vores formel fungerer præcist, og at vi kan finde ud af, hvilke dubletter der er tale om ved hjælp af FILTER funktion i Excel.

🔎 Forklaring af formlen

👉 COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16) : Den COUNTIFS funktionen kontrollerer, om der findes dubletter.

👉 FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16, F5:F16)>1,”No result”) : Endelig er den FILTER funktionen filtrere de dobbelte værdier og opregne dem separat.

5. Find ud af tomme celler ved hjælp af FILTER-funktionen

Vi har et datasæt med nogle tomme celler. Nu vil vi filtrere de celler, der ikke indeholder nogen tomme celler, ved hjælp af funktionen FILTER funktion.

Proceduren for at filtrere de komplette rækker er angivet nedenfor::

📌 Trin:

  • Først skal du vælge celle H5 .
  • Skriv derefter følgende formel i cellen.

=FILTER(B5:F14,(B5:B14"")*(C5:C14"")*(D5:D14"")*(E5:E14"")*(F5:F14""),"No results")

  • Derefter skal du trykke på Indtast .

  • Du får de enheder, der ikke har nogen tomme celler.

Så vi kan sige, at vores formel fungerer godt, og vi kan få værdien uden tomme celler i Excel FILTER funktion.

Lignende læsninger

  • Sådan bruger du Excel HYPERLINK-funktionen (8 eksempler)
  • VLOOKUP og HLOOKUP kombineret Excel-formel (med eksempel)
  • Brug af Excel til at slå op på partiel tekstmatch [2 nemme måder]
  • Sådan Find duplikerede værdier i Excel ved hjælp af VLOOKUP

6. Filtrer celler, der indeholder specifik tekst

Brug af den FILTER funktionen kan vi nemt søge efter en bestemt værdi og filtrere de tilsvarende enheder fra vores oprindelige datasæt. Ud over den FILTER funktion, den ISNUMBER og SØG funktionerne hjælper os også med at færdiggøre formlen. Vores ønskede tekst 'Ellie' vises i celle J4 .

Fremgangsmåden til filtrering af data for en specifik tekst er beskrevet nedenfor::

📌 Trin:

  • I starten skal du vælge celle H7 .
  • Skriv derefter følgende formel ned i cellen.

=FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "Ingen resultater")

  • Derefter skal du trykke på Indtast nøgle.

  • Du vil få resultatet med den pågældende tekst.

Vi er således i stand til at anvende formlen og få værdien for vores specifikke tekstværdi.

🔎 Forklaring af formlen

👉 SEARCH(J4,C5:C14) : Den SØG funktionen returnerer de celler, som vil blive matchet med inputværdien.

👉 ISNUMBER(SEARCH(J4,C5:C14)) : Den ISNUMBER funktionen returnerer sandt, hvis søgeværdien er et andet tal end falsk.

👉 FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "Ingen resultater") : Endelig er den FILTER funktionen udtrækker de matchende rækker og viser dem.

7. Beregning af summering, maksimum, minimum og gennemsnit

Nu skal vi udføre nogle matematiske beregninger ved hjælp af FILTER De data, som vi vil filtrere, vil være i celle J5 Her skal vi bestemme alle værdierne for CSE afdeling.

Ud over den FILTER funktion, den SUM , GENNEMSNITLIG , MIN , og MAX Den anslåede værdi vil ligge i intervallet celler J7:J10 Beregningsproceduren forklares nedenfor trin for trin:

📌 Trin:

  • Først og fremmest skal du vælge celle J7 .
  • Skriv nu følgende formel i cellen for summeringen.

=SUM(FILTER(F5:F14,D5:D14=J5,0))

🔎 Forklaring af formlen

👉 FILTER(F5:F14,D5:D14=J5,0) : Den FILTER funktion filtrere den CGPA værdien af vores ønskede afdeling.

👉 SUM(FILTER(F5:F14,D5:D14=J5,0)) : Endelig er den SUM funktion tilføje dem alle.

  • Tryk på Indtast .

  • Derefter skal du vælge celle J8 , og skriv følgende formel for den gennemsnit værdi.

=GENNEMSNIT(FILTER(F5:F14,D5:D14=J5,0))

🔎 Forklaring af formlen

👉 FILTER(F5:F14,D5:D14=J5,0) : Den FILTER funktionen filtrere CGPA-værdien for vores ønskede afdeling.

👉 GENNEMSNIT(FILTER(F5:F14,D5:D14=J5,0)) : Den GENNEMSNITLIG funktionen vil beregne den gennemsnit værdien af disse værdier.

  • Tryk igen på Indtast .

  • Vælg derefter celle J9 , og skriv følgende formel inde i cellen for at få den minimum værdi.

=MIN(FILTER(F5:F14,D5:D14=J5,0))

🔎 Forklaring af formlen

👉 FILTER(F5:F14,D5:D14=J5,0) : Den FILTER funktionen filtrere CGPA-værdien for vores ønskede afdeling.

👉 MIN(FILTER(F5:F14,D5:D14=J5,0)) : Den MIN funktionen vil finde ud af den minimum værdi blandt de 4 værdier.

  • På samme måde skal du trykke på Indtast .

  • Endelig skal du vælge celle J10 , og skriv følgende formel i cellen for den maksimum værdi.

=MAX(FILTER(F5:F14,D5:D14=J5,0))

🔎 Forklaring af formlen

👉 FILTER(F5:F14,D5:D14=J5,0) : Den FILTER funktionen filtrere CGPA-værdien for vores ønskede afdeling.

👉 MAX(FILTER(F5:F14,D5:D14=J5,0)) : Den MAX funktionen vil finde ud af den maksimum værdi blandt de 4 CGPA-værdier.

  • Tryk på Gå ind på for sidste gang.

  • Du vil bemærke, at alle værdierne for CSE afdeling vil være til rådighed.

Derfor kan vi sige, at alle vores formler fungerer perfekt, og vi er i stand til at få alle de ønskede værdier ved hjælp af Excel FILTER funktion.

8. Filtrer data og returner kun bestemte kolonner

Her skal vi bruge FILTER funktionen to gange i en indlejret betingelse for at få de bestemte kolonner baseret på vores ønskede værdi. Vores ønskede enhed er i celle J5 Vi vil kun vise de ID og Navn kolonne.

Trinene i denne proces er beskrevet nedenfor:

📌 Trin:

  • Først skal du vælge celle H8 .
  • Skriv derefter følgende formel ned i cellen.

=FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0})

  • Derefter skal du trykke på Gå ind på .

  • Du får kun den ID og Navn kolonne i vores ønskede afdeling.

Derfor kan vi sige, at vores formel fungerer korrekt, og at vi kan få nogle specifikke kolonner fra Excel FILTER funktion.

🔎 Forklaring af formlen

👉 FILTER(B5:F14,D5:D14=J5) : Den FILTER funktionen returnerer de matchede rækker fra det givne datasæt med alle kolonnerne.

👉 FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0}) : Den ydre FILTER funktionen vil kun vælge den første to kolonnerne i de valgte data. Vi kan enten bruge 0 , 1 eller TRUE , FALSK .

9. Anvend begrænsning af det returnerede antal rækker

I dette tilfælde vil vi tilføje nogle begrænsninger på FILTER funktion til at få det begrænsede antal rækker. Vores ønskede afdeling er i celle J5 For at kunne anvende begrænsningen skal vi bruge den IFERROR og INDEX funktion også.

Trinene i denne matematik er beskrevet som følger:

📌 Trin:

  • Først skal du vælge celle H8 .
  • Skriv derefter følgende formel i cellen.

=IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}),"No result")

  • Derefter skal du trykke på Gå ind på .

  • Du vil få resultatet.

Så vi kan sige, at vi er i stand til at anvende Excel med succes FILTER , INDEX , og IFERROR fungerer med succes.

🔎 Forklaring af formlen

👉 FILTER(B5:F14,D5:D14=J5) : Den FILTER funktionen returnerer de filtrerede data ved at matche dem med inputværdien.

👉 INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}) : Denne formel returnerer de to første rækker af de matchede data. {1;2} dette gælder for de to første rækker. og {1,2,3,4,5} dette er til at vælge de fem kolonner.

👉 IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}), "Intet resultat") : Endelig er det IFERROR funktionen bruges til at undgå fejlen, hvis der er et problem med andre funktioners returværdier.

10. Brug af jokertegn med FILTER-funktionen

I det sidste eksempel skal vi anvende filterjokertegn til at filtrere dataene. Vi anvender formlen ved hjælp af ISNUMBER , SØG , og FILTER funktion. Vores ønskede værdi er i celle J5 .

Processen forklares nedenfor trin for trin:

📌 Trin:

  • Først skal du vælge celle H8 , og skriv følgende formel i cellen.

=FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "Ingen resultater!")

  • Tryk nu på Indtast .

  • Du får alle resultaterne med celleværdien C .

Endelig kan vi sige, at vores formel fungerer præcist, og vi kan oprette et jokertegn ved hjælp af Excel FILTER funktion.

🔎 Forklaring af formlen

👉 SEARCH(J5,D5:D14) : Den SØG funktionen vil søge i dataene ved at matche dem med inputværdien.

👉 ISNUMBER(SEARCH(J5,D5:D14)) : Denne formel vil kontrollere, hvilket resultat af SØG funktion er ture,

👉 FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "Ingen resultater!") : Endelig er det FILTER funktionen vil vise dem i den ønskede celle.

Alternativer til Excel FILTER-funktionen

Fra vores tidligere ansøgning har du måske bemærket, at Excel FILTER funktionen er en lille praktisk funktion til at få vores ønskede værdier inden for en kort periode. Der findes ikke noget specifikt alternativ til denne funktion. Kombinationen af nogle generelle Excel-funktioner kan dog give os resultaterne af FILTER funktion. Blandt dem er den IFERROR , INDEX , AGGREGAT , RÆKKE , ISNA , MATCH funktioner kan nævnes. Men vi anbefaler dig, at hvis du har den FILTER Kombinationen af disse funktioner vil gøre formlen mere kompliceret at forstå for andre. Desuden kan det gøre dit Excel-program langsommere.

Mulige årsager til, at FILTER-funktionen ikke virker

Nogle gange er det FILTER funktion i Excel fungerer ikke korrekt. Det sker oftest på grund af fejl. Det skyldes hovedsageligt, at den #SPILL! , #CALC! , #VALUE! fejl tillader normalt ikke, at den FILTER funktion til at fungere og returnere de ønskede data. For at eliminere denne fejl skal du gå tilbage til dit oprindelige datasæt og rette dem, og du vil opdage, at FILTER funktionen vil fungere problemfrit.

De hyppigt forekommende fejl i Excel er kort forklaret nedenfor:

Almindelige fejl Når de viser
#VALUE Den vises, når arrayet og include-argumentet har uforenelige dimensioner.
#CALC! Den vises, hvis det valgfrie if_empty-argument er udeladt, og der ikke findes nogen resultater, der opfylder kriterierne.
#NAME Den vises, når du forsøger at bruge FILTER i en ældre version af Excel.
#SPILL Denne fejl opstår, hvis en eller flere celler i spildområdet ikke er helt tomme.
#REF! Denne fejl opstår, hvis en FILTER-formel bruges mellem forskellige arbejdsbøger og lukker kildearbejdsbogen.
#N/A eller #VALUE Denne type fejl kan opstå, hvis en værdi i det medfølgende argument er en fejl eller ikke kan omdannes til en boolsk værdi (0,1 eller TRUE, FALSE).

Konklusion

Det er slutningen af denne artikel. Jeg håber, at denne artikel vil være nyttig for dig, og at du vil være i stand til at anvende FILTER-funktionen i Excel. Del gerne yderligere spørgsmål eller anbefalinger med os i kommentarfeltet nedenfor, hvis du har yderligere spørgsmål eller anbefalinger.

Glem ikke at tjekke vores websted, ExcelWIKI , til flere Excel-relaterede problemer og løsninger. Bliv ved med at lære nye metoder og bliv ved med at vokse!

Forrige indlæg Sådan fjernes flere rækker i Excel (9 metoder)
Næste indlæg Sådan bruges COUNTIFS-funktionen i Excel (4 egnede eksempler)

Hugh West er en meget erfaren Excel-træner og analytiker med over 10 års erfaring i branchen. Han har en bachelorgrad i regnskab og finans og en kandidatgrad i Business Administration. Hugh har en passion for undervisning og har udviklet en unik undervisningstilgang, der er nem at følge og forstå. Hans ekspertviden om Excel har hjulpet tusindvis af studerende og fagfolk verden over med at forbedre deres færdigheder og udmærke sig i deres karriere. Gennem sin blog deler Hugh sin viden med verden og tilbyder gratis Excel-tutorials og onlinetræning for at hjælpe enkeltpersoner og virksomheder med at nå deres fulde potentiale.