جدول المحتويات
أثناء العمل بكميات كبيرة من البيانات في Excel ، قد تجد نفسك أحيانًا في موقف تحتاج فيه إلى البحث عن القيم التي تظهر عدة مرات في مجموعة البيانات الخاصة بك. لذا ، عليك أن ترى هذه البيانات في خلية واحدة. في هذا البرنامج التعليمي ، سوف نوضح لك كيفية استخدام VLOOKUP لقيم متعددة في خلية واحدة في Excel.
بشكل عام ، نحن لا نستخدم وظيفة VLOOKUP هنا مباشرة. سنجد قيمًا متعددة في خلية واحدة ستكون مشابهة لوظيفة VLOOKUP. نأمل أن تجد هذا البرنامج التعليمي مفيدًا.
تنزيل Practice Workbook
Vlookup Multiple Values in One Cell.xlsm2 طرق سهلة للبحث عن قيم متعددة في خلية واحدة
الآن ، سنعرض لك طريقتين للبحث عن قيم متعددة في خلية واحدة في Excel. الأول يستخدم الصيغ والثاني يستخدم أكواد VBA . سنبحث عن القيم المكررة وغير المكررة في هذه المقالة. لذلك ، يمكنك اختيار الطريقة الأنسب وفقًا لمشكلتك.
لتوضيح هذه المشكلة ، سنستخدم مجموعة البيانات التالية:
هنا ، لدينا بعض أسماء البائعين وبيعهم المنتجات . الآن ، هدفنا هو العثور على منتجات البيع لكل مندوب مبيعات.
1. استخدام الصيغ للبحث عن قيم متعددة في خلية واحدة في Excel
ستكون الوظيفة TEXTJOIN الذهاب إلى وظيفة لديناتنفيذ هذه الطريقة. تسمح لك الوظيفة TEXTJOIN بربط سلسلتين أو أكثر مع كل قيمة مفصولة بعلامة محدد . بشكل أساسي ، نقوم بدمج وظائف مختلفة مع وظيفة TEXTJOIN لتنفيذ الصيغة الخاصة بنا.
الوظيفة TEXTJOINمتاحة فقط لبرنامجي Excel 2019 و Office 365.التركيب الأساسي لوظيفة TEXTJOIN:
=TEXTJOIN(delimiter, ignore_empty, text1, [text2], …) هنا ، سيكون المحدد فاصلة ( “,” ) لفصل القيم في خلية واحدة.
1.1 وظائف TEXTJOIN و IF
الآن ، هذه الصيغة سهلة الاستخدام. ستبحث هذه الصيغة عن القيم وتدرجها أيضًا في خلية واحدة باستخدام فاصلة. ولكن ، تذكر أن هذه الصيغة ستعيد القيمة مع التكرارات.
البنية الأساسية:
=TEXTJOIN(", ",TRUE,IF(lookup_value=lookup_range,,finding_range,"")) 📌 الخطوات
1. أولاً ، اكتب الصيغة التالية في الخلية F5 :
=TEXTJOIN(", ",TRUE,IF(E5=B5:B13,C5:C13,"")) 
2. ثم اضغط على إدخال.
3. أخيرًا ، اسحب رمز مقبض التعبئة فوق نطاق الخلايا F6: F7 .
في النهاية ، نجحنا لاستخدام VLOOKUP قيم متعددة في خلية واحدة.
🔎 انهيار الصيغة
نحن نستخدم هذا التقسيم فقط للشخص "John"
➤ IF(E5=B5:B13,C5:C13,"")
هذه الدالة ترجع المصفوفة التالية:
{"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ TEXTJOIN(", ",TRUE,IF(E5=B5:B13,C5:C13,""))
أخيرًا ، ستعيد الوظيفة TEXTJOIN ما يليالنتيجة:
{Mobile, TV, Fridge, Mobile}
اقرأ المزيد: Excel VLOOKUP لإرجاع قيم متعددة في خلية واحدة مفصولة بفاصلة
1.2 وظائف TEXTJOIN و MATCH (بدون تكرار)
الآن ، إذا كنت تريد قيمًا متعددة في خلية واحدة ، فيمكنك استخدام هذه الصيغة. هذه الصيغة هي مزيج من الدالتين TEXTJOIN و MATCH . هذه الصيغة معقدة بعض الشيء لاستخدامها ولكنها بالتأكيد ستعطي القيم التي تريدها.
📌 خطوات
1. أولاً ، اكتب الصيغة التالية في الخلية F5 :
=TEXTJOIN(",", TRUE, IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, "")) 
2. ثم اضغط على إدخال.
3. أخيرًا ، اسحب رمز مقبض التعبئة فوق نطاق الخلايا F6: F7 .
في النهاية ، نجحنا لاستخدام VLOOKUP قيم متعددة في خلية واحدة بدون أي قيم مكررة.
🔎 تفصيل الصيغة
نحن نستخدم هذا التقسيم فقط للشخص "John"
➤ ROW(C5:C13)
يقوم بإرجاع مصفوفة من {5;6;7;8;9;10;11;12;13}
➤ MATCH(ROW(C5:C13), ROW(C5:C13))
يعود: {1;2;3;4;5;6;7;8;9}
➤ IF(E5=B5:B13, C5:C13, "")
تُرجع: {"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ MATCH(C5:C13, IF(E5=B5:B13, C5:C13, "")
ترجع هذه الوظيفة: {8;8;7;9;7;7;7;8;7}
➤ IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")
تعود: {1;1;"";4;"";6;"";1;""}
➤ IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, "")
يعود: {"Mobile";"";"";"TV";"";"Fridge";"";"";""}
➤ TEXTJOIN(",", TRUE, IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, ""))
سيكون الإخراج النهائي المحمول ، التلفزيون ، الثلاجة .
اقرأ المزيد: كيفية أداء VLOOKUP مع صفوف متعددة في Excel (5 طرق)
1.3وظائف TEXTJOIN و UNIQUE (بدون تكرار)
الآن ، تتوفر الوظيفة UNIQUE فقط في Excel 365. لذلك ، إذا كنت تستخدم Excel 365 ، فيمكنك بالتأكيد استخدام هذه الصيغة. الصيغة السابقة صعبة بعض الشيء ولكن هذه الصيغة ستسهل طريقة البحث عن القيم في خلية واحدة. ترجع الدالة UNIQUE قائمة بالقيم الفريدة في قائمة أو نطاق. الآن ، الفرق بين الصيغة الأولى والثالثة يستخدم الدالة UNIQUE قبل الدالة IF .
البنية الأساسية لوظيفة UNIQUE:
=UNIQUE (array, [by_col], [exactly_once]) صفيف - النطاق أو المصفوفة التي يتم استخراج القيم الفريدة منها.
by_col - [اختياري] كيفية المقارنة والاستخراج. بالصف = FALSE (افتراضي) ؛ حسب العمود = TRUE.
بالضبط مرة واحدة - [اختياري] TRUE = القيم التي تحدث مرة واحدة ، FALSE = جميع القيم الفريدة (افتراضي)
📌 خطوات
1. أولاً ، اكتب الصيغة التالية في الخلية F5 :
=TEXTJOIN(", ",TRUE,UNIQUE(IF(E5=B5:B13,C5:C13,""))) 
2. ثم اضغط على إدخال.
3. أخيرًا ، اسحب رمز مقبض التعبئة فوق نطاق الخلايا F6: F7.
كما ترى ، لدينا تم بنجاح استخدام VLOOKUP قيم متعددة في خلية واحدة.
🔎 انهيار الصيغة
نحن نستخدم هذا التقسيم فقط للشخص "John"
➤ IF(E5=B5:B13,C5:C13,"")
يقوم بإرجاع {"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ UNIQUE(IF(E5=B5:B13,C5:C13,""))
ذلكإرجاع {"Mobile";"";"TV";"Fridge"}
TEXTJOIN(", ",TRUE,UNIQUE(IF(E5=B5:B13,C5:C13,"")))
النتيجة النهائية المحمول ، التلفزيون ، الثلاجة
قراءة المزيد: كيفية البحث عن قيم متعددة وإرجاعها في القائمة المنسدلة
2. استخدام أكواد VBA للبحث عن قيم متعددة في خلية واحدة
الوظيفة TEXTJOIN متاحة فقط لـ MS Excel 2019 و MS Excel 365 . لذلك ، إذا كنت معروفًا جيدًا بأكواد VBA في Excel ، فسيكون هذان الرمزان عمليين للغاية بالنسبة لك. الأول سيكون مع التكرارات والثاني سيكون بدون تكرارات. لذا ، اختر طريقتك وفقًا لمشكلتك.
2.1 رموز VBA متعددة القيم في خلية واحدة
📌 الخطوات
1. أولاً. اضغط على Alt + F11 لفتح محرر Visual Basic.
2. ثم ، انقر فوق إدراج & GT. الوحدة النمطية .
3. بعد ذلك ، اكتب الرمز التالي:
6502
4. الآن ، انتقل إلى ورقة العمل الخاصة بك. ثم اكتب الصيغة التالية في الخلية F5 :
=MultipleValues(B5:B13,E5,C5:C13,",") 
5. ثم اضغط على ENTER.
6. أخيرًا ، اسحب رمز Fill Handle فوق نطاق الخلايا F6: F7.
في النهاية ، استخدمنا VLOOKUP قيم متعددة في خلية واحدة .
اقرأ المزيد: VLOOKUP لإرجاع قيم متعددة أفقيًا في Excel
2.2 VBA الرموز للبحث عن قيم متعددة في خلية واحدة (بدون تكرارات)
📌 خطوات
1. أولاً. اضغط على Alt + F11 لفتح محرر Visual Basic.
2. ثم،انقر فوق إدراج & GT. الوحدة النمطية .
3. بعد ذلك ، اكتب الكود التالي:
7181
4. بعد إدخال الكود ، انقر فوق Tools & gt؛ المراجع في نافذة Microsoft Visual Basic for Applications المفتوحة ، ثم في النافذة المنبثقة المراجع - مربع الحوار VBAProject ، حدد الخيار Microsoft Scripting Runtime في المراجع المتاحة مربع القائمة. انقر فوق موافق .
5. الآن ، انتقل إلى ورقة العمل الخاصة بك. بعد ذلك ، اكتب الصيغة التالية في الخلية F5 :
=ValuesNoDup(E5,B5:B13,2) هنا ، 2 هو رقم عمود مجموعة البيانات.
6. ثم اضغط على أدخل .
7. أخيرًا ، اسحب رمز مقبض التعبئة فوق نطاق الخلايا F6: F7.
كما ترى ، لدينا تم استخدام VLOOKUP قيم متعددة في خلية واحدة بدون تكرارات.
قراءة المزيد: كيفية VLOOKUP وإرجاع قيم متعددة في Excel (8 طرق)
الخاتمة
في الختام ، آمل أن يساعدك هذا البرنامج التعليمي في البحث عن قيم متعددة في خلية واحدة في Excel. قم بتنزيل كتيب التدريب وجربها بنفسك. بالتأكيد ، سوف يطور معرفتك ببرنامج Excel. أيضًا ، لا تتردد في تقديم ملاحظات في قسم التعليقات. ملاحظاتك القيمة تحفزنا على إنشاء الكثير من المقالات مثل هذه. لا تنس مراجعة موقعنا على الويب ExcelWIKI للتعرف على المشكلات والحلول المتعلقة ببرنامج Excel.
