SUMPRODUKT er en yderst nyttig funktion med mange formål. Når du sammenligner data mellem to eller flere intervaller og beregner med flere kriterier, er SUMPRODUCT-funktionen dit første valg Den har en unik evne til at håndtere arrays på smarte og elegante måder. Ofte har vi brug for at bruge SUMPRODUCT-IF kombination eller Betinget SUMPRODUCT til at sammenligne kolonner med givne kriterier og finde resultatet. I dag i denne artikel vil vi diskutere den SUMPRODUCT-IF kombineret funktion og nogle andre alternative tilgange til denne kombination.

Download arbejdsbog til øvelser

Download dette øvelsesark for at øve dig i opgaven, mens du læser denne artikel.

Anvendelse af kombinationen SUMPRODUCT+IF.xlsx

Introduktion til SUMPRODUCT-funktionen i Excel

Teknisk set er det SUMPRODUCT-funktion returnerer summen af værdierne i de tilsvarende arrays eller intervaller. Normalt er multiplikation standardoperationen, men division, subtraktion eller addition kan også udføres.

⦿ Syntaks:

Syntaksen for SUMPRODUKT funktion er enkel og direkte.

=SUMPRODUKT(array1, [array2], [array3], ...)

⦿ Argument:

• [array1]: Det første array eller de første rækker af celler, hvis værdier vi ønsker at gange og derefter lægge sammen.
• [ array2], [array3]....: Array-argumenter 2 til 255, hvis værdier vi ønsker at gange og derefter addere.

2 Eksempler på brug af SUMPRODUCT IF-kombination i Excel

I Excel er der ingen indbygget "SUMPRODUKT HVIS" funktion, men du kan bruge den som en array-formel ved at kombinere SUMPRODUKT og IF Lad os diskutere denne formel.

Eksempel 1: Anvend SUMPRODUCT IF-formlen med ét kriterium

Vi kan bruge denne formel med ét kriterium. Følg disse trin for at lære det.

Trin-1:

• Overvej en datatabel, hvor nogle frugtvarer er angivet med "Region" , "Antal" , og "Pris" Vi finder ud af den samlede pris for nogle varer.

Trin 2:

• Opret en anden tabel et sted i regnearket, hvor du vil have den samlede pris for varen. Vi vælger "Cherry" , "Apple", "Plum" varer.

Trin 3:

• Anvend følgende formel i celle H4 Denne formel har følgende format-

=SUMPRODUCT(IF(kriterier rækkevidde=kriterier, værdier rækkevidde1*værdier rækkevidde2))

• Indsæt værdierne i formlen.

=SUMPRODUCT(IF($C$5:$C$21=G5,$D$5:$D$21*$E$5:$E$21))

Hvor,

• Kriterier_range er $C$5:$C$21.
• Kriterierne er G5 , G6 og G7 .
• Værdier_range1 er $D$5:$D$21.
• Værdier_range2 er $E$5:$E$21.

• Anvend denne formel som en array-formel ved at trykke på CTRL+SHIFT+ENTER samtidig. Hvis du bruger Excel 365 , kan du trykke på bare INDTAST for at anvende en array-formel.

Trin 4:

• Vi har fået vores samlede pris. Anvend nu den samme formel for resten af varerne.

Læs mere: SUMPRODUCT med kriterier i Excel (5 metoder)

Eksempel 2: Anvend SUMPRODUCT IF-formel med flere kriterier i forskellige kolonner

Vi vil bruge den samme formel til flere kriterier.

Trin-1:

• Lad os tilføje endnu et kriterium "Region" i tabel 2. I dette tilfælde ønsker vi at finde den samlede pris for "Cherry" fra den "Oceanien" region og "Apple" fra den "Asien" region.

Trin 2:

• Anvend nu nedenstående formel. Indsæt værdierne i formlen.

=SUMPRODUCT(IF($B$5:$B$21=G5,IF($C$5:$C$21=H5,$D$5:$D$21*$E$5:$E$21)))

Hvor,

• Kriterier_range er $B$5:$B$21, $C$5:$C$21.
• Kriterierne er G5, H5.
• Værdier_range1 er $D$5:$D$21.
• Værdier_range2 er $E$5:$E$21.

• Tryk nu på INDTAST .

Trin 3:

• Vores værdi er her. Gør nu det samme for "Apple" punkt.

Læs mere: Sådan bruger du SUMPRODUCT IF i Excel

Sådan bruges kun SUMPRODUCT i stedet for SUMPRODUCT IF Formula i Excel

Der er nogle andre metoder til at udlede de tidligere resultater. En alternativ måde at indsætte kriterierne i SUMPRODUKT funktion som et array ved hjælp af dobbelt unær (-) til at konvertere den TRUE eller FALSK til 1 eller 0 .

SUMPRODUKT med én betingelse:

Vi vil i dette tilfælde tage udgangspunkt i det foregående eksempel. Vi finder den samlede pris på "Mango" fra listen.

• Anvend den betingede SUMPRODUKT nedenstående formel.

=SUMPRODUCT(--(C5:C21=G5),D5:D21,E5:E21)

Hvor,

• Array1 er (-(C5:C21=G5).
• [Array2] er D5:D21.
• [Array3] er E5:E21.

• Tryk på "Enter". Vores resultat er her.

Formel Forklaring:

Vi vil nu forklare, hvordan denne betingede SUMPRODUKT funktionen fungerer

• Når vi går ind i "-(C4:C20=G4)" i formlen denne dobbelte unary (-) konverterer den TRUE eller FALSK til 1 eller 0 . Vælg dette "-(C4:C20=G4)" del i dit regneark og tryk på "F9" for at se de underliggende værdier.

  Output: {0,1,0,0,0,0,0,0,1,1,0,1,1,0,0,0,1}

• Hvis vi nu opdeler arraysene i værdier, vil den faktiske formel se således ud,

=SUMPRODUCT({0,1,0,0,0,0,0,0,1,1,0,1,1,0,0,0,1},{20,50,100,50,500,80,90,56,60,80,100,40,45,25,35,45,90},{15,20,2,5,12,10,15,9,20,30,5,30,25,10,10,20,15})

• Det første array ganges med det andet og det andet array ganges derefter med det tredje array. Følg dette billede

Det er sådan, at denne betingede SUMPRODUKT arbejder.

Læs mere: SUMPRODUCT Datointerval [7 produktive metoder]

Anvendelse af flere betingelser i forskellige kolonner:

I det følgende eksempel finder vi den samlede pris for "Cherry" fra den "Oceanien" region.

• Anvend formlen. Den endelige form af denne formel er,

=SUMPRODUCT(--(B5:B21=G5), --(C5:C21=H5),D5:D21,E5:E21)

Hvor,

• Array1 er (–(C5:C21=G5),–(C5:C21=H5).
• [Array2] er D5:D21.
• [Array3] er E5:E21.

• Tryk på INDTAST . vores resultat er opnået.

Læs mere: SUMPRODUCT-funktion med flere kolonner i Excel (4 enkle måder)

Anvendelse af OR-logik:

Vi kan tilføje ELLER logik til vores formel for at gøre formlen mere dynamisk.

Lad os sige, at vi har brug for at få den samlede pris på "Mango" og "Cherry" fra datatabellen.

• Anvend den SUMPRODUKT formel med ELLER og indsæt værdierne.
• Formlen er

=SUMPRODUCT(--((C5:C21=G5)+(C5:C21=H5)>0),D5:D21,E5:E21)

Hvor,

• Array1 er –((C5:C21=G5)+(C5:C21=H5)>0). Her G5 er "Mango" og H5 er "Cherry" Dette array tæller det samlede antal af "Mango" og "Cherry" i datatabellen.
• [Array2] er D5:D21.
• [Array3] er E5:E21.

• Tryk på "Enter" for at få den samlede pris for produkterne.

Anvendelse af flere AND/OR-kriterier:

I dette tilfælde vil vi anvende or-logik med flere betingelser.

I det følgende eksempel skal vi finde den samlede pris for "Cherry" og "Mango" fra "Asien" og "Europa" regioner.

• For at få resultatet anvender vi nu formlen med OG/ELLER logik. Formlen er

=SUMPRODUCT(--((B5:B21=H4)+(B5:B21=H5)>0),--((C5:C21=H6)+(C5:C21=H7)>0),D5:D21,E5:E21)

Hvor,

• Array1 er –((B5:B21=H4)+(B5:B21=H5)>0),–((C5:C21=H6)+(C5:C21=H7)>0). Her B5:B21 er "Region" Kolonne, H4 og H5 er "Asien" og "Europa" .Tilsvarende, C5:C21 er "Vare" kolonne, H6 og H7 er "Cherry" og "Mango".
• [Array2] er D5:D21.
• [Array3] er E5:E21.

• Tryk på INDTAST for at få den samlede pris.

Hurtige noter

✅ Arrays i den SUMPRODUKT formlen skal have det samme antal rækker og kolonner. Hvis ikke, får du den #VALUE! Fejl.

✅ Den SUMPRODUKT funktionen behandler ikke-numeriske værdier som nuller. Hvis du har ikke-numeriske værdier i din formel, vil svaret blive "0".

✅ Siden den SUMPRODUKT IF formel er en array-formel, skal du trykke på CTRL+SHIFT+ENTER samtidig for at anvende formlen.

✅ Den SUMPRODUKT funktionen understøtter ikke wildcard-tegn.

Konklusion

I dag drøftede vi den SUMPRODUKT IF formel og nogle andre alternative betingede SUMPRODUKT formler i denne artikel. Jeg håber, at denne artikel er nyttig for dig, når du står over for problemer. Hvis du har nogen forvirring, er du velkommen til at kommentere. Hvis du vil lære mere om Excel, kan du besøge vores websted .