Formuła INDEX MATCH z wieloma kryteriami w różnych arkuszach

Hugh West

16-10-2023 Formuły programu Excel
  • Udostępnij To
Hugh West

Podczas pracy z dużą tablicą danych, możesz znaleźć się w sytuacji, w której musisz znaleźć kilka unikalnych wartości lub tekstów, ale nie masz konkretnego identyfikatora do tego celu. W takim przypadku, pionowy lub poziomy lookup z kilkoma warunkami jest używany do znalezienia wyniku. Ale zamiast używać tych funkcji, eksperci zazwyczaj stosują INDEX MATCH Połączenie. INDEX oraz MATCH funkcje są lepsze niż VLOOKUP lub HLOOKUP na wiele sposobów. INDEX MATCH formuła może wyszukać wartości za pomocą wiele kryteriów na różnych arkuszach i zwrócić wynik w innym arkuszu. Dziś, w tym artykule, poznamy kilka podejść do wykorzystania Formuła INDEX-MATCH z wieloma kryteriami w różnych arkuszach.

Pobierz Zeszyt ćwiczeń

Możesz pobrać następujące skoroszyty Excela dla lepszego zrozumienia i samodzielnego przećwiczenia.

Zastosowanie NDEX-MATCH z wieloma kryteriami na różnych arkuszach.xlsx

2 Metody zastosowania formuły INDEX MATCH z wieloma kryteriami w różnych arkuszach w Excelu

Na stronie INDEX-MATCH formuła jest dość wydajna, gdy znajdujemy dane z wiele kryteriów dla kolumn i wierszy w różnych arkuszach. Istnieją dwa różne podejścia do wyszukiwania danych z wieloma kryteriami w różnych arkuszach. Zbadajmy je więc po kolei.

Tutaj użyliśmy Microsoft Excel 365 wersja, możesz użyć każdej innej wersji zgodnie z Twoją wygodą.

1. formuła INDEX MATCH z wieloma kryteriami tylko dla kolumn

Dla wyjaśnienia, będziemy używać Miesięczny raport sprzedaży w danej organizacji. Ten zbiór danych zawiera ID , Imię oraz odpowiednio Sprzedaż w kolumnach B , C oraz D odpowiednio.

Rozważmy scenariusz, w którym Twój szef zlecił Ci zadanie obliczenia Sprzedaż kwoty różnych przedstawicieli handlowych za pomocą tego arkusza. Możesz to zrobić w prosty sposób, używając INDEX-MATCH Możesz to zrobić używając formuły tablicowej lub nie tablicowej. Zobaczmy je więc w akcji.

1.1 Użycie formuły tablicowej

W tym przypadku musimy znaleźć Sprzedaż dla konkretnego ID i szczególny Imię z innego arkusza. Ten arkusz nosi nazwę " Zbiór danych " Teraz wykonaj dokładnie poniższe kroki.

📌 Kroki:

  • Najpierw utwórz w nowym arkuszu zakres danych zawierający kolumny ID , Imię oraz Sprzedaż W tym nowym arkuszu znajdziemy wynik w D5:D7 Zakres. Nazwij ten arkusz jako Array .

Teraz zastosujemy INDEX-MATCH wzór, aby znaleźć Sprzedaż ilość.

Ogólny INDEX-MATCH formuła z wieloma kryteriami jest jak poniżej.

=INDEX(return_range, MATCH(1, (criteria1=range1) * (criteria2=range2) * (...), 0)) Gdzie:

zakres to zakres, z którego zostanie zwrócona wartość.

kryteria1 , kryteria2 , ... to warunki, które muszą być spełnione.

zakres1 , zakres2 , ... to zakresy, na których należy wyszukiwać wymagane kryteria.

  • W tym czasie należy wybrać komórkę D5 i wstawić następujący wzór.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,(Array!B5=Dataset!$B$5:$B$15)*(Array!C5=Dataset!$C$5:$C$15),0)) Tutaj,
  • zakres jest Dataset!$D$5:$D$15 Kliknij na Zbiór danych arkusza i wybrać zakres danych.
  • kryteria1 jest Array!B5 ( M-01 ).
  • kryteria2 jest Array!C5 ( Tom ).
  • zakres1 jest Dataset!$B$5:$B$15 Kliknij na Zbiór danych arkusz i wybierz ID kolumna.
  • zakres2 jest Dataset!$C$5:$C$15 Kliknij na Zbiór danych arkusza i wybrać Imię kolumna.
  • lookup_value dla Funkcja MATCH jest 1 ponieważ zapewnia względną lokalizację wiersza dla każdego z warunków, które są TRUE. Lokalizacja pierwszego wyniku jest pobierana, jeśli istnieje kilka instancji 1 w tablicy.
  • dopasowanie_typu jest 0 .
  • Następnie należy nacisnąć ENTER .

Uwaga: Ponieważ jest to formuła tablicowa, upewnij się, że wcisnąłeś CTRL + SHIFT + ENTER zamiast ENTER jeśli używasz innej wersji programu niż Excel 365. I nie umieszczaj tych nawiasów klamrowych wokół formuły. Excel automatycznie doda je do formuły tablicowej .

  • Obecnie należy ustawić kursor w prawym dolnym rogu komórki D5 . Actually, it's the Uchwyt do napełniania narzędzie.
  • W związku z tym należy dwukrotnie kliknąć na to.

  • W rezultacie kopiuje formułę do kolejnych komórek, a ty otrzymasz wyniki również w tych komórkach.

Read More: Jak wybrać określone dane w programie Excel (6 metod)

1.2 Bez użycia formuły tablicowej

Możemy zrobić wcześniejszy przypadek bez użycia formuły tablicowej, zobaczmy jak.

📌 Kroki:

  • Po pierwsze, zrób tabelę jak w poprzednim przykładzie.

Tutaj użyjemy nie-tablicy INDEX-MATCH formuła, zobaczmy najpierw jej postać ogólną.

INDEX(return_range, MATCH(1, INDEX((criteria1=range1) * (criteria2=range2) * (..), 0, 1), 0))
  • Po drugie, przejdź do komórki D5 i wprowadzić następujący wzór.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,INDEX(('Non Array'!B5=Dataset!$B$5:$B$15)*('Non Array'!C5=Dataset!$C$5:$C$15),0,1),0)) Gdzie,
  • zakres jest Dataset!$D$5:$D$15 Kliknij na Zbiór danych arkusza i wybrać zakres danych.
  • kryteria1 jest 'Non Array'!B5 ( L-02 ).
  • kryteria2 jest 'Non Array'!C5 ( Róża ).
  • zakres1 jest Dataset!$B$5:$B$15 Kliknij na Zbiór danych arkusza i wybrać ID kolumna.
  • zakres2 jest Dataset!$C$5:$C$15 Kliknij na Zbiór danych arkusza i wybrać Imię kolumna.
  • lookup_value dla Funkcja MATCH jest 1 .
  • dopasowanie_typu jest 0 .
  • Następnie naciśnij przycisk ENTER klawisz, aby uzyskać wynik.

Read More: Excel Indeks Dopasowanie pojedynczych/wielu kryteriów do pojedynczych/wielu wyników

Podobne lektury

  • Excel INDEX MATCH Jeśli komórka zawiera tekst
  • INDEX MATCH z 3 kryteriami w Excelu (4 przykłady)
  • Excel INDEX MATCH, aby zwrócić wiele wartości w jednej komórce
  • INDEX MATCH Wiele kryteriów z Wildcard w programie Excel (Kompletny przewodnik)
  • [Naprawiono!] INDEX MATCH nie zwraca prawidłowej wartości w Excelu (5 powodów)

2. formuła INDEX MATCH z wieloma kryteriami dla wierszy i kolumn

Jedną z unikalnych cech INDEX-MATCH formuła polega na tym, że może jednocześnie wyszukiwać wartości zarówno w wierszach, jak i kolumnach w różnych arkuszach. teraz się o tym przekonamy.

Załóżmy, że twój szef właśnie dał ci zbiór danych, w którym Nazwa , ID niektórych sprzedaży z Sprzedaż miesięcy Jan , Mar , Maj , Jul oraz Sep Nazwa tego arkusza to " Zbiór danych2 ".

Obecnie, musisz znaleźć Sprzedaż dla pewnych kryteriów w innym arkuszu. Chodźmy za nami.

📌 Kroki:

  • Na początku skonstruuj inną tabelę w innym arkuszu, zawierającą kolumny Nazwa , ID , Miesiąc gdzie podane są kryteria. Następnie nazwij ten arkusz Wiersz-kolumna Musisz odzyskać Sprzedaż stosując podane kryteria.

W związku z tym musimy zastosować INDEX-MATCH formuła z wieloma kryteriami w tym arkuszu. Format tej formuły jest jak poniżej.

=INDEX(table_array, MATCH(vlookup_value, lookup_column, 0), MATCH(hlookup_value1 & hlookup_value2, lookup_row1 & lookup_row2, 0))
  • Następnie przejdź do komórki E5 i zadzwonić do Funkcja INDEX .
=INDEX(
  • Następnie należy przejść do " Zbiór danych2 " arkusz.

  • Później należy wybrać tablica który jest C5:G19 zakres w Zbiór danych2 arkusz roboczy.

  • Następnie uzupełnij pełną formułę jak poniżej.
=INDEX(Dataset2!$C$6:$G$20,MATCH('Row-Column'!B5,Dataset2!$B$6:$B$11,0),MATCH('Row-Column'!C5&'Row-Column'!D5,Dataset2!$C$4:$G$4&Dataset2!$C$5:$G$5,0)) Gdzie,
  • vlookup_value jest 'Wiersz-kolumna'!B5 ( K-01 ). lookup_kolumny jest Dataset2!$B$6:$B$11 .
  • hlookup_value1 jest 'Wiersz-kolumna'!C5 ( Tom ).
  • hlookup_value2 jest 'Wiersz-kolumna'!D5 ( Maj ).
  • lookup_row1 jest Dataset2!$C$4:$G$4 .
  • lookup_row2 jest Dataset2!$C$5:$G$5 .
  • dopasowanie_typu jest 0 .

Dlatego na poniższym obrazku możemy zobaczyć wybrane wiersze i kolumny.

  • Na koniec naciśnij ENTER .

  • Dodatkowo należy użyć Uchwyt do napełniania narzędzie, aby uzyskać pełne wyniki w dolnych komórkach kolumny.

Jak zastosować formułę INDEX MATCH z wieloma kryteriami dla zakresu dat?

Możemy wyodrębnić cenę danego produktu w określonym dniu.

Mamy tu listę produktów z ich okresami początkowymi i końcowymi oraz odpowiadającą im ceną jednostkową.

Załóżmy, że chcemy zobaczyć cenę Lody na stronie 02-10-22 (miesiąc-dzień-rok) . Jeśli podana data mieści się w oferowanym przedziale czasowym, będziemy mieli wyciągniętą cenę w dowolnej pustej komórce. Zatem, bez dalszej zwłoki, zobaczmy, jak to zrobić.

📌 Kroki:

  • Po pierwsze, zbuduj zakres wyjściowy w D19:D21 Tutaj decydujemy się na znalezienie go dla 3 produkty. można dostosować go do swoich potrzeb.

  • Po drugie, przejdź do komórki D19 i wprowadź następującą formułę tablicową.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=B19)*($D$5:$D$16>=C19)*($C$5:$C$16<=C19)),0))
  • Następnie uderz w ENTER .

Możemy zobaczyć #N/A błąd w komórce D21 ponieważ data w komórce C21 nie leży w opisanym okresie w zbiorze danych.

Jeśli chcesz poznać więcej technik i przykładów dotyczących tego tematu, możesz przeczytać artykuł Jak użyć INDEX MATCH z wieloma kryteriami dla zakresu dat? .

Inteligentna alternatywa dla INDEX MATCH z wieloma kryteriami

Jeśli jesteś użytkownikiem Office 365 , tylko wtedy jesteś uprawniony do uzyskania korzyści z tej funkcji.Teraz użyjemy Funkcja FILTRU aby wykonać to samo zadanie. Aby więc tak się stało, zastosuj się do poniższych wskazówek.

📌 Kroki:

  • Po pierwsze, utwórz arkusz taki jak Metoda 1 .
  • Następnie wybierz komórkę D5 i wstawić następujący wzór.
=FILTER(Dataset!$D$5:$D$15,(Dataset!$B$5:$B$15=Alternative!B5)*(Dataset!$C$5:$C$15=Alternative!C5))

Dzięki temu ta formuła jest łatwiejsza do zastosowania i zrozumienia niż poprzednie.Aby uzyskać wyjaśnienie, przejdź do INDEX MATCH z wieloma kryteriami artykuł.

  • Po drugie, naciśnij przycisk ENTER klucz.

Szybkie notatki

⏩ The INDEX MATCH jest zwykle formułą tablicową. Musisz więc nacisnąć CTRL+SHIFT+ENTER zamiast ENTER aby uzyskać wynik.

⏩ Jeśli chcesz zastosować tę samą formułę dla pozostałych komórek, pamiętaj, aby zamrozić zakres danych za pomocą bezwzględnego odwołania do komórki ( $ ). Wystarczy nacisnąć F4 aby zastosować go do wzoru.

Wniosek

Ten artykuł wyjaśnia, jak używać INDEX MATCH z wieloma kryteriami w różnych arkuszach w Excelu w prosty i zwięzły sposób. Dodatkowo, nie zapomnij pobrać Praktyka plik. dziękujemy za przeczytanie tego artykułu. mamy nadzieję, że był on pomocny. prosimy dać nam znać w sekcji komentarzy, jeśli masz jakieś pytania lub sugestie. zapraszamy na naszą stronę internetową, Exceldemy , dostawcy kompleksowych rozwiązań dla programu Excel, aby dowiedzieć się więcej.

Poprzedni post Jak wydrukować arkusz Excel z liniami (3 proste sposoby)
Następny post Wykres rozkładu normalnego w Excelu z średnią i odchyleniem standardowym

Hugh West jest bardzo doświadczonym trenerem i analitykiem Excela z ponad 10-letnim doświadczeniem w branży. Posiada tytuł licencjata w dziedzinie rachunkowości i finansów oraz tytuł magistra administracji biznesowej. Hugh ma pasję do nauczania i opracował unikalne podejście do nauczania, które jest łatwe do naśladowania i zrozumienia. Jego specjalistyczna wiedza na temat programu Excel pomogła tysiącom studentów i profesjonalistów na całym świecie doskonalić swoje umiejętności i osiągać doskonałe wyniki w karierze. Za pośrednictwem swojego bloga Hugh dzieli się swoją wiedzą ze światem, oferując bezpłatne samouczki programu Excel i szkolenia online, aby pomóc osobom indywidualnym i firmom w pełni wykorzystać swój potencjał.