Sadržaj
U Excelu ćete ponekad možda trebati generirati popis na temelju kriterija. Danas ćemo vam pokazati kako generirati popis na temelju kriterija. Za ovu sesiju koristimo Excel 365, iako se preporučuje korištenje ove verzije, slobodno upotrijebite svoju.
Prvo, upoznajmo se sa skupom podataka koji je baza naših primjera.
Ovdje imamo skup podataka nekoliko ljudi s različitih lokacija zajedno s njihovim vozilima. Pomoću ovih podataka formirat ćemo popis na temelju kriterija.
Imajte na umu da je ovo osnovna tablica s lažnim podacima kako bi stvari bile jednostavne. U praktičnom scenariju možete naići na puno veći i složeniji skup podataka.
Radna bilježnica za vježbe
Radnu bilježnicu za vježbe možete preuzeti sa sljedeće veze.
Excel Generiraj popis na temelju kriterija.xlsx
Generiraj popis na temelju kriterija
Na primjer, izradit ćemo popis ljudi na temelju njihove regije.
Budući da je skup podataka mali, znamo da postoje 4 regije. Pohranili smo nazive regija i pronaći ćemo popis na temelju regije.
1. Upotreba kombinacije INDEX-SMALL za generiranje popisa
Ovdje nam treba popis, tako da bi naša formula trebala biti jedna koji će dohvatiti više vrijednosti iz tablice. Za taj zadatak možemo koristiti kombinaciju funkcija INDEX i SMALL .
Da biste upoznali te funkcije, provjerite ove članke: INDEX, SMALL.
Uz ove dvije, trebat ćemo nekoliko pomoćnih funkcija, IF , ROW i IFERROR . Dodatne informacije potražite u člancima: IF, ROW, IFERROR.
Istražimo formulu
=IFERROR(INDEX($B$2:$B$12,SMALL(IF($C$2:$C$12=$G$2,ROW($B$2:$B$12)),ROW(1:1))-1,1),"") 
Ovdje svaka funkcija ima svoju svrhu. Funkcija INDEX vraća vrijednost iz niza B2:B12 (stupac naziva), a veliki dio SMALL daje broj retka koji treba dohvatiti.
IF, unutar SMALL, provjerava jesu li kriteriji usklađeni ili ne, a funkcija ROW iterira po ćelijama stupca .
Tada vanjski RED označava k-tu vrijednost za funkciju SMALL . Ove funkcije zajedno vraćaju broj retka, a INDEX vraća rezultat.
IFERROR za rješavanje bilo kakve pogreške koja može proizaći iz formule.
Povucite prema dolje i dobit ćete sve ljude iz dane regije.
Slično, napišite formulu za ostale regije (formula je ista, samo pomaknite ćeliju).
Alternativna kombinacija INDEX-SMALL
Možemo napisati formulu na alternativni način. Funkcije koje se koriste za formulu bit će iste kao prethodne. Samo će prezentacija biti drugačija.
Da vidimo formulu
=IFERROR(INDEX($B$2:$B$12,SMALL(IF($C$2:$C$12=G$2,ROW($B$2:$B$12)-1),ROW(1:1)),1),"") Opet, trebate pritisnuti CTRL + SHIFT + ENTER za izvršenjeformula.
Postoji mala razlika između ove dvije formule, možete li ih razlikovati?
Da, u našoj ranijoj formuli oduzeli smo 1 od na samom kraju MALOG dijela, ali ovdje smo oduzeli 1 unutar IF dijela.
Svrha oduzimanja 1 je kanaliziranje do odgovarajućeg broja retka. Ranije smo to konačno učinili, ovdje smo to učinili ranije i nastavite s daljnjom operacijom.
Napišite formulu za ostale kriterije da dovršite popis.
Pročitajte više: Kako napraviti popis unutar ćelije u Excelu (3 brze metode)
2. Upotreba funkcije AGGREGATE za generiranje popisa
Excel vam pruža funkcija pod nazivom AGGREGATE koju možete koristiti za obavljanje raznih zadataka. Ovdje možemo koristiti funkciju za generiranje popisa na temelju kriterija.
Funkcija AGGREGATE vraća zbirni izračun kao što je AVERAGE, COUNT, MAX, itd.
Sintaksa za AGGREGATE funkciju je kako slijedi:
AGGREGATE(function_number,behavior_options, range) function_number: Ovaj broj određuje koji izračun treba napraviti.
behavior_options: Postavite ovo pomoću broja. Ovaj broj označava kako će se funkcija ponašati.
raspon: Raspon koji želite agregirati.
Funkcija AGGREGATE obavlja nekoliko zadataka tako da broj unutar njega su unaprijed definirane funkcije. Navodimo nekoliko često korištenih funkcijabrojevi
| Funkcija | Funkcija_broj |
|---|---|
| PROSJEČNO | 1 |
| BROJ | 2 |
| BROJ | 3 |
| MAKSIMALNO | 4 |
| MIN | 5 |
| PROIZVOD | 6 |
| SUM | 9 |
| VELIKI | 14 |
| MALI | 15 |
Da biste saznali više o funkciji, posjetite stranicu Microsoft Support .
Pogledajmo sada formulu,
=IFERROR(INDEX($B$2:$B$12,AGGREGATE(15,6,IF($C$2:$C$12=G$2,ROW($B$2:$B$12)-1),ROW(1:1)),1),"") 
Ovdje uz funkciju AGGREGATE upotrijebili smo INDEX . INDEX sadrži niz koji vraća vrijednosti na temelju podudaranja pronađenih u kasnijem dijelu formule.
Možete vidjeti da smo upotrijebili 15 kao broj_funkcije u AGGREGATE . Iz gornje tablice možete vidjeti 15 poziva za rad funkcije SMALL . Možete li se sada povezati?
Da, izveli smo formulu INDEX-SMALL na način funkcije AGGREGATE .
6 za opciju ponašanja, koja označava ignoriraj vrijednosti pogreške .
Napiši formulu za ostale vrijednosti.
Slična čitanja
- Kako napraviti popis obaveza u Excelu (3 jednostavne metode)
- Stvaranje popisa za slanje e-pošte u Excelu (2 metode)
- Kako napraviti numerirani popis u Excelu (8 metoda)
3. Generirajte jedinstveni popis koristeći INDEX-MATCH-COUNTIF
Možemo izraditi jedinstveni popis na temelju kriterija. Za to možemo koristiti kombinaciju INDEX , MATCH i COUNTIF .
COUNTIF broji ćelije u raspon koji ispunjava jedan uvjet. A MATCH locira poziciju tražene vrijednosti u rasponu. Za više informacija o ovim funkcijama posjetite ove članke: MATCH, COUNTIF.
Istražimo formulu
=IFERROR(INDEX($B$2:$B$12, MATCH(0, IF(G$2=$C$2:$C$12, COUNTIF($G$2:$G2, $B$2:$B$12), ""), 0)),"") 
U ovoj formuli: B2: B12 je raspon stupaca koji sadrži jedinstvene vrijednosti iz kojih želite izdvojiti, C2:C12 je stupac koji sadrži kriterij na kojem se temeljite. G2 označava kriterij.
Unutar funkcije MATCH dali smo 0 kao lookup_array, a za lookup_range upotrijebili smo IF dio koji sadrži COUNTIF . Dakle, ovaj dio vraća vrijednost sve dok se pronađe 0. Vrijednost ovdje funkcionira kao broj retka za INDEX .
Povucite je prema dolje i pronaći ćete sve jedinstvene vrijednosti.
Ne zaboravite upotrijebiti CTRL+SHIFT + ENTER za izvođenje formule.
Ovo je bilo časno spominjanje pristupa generiranju jedinstvenog popis. Slijedite ovaj članak da biste saznali više o stvaranju jedinstvenog popisa na temelju kriterija .
4. Upotreba funkcije FILTER za generiranje popisa na temelju kriterija
Ako koristite Excel 365, tada možete izvršiti zadatak s jednim ugrađenimu funkciji pod nazivom FILTER .
Funkcija FILTER filtrira niz podataka na temelju zadanih kriterija i izdvaja podudarne zapise. Da biste saznali više o funkciji, posjetite ovaj članak: FILTER .
Sada će naša formula biti sljedeća,
=FILTER($B$2:$B$12,$C$2:$C$12=G$2) 
B2:B12 je niz koji treba filtrirati. Zatim smo dali uvjet, na temelju čega ćemo generirati popis.
Ovdje nećete morati povlačiti formulu prema dolje, to će odjednom dati sve vrijednosti i ispuniti popis.
Pročitajte više: Kako napraviti abecedni popis u Excelu (3 načina)
Zaključak
To je sve za danas. Naveli smo nekoliko načina za generiranje popisa na temelju kriterija. Nadam se da će vam ovo pomoći. Slobodno komentirajte ako vam se nešto čini teško shvatljivim. Obavijestite nas o drugim metodama koje smo ovdje propustili.
