SUMPRODUCT е изключително полезна функция с многобройни цели. Когато сравнявате данни между два или повече диапазона и изчислявате с множество критерии, функцията SUMPRODUCT е първият ви избор. . Той има уникалната способност да работи с масиви по интелигентен и елегантен начин. Често се налага да използваме SUMPRODUCT-IF комбинация или Условен SUMPRODUCT за сравняване на колони с дадени критерии и намиране на резултата. Днес в тази статия ще обсъдим Комбинирана функция SUMPRODUCT-IF и някои други алтернативни подходи към тази комбинация.

Изтегляне на работна тетрадка за практика

Изтеглете този тренировъчен лист, за да упражните задачата, докато четете тази статия.

Използване на комбинацията SUMPRODUCT+IF.xlsx

Въведение във функцията SUMPRODUCT в Excel

От техническа гледна точка Функция SUMPRODUCT връща сумата от стойностите на съответните масиви или диапазони. Обикновено операцията по подразбиране е умножение, но може да се извърши и деление, изваждане или събиране.

⦿ Синтаксис:

Синтаксисът на SUMPRODUCT функцията е проста и директна.

=SUMPRODUCT(array1, [array2], [array3], ...)

⦿ Аргумент:

• [array1]: Първият масив или диапазони от клетки, чиито стойности искаме да умножим и след това да съберем.
• [ array2], [array3]...: Аргументи от масив от 2 до 255, чиито стойности искаме да умножим и след това да съберем.

2 Примери за използване на комбинацията SUMPRODUCT IF в Excel

В Excel няма вграден "SUMPRODUCT IF" но можете да я използвате като формула за масив, като комбинирате SUMPRODUCT и IF функции. Нека да обсъдим тази формула.

Пример 1: Прилагане на формулата SUMPRODUCT IF с един критерий

Можем да използваме тази формула с един критерий. Следвайте тези стъпки, за да научите.

Стъпка 1:

• Разгледайте таблица с данни, в която са дадени някои плодове Елементи с "Регион" , "Qty" , и "Цена" . Ще разберем общата цена на някои продукти.

Стъпка 2:

• Създайте друга таблица навсякъде в работния лист, където искате да получите общата цена на продукта. Избираме "Череша" , "Apple", "Plum" артикули.

Стъпка 3:

• Приложете следната формула в клетка H4 Форматът на тази формула е-

=SUMPRODUCT(IF(criteria range=критерии, values range1*values range2))

• Вмъкнете стойностите във формулата.

=SUMPRODUCT(IF($C$5:$C$21=G5,$D$5:$D$21*$E$5:$E$21))

Къде,

• Criteria_range е $C$5:$C$21.
• Критериите са G5 , G6 и G7 .
• Values_range1 е $D$5:$D$21.
• Values_range2 е $E$5:$E$21.

• Приложете тази формула като формула за масив, като натиснете CTRL+SHIFT+ENTER едновременно. Ако използвате Excel 365 , можете да натиснете само ВЪВЕДЕТЕ за прилагане на формула за масив.

Стъпка 4:

• Получихме общата цена. Сега приложете същата формула за останалите елементи.

Прочетете още: SUMPRODUCT с критерии в Excel (5 метода)

Пример 2: Прилагане на формулата SUMPRODUCT IF с множество критерии в различни колони

Ще използваме същата формула за множество критерии.

Стъпка 1:

• Нека добавим още един критерий "Регион" в таблица 2. В този случай искаме да намерим общата цена на "Череша" от "Океания" регион и "Apple" от "Азия" регион.

Стъпка 2:

• Сега приложете формулата по-долу. Въведете стойностите във формулата.

=SUMPRODUCT(IF($B$5:$B$21=G5,IF($C$5:$C$21=H5,$D$5:$D$21*$E$5:$E$21))

Къде,

• Criteria_range е $B$5:$B$21, $C$5:$C$21.
• Критериите е G5, H5.
• Values_range1 е $D$5:$D$21.
• Values_range2 е $E$5:$E$21.

• Сега натиснете ВЪВЕДЕТЕ .

Стъпка 3:

• Нашата стойност е тук. Сега направете същото за "Apple" елемент.

Прочетете още: Как да използвате SUMPRODUCT IF в Excel

Как да използвате само SUMPRODUCT вместо SUMPRODUCT IF формула в Excel

Съществуват и други подходи за получаване на предходните резултати. Алтернативен начин за вмъкване на критериите в SUMPRODUCT като масив с помощта на двоен едночлен (-) за преобразуване на TRUE или FALSE в 1 или 0 .

SUMPRODUCT с едно условие:

В този случай ще разгледаме предишния пример. Ще намерим общата цена на "Манго" от списъка.

• Прилагане на условието SUMPRODUCT формула по-долу.

=SUMPRODUCT(--(C5:C21=G5),D5:D21,E5:E21)

Къде,

• Масив1 е (-(C5:C21=G5).
• [Array2] е D5:D21.
• [Array3] е E5:E21.

• Натиснете "Въведете". Нашият резултат е тук.

Обяснение на формулата:

Сега ще обясним как това условно SUMPRODUCT функцията работи

• Когато влезем в "-(C4:C20=G4)" във формулата този двоен едночлен (-) преобразува TRUE или FALSE в 1 или 0 . Изберете това "-(C4:C20=G4)" във вашия работен лист и натиснете "F9" за да видите основните стойности.

  Изход: {0,1,0,0,0,0,0,0,1,1,0,1,1,0,0,0,1}

• Ако сега разделим масивите на стойности, действителната формула ще изглежда така,

=SUMPRODUCT({0,1,0,0,0,0,0,0,1,1,0,1,1,0,0,0,1},{20,50,100,50,500,80,90,56,60,80,100,40,45,25,35,45,90},{15,20,2,5,12,10,15,9,20,30,5,30,25,10,10,20,15})

• Първият масив ще се умножи с втория, а след това вторият масив ще се умножи с третия масив. Следвайте тази картина

Ето как този условен SUMPRODUCT работи.

Прочетете още: SUMPRODUCT Обхват на датата [7 продуктивни метода]

Прилагане на множество условия в различни колони:

В следващия пример ще открием общата цена на "Череша" от "Океания" регион.

• Приложете формулата. Окончателната форма на тази формула е,

=SUMPRODUCT(--(B5:B21=G5), --(C5:C21=H5),D5:D21,E5:E21)

Къде,

• Масив1 е (–(C5:C21=G5),–(C5:C21=H5).
• [Array2] е D5:D21.
• [Array3] е E5:E21.

• Натиснете ВЪВЕДЕТЕ . Резултатът ни е постигнат.

Прочетете още: Функция SUMPRODUCT с множество колони в Excel (4 прости начина)

Прилагане на логиката OR:

Можем да добавим ИЛИ логика към нашата формула, за да я направим по-динамична.

Да речем, че трябва да получим общата цена на "Манго" и "Череша" от таблицата с данни.

• Приложете SUMPRODUCT формула с ИЛИ и въведете стойностите.
• Формулата е

=SUMPRODUCT(--((C5:C21=G5)+(C5:C21=H5)>0),D5:D21,E5:E21)

Къде,

• Масив1 е –((C5:C21=G5)+(C5:C21=H5)>0). Тук G5 е "Манго" и H5 е "Череша" . Този масив отчита общия брой на "Манго" и "Череша" в таблицата с данни.
• [Array2] е D5:D21.
• [Array3] е E5:E21.

• Натиснете "Enter" за да получите общата цена на продуктите.

Прилагане на множество критерии AND/OR:

В този случай ще приложим логиката Or с няколко условия.

В следващия пример трябва да намерим общата цена на "Череша" и "Манго" от "Азия" и "Европа" региони.

• За да получим резултата, сега ще приложим формулата с И/ИЛИ логика. Формулата е

=SUMPRODUCT(--((B5:B21=H4)+(B5:B21=H5)>0),--((C5:C21=H6)+(C5:C21=H7)>0),D5:D21,E5:E21)

Къде,

• Масив1 е –((B5:B21=H4)+(B5:B21=H5)>0),–((C5:C21=H6)+(C5:C21=H7)>0). Тук B5:B21 е "Регион" Колона, H4 и H5 е "Азия" и "Европа" .По същия начин, C5:C21 е "Item" колона, H6 и H7 е "Череша" и "Манго".
• [Array2] е D5:D21.
• [Array3] е E5:E21.

• Натиснете ВЪВЕДЕТЕ за да получите общата цена.

Бързи бележки

✅ Масиви в SUMPRODUCT трябва да има еднакъв брой редове и колони. Ако това не е така, ще се получи #VALUE! Грешка.

✅ SUMPRODUCT Ако във формулата ви има нецифрени стойности, отговорът ще бъде "0".

✅ Тъй като SUMPRODUCT IF формула е формула на масив, която трябва да натиснете CTRL+SHIFT+ENTER едновременно, за да приложите формулата.

✅ SUMPRODUCT функцията не поддържа заместващи символи.

Заключение

Днес обсъдихме SUMPRODUCT IF формула и някои други алтернативни условни SUMPRODUCT формулите в тази статия. Надявам се, че тази статия е полезна за вас, когато се сблъсквате с проблеми. Ако имате някакви неясноти, можете да коментирате. За да научите повече за Excel, моля, посетете нашия сайт .