Hoe te gebruiken INDEX MATCH formule in Excel (9 voorbeelden)

Hugh West

16-10-2023 Excel Formules
  • Deel Dit
Hugh West

Af en toe moeten we zoeken naar specifieke informatie in onze grote Excel werkblad. Maar het is vermoeiend om er handmatig naar te zoeken. Een formule die samenwerkt de functies INDEX en MATCH kan het geweldige werk van gegevens zoeken heel gemakkelijk doen. Het kan ook geavanceerde lookups uitvoeren. In dit artikel laten we je de eenvoudige en effectieve manieren zien om Gebruik de INDEX MATCH Formule in Excel.

Ter illustratie gebruiken we een voorbeeld dataset. De volgende dataset vertegenwoordigt bijvoorbeeld de Verkoper , Product en Netto verkoop van een bedrijf.

Download Praktijk Werkboek

Download het volgende werkboek om zelf te oefenen.

Gebruik van INDEX-MATCH.xlsx

Inleiding tot de INDEX-functie

  • Syntax

INDEX(array, rij_getal,[kolom_getal])

  • Argumenten

array: Het bereik waar de gegevens vandaan komen.

row_num: Het rijnummer van de te retourneren gegevens.

[column_num]: Het kolomnummer van de te retourneren gegevens.

  • Doelstelling

De INDEX-functie haalt de celwaarde of referentie op van de cel op het snijpunt van een bepaalde rij en kolom in een bepaald bereik.

In de volgende dataset, Nate Sales 17000 is aanwezig in de 4e rij en 3e kolom in het bereik B5:D10 .

Inleiding tot de MATCH-functie

  • Syntax

MATCH(lookup_value,lookup_array,[match_type])

  • Argumenten

lookup_value: De waarde waarnaar moet worden gezocht in het gegevensbereik.

lookup_array : Het gegevensbereik van waaruit wordt gezocht naar de lookup_waarde .

[match_type]: - 1/0/1 . -1 staat voor een waarde groter dan de exacte overeenkomst, 0 voor een exacte overeenkomst, en 1 voor de waarde minder dan de exacte overeenkomst.

  • Doelstelling

De MATCH-functie geeft de relatieve positie van de lookup_waarde in een matrix.

In de onderstaande dataset is de F4 celwaarde is Frank ( lookup_waarde ) en Frank is aanwezig in de 3e positie in de Verkoper sectie ( B5:B10 ). Dus het retourneert 3 .

9 Voorbeelden van het gebruik van de INDEX MATCH formule in Excel

Nu maken we een formule die de twee functies combineert. We weten al dat de INDEX functie heeft rij- en kolomnummers nodig om gegevens op te halen, terwijl de MATCH De functie geeft de locatie van de gegevens weer. We kunnen dus gemakkelijk hun argument plaatsen om de rij- en kolomnummers te krijgen.

In de volgende dataset zijn de INDEX functie zal de gegevens halen uit B5:D10 . de MATCH functie geeft rijnummer terug 3 en we hebben het kolomnummer gespecificeerd. Dus de formule zal de gegevens die aanwezig zijn in de 3e rij en 3e kolom in de reeks.

1. Opzoeken in twee richtingen met INDEX MATCH in Excel

Twee-weg lookup betekent het ophalen van zowel het rijnummer als het kolomnummer met behulp van de MATCH functie die nodig is voor de INDEX functie. Volg daarom de onderstaande stappen om de taak uit te voeren.

STAPPEN:

  • Selecteer eerst de cel F6 .
  • Typ dan de formule:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

  • Druk tenslotte op Ga naar en het geeft de waarde terug.

🔎 Hoe werkt de formule?

  • MATCH(F5,B5:B10,0)

De MATCH formule keert terug 3 naar INDEX als rijnummer.

  • MATCH(F4,B4:D4,0))

Deze MATCH formule keert terug 3 naar INDEX als kolomnummer.

  • INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

Tot slot INDEX functie retourneert 13500 die in de 3e rij en 3e kolom in het bereik B5:D10 .

Lees meer: SUMPRODUCT met INDEX en MATCH functies in Excel

Het grote voordeel van de INDEX MATCH formule is dat het gegevens kan ophalen van de linkerkant van de lookup waarde. Dus, leer de stappen om de operatie uit te voeren.

STAPPEN:

  • Selecteer eerst de cel F5 .
  • Vervolgens typt u de formule:
=INDEX(B5:B10,MATCH(F4,C5:C10,0))

  • Druk tenslotte op Ga naar en het geeft de waarde terug.

Hier geeft de formule de Verkoper naam die links van de opzoekwaarde staat Kabel .

🔎 Hoe werkt de formule?

  • MATCH(F4,C5:C10,0)

De MATCH formule keert terug 1 naar INDEX als rijnummer.

  • INDEX(B5:B10,MATCH(F4,C5:C10,0))

Tot slot INDEX functie retourneert Wilham die in de 1e rij in het bereik B5:B10 .

Lees meer: Hoe te gebruiken INDEX MATCH formule in Excel (9 voorbeelden)

3. Hoofdlettergevoelig opzoeken met de formule INDEX MATCH

De MATCH functie is standaard niet hoofdlettergevoelig. We kunnen echter het volgende toepassen de EXACTE functie op te zoeken die hoofd- en kleine letters respecteert. Volg dus het proces om Gebruik de formule INDEX MATCH om te presteren Zaak - Gevoelig opzoeken in Excel .

STAPPEN:

  • Selecteer in het begin de cel F5 .
  • Typ daarna de formule:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

  • Druk uiteindelijk op Ga naar om de waarde terug te geven.

🔎 Hoe werkt de formule?

  • EXACT(F4,B5:B10)

De EXACT functie retourneert WARE alleen voor de eerste gegevens ( B5 ) in de reeks B5:B10 en FALSE voor anderen.

  • MATCH(TRUE,EXACT(F4,B5:B10),0)

Deze MATCH formule keert terug 1 naar INDEX als rijnummer.

  • INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

Tot slot INDEX functie retourneert 2600 die in de 1e rij in het bereik D5:D10 .

Lees meer: Voorbeelden met INDEX-MATCH formule in Excel (8 benaderingen)

4. Gebruik INDEX MATCH voor de dichtstbijzijnde overeenkomst.

Soms krijgen we niet de exacte match van een lookup waarde in de lookup array. In dat geval willen we zoeken naar de dichtstbijzijnde match. Dat gebeurt vooral met numerieke lookup waarden. Leer nu het proces om de Dichtstbijzijnde wedstrijd met behulp van de INDEX MATCH formule.

STAPPEN:

  • Selecteer cel F5 eerst.
  • Typ dan de formule:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

  • Druk tenslotte op Ga naar .

🔎 Hoe werkt de formule?

  • ABS (D5:D10-F4)

Ten eerste trekt de formule de F4 celwaarde uit het bereik D5:D10 om de verschillen te genereren en we gebruiken de ABS-functie om de negatieve resultaten om te zetten in positieve.

  • MIN(ABS(D5:D10-F4))

Dan, de MIN-functie geeft het kleinste verschil terug dat 500 .

  • MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)

MIN(ABS(D5:D10-F4)) De output van de formule is de opzoekwaarde ( 500 ) voor de MATCH functie en de lookup array is ABS (D5:D10-F4) formule outputs.

  • INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

Uiteindelijk is de INDEX functie retourneert Router omdat het de dichtstbijzijnde Netto verkoop tot 5000 .

5. Opzoeken van meerdere criteria met de formule INDEX MATCH

Een van de nuttigste operaties met de INDEX MATCH formule is dat het een lookup kan uitvoeren op basis van meerdere voorwaarden. Volg de onderstaande stappen om te zien hoe we de Netto verkoop gebaseerd op Verkoper naam en Product .

STAPPEN:

  • Kies eerst de cel F6 om de formule in te typen:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

  • Druk vervolgens op Ga naar en je krijgt het resultaat.

🔎 Hoe werkt de formule?

  • MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)

De MATCH formule keert terug 2 naar INDEX Hier vergelijken we de meerdere criteria door booleaanse logica toe te passen.

  • INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

Tot slot INDEX functie retourneert 11500 die in de 2e rij in het bereik D5:D10 .

Lees meer: Hoe de INDEX-MATCH formule in Excel gebruiken om meerdere resultaten te genereren

Vergelijkbare lezingen

  • Meerdere criteria in Excel met de functie INDEX, MATCH en COUNTIF
  • Werkbladfuncties INDEX & MATCH gebruiken in Excel VBA
  • Excel Index Enkele/meerdere criteria matchen met enkele/meerdere resultaten
  • INDEX MATCH over meerdere bladen in Excel (met alternatief)
  • SUMIF met de functies INDEX en MATCH in Excel

6. Excel INDEX MATCH Formule met jokertekens

We kunnen een sterretje ( * ), die een Jokerteken om de gedeeltelijke overeenkomst voor een opzoekwaarde te vinden. Zie het onderstaande voorbeeld om de taak uit te voeren. We hebben Nat in de cel F4 Er is geen Verkoper met die naam, maar we hebben Nathan wat een gedeeltelijke overeenkomst is.

STAPPEN:

  • Selecteer eerst de cel F5 .
  • Daarna typ je de formule:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

  • Druk tenslotte op Ga naar en het zal de Netto verkoop van Nathan .

🔎 Hoe werkt de formule?

  • MATCH(F4&"*",B5:B10,0)

F4&"*" is onze opzoekwaarde waarbij het sterretje een jokerteken is dat een willekeurig aantal tekens vertegenwoordigt die beginnen met Nat De formule geeft als resultaat 4 .

  • INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

Tot slot INDEX functie retourneert 17000 die in de 4e rij in het bereik D5:D10 .

Lees meer: INDEX MATCH meerdere criteria met jokerteken in Excel (een complete gids)

7. INDEX MATCH toepassen voor drievoudig zoeken in Excel

Het geavanceerde gebruik van de INDEX MATCH formule gaat over het uitvoeren van een Drieweg Een andere syntaxis van de INDEX functie is:

INDEX (array, row_num, [col_num], [area_num])

Waar, [area_num] ( Optioneel ) betekent Als het array-argument uit meerdere bereiken bestaat, zal dit getal de specifieke verwijzing uit alle bereiken selecteren.

In dit voorbeeld gebruiken we dit optionele argument om de gewenste gegevens van een van de maanden van Januari , Februari en Maart Volg daarom de onderstaande stappen om Gebruik de INDEX MATCH Formule in Excel voor Drieweg Kijk op .

STAPPEN:

  • Kies eerst de cel F7 om de formule in te typen:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januari",1,IF(F4="Februari",2,3))))

  • Druk vervolgens op Ga naar Zo zie je de uitvoer.

🔎 Hoe werkt de formule?

  • IF(F4="januari",1,IF(F4="februari",2,3))

De IF-functie zal terugkeren 2 als onze gegeven maand is Februari . de INDEX functie zal de waarde ophalen uit de 2e reeks, d.w.z. Februari .

  • MATCH(F6,B5:D5,0)

De MATCH functie retourneert 3 .

  • MATCH(F5,B6:B7,0)

Deze MATCH functie retourneert 2 .

  • INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januari",1,IF(F4="Februari",2,3))))

Tot slot INDEX functie retourneert 12500 die op het snijpunt ligt van de 3e kolom en 2e rij van de 2e array.

Lees meer: Hoe INDEX MATCH gebruiken in plaats van VLOOKUP in Excel (3 manieren)

8. De waarden van de hele rij/kolom ophalen met de formule INDEX MATCH

Een andere toepassing van de INDEX MATCH De formule haalt gegevens op uit de hele rij of kolom. Leer dus de procedure om de bewerking uit te voeren.

STAPPEN:

  • Selecteer in het begin de cel F5 Typ hier de formule:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

  • Druk daarna op Ga naar en het zal de gegevens van de gehele 3e rij in het bereik B5:D10 .

🔎 Hoe werkt de formule?

  • MATCH(F4,B5:B10,0)

De MATCH formule keert terug 3 naar INDEX als rijnummer.

  • INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

De INDEX functie retourneert alle waarden in de 3e rij in het bereik B5:D10 .

Lees meer: Indexwedstrijd som meerdere rijen op in Excel (3 manieren)

9. Zoek een overeenkomst bij benadering met behulp van INDEX MATCH

De INDEX MATCH formule is zeer nuttig bij het vinden van de benaderde overeenkomst. In dit voorbeeld vinden we het product voor een benaderde Netto verkoop van 6000 Dus, volg het proces.

STAPPEN:

  • Klik eerst op cel F5 .
  • Typ dan de formule:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

  • Druk tenslotte op Ga naar .

OPMERKING: De gegevens moeten in Oplopend of Aflopend om deze formule te laten werken.

🔎 Hoe werkt de formule?

  • MATCH(F4,D5:D10,1)

De MATCH formule gebruikt 1 als het match type argument dat de grootste waarde teruggeeft die kleiner of gelijk is aan de lookup waarde. 6000 Hier, zal het terugkeren 2 .

  • INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

De INDEX functie geeft een Router die in de 2e rij in het bereik C5:C10 .

Lees meer: Hoe INDEX en Match te gebruiken voor gedeeltelijke overeenstemming (2 manieren)

Waarom is INDEX MATCH voordeliger dan VLOOKUP?

1. De formule INDEX MATCH kijkt naar beide linker- en rechterzijden van de opzoekwaarde.

De VLOOKUP-functie kan geen gegevens ophalen van de linkerkant van de lookup waarde. Maar de INDEX MATCH formule kan doen.

2. INDEX MATCH werkt met verticale en horizontale bereiken

VLOOKUP kan alleen gegevens ophalen uit een verticale array, terwijl de INDEX MATCH kan zowel verticale als horizontale gegevens doorlopen.

3. VLOOKUP mislukt met aflopende gegevens

De VLOOKUP functie kan niet omgaan met gegevens in aflopende volgorde als het gaat om de benaderde overeenkomst.

4. Formule met INDEX MATCH is iets sneller

VLOOKUP is een wat tragere functie als je met te veel rijen en kolommen werkt.

5. Onafhankelijk van de werkelijke kolompositie

VLOOKUP is niet onafhankelijk van de actuele positie van de kolom. Dus, wanneer u een kolom verwijdert, zal de VLOOKUP functie zal een onjuist resultaat opleveren.

6. VLOOKUP is niet moeilijk te gebruiken

De VLOOKUP functie is gemakkelijker te gebruiken dan de INDEX MATCH functies. En de meeste van onze opzoekingen kunnen worden gedaan met VLOOKUP gemakkelijk.

Lees meer: INDEX MATCH vs VLOOKUP-functie (9 voorbeelden)

Conclusie

Voortaan kunt u Gebruik de INDEX MATCH Formule in Excel Blijf ze gebruiken en laat ons weten of je nog meer manieren hebt om de taak uit te voeren. Vergeet niet om opmerkingen, suggesties of vragen te plaatsen in de commentaarsectie hieronder.

Vorige post Rijen tellen met VBA in Excel (5 manieren)
Volgende bericht Tekst in Excel-bereik zoeken en celverwijzing teruggeven (3 manieren)

Hugh West is een zeer ervaren Excel-trainer en -analist met meer dan 10 jaar ervaring in de branche. Hij heeft een bachelor in Accounting en Finance en een master in Business Administration. Hugh heeft een passie voor lesgeven en heeft een unieke lesaanpak ontwikkeld die gemakkelijk te volgen en te begrijpen is. Zijn deskundige kennis van Excel heeft duizenden studenten en professionals over de hele wereld geholpen hun vaardigheden te verbeteren en uit te blinken in hun carrière. Via zijn blog deelt Hugh zijn kennis met de wereld en biedt hij gratis Excel-tutorials en online trainingen aan om individuen en bedrijven te helpen hun volledige potentieel te bereiken.