Cara SUMIF antara Dua Tarikh dan dengan Kriteria Lain (7 Cara)

Hugh West

18-10-2023 Formula Excel
  • Berkongsi Ini
Hugh West

Jika anda mencari beberapa cara termudah untuk SUMIF antara dua tarikh dan kriteria lain, maka anda akan mendapati artikel ini berguna. Menambah nilai dalam had tempoh masa dan berdasarkan kriteria perlu dilakukan kadangkala dan untuk melakukan tugas ini dengan cepat, anda boleh mengikuti artikel ini.

Muat Turun Buku Kerja

SUMIF antara Tarikh.xlsm

7 Cara untuk SUMIF antara Dua Tarikh dan dengan Kriteria Lain

Di sini, kami mempunyai set data berikut yang mengandungi rekod jualan beberapa produk dengan anggaran tarikh penghantarannya dan kawasan jualan syarikat. Menggunakan set data ini, kami akan menunjukkan cara menjumlahkan nilai jualan berdasarkan rantau dan julat tarikh yang ditentukan.

Kami telah menggunakan versi Microsoft Excel 365 di sini, anda boleh menggunakan mana-mana versi lain mengikut keselesaan anda.

Kaedah-1: Menggunakan Fungsi SUMIFS untuk SUMIF antara Dua Tarikh dengan Kriteria Lain

Kami ingin merumuskan nilai jualan untuk Timur Wilayah dan untuk tarikh antara 1/10/2022 dan 3/20/2022 (m-dd-yyyy) dengan menggunakan fungsi SUMIFS di sini.

Langkah :

➤ Taip formula berikut dalam sel E14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")

Di sini, E4:E11 ialah julat jualan yang nilainya ingin kami jumlahkan, C4:C11 ialah julat tarikh untuk kriteria pertama, “>=”&B14 ialah kriteria pertamayang bermaksud lebih besar daripada atau sama dengan tarikh mula 1/10/2022 . Julat kriteria kedua adalah serupa dengan yang pertama dan kriteria untuk julat ini ialah “<=”&C14 yang bermaksud kurang daripada atau sama dengan tarikh tamat 3/20/2022 dan julat kriteria terakhir ialah D4:D11 mengandungi wilayah, kriteria untuk julat ini ialah Timur .

➤ Tekan ENTER .

Kini, anda akan mendapat jumlah jualan $13,806.00 untuk julat tarikh kami yang ditentukan dengan kriteria lain: Timur Wilayah .

Baca Lagi: Cara Melakukan Bulan Julat Tarikh SUMIF dalam Excel (9 Cara)

Kaedah-2: Menggunakan SUMIFS dan EOMONTH untuk SUMIF antara Dua Tarikh dengan Kriteria Lain

Dalam bahagian ini, kami akan cuba mencari jumlah nilai jualan untuk tarikh Januari bulan dan Selatan Wilayah . Jadi, kami akan menggunakan Fungsi EOMONTH dengan fungsi SUMIFS di sini.

Langkah :

➤ Taip formula berikut dalam sel D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)

Di sini, E4:E11 ialah julat jualan yang nilainya kita mahu jumlahkan, C4:C11 ialah julat tarikh untuk kriteria pertama, “>=”&B14 ialah kriteria pertama yang bermaksud lebih besar daripada atau sama dengan tarikh mula 1/1/2022 . Julat kriteria kedua adalah serupa dengan yang pertama dan yangkriteria untuk julat ini ialah “<=”&EOMONTH(B14,0) yang bermaksud kurang daripada atau sama dengan tarikh tamat Januari bulan, 1/31/2022 , dan julat kriteria terakhir ialah D4:D11 mengandungi wilayah, kriteria untuk julat ini ialah Timur .

➤ Tekan ENTER .

Selepas itu, anda akan mendapat jumlah jualan, $6,835.00 untuk tarikh Januari bulan dengan kriteria lain: Selatan Wilayah .

Baca Lagi: Cara Menggunakan SUMIFS kepada Nilai SUM dalam Julat Tarikh dalam Excel

Kaedah-3: SUMIFS dan DATE Berfungsi untuk SUMIF antara Dua Tarikh

Di sini, kita akan menggunakan fungsi SUMIFS dan DATE fungsi , untuk meringkaskan, nilai jualan untuk Utara Wilayah dan untuk tarikh dalam 1/10/2022 dan 20/3/2022 .

Langkah :

➤ Taip formula berikut dalam sel E14 .

=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)

Di sini, E4: E11 ialah julat jualan yang nilainya ingin kami jumlahkan, C4:C11 ialah julat tarikh untuk kriteria pertama dan kedua, dan julat kriteria terakhir ialah D4:D11 mengandungi kawasan.

  • ">="&DATE(2022,1,10) menjadi

    ">= 44571"

  • DATE(2022,3,20) → mengembalikan nombor nilai tarikh

    Output → 44640

  • "<="&DATE(2022,3,20) menjadi

    "<= 44640"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) menjadi

    SUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”) → menyemak jika nilai tarikh julat C4:C11 lebih besar daripada atau sama dengan 44571 dan kurang daripada atau sama dengan 44640 dan rantau Utara dalam julat D4:D11

    Output → $9,496.00

➤ Tekan ENTER .

Kemudian, anda akan mendapat jumlah jualan, $9,496.00 untuk julat tarikh kami yang ditentukan dengan kriteria lain: Utara Wilayah .

Kandungan Berkaitan: Cara Menggunakan Formula IF untuk Julat Tarikh dalam Excel (6 Kaedah)

Bacaan Serupa:

  • Cara Menetapkan Peringatan Tarikh Akhir dalam Excel (3 Kaedah Pantas)
  • Gunakan Jadual Pangsi untuk Menapis Julat Tarikh dalam Excel (5 Cara)
  • Julat Tarikh dan Nilai Pulangan VLOOKUP dalam Excel (4 Kaedah yang Sesuai)
  • Cara Mengira Purata Jika dalam Julat Tarikh dalam Excel (3 Cara)

Kaedah-4: Menggunakan Fungsi SUMIFS dengan TODAY

S andaikan, anda ingin mendapatkan jumlah nilai jualan untuk tarikh antara 1/1/2022 dan tarikh hari ini ( 3/23/2022 ) dan untuk Timur Wilayah . Dan, untuk melakukan ini, anda boleh menggunakan fungsi HARI INI bersama-sama dengan fungsi SUMIFS .

Langkah :

➤ Taip formula berikut dalam sel D14 .

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)

Di sini, E4:E11 ialah julat jualan yangnilai yang ingin kami jumlahkan, C4:C11 ialah julat tarikh untuk kriteria pertama dan kedua, dan julat kriteria terakhir ialah D4:D11 mengandungi wilayah.

  • ">="&B14 menjadi

    ">= 44562"

  • TODAY() → mengembalikan tarikh hari ini

    Output → 44643 (3/23/2022)

  • "<="&TODAY() menjadi

    "<= 44643"

  • SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14) menjadi

    SUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”) → menyemak sama ada nilai tarikh julat C4:C11 lebih besar daripada atau sama dengan 44562 dan kurang daripada atau sama dengan 44643 dan wilayah Timur dalam D4: D11 julat

    Output → $15,208.00

➤ Tekan ENTER .

Akhir sekali, anda akan mendapat jumlah jualan iaitu $15,208.00 untuk tarikh antara hari pertama Januari 2022 dan tarikh hari ini dengan kriteria: Timur Wilayah .

Jika anda ingin menukar tarikh terakhir tarikh julat dari tarikh hari ini hingga 10 hari sebelum tarikh hari ini kemudian gunakan formula berikut

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)

Untuk tarikh terakhir sebagai tarikh 10 hari selepas tarikh hari ini

=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)

Baca Lagi: Excel VBA: Tapis Tarikh sebelum Hari Ini (Dengan Langkah Pantas)

Kaedah-5: Gabungan Fungsi SUM dan IF kepada SUMIF antara Dua Tarikh dan dengan Kriteria Lain

Anda boleh menggunakan gabungan fungsi SUM dan Fungsi IF kepadahitung jumlah jualan untuk tarikh antara 1/10/2022 hingga 3/20/2022 dan untuk Timur Wilayah .

Langkah :

➤ Taip formula berikut dalam sel E14 .

=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))

Di sini, E4:E11 ialah julat jualan yang nilainya ingin kita jumlahkan, C4 :C11 ialah julat tarikh untuk kriteria pertama dan kedua, dan julat kriteria terakhir ialah D4:D11 mengandungi wilayah.

  • IF((C4:C11)>=B14 → menyemak sama ada nilai tarikh julat C4:C11 lebih besar daripada atau sama dengan nilai B14 .

    Output → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • IF((C4:C11)<=C14 → menyemak sama ada nilai tarikh julat C4:C11 kurang daripada atau sama dengan nilai C14 .

    Output → {TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}

  • IF(D4:D11=D14,E4:E11) → menyemak sama ada kawasan daripada julat D4:D11 sama dengan rantau Timur C14 dan mengembalikan

    ({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)

    Output → {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))) menjadi

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE} , SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) , {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    → {FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

    Output → {FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}

  • SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))) menjadi

    SUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})

    Output → $13,806.00

➤ Tekan ENTER .

Akhirnya, anda akan mendapat jumlah jualan, $13,806.00 untuk julat tarikh kami yang ditentukan dengan kriteria lain: Timur Wilayah .

Kandungan Berkaitan: SUMIF Excel dengan Julat Tarikh dalam Bulan &Tahun (4 Contoh)

Kaedah-6: Menggunakan Fungsi SUMPRODUCT, MONTH dan YEAR

Di sini, kita akan menggunakan fungsi SUMPRODUCT , iaitu Fungsi BULAN dan fungsi TAHUN untuk meringkaskan nilai jualan untuk tarikh Januari bulan dan Timur Wilayah.

Langkah :

➤ Taip formula berikut dalam sel E14 .

=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)

Di sini, E4:E11 ialah julat jualan yang nilainya ingin kita jumlahkan, C4:C11 ialah julat tarikh untuk kriteria pertama dan kedua, dan julat kriteria terakhir ialah D4:D11 mengandungi wilayah.

  • MONTH(C4:C11) → BULAN mengembalikan nombor bulan tarikh

    Output → {1;1;1;2;2;3;3;3}

  • MONTH(C4:C11)=1 menjadi

    {1;1;1;2;2;3;3;3}=1

    Output → {TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}

  • YEAR(C4:C11) → mengembalikan nilai tahun tarikh

    Output → {2022;2022;2022;2022;2022;2022;2022;2022}

  • YEAR(C4:C11)=2022 menjadi

    {2022;2022;2022;2022;2022;2022;2022;2022}=2022

    Output → {TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}

  • D4:D11=D14 → menyemak jika kawasan julat D4:D11 sama dengan rantau Timur C14

    Output → {TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}
  • SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11) menjadi

    → SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)

    → SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11)  SUMPRODUCT({1402;5935;0;0;0;0;0;0})

    Output → $7,337.00

➤ Tekan ENTER .

Selepas itu, anda akan mendapat jumlah daripada jualan, $7,337.00 untuk Januari bulan dengan kriteria lain: Timur Wilayah .

Baca Lagi: Excel SUMIF dengan Julat Tarikh dalam Bulan & Tahun (4 Contoh)

Kaedah-7: Kod VBA ke SUMIF antara Dua Tarikh dengan Kriteria Berbeza

Kami akan menggunakan kod VBA di sini untuk melaksanakan pengiraan jumlah nilai jualan antara dua tarikh 1/10/2022 dan 3/20/2022 dengan kriteria Timur Wilayah .

Langkah :

➤ Pergi ke Pembangun Tab >> Visual Basic Pilihan.

Kemudian, Visual Basic Editor akan dibuka .

➤ Pergi ke Sisipkan Tab >> Modul Pilihan.

Selepas itu, Modul akan dibuat.

➤ Tulis kod berikut

8994

Kami akan mendapat nilai kami dalam sel E14 dan DATEVALUE akan menukar rentetan tarikh kepada nilai tarikh dan kemudian selepas memenuhi kriteria SUMIFS akan mengembalikan nilai jualan tambahan dalam sel E14 .

➤ Tekan F5 .

Akhir sekali, anda akan mendapat jumlah jualan sebanyak $13,806.00 untuk julat tarikh kami yang ditentukan dengan kriteria lain: Timur Wilayah .

Baca Lagi: Cara Menggunakan SUMIFS dengan Julat Tarikh dan Pelbagai Kriteria (7 Cara Pantas)

Bahagian Amalan

Untuk melakukan latihan sendiri, kami telah menyediakan bahagian Amalan seperti di bawah dalam helaian bernama Berlatih . Tolong buatsendiri.

Kesimpulan

Dalam artikel ini, kami cuba membincangkan cara untuk SUMIF antara dua tarikh dan kriteria lain dengan mudah . Harap anda akan mendapati ia berguna. Jika anda mempunyai sebarang cadangan atau soalan, sila kongsikannya di bahagian komen.

Catatan sebelum ini Cara Membahagi Helaian Excel kepada Pelbagai Lembaran Kerja (3 Kaedah) -
Post seterusnya Cara Mengira Purata Wajaran dengan Peratusan dalam Excel

Hugh West ialah jurulatih dan penganalisis Excel yang sangat berpengalaman dengan lebih 10 tahun pengalaman dalam industri. Beliau memiliki Ijazah Sarjana Muda Perakaunan dan Kewangan serta Ijazah Sarjana dalam Pentadbiran Perniagaan. Hugh mempunyai minat untuk mengajar dan telah membangunkan pendekatan pengajaran yang unik yang mudah diikuti dan difahami. Pengetahuan pakar Excel beliau telah membantu beribu-ribu pelajar dan profesional di seluruh dunia meningkatkan kemahiran mereka dan cemerlang dalam kerjaya mereka. Melalui blognya, Hugh berkongsi pengetahuannya dengan dunia, menawarkan tutorial Excel percuma dan latihan dalam talian untuk membantu individu dan perniagaan mencapai potensi penuh mereka.