Innholdsfortegnelse
Når du arbeider med store datamengder i Excel, kan du noen ganger havne i en situasjon der du trenger å søke etter verdier som vises flere ganger i datasettet ditt. Så du må se disse dataene i én celle. I denne opplæringen vil vi vise deg hvordan du bruker VLOOKUP for flere verdier i én celle i Excel.
Generelt sett bruker vi ikke direkte LOKUP -funksjonen her. Vi skal finne flere verdier i en celle som vil ligne VLOOKUP-funksjonen. Vi håper du vil finne denne veiledningen nyttig.
Last ned Practice Workbook
Vlookup Multiple Values in One Cell.xlsm2 enkle metoder for Vlookup for Flere verdier i én celle
Nå skal vi vise deg 2 måter å slå opp flere verdier i én celle i Excel. Den første bruker formlene og den andre bruker VBA -kodene. Vi vil slå opp både gjentatte og ikke-gjentatte verdier i denne artikkelen. Så du kan velge den metoden som passer best i forhold til problemet ditt.
For å demonstrere dette problemet, skal vi bruke følgende datasett:
Her har vi noen selgeres navn og deres selger produkter . Nå er målet vårt å finne salgsproduktene til hver selger.
1. Bruke formler til å søke opp flere verdier i én celle i Excel
TEXTJOIN funksjonen vil være vår go-to-funksjon tilimplementere denne metoden. Funksjonen TEXTJOIN lar deg slå sammen 2 eller flere strenger med hver verdi atskilt med en skilletegn . Hovedsakelig kombinerer vi forskjellige funksjoner med TEXTJOIN-funksjonen for å implementere formelen vår.
TEXTJOINfunksjonen er kun tilgjengelig for Excel 2019 og Office 365.Den grunnleggende syntaksen til TEXTJOIN-funksjonen:
=TEXTJOIN(delimiter, ignore_empty, text1, [text2], …) Her vil skilletegnet vårt være et komma ( “,” ) for å skille verdier i én celle.
1.1 TEXTJOIN- og IF-funksjonene
Nå er denne formelen ganske enkel å bruke. Denne formelen vil slå opp verdiene og også sette dem inn i én celle med et skilletegn, komma. Men husk at denne formelen vil returnere verdien med duplikater.
Den grunnleggende syntaksen:
=TEXTJOIN(", ",TRUE,IF(lookup_value=lookup_range,,finding_range,"")) 📌 Trinn
1. Skriv først inn følgende formel i Celle F5 :
=TEXTJOIN(", ",TRUE,IF(E5=B5:B13,C5:C13,"")) 
2. Trykk deretter Enter.
3. Til slutt drar du Fyllhåndtak -ikonet over celleområdet F6:F7 .
Til slutt lykkes vi for å bruke VLOOKUP flere verdier i én celle.
🔎 Oversikt over formelen
Vi bruker denne inndelingen kun for personen «John»
➤ IF(E5=B5:B13,C5:C13,"")
Denne funksjonen returnerer følgende matrise:
{"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ TEXTJOIN(", ",TRUE,IF(E5=B5:B13,C5:C13,""))
Til slutt vil TEXTJOIN funksjonen returnere følgenderesultat:
{Mobile, TV, Fridge, Mobile}
Les mer: Excel VLOOKUP for å returnere flere verdier i én celle atskilt med komma
1.2 TEXTJOIN- og MATCH-funksjonene (uten duplikater)
Nå, hvis du vil ha flere verdier i én celle, kan du bruke denne formelen. Denne formelen er en kombinasjon av funksjonene TEXTJOIN og MATCH . Denne formelen er litt komplisert å bruke, men den vil garantert gi de ønskede verdiene.
📌 TRINN
1. Skriv først inn følgende formel i Celle F5 :
=TEXTJOIN(",", TRUE, IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, "")) 
2. Trykk deretter Enter.
3. Til slutt drar du Fyllhåndtak -ikonet over celleområdet F6:F7 .
Til slutt lykkes vi å bruke VLOOKUP flere verdier i én celle uten noen dupliserte verdier.
🔎 Oversikt over formelen
Vi bruker denne inndelingen kun for personen «John»
➤ ROW(C5:C13)
Den returnerer en matrise med {5;6;7;8;9;10;11;12;13}
➤ MATCH(ROW(C5:C13), ROW(C5:C13))
Den returnerer: {1;2;3;4;5;6;7;8;9}
➤ IF(E5=B5:B13, C5:C13, "")
Den returnerer: {"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ MATCH(C5:C13, IF(E5=B5:B13, C5:C13, "")
Denne funksjonen returnerer: {8;8;7;9;7;7;7;8;7}
➤ IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")
Den returnerer: {1;1;"";4;"";6;"";1;""}
➤ IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, "")
Den returnerer: {"Mobile";"";"";"TV";"";"Fridge";"";"";""}
➤ TEXTJOIN(",", TRUE, IF(IFERROR(MATCH(C5:C13, IF(E5=B5:B13, C5:C13, ""), 0),"")=MATCH(ROW(C5:C13), ROW(C5:C13)), C5:C13, ""))
Den endelige utgangen blir Mobil, TV, Kjøleskap .
Les mer: Hvordan utføre VLOOKUP med flere rader i Excel (5 metoder)
1.3TEXTJOIN og UNIQUE-funksjoner (uten duplikater)
Nå er UNIQUE -funksjonen bare tilgjengelig i Excel 365. Så hvis du bruker Excel 365 kan du definitivt bruke denne formelen. Den forrige formelen er litt vanskelig, men denne formelen vil gjøre det enklere å slå opp verdier i én celle. UNIQUE-funksjonen returnerer en liste med unike verdier i en liste eller et område. Forskjellen mellom den første og den tredje formelen er å bruke UNIKK -funksjonen før HVIS -funksjonen.
Den grunnleggende syntaksen til UNIK-funksjonen:
=UNIQUE (array, [by_col], [exactly_once]) matrise – Område eller matrise som unike verdier skal trekkes ut fra.
by_col – [valgfritt] Hvordan sammenligne og trekke ut. Etter rad = FALSE (standard); etter kolonne = TRUE.
exactly_once – [valgfritt] TRUE = verdier som forekommer én gang, FALSE= alle unike verdier (standard)
📌 TRINN
1. Skriv først inn følgende formel i Celle F5 :
=TEXTJOIN(", ",TRUE,UNIQUE(IF(E5=B5:B13,C5:C13,""))) 
2. Trykk deretter Enter.
3. Til slutt drar du Fyllhåndtak -ikonet over celleområdet F6:F7.
Som du kan se, har vi vellykket brukt VLOOKUP flere verdier i én celle.
🔎 Oversikt over formelen
Vi bruker denne oversikten bare for personen «John»
➤ IF(E5=B5:B13,C5:C13,"")
Den returnerer {"Mobile";"";"";"TV";"";"Fridge";"";"Mobile";""}
➤ UNIQUE(IF(E5=B5:B13,C5:C13,""))
Detreturnerer {"Mobile";"";"TV";"Fridge"}
➤ TEXTJOIN(", ",TRUE,UNIQUE(IF(E5=B5:B13,C5:C13,"")))
Endelig resultat Mobil,TV,kjøleskap
Les mer: Hvordan Vlookup og returnerer flere verdier i rullegardinlisten
2. Bruke VBA-koder til Vlookup flere verdier i én celle
TEXTJOIN -funksjonen er bare tilgjengelig for MS Excel 2019 og MS Excel 365 . Så hvis du er godt kjent om Excels VBA-koder, vil disse to kodene være veldig praktiske for deg. Den første vil være med duplikater og den andre vil være uten duplikater. Så velg metoden din i henhold til problemet ditt.
2.1 VBA-koder flere verdier i én celle
📌 TRINN
1. Først. Trykk Alt+F11 for å åpne Visual Basic Editor.
2. Klikk deretter på Sett inn > Modul .
3. Deretter skriver du inn følgende kode:
1845
4. Gå nå til regnearket ditt. Deretter skriver du inn følgende formel i Celle F5 :
=MultipleValues(B5:B13,E5,C5:C13,",") 
5. Trykk deretter ENTER.
6. Til slutt drar du Fill Handle-ikonet over celleområdet F6:F7.
Til slutt har vi brukt VLOOKUP flere verdier i én celle .
Les mer: VLOOKUP for å returnere flere verdier horisontalt i Excel
2.2 VBA Koder for å SLÅ OPP flere verdier i én celle (uten duplikater)
📌 TRINN
1. Først. Trykk Alt+F11 for å åpne Visual Basic Editor.
2. Deretter,klikk på Sett inn > Modul .
3. Deretter skriver du inn følgende kode:
9408
4. Etter å ha satt inn koden, klikk Verktøy > Referanser i det åpnede Microsoft Visual Basic for Applications-vinduet, og deretter, i dialogboksen Referanser – VBAProject som vises, merk av for Microsoft Scripting Runtime i Tilgjengelige referanser listeboks. Klikk på OK .
5. Gå nå til regnearket ditt. Skriv deretter inn følgende formel i Celle F5 :
=ValuesNoDup(E5,B5:B13,2) Her er 2 kolonnenummeret til datasettet.
6. Trykk deretter Enter .
7. Til slutt drar du Fyllhåndtak -ikonet over celleområdet F6:F7.
Som du kan se, har vi brukte VLOOKUP flere verdier i én celle uten duplikater.
Les mer: Hvordan VLOOKUP og returnerer flere verdier i Excel (8 metoder)
Konklusjon
For å konkludere, håper jeg denne veiledningen vil hjelpe deg med å vlookup flere verdier i én celle i Excel. Last ned øvelsesboken og prøv disse selv. Det vil sikkert utvikle Excel-kunnskapen din. Gi også gjerne tilbakemelding i kommentarfeltet. Din verdifulle tilbakemelding holder oss motiverte til å lage mange artikler som disse. Ikke glem å sjekke nettstedet vårt ExcelWIKI for Excel-relaterte problemer og løsninger.
