Fórmula INDEX MATCH amb criteris múltiples en un full diferent

Hugh West

16-10-2023 Fórmules Excel
  • Comparteix Això
Hugh West

Quan treballeu amb una gran varietat de dades, és possible que us trobeu en una situació en què necessiteu trobar alguns valors o textos únics però no teniu un identificador específic per a aquest propòsit. En aquest cas, s'utilitza una cerca vertical o horitzontal amb diverses condicions per trobar el resultat. Però en lloc d'utilitzar aquestes funcions, els usuaris experts normalment apliquen la combinació INDEX MATCH . La combinació de les funcions INDEX i MATCH és superior a VLOOKUP o HLOOKUP en molts aspectes. La fórmula INDEX MATCH pot cercar valors amb criteris múltiples en un full diferent i retornar el resultat en un altre full de treball. Avui, en aquest article, aprendrem alguns enfocaments per utilitzar la fórmula INDEX-COMPARACIÓ amb diversos criteris en diferents fulls.

Descarregar el quadern de pràctiques

Pots baixar el seguint els quaderns d'Excel per entendre's i practicar millor.

Aplicar NDEX-MATCH amb criteris múltiples en diferents fulls.xlsx

2 mètodes per aplicar la fórmula INDEX MATCH amb diversos criteris en un full diferent d'Excel

La fórmula INDEX-MATCH és bastant eficient quan cerqueu dades amb criteris múltiples tant per a columnes com per a files en fulls diferents. Hi ha dos enfocaments distintius per cercar dades amb diversos criteris en diferents fulls. Així doncs, anem a explorar-los un per un.

Aquí tenimHa utilitzat la versió Microsoft Excel 365 , podeu utilitzar qualsevol altra versió segons la vostra conveniència.

1. Fórmula de concordança d'índex amb criteris múltiples només per a columnes

Per aclarir-ho, utilitzarem un Informe de vendes mensual d'una organització concreta. Aquest conjunt de dades inclou l' ID , el Nom i les seves respectives Vendes a les columnes B , C i D corresponent.

Penseu en un escenari en què el vostre cap us ha assignat la tasca de calcular els imports Vendes de diversos representants de vendes utilitzant aquest full de treball. Podeu fer-ho fàcilment utilitzant la fórmula INDEX-MATCH . Podeu fer-ho utilitzant una fórmula de matriu o una fórmula que no sigui matriu. Així doncs, veiem-los en acció.

1.1 Ús de la fórmula de matriu

En aquest cas hem de trobar Vendes per a un ID i un Nom específic d'un full de treball diferent. Aquest full de treball s'anomena " Conjunt de dades " . Ara, seguiu els passos següents amb cura.

📌 Passos:

  • Primer, feu un interval de dades en un full de treball nou que contingui columnes ID , Nom i Vendes . En aquest nou full de treball, trobarem el resultat a l'interval D5:D7 . Anomena aquest full de treball com a Matriu .

Ara, aplicarem la INDEX-MATCH fórmula per trobar les Vendes import.

La fórmula genèrica INDEX-MATCH amb diversos criteris és com la següent.

=INDEX(return_range, MATCH(1, ( criteri1=interval1) * (criteri2=interval2) * (…), 0))On:

interval_retorn és l'interval des del qual es retornarà el valor.

criteri1 , criteri2 , … són les condicions que s'han de complir.

interval1 , interval2 , … són els intervals en què s'han de cercar els criteris requerits.

  • En aquest moment, seleccioneu la cel·la D5 i inseriu la fórmula següent.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,(Array!B5=Dataset!$B$5:$B$15)*(Array!C5=Dataset!$C$5:$C$15),0)) Aquí,
  • interval_retorn és Conjunt de dades!$D$5:$D$15 . Feu clic al full de treball Conjunt de dades i seleccioneu l'interval de dades.
  • criteri1 és Matriu!B5 ( M-01 ).
  • criteri2 és Matriu!C5 ( Tom ).
  • interval1 és Conjunt de dades!$B$5:$B$15 . Feu clic al full de treball Conjunt de dades i seleccioneu la columna ID .
  • interval2 és Conjunt de dades!$C$5:$C$15 . Feu clic al full de treball Conjunt de dades i seleccioneu la columna Nom .
  • valor_de_cerca per a la funció MATCH és 1 ja que proporciona la ubicació relativa de la fila per a cadascuna de les condicions que són VERTADES. La ubicació del primer resultat es recupera si hi ha diverses instàncies d'1 almatriu.
  • match_type és 0 .
  • Després, premeu ENTER .

Nota: Com que es tracta d'una fórmula de matriu, assegureu-vos de prémer CTRL + MAJÚS + INTRO en comptes de ENTER si feu servir qualsevol versió que no sigui Excel 365. I no posis aquestes claus al voltant de la fórmula. L'Excel els afegirà automàticament a la fórmula de matriu .

  • Actualment, porteu el cursor a l'extrem inferior dret de la cel·la D5 . En realitat, és l'eina Emplenar mànec .
  • Per tant, feu doble clic sobre aquesta.

  • Com com a resultat, copia la fórmula a les cel·les següents i també obtindreu resultats en aquestes cel·les.

Més informació: Com seleccionar dades específiques a Excel (6 mètodes)

1.2 Sense utilitzar la fórmula de matriu

Podem fer el cas anterior sense utilitzar la fórmula de matriu. Vegem com.

📌 Passos:

  • En primer lloc, fes una taula com l'exemple anterior.

Aquí, utilitzarem la fórmula INDEX-MATCH que no sigui matriu. Vegem-ne primer la forma genèrica.

INDEX(interval_retorn, MATCH(1, INDEX((criteri1=interval1) * (criteri2=interval2) * (..), 0, 1) , 0))
  • En segon lloc, aneu a la cel·la D5 i introduïu la fórmula següent.
=INDEX(Dataset!$D$5:$D$15,MATCH(1,INDEX(('Non Array'!B5=Dataset!$B$5:$B$15)*('Non Array'!C5=Dataset!$C$5:$C$15),0,1),0)) On,
  • interval_retorn és Conjunt de dades!$D$5:$D$15 . Feu clic a Conjunt de dades i seleccioneu l'interval de dades.
  • criteri1 és 'No Array'!B5 ( L-02 ).
  • criteri2 és 'No Array'!C5 ( Rose ).
  • interval1 és Conjunt de dades!$B$5:$B$15 . Feu clic al full de treball Conjunt de dades i seleccioneu la columna ID .
  • interval2 és Conjunt de dades!$C$5:$C$15 . Feu clic al full de treball Conjunt de dades i seleccioneu la columna Nom .
  • valor_de_cerca per a la funció MATCH és 1 .
  • match_type és 0 .
  • A continuació, premeu la tecla ENTER per obtenir el resultat.

Llegir més: Index d'Excel Relaciona criteris únics/múltiples amb resultats únics/múltiples

Lectures similars

  • Coincidència d'índex d'Excel si la cel·la conté text
  • Coincidència d'índex amb 3 criteris a Excel (4 exemples)
  • Coincidència d'índex d'Excel per retornar diversos valors a Una cel·la
  • INDEX MATCH Diversos criteris amb comodí a Excel (una guia completa)
  • [Fixat!] INDEX MATCH no retorna el valor correcte a Excel (5 raons)

2. Fórmula INDEX MATCH amb criteris múltiples per a files i columnes

Una de les característiques úniques de la INDEX-MATCH La fórmula és que pot cercar valors simultàniament a les dues files i columnes en diferentsllençols. Ara ho descobrirem.

Considerem que el teu cap t'acaba de donar un conjunt de dades on Nom , ID d'algunes vendes amb Ventes dels mesos gen , mar , Es donen maig , jul i set . El nom d'aquest full de treball és " Dataset2 ".

En l'actualitat, heu de trobar el Vendes per a uns criteris donats en un full diferent. Seguim-nos.

📌 Passos:

  • En principi, construïu una altra taula en un full diferent que contingui les columnes Nom , ID , Mes on es donen els criteris. A continuació, poseu un nom a aquest full Fila-Columna . Heu de recuperar les Vendes utilitzant els criteris donats.

En conseqüència, hem d'aplicar el <1 Fórmula>INDEX-MATCH amb diversos criteris en aquest full. El format d'aquesta fórmula és com el següent.

=INDEX(matriu_taula, MATCH(valor_cerca, columna_cerca, 0), MATCH(valor_cerca1 & valor_recerca2, fila_cerca1 i fila_cerca2, 0) )
  • A continuació, aneu a la cel·la E5 i truqueu a la funció INDEX .
=INDEX(
  • Després, navegueu fins al full " Dataset2 ".

  • Més endavant, seleccioneu el table_array que és l'interval C5:G19 al Dataset2 full de treball.

  • A continuació, completeu la fórmula completa com la següent.
=INDEX(Dataset2!$C$6:$G$20,MATCH('Row-Column'!B5,Dataset2!$B$6:$B$11,0),MATCH('Row-Column'!C5&'Row-Column'!D5,Dataset2!$C$4:$G$4&Dataset2!$C$5:$G$5,0)) On,
  • vlookup_value és 'Columna de fila'! B5 ( K-01 ). columna_de_cerca és Conjunt de dades2!$B$6:$B$11 .
  • hlookup_value1 és 'Row-Columna'! C5 ( Tom ).
  • hlookup_value2 és 'Columna de fila'! D5 ( Maig ).
  • lookup_row1 és Dataset2!$C$4:$G$4 .
  • lookup_row2 és Dataset2! $C$5:$G$5 .
  • match_type és 0 .

Per tant, podem veure les files i columnes seleccionades a la imatge següent.

  • Finalment, premeu INTRO .

  • A més, utilitzeu l'eina Emplenar mànec per obtenir resultats complets a les cel·les inferiors de la columna.

Com aplicar la fórmula INDEX MATCH amb diversos criteris per a l'interval de dates

Podem extreure el preu de un producte determinat en una data concreta.

Aquí tenim una llista de productes amb els períodes d'inici i finalització i el preu unitari corresponent.

Suposem volem veure el preu d'un Gelat el 02-10-22 (mes-dia-any) . Si la data indicada es troba dins del període de temps ofert, tindrem el preu extret en qualsevol cel·la en blanc. Així que, sense més demora, veurem com fer-ho

📌 Passos:

  • En primer lloc, creeu un interval de sortida a l'interval D19:D21 . Aquí, optem per trobar-lo per a 3 productes. Podeu personalitzar-lo segons les vostres necessitats.

  • En segon lloc, aneu a la cel·la D19 i introduïu la fórmula de matriu següent.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=B19)*($D$5:$D$16>=C19)*($C$5:$C$16<=C19)),0))
  • Després, premeu ENTER .

Podem veure un #N/A error a la cel·la D21 perquè la data de la cel·la C21 no es troba dins del període descrit a la conjunt de dades.

Si voleu conèixer més tècniques i exemples sobre aquest tema, podeu llegir l'article Com utilitzar INDEX MATCH amb diversos criteris per a l'interval de dates .

Alternativa intel·ligent d'INDEX MATCH amb criteris múltiples

Si sou un usuari d' Office 365 , només aleshores podreu obtenir el benefici d'aquesta funció. Ara, utilitzarem la funció FILTRE per fer el mateix treball. Per tant, per fer-ho realitat, seguiu les directrius següents.

📌 Passos:

  • Primer, creeu un full de treball com Mètode 1 .
  • A continuació, seleccioneu la cel·la D5 i inseriu la fórmula següent.
=FILTER(Dataset!$D$5:$D$15,(Dataset!$B$5:$B$15=Alternative!B5)*(Dataset!$C$5:$C$15=Alternative!C5))

Així, aquesta fórmula és més fàcil d'aplicar i entendre que les anteriors. Per obtenir-ne una explicació, aneu a l'article CONCORDACIÓ ÍNDICE amb criteris múltiples .

  • En segon lloc, premeu la tecla ENTER .

Notes ràpides

⏩ El INDEXMATCH normalment és una fórmula matricial. Per tant, heu de prémer CTRL+MAJ+ENTER en lloc de ENTER per obtenir el resultat.

⏩ Si voleu aplicar la mateixa fórmula per a la resta de les cel·les, recordeu congelar l'interval de dades mitjançant una referència de cel·la absoluta ( $ ). Simplement premeu F4 per aplicar-lo a la fórmula.

Conclusió

Aquest article explica com utilitzar INDEX MATCH amb diversos criteris en diferents fulls de Excel·leu d'una manera senzilla i concisa. A més, no us oblideu de baixar el fitxer Pràctica . Gràcies per llegir aquest article. Esperem que això hagi estat útil. Feu-nos-ho saber a la secció de comentaris si teniu cap consulta o suggeriment. Visiteu el nostre lloc web, Exceldemy , un proveïdor únic de solucions d'Excel, per explorar-ne més.

Publicació anterior Com imprimir un full d'Excel amb línies (3 maneres senzilles)
Següent post Traceu la distribució normal en Excel amb mitjana i desviació estàndard

Hugh West és un entrenador i analista d'Excel molt experimentat amb més de 10 anys d'experiència en el sector. És llicenciat en Comptabilitat i Finances i Màster en Administració i Direcció d'Empreses. Hugh té una passió per l'ensenyament i ha desenvolupat un enfocament pedagògic únic que és fàcil de seguir i entendre. El seu coneixement expert d'Excel ha ajudat a milers d'estudiants i professionals de tot el món a millorar les seves habilitats i a destacar en les seves carreres. A través del seu bloc, Hugh comparteix els seus coneixements amb el món, oferint tutorials d'Excel gratuïts i formació en línia per ajudar les persones i les empreses a assolir tot el seu potencial.