INDEX MATCH Formula na may Maramihang Pamantayan sa Iba't ibang Sheet

Hugh West

16-10-2023 Mga Formula ng Excel
  • Ibahagi Ito
Hugh West

Kapag nagtatrabaho sa isang malaking hanay ng data, maaari mong makita ang iyong sarili sa isang sitwasyon kung saan kailangan mong maghanap ng ilang natatanging value o text ngunit wala kang partikular na identifier para sa layuning ito. Sa kasong ito, isang patayo o pahalang na paghahanap na may ilang kundisyon ang ginagamit upang mahanap ang resulta. Ngunit sa halip na gamitin ang mga function na ito, karaniwang ginagamit ng mga ekspertong user ang kumbinasyong INDEX MATCH . Ang kumbinasyon ng INDEX at MATCH function ay mas mataas kaysa sa VLOOKUP o HLOOKUP sa maraming paraan. Ang formula na INDEX MATCH ay maaaring maghanap ng mga value na may maraming pamantayan sa ibang sheet at ibalik ang resulta sa isa pang worksheet. Ngayon, sa artikulong ito, matututunan natin ang ilang diskarte sa paggamit ng INDEX-MATCH formula na may maraming pamantayan sa iba't ibang sheet.

I-download ang Practice Workbook

Maaari mong i-download ang pagsunod sa mga workbook ng Excel para sa mas mahusay na pag-unawa at pagsasanay sa iyong sarili.

Paglalapat ng NDEX-MATCH na may Maramihang Pamantayan sa Iba't ibang Sheet.xlsx

2 Paraan para Ilapat ang INDEX MATCH Formula na may Maramihang Pamantayan sa Iba't ibang Sheet sa Excel

Ang formula na INDEX-MATCH ay medyo mahusay kapag nakakahanap ka ng data na may maraming pamantayan para sa parehong mga column at row sa magkakaibang mga sheet. Mayroong dalawang natatanging diskarte sa paghahanap ng data na may maraming pamantayan sa iba't ibang mga sheet. Kaya, i-explore natin sila isa-isa.

Narito, mayroon tayoginamit ang bersyon ng Microsoft Excel 365 , maaari kang gumamit ng anumang iba pang bersyon ayon sa iyong kaginhawahan.

1. INDEX MATCH Formula na may Maramihang Pamantayan para sa Mga Column Lamang

Para sa paglilinaw, gagamit tayo ng Buwanang Ulat sa Pagbebenta ng isang partikular na organisasyon. Kasama sa dataset na ito ang ID , First Name , at ang kani-kanilang Sales sa mga column B , C , at D nang naaayon.

Isaalang-alang ang isang senaryo kung saan itinalaga sa iyo ng iyong boss ang gawain ng pagkalkula ng Mga Benta mga halaga ng iba't ibang kinatawan ng pagbebenta gamit ang worksheet na ito. Madali mo itong magagawa sa pamamagitan ng paggamit ng formula na INDEX-MATCH . Magagawa mo ito gamit ang alinman sa array o non-array formula. Kaya, tingnan natin ang mga ito sa pagkilos.

1.1 Gamit ang Array Formula

Sa kasong ito kailangan nating maghanap ng Mga Benta para sa isang partikular na ID at isang partikular na Unang Pangalan mula sa ibang worksheet. Ang worksheet na ito ay pinangalanang " Dataset " . Ngayon, sundin nang mabuti ang mga hakbang sa ibaba.

📌 Mga Hakbang:

  • Una, gumawa ng hanay ng data sa isang bagong worksheet na naglalaman ng mga column ID , Unang Pangalan , at Mga Benta . Sa bagong worksheet na ito, makikita natin ang resulta sa hanay na D5:D7 . Pangalanan ang worksheet na ito bilang Array .

Ngayon, ilalapat namin ang INDEX-MATCH formula upang mahanap ang Mga Benta halaga.

Ang generic na formula na INDEX-MATCH na may maraming pamantayan ay tulad ng sumusunod.

=INDEX(return_range, MATCH(1, ( criteria1=range1) * (criteria2=range2) * (…), 0))Kung saan:

return_range ay ang range kung saan ibabalik ang value.

criteria1 , criteria2 , … ang mga kundisyon na dapat matugunan.

range1 , range2 , … ay ang mga saklaw kung saan dapat hanapin ang kinakailangang pamantayan.

  • Sa oras na ito, piliin ang cell D5 at ipasok ang sumusunod na formula.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,(Array!B5=Dataset!$B$5:$B$15)*(Array!C5=Dataset!$C$5:$C$15),0)) Dito, ang
  • return_range ay Dataset!$D$5:$D$15 . Mag-click sa Dataset worksheet at piliin ang hanay ng data.
  • criteria1 ay Array!B5 ( M-01 ).
  • criteria2 ay Array!C5 ( Tom ).
  • range1 ay Dataset!$B$5:$B$15 . Mag-click sa Dataset worksheet at piliin ang column na ID .
  • range2<9 Ang> ay Dataset!$C$5:$C$15 . Mag-click sa Dataset worksheet at piliin ang column na First Name .
  • lookup_value para sa MATCH function ay 1 dahil nagbibigay ito ng kaugnay na lokasyon ng row para sa bawat isa sa mga kundisyon na TOTOO. Ang lokasyon ng unang resulta ay kinukuha kung mayroong ilang pagkakataon ng 1 saarray.
  • match_type ay 0 .
  • Pagkatapos noon, pindutin ang ENTER .

Tandaan: Dahil isa itong array formula, tiyaking pinindot mo ang CTRL + SHIFT + ENTER sa halip na ENTER kung gumagamit ka ng anumang bersyon maliban sa Excel 365 . At huwag ilagay ang mga kulot na braces sa paligid ng formula. Awtomatikong idaragdag ng Excel ang mga ito sa array formula .

  • Sa kasalukuyan, dalhin ang cursor sa kanang ibabang sulok ng cell D5 . Sa totoo lang, ito ang tool na Fill Handle .
  • Dahil dito, i-double click ito.

  • Bilang isang resulta, kinokopya nito ang formula sa mga sumusunod na cell, at makakakuha ka rin ng mga resulta sa mga cell na iyon.

Magbasa Nang Higit Pa: Paano Pumili ng Tukoy na Data sa Excel (6 na Paraan)

1.2 Nang Hindi Gumagamit ng Array Formula

Magagawa natin ang naunang kaso nang hindi gumagamit ng array formula. Tingnan natin kung paano.

📌 Mga Hakbang:

  • Una, gumawa ng talahanayan tulad ng nakaraang halimbawa.

Dito, gagamitin namin ang non-array na INDEX-MATCH na formula. Tingnan muna natin ang generic na anyo nito.

INDEX(return_range, MATCH(1, INDEX((criteria1=range1) * (criteria2=range2) * (..), 0, 1) , 0))
  • Pangalawa, pumunta sa cell D5 at ilagay ang sumusunod na formula.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,INDEX(('Non Array'!B5=Dataset!$B$5:$B$15)*('Non Array'!C5=Dataset!$C$5:$C$15),0,1),0)) Kung saan,
  • return_range ay Dataset!$D$5:$D$15 . Mag-click sa Dataset worksheet at piliin ang hanay ng data.
  • criteria1 ay 'Non Array'!B5 ( L-02 ).
  • criteria2 ay 'Non Array'!C5 ( Rose ).
  • range1 ay Dataset!$B$5:$B$15 . Mag-click sa Dataset worksheet at piliin ang column na ID .
  • range2<9 Ang> ay Dataset!$C$5:$C$15 . Mag-click sa Dataset worksheet at piliin ang column na First Name .
  • lookup_value para sa MATCH function ay 1 .
  • match_type ay 0 .
  • Pagkatapos, pindutin ang ENTER key para makuha ang resulta.

Magbasa Nang Higit Pa: Excel Index Itugma ang isa/maraming pamantayan na may iisa/maraming resulta

Mga Katulad na Pagbasa

  • Excel INDEX MATCH Kung Naglalaman ang Cell ng Text
  • INDEX MATCH na may 3 Criteria sa Excel (4 na Halimbawa)
  • Excel INDEX MATCH para Magbalik ng Maramihang Value sa Isang Sel Excel (5 Dahilan)

2. INDEX MATCH Formula na may Maramihang Pamantayan para sa Mga Row at Column

Isa sa mga natatanging feature ng INDEX-MATCH ang formula ay maaari itong sabay na maghanap ng mga halaga sa parehong mga row at column sa magkaibangmga sheet. Malalaman natin ngayon.

Isaalang-alang natin na binigyan ka ng iyong boss ng isang dataset kung saan Pangalan , ID ng ilang benta na may Mga Benta ng mga buwan Ene , Mar , Mayo , Hul at Sep ay ibinigay. Ang pangalan ng worksheet na ito ay " Dataset2 ".

Sa kasalukuyan, kailangan mong hanapin ang Sales para sa ilang ibinigay na pamantayan sa ibang sheet. Subaybayan natin.

📌 Mga Hakbang:

  • Sa una, bumuo ng isa pang talahanayan sa ibang sheet na naglalaman ng mga column Pangalan , ID , Buwan kung saan ibinigay ang mga pamantayan. Pagkatapos, pangalanan ang sheet na ito Row-Column . Kailangan mong kunin ang Mga Benta gamit ang ibinigay na pamantayan.

Dahil dito, kailangan nating ilapat ang INDEX-MATCH formula na may maraming pamantayan sa sheet na ito. Ang format ng formula na ito ay tulad ng sumusunod.

=INDEX(table_array, MATCH(vlookup_value, lookup_column, 0), MATCH(hlookup_value1 & hlookup_value2, lookup_row1 & lookup_row2, 0) )
  • Pagkatapos, pumunta sa cell E5 at tawagan ang INDEX function .
=INDEX(
  • Pagkatapos nito, mag-navigate sa “ Dataset2 ” na sheet.

  • Mamaya, piliin ang table_array na siyang C5:G19 range sa Dataset2 worksheet.

  • Susunod, kumpletuhin ang buong formula tulad ng sumusunod.
=INDEX(Dataset2!$C$6:$G$20,MATCH('Row-Column'!B5,Dataset2!$B$6:$B$11,0),MATCH('Row-Column'!C5&'Row-Column'!D5,Dataset2!$C$4:$G$4&Dataset2!$C$5:$G$5,0)) Kung saan,
  • vlookup_value ay 'Row-Column'!B5 ( K-01 ). lookup_column ay Dataset2!$B$6:$B$11 .
  • Ang hlookup_value1 ay 'Row-Column'!C5 ( Tom ).
  • hlookup_value2 ay 'Row-Column'!D5 ( Mayo ).
  • <8 Ang>lookup_row1 ay Dataset2!$C$4:$G$4 .
  • lookup_row2 ay Dataset2! $C$5:$G$5 .
  • match_type ay 0 .

Samakatuwid, makikita natin ang mga napiling row at column sa larawan sa ibaba.

  • Sa wakas, pindutin ang ENTER .

  • Bukod pa rito, gamitin ang tool na Fill Handle para makakuha ng kumpletong resulta sa ibabang mga cell sa column.

Paano Mag-apply ng INDEX MATCH Formula na may Maramihang Pamantayan para sa Hanay ng Petsa

Maaari naming i-extract ang presyo ng isang partikular na produkto sa isang partikular na petsa.

Narito, mayroon kaming listahan ng mga produkto kasama ang kanilang simula at pagtatapos na mga panahon at ang kanilang katumbas na presyo ng yunit.

Ipagpalagay na gusto naming makita ang presyo ng isang Ice Cream sa 02-10-22 (buwan-araw-taon) . Kung mahulog ang ibinigay na petsa sa loob ng inaalok na yugto ng panahon, kukunin namin ang presyo sa anumang blangkong cell. Kaya, nang walang karagdagang pagkaantala, tingnan natin kung paano gawinito.

📌 Mga Hakbang:

  • Una, bumuo ng hanay ng output sa hanay ng D19:D21 . Dito, pinili naming hanapin ito para sa 3 mga produkto. Maaari mo itong i-customize ayon sa iyong mga pangangailangan.

  • Pangalawa, pumunta sa cell D19 at ilagay ang sumusunod na array formula.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=B19)*($D$5:$D$16>=C19)*($C$5:$C$16<=C19)),0))
  • Pagkatapos noon, pindutin ang ENTER .

Nakikita namin ang isang #N/A error sa cell D21 dahil ang petsa sa cell C21 ay hindi nasa loob ng inilarawang panahon sa dataset.

Kung gusto mong malaman ang higit pang mga diskarte at halimbawa tungkol sa paksang ito, maaari mong basahin ang artikulong Paano Gamitin ang INDEX MATCH na may Maramihang Pamantayan para sa Hanay ng Petsa .

Matalinong Alternatibong INDEX MATCH na may Maramihang Pamantayan

Kung user ka ng Office 365 , karapat-dapat ka lang na makuha ang benepisyo ng function na ito. Ngayon, gagamitin namin ang FILTER function para gawin ang parehong trabaho. Kaya, para magawa ito, sumunod sa mga alituntunin sa ibaba.

📌 Mga Hakbang:

  • Una, gumawa ng worksheet tulad ng Paraan 1 .
  • Pagkatapos, piliin ang cell D5 at ipasok ang sumusunod na formula.
=FILTER(Dataset!$D$5:$D$15,(Dataset!$B$5:$B$15=Alternative!B5)*(Dataset!$C$5:$C$15=Alternative!C5))

Kaya, ang formula na ito ay mas madaling ilapat at maunawaan kaysa sa mga nauna. Para sa paliwanag, pumunta sa artikulong INDEX MATCH with Multiple Criteria .

  • Pangalawa, pindutin ang ENTER key.

Mga Mabilisang Tala

⏩ Ang INDEXAng MATCH ay karaniwang isang array formula. Kaya, kailangan mong pindutin ang CTRL+SHIFT+ENTER sa halip na ENTER para makuha ang resulta.

⏩ Kung gusto mong ilapat ang parehong formula para sa natitirang bahagi ng ang mga cell, tandaan na i-freeze ang hanay ng data gamit ang isang ganap na sanggunian ng cell ( $ ). Pindutin lang ang F4 para ilapat ito sa formula.

Konklusyon

Ipinapaliwanag ng artikulong ito kung paano gamitin ang INDEX MATCH na may maraming pamantayan sa iba't ibang sheet sa Excel sa isang simple at maigsi na paraan. Bukod pa rito, huwag kalimutang i-download ang Practice file. Salamat sa pagbabasa ng artikulong ito. Umaasa kami na ito ay nakatulong. Mangyaring ipaalam sa amin sa seksyon ng komento kung mayroon kang anumang mga katanungan o mungkahi. Pakibisita ang aming website, Exceldemy , isang one-stop na Excel solution provider, para mag-explore pa.

Nakaraang post Paano Mag-print ng Excel Sheet na may Mga Linya (3 Madaling Paraan)
Susunod na post I-plot ang Normal Distribution sa Excel na may Mean at Standard Deviation

Si Hugh West ay isang napakaraming Excel trainer at analyst na may higit sa 10 taong karanasan sa industriya. May hawak siyang Bachelor's degree sa Accounting and Finance at Master's degree sa Business Administration. Si Hugh ay may hilig sa pagtuturo at nakabuo ng kakaibang diskarte sa pagtuturo na madaling sundin at maunawaan. Ang kanyang dalubhasang kaalaman sa Excel ay nakatulong sa libu-libong mag-aaral at propesyonal sa buong mundo na mapabuti ang kanilang mga kasanayan at maging mahusay sa kanilang mga karera. Sa pamamagitan ng kanyang blog, ibinahagi ni Hugh ang kanyang kaalaman sa mundo, nag-aalok ng mga libreng Excel tutorial at online na pagsasanay upang matulungan ang mga indibidwal at negosyo na maabot ang kanilang buong potensyal.