Sommario
La tecnica più semplice per stabilire la posizione relativa di un numero in un elenco di numeri è quella di ordinare l'elenco in ordine decrescente (dal più grande al più piccolo) o ascendente (dal più piccolo al più grande). In questo articolo, mi concentrerò sui modi di ordinare utilizzando la funzione RANK in Excel sotto diversi aspetti.
Funzione RANK in Excel (visualizzazione rapida)
Nell'immagine seguente, si possono vedere le basi del metodo RANK Si tratta di una sintesi dell'articolo che rappresenta un'applicazione della funzione di Excel. RANK in Excel.
Scarica il quaderno di esercizi
Qui ho messo a disposizione il quaderno di esercizi, che potete scaricare dal link sottostante.
Utilizzo della funzione RANK.xlsxIntroduzione alla funzione RANK
- Funzione Obiettivo:
Il RANK restituisce la posizione di un dato numero in un dato elenco di altri numeri.
- Sintassi:
=RANK (numero, riferimento, [ordine])
- Argomenti Spiegazione:
ARGOMENTO | RICHIESTO/FACOLTATIVO | SPIEGAZIONE |
| numero | Richiesto | Il numero che si vuole classificare. |
| Rif. | Richiesto | È il riferimento (una matrice o un elenco di numeri) che contiene il numero. |
| [ordine] | Opzionale | È il modo di fare classifica. 0 è usato per l'ordine decrescente e 1 viene utilizzato per l'ordine ascendente. |
- Parametro di ritorno:
Restituisce un numero di rango.
6 esempi ideali di utilizzo della funzione RANK in Excel
Per illustrare questo articolo, ho preso il seguente set di dati, che contiene i dati di Nomi di alcuni studenti e dei loro Punteggi ottenuti . lo farò Classifica questi studenti in base alla Punteggi ottenuti utilizzando il RANK in Excel. Vi spiegherò 6 esempi ideali.
1. Utilizzare la funzione RANK in ordine decrescente
In questo primo esempio, utilizzerò il metodo RANK per classificare gli studenti in ordine decrescente. Vediamo come fare.
Passi:
- Per prima cosa, selezionare la cella in cui si vuole mostrare il valore Classifica Qui ho selezionato Cella D5 .
- In secondo luogo, in Cella D5 scrivere la seguente formula.
=RANK(C5,$C$5:$C$15,0) 
- Dopodiché, premere Entrare per ottenere il risultato.
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula.
- Infine, si vedrà che la formula è stata copiata in tutte le altre celle e che si sono ottenuti i voti di ogni studente.
2. Applicare la funzione RANK in ordine crescente in Excel
È anche possibile classificare i valori utilizzando il parametro RANK In questo esempio, vi mostrerò come farlo. La formula sarà la stessa, tranne che per il fatto che 1 sarà utilizzato per il file ordine ascendente Vediamo i passaggi.
Passi:
- All'inizio, selezionare la cella in cui si desidera che il Classifica Qui ho selezionato Cella D5 .
- Poi, in Cella D5 scrivere la seguente formula.
=RANK(C5,$C$5:$C$15,1) 
- Dopodiché, premere Entrare per ottenere il Classifica .
- Successivamente, trascinare il campo Maniglia di riempimento per copiare la formula.
- Qui si può vedere che ho copiato la formula in tutte le altre celle e ho ottenuto una classifica per ogni studente.
3. Impiegare la funzione RANK in cellule non contigue
A volte vi capiterà di dover affrontare una situazione in cui dovrete classificare le celle vuote o non contigue In questo esempio, vi mostrerò come potete classificarvi in questo tipo di situazione utilizzando il metodo RANK Vediamo i passaggi.
Passi:
- Per prima cosa, selezionare la cella in cui si desidera che il Classifica .
- In secondo luogo, scrivete la seguente formula nella cella selezionata.
=IFERROR(RANK(C5,($C$5,$C$6,$C$9:$C$12),0),"") 
- In terzo luogo, premere Entrare e si otterrà il Classifica .
🔎 Come funziona la formula?
- RANK(C5,($C$5,$C$6,$C$9:$C$12),0): Qui, nel RANK ho selezionato la cella C5 come il numero , ($C$5,$C$6,$C$9:$C$12) come il Rif. , e 0 come ordine La formula restituisce il grado della cella C5 nel rif. in ordine decrescente E se non trova il numero nell'intervallo di riferimento, restituisce un errore.
- IFERROR(RANK(C5,($C$5,$C$6,$C$9:$C$12),0),""): Ora, la funzione IFERROR restituisce una stringa vuota se trova un errore, altrimenti restituisce il grado.
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula.
- Infine, si può notare che ho copiato la formula nelle altre celle e ho ottenuto il risultato desiderato.
Letture simili
- Come utilizzare la funzione AVERAGEIFS in Excel (4 esempi)
- Come usare la funzione COUNT in Excel (con 5 esempi)
- I diversi modi di contare in Excel
- Come calcolare la media, la mediana e la modalità in Excel
- Come utilizzare la funzione CORREL in Excel (3 esempi e VBA)
4. Ottenere il valore unico utilizzando la funzione RANK di Excel
Se due numeri sono uguali, il RANK restituisce automaticamente un oggetto rango duplicato Per esempio, se due studenti diversi ottengono gli stessi voti (vedi figura seguente), si troveranno classifiche duplicate per i loro Punteggi ottenuti .
Ora vi mostrerò come potete risolvere questo problema e ottenere una rango unico In questo tipo di situazione, vi mostro i passaggi.
Passi:
- All'inizio, selezionare la cella in cui si desidera che il Classifica .
- Quindi, scrivere la seguente formula nella cella selezionata.
=RANK(C5,$C$5:$C$15,0)+COUNTIF($C$5:C5,C5)-1 
- Quindi, premere Entrare e si otterrà il Classifica .
🔎 Come funziona la formula?
- RANK(C5,$C$5:$C$15,0): Qui, nel RANK ho selezionato la funzione C5 come il numero , C5:C15 come il Rif. , e 0 come il ordine Ora, la formula restituirà il grado del valore nella cella C5 nell'intervallo di celle C5:C15 in ordine decrescente .
- COUNTIF($C$5:C5,C5): Ora, in la funzione COUNTIF , ho selezionato $C$5:C5 come il gamma e C5 come il criteri La formula restituirà il numero di celle nella cartella gamma che corrispondono al criteri .
- RANK(C5,$C$5:$C$15,0)+COUNTIF($C$5:C5,C5)-1: Infine, questa formula somme i risultati ottenuti da questi 2 e poi sottrae 1 dal sommatoria .
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula nelle altre celle.
- Alla fine, si vedrà che la formula è stata copiata nelle altre celle e che si è ottenuta la formula Classifica unica .
5. Utilizzare la funzione RANK per rompere i legami in Excel
In alcuni casi, non è possibile applicare il metodo precedente per ottenere un rango unico È necessario rompere i legami basato su criteri secondari .
Assumendo che la percentuale di Presenza per ogni studente. Nell'immagine seguente, si può vedere che il set di dati contiene sia Punteggi ottenuti e Presenza Se uno studente ha più Presenza sarà in vantaggio rispetto all'altro che ha lo stesso punteggio, ma ha meno Presenza .
Vediamo come ottenere il grado utilizzando un tie-break.
Passi:
- Per prima cosa, selezionare la cella in cui si desidera che il Classifica sulla base del criteri primari .
- Quindi, scrivere la seguente formula nella cella selezionata.
=RANK(C5,$C$5:$C$15,0) 
- Successivamente, premere Entrare per ottenere il Classifica .
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula nelle altre celle.
- Successivamente, si può vedere che ho un Classifica per ogni studente.
- Successivamente, selezionare la cella in cui si desidera ottenere il valore Tie Break Qui ho selezionato Cella F5 .
- Poi, in Cella F5 scrivere la seguente formula.
=IF(COUNTIF($C$5:$C$15,C5)>1,RANK(D5,$D$5:$D$15,1)/100,0) 
- Successivamente, premere Entrare per ottenere il risultato.
🔎 Come funziona la formula?
- COUNTIF($C$5:$C$15,C5): Qui, nel COUNTIF ho selezionato l'intervallo di celle C5:C15 come il gamma e cella C5 come il criteri La formula restituisce il numero di celle dell'intervallo selezionato che corrispondono ai criteri indicati.
- RANK(D5,$D$5:$D$15,1): Ora, nel RANK ho selezionato la cella D5 come il numero , D5:D15 come il Rif. , e 1 come il ordine La formula classifica i valori in ordine ascendente .
- RANK(D5,$D$5:$D$15,1)/100: Qui, il risultato ottenuto con il metodo RANK è diviso per 100 .
- IF(COUNTIF($C$5:$C$15,C5)>1,RANK(D5,$D$5:$D$15,1)/100,0): Infine, la funzione IF controlla se il valore ottenuto da COUNTIF è maggiore di 1 . se il test_logico è Vero poi va nel RANK Altrimenti, restituisce 0 .
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula nelle altre celle.
- Qui si può vedere che ho copiato la formula in tutte le celle e ho ottenuto il risultato desiderato.
- Successivamente, determinerò il Classifica finale dal Classifica e il Tie Break .
- Per farlo, selezionare Cellula G5 .
- Poi, in Cellula G5 scrivere la seguente formula.
=E5+F5 
- Successivamente, premere Entrare per ottenere il risultato.
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula nelle altre celle.
- Infine, si può vedere che ho copiato la formula in tutte le celle e ho ottenuto la formula Classifica finale utilizzando un Legare Pausa .
6. Applicare la funzione RANK ignorando gli zeri in Excel
In questo esempio, vi mostrerò come potete Classifica valori ignorando gli zeri Per questo esempio ho preso il seguente set di dati che contiene Mese e Profitto . il profitti negativi significare un perdita e zeri significare un pareggio Utilizzerò il programma Excel RANK per classificare il Profitti ignorando gli zeri .
Vediamo i passaggi.
Passi:
- Per prima cosa, selezionare la cella in cui si desidera che il Classifica Qui ho selezionato Cella D5 .
- In secondo luogo, in Cella D5 scrivere la seguente formula.
=IF(C5=0,"",IF(C5>0,RANK(C5,$C$5:$C$16,0),RANK(C5,$C$5:$C$16,0)-COUNTIF($C$5:$C$16,0)) 
- In terzo luogo, premere Entrare per ottenere il risultato.
🔎 Come funziona la formula?
- RANK(C5,$C$5:$C$16,0): Qui, il RANK restituisce la funzione Classifica di cella C5 nell'intervallo di celle C5:C15 in ordine decrescente .
- COUNTIF($C$5:$C$16,0): Ora, nel COUNTIF ho selezionato l'intervallo di celle C5:C15 come il gamma e 0 come il criteri La formula restituirà il numero di celle che corrispondono ai criteri.
- RANK(C5,$C$5:$C$16,0)-COUNTIF($C$5:$C$16,0): In questo caso, la formula sottrarre il risultato ottenuto dal COUNTIF dal risultato ottenuto dalla funzione RANK funzione.
- IF(C5>0,RANK(C5,$C$5:$C$16,0),RANK(C5,$C$5:$C$16,0)-COUNTIF($C$5:$C$16,0)): Ora, il SE controlla se il valore nella cella C5 è maggiore di 0 . se il test_logico è Vero restituirà il risultato del metodo RANK Altrimenti, restituirà il risultato della funzione RANK e il COUNTIF funzione.
- IF(C5=0,"",IF(C5>0,RANK(C5,$C$5:$C$16,0),RANK(C5,$C$5:$C$16,0)-COUNTIF($C$5:$C$16,0)): Infine, questo SE controlla se il valore nella cella C5 è 0 . se il test_logico è Vero la formula restituirà un valore stringa vuota Altrimenti, si passerà al secondo Funzione IF .
- Successivamente, trascinare il file Maniglia di riempimento per copiare la formula.
- Qui si può vedere che ho copiato la formula nelle altre celle e ho ottenuto il risultato desiderato.
Errori comuni nell'uso della funzione RANK in Excel
| Errori comuni | Quando si presentano |
| #N/A | Si verifica quando il numero dato che si vuole trovare non è disponibile nel riferimento (l'elenco dei numeri). |
Cose da ricordare
- Microsoft avverte che il RANK La funzione potrebbe non essere più disponibile in futuro, in quanto sono state sviluppate nuove e migliori funzioni per classificare con maggiore precisione e utilizzo.
- Se si omette l'ordine (poiché è un argomento facoltativo) durante l'inserimento del file RANK la funzione ordina automaticamente in ordine decrescente.
Conclusione
Sono giunto alla fine del mio articolo, in cui ho cercato di coprire i diversi utilizzi di RANK Se si dispone di un metodo interessante e unico per utilizzare la funzione RANK funzione, condividetela nella sezione commenti qui sotto.
Grazie per essere stato con me.
