Kuidas kasutada VLOOKUP-i mitme veeru jaoks Excelis (6 näidet)

Hugh West

14-10-2023 Exceli valemid
  • Jaga Seda
Hugh West

Täna räägin ma MS Excel populaarne ja palju kasutatud funktsioon nimega funktsioon VLOOKUP Seda funktsiooni saab kasutada andmete väljavõtmiseks, võrdlemiseks, nihutamiseks või otsimiseks mis tahes tabelis või vahemikus. Neid funktsioone saab kasutada mitme veeru puhul. Selles artiklis näitan, kuidas me saame kasutada VLOOKUP funktsioon mitme veeru jaoks erinevatel eesmärkidel Excelis.

Lae alla praktiline töövihik

Praktilise töövihiku saate alla laadida siit.

VLOOKUP-i kasutamine mitme veeru jaoks.xlsx

6 ideaalset näidet VLOOKUP-i kasutamisest mitme veeru jaoks Excelis

Siinkohal olen võtnud selle artikli jaoks järgmise andmekogumi. See sisaldab Toote üksikasjad mõnede toodete puhul. Kasutan seda andmestikku, et selgitada, kuidas kasutada VLOOKUPi mitme veeru jaoks Excelis.

1. Saada väärtused mitmest veerust, kasutades Exceli VLOOKUP-funktsiooni

Oletame, et teil on Toote üksikasjad nimekiri koos oma ID , Nimi ja Ühiku hind On veel üks tabel, mille nimi on Müügi ülevaade Selles tabelis on ID , Nimi , Ühiku hind , Kogus ja Müük kokku Teie ülesanne on genereerida automaatne arvutus Müük kokku tabelis, kui te lihtsalt sisestate toote ID Valem võtab toote nimed ja hinnad välja. Toote üksikasjad tabelit ja genereerida Müük kokku automaatselt.

Vaatame, kuidas seda teha.

Sammud:

  • Kõigepealt valige lahter, kuhu soovite toodet sisestada. Nimi Siin valisin ma Lahter C15 .
  • Teiseks on Lahter C15 kirjutada järgmine valem.
=VLOOKUP(B15,$B$6:$D$11,{2,3},0)

  • Kolmandaks, vajutage Sisesta tulemuse saamiseks.
  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

🔎 Kuidas valem töötab?

  • In the VLOOKUP funktsiooni esimene argument kannab andmeid, mida tabelis otsitakse. B15 sisaldab ID mis sobitatakse tootenimekirja tabeliga ID .
  • $B$6:$D$11 on tabeli massiivi vahemik, kus andmeid otsitakse.
  • {2,3} see tähendab, et me eraldame sobitatud ridade teise ja kolmanda veeru väärtused.
  • 0 määratleb, et me tahame saada täpset kokkulangevust.
  • Pärast seda lohistage Täitmise käepide alla, et kopeerida valem teistesse lahtritesse.

  • Lõpuks näete, et ma kopeerisin valemi teistesse lahtritesse ja sain soovitud väljundi.

Märkus: Et genereerida Müük kokku , olen kasutanud järgmist valemit.

=D15*E15

Ja siis kopeeris selle alla kuni F20.

Loe edasi: Excel VLOOKUP mitme väärtuse vertikaalseks tagastamiseks

2. Kasutage VLOOKUP-funktsiooni mitme veeru jaoks erinevatest töövihikutest

Selles näites kasutan ma Exceli VLOOKUP funktsioon, et saada andmeid mitu veergu erinevatest töövihikutest. Nüüd on andmekogum endiselt sama, kuid kaks tabelit asuvad kahes erinevas töövihikus. Toote üksikasjad tabel asub töövihikus nimega Toote-loetelu-tabel . Selles näites võtan sellest tabelist välja nimed ja hinnad.

Vaatame samme.

Sammud:

  • Alguses valige lahter, kuhu soovite toote Nimi .
  • Seejärel kirjutage sellesse valitud lahtrisse järgmine valem. Siinkohal olen kasutanud kasutatava Exceli töövihiku nime. Te peate seda vastavalt muutma.
=VLOOKUP(B6,'[Product-List-Table.xlsx]Product Details'!$B$5:$D$10,{2,3},0)

  • Seejärel vajutage Sisesta tulemuse saamiseks.
  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

Siin on valem sama, mis eelmise meetodi valem. Ainus oluline erinevus on see, et siin on lähtetabel teises failis, mistõttu pidime kasutama faili viidet kasutades '[Product-List-Table.xlsx]Product Details'!$B$5:$D$10 osa.

  • Pärast seda lohistage Täitmise käepide alla, et valemit kopeerida.

  • Järgneval pildil näete, et ma kopeerisin valemi teistesse lahtritesse ja sain soovitud väljundi.

Loe edasi: VLOOKUP mitme veeru tagastamiseks Excelis (4 näidet)

Sarnased lugemised

  • VLOOKUP ei tööta (8 põhjust & lahendused)
  • Exceli VLOOKUP, et leida viimane väärtus veerus (koos alternatiividega)
  • VLOOKUP ja kõigi kokkulangevuste tagastamine Excelis (7 võimalust)
  • VBA VLOOKUP-i kasutamine Excelis teise töölehe väärtuste leidmiseks

3. VLOOKUPi rakendamine väärtuste leidmiseks mitmest veerust ja kogusumma saamiseks

Selle näite jaoks olen võtnud järgmise andmestiku. Oletame, et teil on olemas Nimi mõnede õpilaste ja nende saadud hinded Füüsika ja Keemia . Teil on teine tabel, kus on ainult nimed ja te soovite näidata nende nimede kõrval koguarvu. Nüüd näitan teile, kuidas saate rakendada VLOOKUP funktsioon, et leida väärtusi mitu veergu ja saada Markid kokku neist Excelis.

Ma näitan teile, kuidas seda teha.

Sammud:

  • Kõigepealt valige lahter, kuhu soovite sisestada Markid kokku Siin valisin ma Cell G5 .
  • Teiseks on Cell G5 kirjutada järgmine valem.
=SUM(VLOOKUP(F5,$B$5:$D$12,{2,3},FALSE))

  • Kolmandaks, vajutage Sisesta saada Kokku Marks .
  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

🔎 Kuidas valem töötab?

  • VLOOKUP(F5,$B$5:$D$12,{2,3},FALSE): Siin on VLOOKUP funktsioon, valisin F5 nagu lookup_value , $B$5:$D$12 nagu table_array , {2,3} nagu col_index_num ja VALE nagu range_lookup Valem tagastab vasted lookup_value veergudest 2 ja 3 kohta table_array .
  • SUM(VLOOKUP(F5,$B$5:$D$12,{2,3},FALSE)): Nüüd, funktsioon SUM tagastab kokkuvõte kahest väärtusest, mille ta sai VLOOKUP funktsioon.
  • Seejärel lohistage Täitmise käepide alla, et kopeerida valem teistesse lahtritesse.

  • Järgnevalt näete, et olen kopeerinud valemi kõikidesse teistesse lahtritesse ja saanud soovitud väljundi.

4. VLOOKUP ja IFERROR funktsioonide kasutamine mitme veeru võrdlemiseks Excelis

Selles osas oletame, et teil on andmekogum, milleks on Ülesanded ja nende töötajate nimed, kellele see ülesanne on määratud. On olemas veerg, mis sisaldab järgmiste töötajate nimesid Vanad töötajad kes olid määratud selle ülesande täitmiseks, nimed Uued töötajad kes olid määratud selle ülesande täitmiseks, ja nende nimed, kes olid Oodatavad praegused töötajad nende ülesannete jaoks. Nüüd on teie ülesanne võrrelda kahe veeru nimesid Vanad töötajad ja Uued töötajad ja tuvastada vasteid. Seejärel tuleb võrrelda Praegused oodatavad töötajad Names veerus tuvastatud vasteid ja tagastab selle nime, kui see on kõigis 3 veerud.

Vaatame, kuidas seda teha.

Sammud:

  • Kõigepealt valige lahter, kus soovite nime Sobitatud töötaja .
  • Seejärel kirjutage sellesse valitud lahtrisse järgmine valem.
=IFERROR(VLOOKUP(IFERROR(VLOOKUP(C6:C11,D6:D11,1,FALSE),""),E6:E11,1,FALSE),"")

  • Lõpuks vajutage Sisesta Kui kasutate vanemat versiooni programmi Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

🔎 Kuidas valem töötab?

  • VLOOKUP(C6:C11,D6:D11,1,FALSE): Selles valemi osas võrreldakse Vanad töötajad veerg ja Uued töötajad veerus.
  • IFERROR(VLOOKUP(C6:C11,D6:D11,1,FALSE),""): Nüüd, funktsioon IFERROR asendab #N/A koos tühi string .
  • VLOOKUP(IFERROR(VLOOKUP(C6:C11,D6:D11,1,FALSE),""),E6:E11,1,FALSE): Siin on VLOOKUP funktsioon võrdleb Praegused oodatavad töötajad veergu vastu, mis vastab esimesest tagastatud väärtustele VLOOKUP funktsioon.
  • IFERROR(VLOOKUP(IFERROR(VLOOKUP(C6:C11,D6:D11,1,FALSE),""),E6:E11,1,FALSE),""): Lõpuks on IFERROR funktsioon asendab #N/A koos tühi string .

Loe edasi: Miks VLOOKUP tagastab #N/A, kui vaste on olemas? (5 põhjust & Lahendused)

5. CHOOSE ja VLOOKUP funktsioonide kombineerimine mitme kriteeriumi jaoks

Siinkohal näitan teile, kuidas saate andmeid ekstraheerida mitu veergu kasutades mitu kriteeriumi Oletame, et meil on müügiteabe andmestik, mille puhul on Müügiinimene , Kuu ja Müük . Nüüd on teie ülesanne luua uus tabel, kus te näitate kogu müüki veerus, kus iga veerg esindab iga kuud.

Vaatame samme.

Sammud:

  • Alustuseks valige lahter, kuhu soovite sisestada Müük kuu aega. Siin valisin Cell G6 .
  • Järgnevalt Cell G6 kirjutada järgmine valem.
=VLOOKUP($F6&G$5,CHOOSE({1,2},$B$5:$B$12&$C$5:$C$12,$D$5:$D$12),2,0)

  • Seejärel vajutage Sisesta tulemuse saamiseks.
  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

🔎 Kuidas valem töötab?

  • CHOOSE({1,2},$B$5:$B$12&$C$5:$C$12,$D$5:$D$12): Siinkohal on funktsioon CHOOSE , valisin ma {1,2} nagu index_num , $B$5:$B$12&$C$5:$C$12 nagu väärtus1 ja $D$5:$D$12 nagu value2 See valem tagastab väärtuse, kasutades index_num .
  • VLOOKUP($F6&G$5,CHOOSE({1,2},$B$5:$B$12&$C$5:$C$12,$D$5:$D$12),2,0): Nüüd on VLOOKUP funktsioon leiab vaste ja tagastab vastava väärtuse.
  • Seejärel lohistage Täitmise käepide allapoole, et valemit kopeerida.

  • Seejärel lohistage Täitke käepide paremale .

  • Lõpuks näete, et ma kopeerisin valemi kõikidesse teistesse lahtritesse ja sain soovitud väljundi.

Loe edasi: Kasutage VLOOKUP-i mitme kriteeriumiga Excelis (6 meetodit + alternatiivid)

6. VLOOKUP- ja MATCH-funktsioonide rakendamine väärtuse dünaamiliseks otsimiseks mitmest veerust

Selles näites näitan teile, kuidas saate dünaamiliselt leida väärtuse mitmest veerust, kasutades funktsiooni VLOOKUP funktsiooniga Excelis. Olen võtnud selle näite jaoks järgmise andmestiku. See sisaldab Üliõpilase ID , Nimi ja Marks Teises tabelis on mul Õpilase ID Nüüd kasutan ma VLOOKUP funktsioon, et leida väärtus selle vastu Üliõpilase ID dünaamiliselt.

Vaatame, kuidas seda teha.

Sammud:

  • Kõigepealt valige lahter, kuhu soovite sisestada Marks .
  • Teiseks kirjutage sellesse valitud lahtrisse järgmine valem.
=VLOOKUP(F5,$B$4:$D$12,MATCH($G$4,$B$4:$D$4,0),FALSE)

  • Kolmandaks, vajutage Sisesta tulemuse saamiseks.

🔎 Kuidas valem töötab?

  • MATCH($G$4,$B$4:$D$4,0): Siinkohal on funktsioon MATCH , valisin ma $G$4 kui l ookup_value , $B$4:$D$4 nagu lookup_array ja 0 nagu match_type Valem tagastab suhtelise asukoha. lookup_value aastal lookup_array .
  • VLOOKUP(F5,$B$4:$D$12,MATCH($G$4,$B$4:$D$4,0),FALSE): Nüüd on VLOOKUP funktsioon tagastab vaste.
  • Pärast seda lohistage Täitmise käepide alla, et valemit kopeerida.

  • Lõpuks näete, et ma kopeerisin valemi teistesse lahtritesse ja sain soovitud väljundi.

Alternatiiv VLOOKUP-funktsioonile mitme veeru jaoks Excelis

Selles jaotises teen sama operatsiooni, kuid erinevate funktsioonidega (ilma VLOOKUP ). Siinkohal kasutan ma funktsioon INDEX ja Match funktsiooni. Nüüd vaatleme sama andmestikku, mida kasutasite esimeses näites. Leian, et Ühiku hind toote kohta, kasutades Nimi ja ID .

Vaatame samme.

Sammud:

  • Alguses valige lahter, kus soovite, et Ühiku hind .
  • Seejärel kirjutage sellesse valitud lahtrisse järgmine valem.
=INDEX(D:D,MATCH(1,(C:C=C15)*(B:B=B15),0))

  • Kolmandaks, vajutage Sisesta tulemuse saamiseks.
  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 seejärel vajutage Ctrl + Vahetus + Sisesta .

🔎 Kuidas valem töötab?

  • MATCH(1,(C:C=C15)*(B:B=B15),0): See osa valemist vastab sisestatud ID ja Nimi koos andmekogumiga ja "1" viitab siinkohal TÕELINE nagu tagastab rea numbri, kus kõik kriteeriumid on TÕELINE .
  • INDEX(D:D,MATCH(1,(C:C=C15)*(B:B=B15),0)): Nüüd on INDEX funktsioon tagastab väärtuse vahemikust D:D .
  • Seejärel lohistage Täitmise käepide alla, et kopeerida valem teistesse lahtritesse.

  • Lõpuks näete, et olen kopeerinud valemi kõikidesse teistesse lahtritesse ja saanud soovitud väljundi.

Loe edasi: INDEX MATCH vs VLOOKUP funktsioon (9 näidet)

Levinumad vead nende funktsioonide kasutamisel

Tavalised vead

Kui nad näitavad

#N/A Viga See viga ilmneb, kui valem on massiivi valem ja te lihtsalt vajutate nuppu Sisesta . Selle lahendamiseks vajutage CTRL + SHIFT + SISESTA .
#N/A aadressil VLOOKUP Praktikas võib see viga ilmneda mitmel põhjusel, sealhulgas järgmistel põhjustel
  • Otsinguväärtust ei ole tabelis olemas.
  • Otsinguväärtus on valesti kirjutatud või sisaldab täiendavat tühikut.
  • Tabeli vahemik ei ole õigesti sisestatud.
  • Te kopeerite VLOOKUP ja tabeliviide ei ole lukustatud.
#VALUE aadressil VALI Kui index_num on väljaspool ulatust, VALI tagastab #VALUE viga.
Range või massiivi konstant VALI funktsioon ei võta väärtusi vahemikust või massiivi konstandist.
#VALUE aadressil INDEX Kõik vahemikud peavad olema ühel lehel, vastasel juhul INDEX tagastab #VALUE viga.

Asjad, mida meeles pidada

  • Kui kasutate vanemat versiooni Microsoft Excel kui Excel 2019 siis peate vajutama Ctrl + Vahetus + Sisesta . massiivi valemid .

Praktika sektsioon

Siinkohal olen iga näite kohta esitanud harjutuse osa, et saaksite harjutada, kuidas kasutada VLOOKUP funktsioon mitme veeru jaoks Excelis.

Kokkuvõte

Niisiis, need on mõned viisid, kuidas kasutada VLOOKUP funktsioon mitme veeru jaoks Excelis. Olen näidanud kõiki meetodeid koos vastavate näidetega, kuid neid võib olla palju muid iteratsioone. Olen käsitlenud ka kasutatud funktsioonide põhialuseid. Lisaks on artikli alguses lisatud ka harjutustöömapp. Laadige see alla, et harjutada näiteid. Kui teil on mõni muu meetod, siis jagage seda julgelt meiega.

Eelmine postitus Kuidas külmutada paneelid VBA-ga Excelis (5 sobivat viisi)
Järgmine postitus Kuidas lisada Excelis aega minutid (5 lihtsat viisi)

Hugh West on suurte kogemustega Exceli koolitaja ja analüütik, kellel on selles valdkonnas üle 10-aastane kogemus. Tal on raamatupidamise ja rahanduse bakalaureusekraad ning ärijuhtimise magistrikraad. Hugh’l on kirg õpetamise vastu ning ta on välja töötanud ainulaadse õpetamisviisi, mida on lihtne järgida ja mõista. Tema Exceli ekspertteadmised on aidanud tuhandetel õpilastel ja spetsialistidel üle maailma oma oskusi parandada ja karjääris silma paista. Oma ajaveebi kaudu jagab Hugh oma teadmisi maailmaga, pakkudes tasuta Exceli õpetusi ja veebikoolitusi, mis aitavad üksikisikutel ja ettevõtetel oma potentsiaali täielikult ära kasutada.