Excel 365 μας παρέχει μια ισχυρή συνάρτηση για το αυτόματο φιλτράρισμα των συνόλων δεδομένων μας, που ονομάζεται ΦΊΛΤΡΟ Κάνει το έργο μας ευκολότερο με τη χρήση αυτής της συνάρτησης στους τύπους του Excel. Αυτό το άρθρο θα μοιραστεί την πλήρη ιδέα για το πώς η συνάρτηση ΦΊΛΤΡΟ η συνάρτηση λειτουργεί στο Excel ανεξάρτητα και στη συνέχεια με άλλες συναρτήσεις του Excel. Αν είστε επίσης περίεργοι γι' αυτό, κατεβάστε το βιβλίο ασκήσεων και ακολουθήστε μας.

Κατεβάστε το βιβλίο ασκήσεων

Κατεβάστε αυτό το τετράδιο ασκήσεων για εξάσκηση ενώ διαβάζετε αυτό το άρθρο.

Χρήση της συνάρτησης FILTER.xlsx

Εισαγωγή στη λειτουργία FILTER στο Excel

Λειτουργία Στόχος:

Φιλτράρετε ορισμένα συγκεκριμένα κελιά ή τιμές σύμφωνα με τις απαιτήσεις μας.

Σύνταξη:

=FILTER (array, include, [if_empty])

Επιχειρήματα Επεξήγηση:

Παράμετρος επιστροφής:

Η συνάρτηση επιστρέφει ένα δυναμικό αποτέλεσμα. Όταν αλλάζουν οι τιμές στα δεδομένα προέλευσης ή όταν αλλάζει το μέγεθος του πίνακα δεδομένων προέλευσης, τα αποτελέσματα από το FILTER θα ενημερώνονται αυτόματα.

10 κατάλληλα παραδείγματα χρήσης της συνάρτησης FILTER στο Excel

Για να παρουσιάσουμε τα παραδείγματα, εξετάζουμε ένα σύνολο δεδομένων των 10 Το αναγνωριστικό τους, το όνομά τους, το τμήμα τους, το εξάμηνο εγγραφής τους και το ποσό του CGPA βρίσκονται στο εύρος των κελιών B5:F14 .

📚 Σημείωση:

Όλες οι λειτουργίες αυτού του άρθρου πραγματοποιούνται με τη χρήση του Microsoft Office 365 εφαρμογή.

1. Εκτέλεση της λειτουργίας AND με τη λειτουργία FILTER για πολλαπλά κριτήρια

Στο πρώτο παράδειγμα, θα εκτελέσουμε το ΚΑΙ λειτουργία από το ΦΊΛΤΡΟ Οι επιθυμητές συνθήκες μας είναι στο εύρος των κυττάρων C5:C6 .

Τα βήματα για την ολοκλήρωση αυτού του παραδείγματος παρατίθενται παρακάτω:

📌 Βήματα:

• Πρώτα απ' όλα, επιλέξτε το κελί B10 .
• Τώρα, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(Dataset!B5:F14,(Dataset!D5:D14=C5)*(Dataset!F5:F14>=C6), "no results")

• Στη συνέχεια, πατήστε Εισάγετε το .

• Θα λάβετε το φιλτραρισμένο αποτέλεσμα στο εύρος των κελιών B10:F11 .

Έτσι, μπορούμε να πούμε ότι είμαστε σε θέση να εφαρμόσουμε το ΦΊΛΤΡΟ συνάρτηση για ΚΑΙ λειτουργία.

2. Εφαρμογή της λειτουργίας OR με τη λειτουργία FILTER για πολλαπλά κριτήρια

Στο δεύτερο παράδειγμα, θα χρησιμοποιήσουμε την εντολή ΦΊΛΤΡΟ συνάρτηση για το Ή Εδώ, αναφέραμε τις συνθήκες στην περιοχή των κυττάρων C5:C6 .

Τα βήματα για την ολοκλήρωση αυτού του παραδείγματος έχουν ως εξής:

📌 Βήματα:

• Πρώτον, επιλέξτε το κελί B10 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(Dataset!B5:F14,(Dataset!D5:D14=OR!C5)+(Dataset!F5:F14>=OR!C6), "no results")

• Τύπος Εισάγετε το .

• Θα καταλάβετε το φιλτραρισμένο αποτέλεσμα στα επιθυμητά κελιά.

Ως εκ τούτου, είμαστε σε θέση να χρησιμοποιήσουμε το ΦΊΛΤΡΟ λειτουργία τέλεια για το Ή λειτουργία.

3. Συνδυασμός της λογικής AND και OR με τη λειτουργία FILTER

Τώρα, θα χρησιμοποιήσουμε το ΦΊΛΤΡΟ συνάρτηση για μια συνδυασμένη ΚΑΙ και Ή Οι συνθήκες βρίσκονται στο εύρος των κελιών C5:C7 .

Τα βήματα για την υλοποίηση αυτού του παραδείγματος παρατίθενται παρακάτω:

📌 Βήματα:

• Αρχικά, επιλέξτε το κελί B11 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(Dataset!B5:F14,(Dataset!F5:F14>=Combine!C7)*((Dataset!D5:D14=Combine!C5)+(Dataset!D5:D14=Combine!C6)), "No results")

• Πατήστε το Εισάγετε το .

• Θα παρατηρήσετε ότι το φιλτραρισμένο αποτέλεσμα θα είναι διαθέσιμο στα κελιά.

Επομένως, ο τύπος μας λειτουργεί αποτελεσματικά και είμαστε σε θέση να εκτελέσουμε την ΚΑΙ και Ή λειτουργίες ταυτόχρονα από το ΦΊΛΤΡΟ λειτουργία.

4. Φιλτράρισμα αντιγράφων με χρήση της λειτουργίας FILTER

Σε αυτό το παράδειγμα, θα φιλτράρουμε τις διπλές οντότητες από το σύνολο δεδομένων μας. Το σύνολο δεδομένων μας περιέχει 2 διπλές οντότητες.

Τα βήματα αυτού του παραδείγματος δίνονται παρακάτω:

📌 Βήματα:

• Στην αρχή, επιλέξτε το κελί H5 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16)>1,"No result")

• Έτσι, πατήστε το Εισάγετε το .

• Θα δείτε ότι όλες οι διπλές τιμές παρατίθενται ξεχωριστά.

Επιτέλους, μπορούμε να πούμε ότι ο τύπος μας λειτουργεί με ακρίβεια και ότι είμαστε σε θέση να υπολογίσουμε τα αντίγραφα από το ΦΊΛΤΡΟ στο Excel.

🔎 Επεξήγηση του τύπου

👉 COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16,F5:F16) : Η COUNTIFS ελέγχει την παρουσία των διπλών τιμών.

👉 FILTER(B5:F16,COUNTIFS(B5:B16,B5:B16,C5:C16,C5:C16,D5:D16,D5:D16,E5:E16,E5:E16,F5:F16, F5:F16)>1,”No result”) : Τέλος, το ΦΊΛΤΡΟ φιλτράρει τις διπλές τιμές και τις παραθέτει ξεχωριστά.

5. Εύρεση κενών κελιών με τη λειτουργία FILTER

Έχουμε ένα σύνολο δεδομένων με μερικά κενά κελιά. Τώρα, θα φιλτράρουμε τα κελιά που δεν περιέχουν καμία κενή συνάρτηση με τη βοήθεια της συνάρτησης ΦΊΛΤΡΟ λειτουργία.

Η διαδικασία για το φιλτράρισμα των πλήρων γραμμών δίνεται παρακάτω::

📌 Βήματα:

• Πρώτον, επιλέξτε το κελί H5 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(B5:F14,(B5:B14"")*(C5:C14"")*(D5:D14"")*(E5:E14"")*(F5:F14""),"No results")

• Μετά από αυτό, πατήστε Εισάγετε το .

• Θα λάβετε εκείνες τις οντότητες που δεν έχουν κενά κελιά.

Έτσι, μπορούμε να πούμε ότι ο τύπος μας λειτουργεί καρποφόρα και είμαστε σε θέση να λάβουμε την τιμή χωρίς κενά κελιά από το Excel ΦΊΛΤΡΟ λειτουργία.

Παρόμοιες αναγνώσεις

• Πώς να χρησιμοποιήσετε τη λειτουργία HYPERLINK του Excel (8 παραδείγματα)
• Συνδυασμένος τύπος VLOOKUP και HLOOKUP του Excel (με παράδειγμα)
• Χρησιμοποιώντας το Excel για να αναζητήσετε μερικό αγώνα κειμένου [2 εύκολοι τρόποι]
• Πώς να βρείτε διπλές τιμές στο Excel χρησιμοποιώντας το VLOOKUP

6. Φιλτράρετε τα κελιά που περιέχουν συγκεκριμένο κείμενο

Χρησιμοποιώντας το ΦΊΛΤΡΟ συνάρτηση, μπορούμε εύκολα να αναζητήσουμε οποιαδήποτε συγκεκριμένη τιμή και να φιλτράρουμε τις αντίστοιχες οντότητες από το αρχικό μας σύνολο δεδομένων. Εκτός από τη συνάρτηση ΦΊΛΤΡΟ λειτουργία, η ISNUMBER και ΑΝΑΖΗΤΗΣΗ μας βοηθούν επίσης να συμπληρώσουμε τον τύπο. Το επιθυμητό μας κείμενο 'Ellie' εμφανίζεται στο κελί J4 .

Η προσέγγιση του φιλτραρίσματος των δεδομένων για ένα συγκεκριμένο κείμενο περιγράφεται παρακάτω::

📌 Βήματα:

• Στην αρχή, επιλέξτε το κελί H7 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "No results")

• Στη συνέχεια, πατήστε το πλήκτρο Εισάγετε το κλειδί.

• Θα λάβετε το αποτέλεσμα με το συγκεκριμένο κείμενο.

Έτσι, είμαστε σε θέση να εφαρμόσουμε τον τύπο με επιτυχία και να λάβουμε την τιμή για τη συγκεκριμένη τιμή του κειμένου μας.

🔎 Επεξήγηση του τύπου

👉 SEARCH(J4,C5:C14) : Η ΑΝΑΖΗΤΗΣΗ θα επιστρέψει τα κελιά που θα αντιστοιχηθούν με την τιμή εισόδου.

👉 ISNUMBER(SEARCH(J4,C5:C14)) : Η ISNUMBER η συνάρτηση θα επιστρέψει true αν η τιμή αναζήτησης είναι ένας αριθμός εκτός του false.

👉 FILTER(B5:F14,ISNUMBER(SEARCH(J4,C5:C14)), "No results") : Τέλος, το ΦΊΛΤΡΟ εξάγει τις γραμμές που ταιριάζουν και τις εμφανίζει.

7. Υπολογισμός του αθροίσματος, του μέγιστου, του ελάχιστου και του μέσου όρου

Τώρα, πρόκειται να εκτελέσουμε ορισμένους μαθηματικούς υπολογισμούς με τη βοήθεια του ΦΊΛΤΡΟ Τα δεδομένα για τα οποία θα φιλτράρουμε θα βρίσκονται στο κελί J5 Εδώ, θα καθορίσουμε όλες τις τιμές για το CSE τμήμα.

Εκτός από το ΦΊΛΤΡΟ λειτουργία, η SUM , ΜΈΣΟΣ ΌΡΟΣ , MIN , και MAX Η εκτιμώμενη τιμή θα είναι στο εύρος των κελιών J7:J10 Η διαδικασία υπολογισμού εξηγείται παρακάτω βήμα προς βήμα:

📌 Βήματα:

• Πρώτα απ' όλα, επιλέξτε το κελί J7 .
• Τώρα, γράψτε τον ακόλουθο τύπο στο κελί για το άθροισμα.

=SUM(FILTER(F5:F14,D5:D14=J5,0))

🔎 Επεξήγηση του τύπου

👉 FILTER(F5:F14,D5:D14=J5,0) : Η ΦΊΛΤΡΟ συνάρτηση φιλτράρει το CGPA αξία του επιθυμητού μας τμήματος.

👉 SUM(FILTER(F5:F14,D5:D14=J5,0)) : Τέλος, το SUM συνάρτηση προσθέτει όλα αυτά.

• Τύπος Εισάγετε το .

• Μετά από αυτό, επιλέξτε το κελί J8 , και γράψτε τον ακόλουθο τύπο για το μέσος όρος αξία.

=AVERAGE(FILTER(F5:F14,D5:D14=J5,0))

🔎 Επεξήγηση του τύπου

👉 FILTER(F5:F14,D5:D14=J5,0) : Η ΦΊΛΤΡΟ συνάρτηση φιλτράρει την τιμή CGPA του επιθυμητού τμήματος.

👉 AVERAGE(FILTER(F5:F14,D5:D14=J5,0)) : Η ΜΈΣΟΣ ΌΡΟΣ η συνάρτηση θα υπολογίσει το μέσος όρος αξία αυτών των τιμών.

• Πιέστε ξανά Εισάγετε το .

• Στη συνέχεια, επιλέξτε το κελί J9 , και γράψτε τον ακόλουθο τύπο μέσα στο κελί για να λάβετε το ελάχιστο αξία.

=MIN(FILTER(F5:F14,D5:D14=J5,0))

🔎 Επεξήγηση του τύπου

👉 FILTER(F5:F14,D5:D14=J5,0) : Η ΦΊΛΤΡΟ συνάρτηση φιλτράρει την τιμή CGPA του επιθυμητού τμήματος.

👉 MIN(FILTER(F5:F14,D5:D14=J5,0)) : Η MIN συνάρτηση θα υπολογίσει το ελάχιστο τιμή μεταξύ των 4 αξίες.

• Παρομοίως, πατήστε το Εισάγετε το .

• Τέλος, επιλέξτε το κελί J10 , και γράψτε τον ακόλουθο τύπο μέσα στο κελί για το μέγιστο αξία.

=MAX(FILTER(F5:F14,D5:D14=J5,0))

🔎 Επεξήγηση του τύπου

👉 FILTER(F5:F14,D5:D14=J5,0) : Η ΦΊΛΤΡΟ συνάρτηση φιλτράρει την τιμή CGPA του επιθυμητού τμήματος.

👉 MAX(FILTER(F5:F14,D5:D14=J5,0)) : Η MAX η συνάρτηση θα βρει το μέγιστο τιμή μεταξύ των 4 Τιμές CGPA.

• Τύπος Εισάγετε το για τελευταία φορά.

• Θα παρατηρήσετε ότι όλες οι τιμές για το CSE τμήμα θα είναι διαθέσιμο.

Ως εκ τούτου, μπορούμε να πούμε ότι όλοι οι τύποι μας λειτουργούν τέλεια και ότι είμαστε σε θέση να λάβουμε όλες τις επιθυμητές τιμές από το Excel ΦΊΛΤΡΟ λειτουργία.

8. Φιλτράρισμα δεδομένων και επιστροφή μόνο συγκεκριμένων στηλών

Εδώ, θα χρησιμοποιήσουμε το ΦΊΛΤΡΟ συνάρτηση δύο φορές σε μια εμφωλευμένη συνθήκη για να πάρουμε τις συγκεκριμένες στήλες με βάση την επιθυμητή τιμή μας. Η επιθυμητή μας οντότητα βρίσκεται στο κελί J5 . Θα δείξουμε μόνο το ID και το Όνομα στήλη.

Τα βήματα αυτής της διαδικασίας παρατίθενται παρακάτω:

📌 Βήματα:

• Πρώτον, επιλέξτε το κελί H8 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0})

• Μετά από αυτό, πατήστε Εισάγετε το .

• Θα λάβετε μόνο το ID και Όνομα στήλη του επιθυμητού μας τμήματος.

Επομένως, μπορούμε να πούμε ότι ο τύπος μας λειτουργεί σωστά και ότι είμαστε σε θέση να πάρουμε κάποιες συγκεκριμένες στήλες από το Excel ΦΊΛΤΡΟ λειτουργία.

🔎 Επεξήγηση του τύπου

👉 FILTER(B5:F14,D5:D14=J5) : Η ΦΊΛΤΡΟ θα επιστρέψει τις γραμμές που ταιριάζουν με το δεδομένο σύνολο δεδομένων με όλες τις στήλες.

👉 FILTER(FILTER(B5:F14,D5:D14=J5),{1,1,0,0,0}) : Το εξωτερικό ΦΊΛΤΡΟ η συνάρτηση θα επιλέξει μόνο το πρώτο δύο στήλες των επιλεγμένων δεδομένων. Μπορούμε είτε να χρησιμοποιήσουμε 0 , 1 ή ΑΛΗΘΙΝΟ , FALSE .

9. Εφαρμογή περιορισμού στον επιστρεφόμενο αριθμό σειρών

Σε αυτή την περίπτωση, θα προσθέσουμε κάποιους περιορισμούς στην ΦΊΛΤΡΟ συνάρτηση για να πάρουμε τον περιορισμένο αριθμό γραμμών. Το επιθυμητό τμήμα μας βρίσκεται στο κελί J5 Για την εφαρμογή του περιορισμού, πρέπει να χρησιμοποιήσουμε το IFERROR και INDEX λειτουργία επίσης.

Τα βήματα αυτού του μαθηματικού συστήματος περιγράφονται ως εξής:

📌 Βήματα:

• Αρχικά, επιλέξτε το κελί H8 .
• Στη συνέχεια, γράψτε τον ακόλουθο τύπο στο κελί.

=IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}),"No result")

• Στη συνέχεια, πατήστε Εισάγετε το .

• Θα έχετε το αποτέλεσμα.

Έτσι, μπορούμε να πούμε ότι είμαστε σε θέση να εφαρμόσουμε με επιτυχία το Excel ΦΊΛΤΡΟ , INDEX , και IFERROR λειτουργεί με επιτυχία.

🔎 Επεξήγηση του τύπου

👉 FILTER(B5:F14,D5:D14=J5) : Η ΦΊΛΤΡΟ η συνάρτηση θα επιστρέψει τα φιλτραρισμένα δεδομένα, αντιστοιχίζοντάς τα με την τιμή εισόδου.

👉 INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}) : Αυτός ο τύπος θα επιστρέψει τις δύο πρώτες γραμμές των δεδομένων που ταιριάζουν. {1;2} αυτό ισχύει για τις δύο πρώτες σειρές. {1,2,3,4,5} αυτό είναι για την επιλογή των πέντε στηλών.

👉 IFERROR(INDEX(FILTER(B5:F14,D5:D14=J5),{1;2},{1,2,3,4,5}), "No result") : Τέλος, η IFERROR χρησιμοποιείται για την αποφυγή του σφάλματος εάν υπάρχει πρόβλημα με τις τιμές επιστροφής άλλων συναρτήσεων.

10. Χρήση Wildcard με τη λειτουργία FILTER

Στο τελευταίο παράδειγμα, θα εφαρμόσουμε το φίλτρο μπαλαντέρ για το φιλτράρισμα των δεδομένων. Θα εφαρμόσουμε τον τύπο με τη βοήθεια του ISNUMBER , ΑΝΑΖΗΤΗΣΗ , και ΦΊΛΤΡΟ Η επιθυμητή τιμή μας βρίσκεται στο κελί J5 .

Η διαδικασία εξηγείται παρακάτω βήμα προς βήμα:

📌 Βήματα:

• Πρώτον, επιλέξτε το κελί H8 , και γράψτε τον ακόλουθο τύπο στο κελί.

=FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "No Results!")

• Τώρα, πατήστε Εισάγετε το .

• Θα λάβετε όλα τα αποτελέσματα με την τιμή του κελιού C .

Τέλος, μπορούμε να πούμε ότι ο τύπος μας λειτουργεί με ακρίβεια και είμαστε σε θέση να δημιουργήσουμε ένα μπαλαντέρ από το Excel ΦΊΛΤΡΟ λειτουργία.

🔎 Επεξήγηση του τύπου

👉 SEARCH(J5,D5:D14) : Η ΑΝΑΖΗΤΗΣΗ η συνάρτηση θα αναζητήσει τα δεδομένα ταιριάζοντας τα με την τιμή εισόδου.

👉 ISNUMBER(SEARCH(J5,D5:D14)) : Αυτός ο τύπος θα ελέγξει ποιο αποτέλεσμα της ΑΝΑΖΗΤΗΣΗ λειτουργία είναι ture,

👉 FILTER($B$5:$F$14,ISNUMBER(SEARCH(J5,D5:D14)), "No Results!") : Τέλος, η ΦΊΛΤΡΟ θα τα εμφανίσει στο επιθυμητό μας κελί.

Εναλλακτικές λύσεις της λειτουργίας FILTER του Excel

Από την προηγούμενη εφαρμογή μας, ίσως παρατηρήσετε ότι το Excel ΦΊΛΤΡΟ είναι μια μικρή εύχρηστη συνάρτηση για να πάρουμε τις επιθυμητές τιμές μας μέσα σε σύντομο χρονικό διάστημα. Δεν υπάρχει συγκεκριμένη εναλλακτική λύση αυτής της συνάρτησης. Ωστόσο, ο συνδυασμός κάποιων γενικών συναρτήσεων του Excel μπορεί να μας επιστρέψει τα αποτελέσματα της συνάρτησης ΦΊΛΤΡΟ Μεταξύ αυτών, η IFERROR , INDEX , ΑΓΚΡΕΓΑΤΟ , ΣΕΙΡΑ , ISNA , ΜΑΤΣ Αλλά, σας συνιστούμε ότι αν έχετε το ΦΊΛΤΡΟ Ο συνδυασμός αυτών των συναρτήσεων θα κάνει τον τύπο πιο πολύπλοκο για να τον κατανοήσουν οι άλλοι. Εκτός αυτού, μπορεί να επιβραδύνει την εφαρμογή του Excel.

Πιθανές αιτίες εάν η λειτουργία FILTER δεν λειτουργεί

Μερικές φορές, η ΦΊΛΤΡΟ λειτουργία του Excel δεν λειτουργεί σωστά. Τις περισσότερες φορές, αυτό συμβαίνει λόγω της παρουσίας σφάλματος. Κυρίως, η #SPILL! , #CALC! , #VALUE! σφάλματα συνήθως δεν επιτρέπουν την ΦΊΛΤΡΟ συνάρτηση για να λειτουργήσει και να επιστρέψει τα επιθυμητά δεδομένα. Για την εξάλειψη αυτού του σφάλματος, επιστρέψτε στο αρχικό σας σύνολο δεδομένων και διορθώστε τα, και θα διαπιστώσετε ότι το ΦΊΛΤΡΟ η λειτουργία θα λειτουργήσει ομαλά.

Τα συχνά εμφανιζόμενα σφάλματα του Excel εξηγούνται παρακάτω συνοπτικά:

Συμπέρασμα

Αυτό είναι το τέλος αυτού του άρθρου. Ελπίζω ότι αυτό το άρθρο θα σας φανεί χρήσιμο και ότι θα είστε σε θέση να εφαρμόσετε τη λειτουργία FILTER στο Excel. Παρακαλούμε μοιραστείτε μαζί μας τυχόν περαιτέρω ερωτήματα ή συστάσεις στην παρακάτω ενότητα σχολίων εάν έχετε περαιτέρω ερωτήσεις ή συστάσεις.

Μην ξεχάσετε να ελέγξετε την ιστοσελίδα μας, ExcelWIKI , για διάφορα προβλήματα και λύσεις που σχετίζονται με το Excel. Συνεχίστε να μαθαίνετε νέες μεθόδους και να εξελίσσεστε!