Як вярнуць некалькі значэнняў на аснове аднаго крытэрыю ў Excel

Hugh West

29-05-2023 Формулы excel
  • Падзяліцца Гэтым
Hugh West

Калі вы шукаеце, каб Excel вяртаў некалькі значэнняў на аснове аднаго крытэрыю, вы знаходзіцеся ў правільным месцы. Пры выкарыстанні Excel пошук некалькіх значэнняў на аснове розных крытэрыяў з'яўляецца звычайнай працай і неабходны для эфектыўнай працы любой праграмы. У гэтым артыкуле мы паспрабуем абмеркаваць спосабы вяртання некалькіх значэнняў на аснове аднаго крытэрыю ў Excel.

Спампаваць практычны сшытак

Вярнуць некалькі значэнняў на аснове аднаго крытэрыю .xlsx

3 спосабы вяртання некалькіх значэнняў на аснове аднаго крытэрыю ў Excel

Давайце спачатку паглядзім на гэты набор даных. У нас ёсць спіс усіх чэмпіянатаў свету ФІФА , якія адбыліся з 1930 да 2018 . У нас ёсць Год у Калонцы B , Краіна-гаспадар у Калонцы C , краіны Чэмпіёны ў Калонка D, і Краіны, якія занялі другое месца ў Калонцы E .

Давайце паспрабуем каб атрымаць некалькі значэнняў на аснове аднаго крытэрыю з гэтага набору даных.

1. Вяртанне некалькіх значэнняў на аснове аднаго крытэрыю ў адну ячэйку

Перш за ўсё, давайце паспрабуем вярнуць некалькі значэнняў у адну ячэйку.

Мы паспрабуем вылучыць назвы ўсіх краін-чэмпіёнаў у адзін слупок і гады, у якія яны сталі чэмпіёнамі, у суседнія ячэйкі.

Дапусцім, мы вылучым назвы краін-чэмпіёнаў у Калонцы G з назвай Краіна

  • Па-першае,мы будзем выкарыстоўваць функцыю UNIQUE Excel. Увядзіце гэту формулу ў першую ячэйку G5 .
=UNIQUE(D5:D25)

Тут спасылаецца D5:D25 да чэмпіёна чэмпіянатаў свету.

  • Па-другое, націсніце ENTER .
  • У рэшце рэшт, мы знойдзем усе вынікі ў Калонцы G

Заўвага : Пры выкарыстанні Microsoft 365 не трэба выкарыстоўваць Марку запаўнення , каб атрымаць усе значэнні. Усе значэнні з'явяцца аўтаматычна ў якасці выхадных дадзеных.

1.1. Выкарыстанне функцый TEXTJOIN і IF

Выкарыстанне камбінацыі функцый TEXTJOIN і IF - звычайнае прымяненне для пошуку некалькіх значэнняў на аснове аднаго крытэрыю. Выкарыстанне гэтых дзвюх функцый у асноўным высвятляе агульныя значэнні базавага значэння па двух ці больш крытэрыях.

У наступным наборы даных мы маем чэмпіёны краіны ў Слупку G паўтараецца адзін раз. Нам трэба знайсці гады гэтых чэмпіёнаў каманд у адной ячэйцы паасобку.

  • Каб зрабіць гэта, спачатку запішыце формулу ў H5 такая ячэйка.
=TEXTJOIN(",",TRUE,IF($D$5:$D$25=G5,$B$5:$B$25,""))

  • Па-другое, націсніце ENTER каб атрымаць вывад як 1930,1950 .
  • Па-трэцяе, выкарыстоўвайце Марку запаўнення , перацягваючы курсор уніз, утрымліваючы правы ніжні вугал H5

  • У рэшце рэшт, мы атрымаем наступныя вынікігэта.

Тлумачэнне формулы

  • Тут $B$5 :$B$25 - масіў пошуку. Мы хочам паглядзець на гады. Калі вы хочаце што-небудзь яшчэ, выкарыстоўвайце гэта.
  • $D$5:$D$25=G5 гэта крытэрыі, якім мы хочам адпавядаць. Мы хочам супаставіць ячэйку G5 ( Уругвай ) са слупком Чэмпіён ( $D$5:$D$25). Калі вы хочаце што-небудзь яшчэ, выкарыстоўвайце гэта.

1.2. Выкарыстанне функцый TEXTJOIN і FILTER

Мы таксама можам знайсці той жа вынік, што і папярэдні, выкарыстоўваючы камбінацыю функцый TEXTJOIN і FILTER .

  • Такім чынам, спачатку запішыце формулу ў ячэйку H5 так.
=TEXTJOIN(",",TRUE,FILTER($B$5:$B$25,$D$5:$D$25=G5))

  • Па-другое, націсніце ENTER .
  • Па-трэцяе, выкарыстоўвайце Марку запаўнення .
  • У рэшце рэшт, мы атрымаем вывесці так.

Тлумачэнне формулы

  • Тут $ B$5:$B$25 - масіў пошуку. Мы хочам паглядзець на гады. Калі вы хочаце што-небудзь яшчэ, выкарыстоўвайце гэта.
  • $D$5:$D$25=G5 гэта крытэрыі, якім мы хочам адпавядаць. Мы хочам супаставіць ячэйку G5 ( Уругвай ) са слупком Чэмпіён ( $D$5:$D$25). Калі вы хочаце што-небудзь яшчэ, выкарыстоўвайце гэта.

Дадатковая інфармацыя: Як атрымаць даныя з ячэйкі ў Excel (5 метадаў)

2. Вярнуць некалькі значэнняў на аснове аднаго крытэрыю ў слупок

Вышэйзгаданыя функцыі даступныя толькіу офіс 365 . Цяпер, калі ў вас няма падпіскі на office 365 , вы можаце прытрымлівацца гэтых метадаў і вяртаць некалькі значэнняў на аснове крытэрыю ў слупку.

2.1. Выкарыстоўваючы камбінацыю функцый INDEX, SMALL, MATCH, ROW і ROWS

Дапусцім, нам трэба высветліць, у якія гады Бразілія стала чэмпіёнам. Мы можам знайсці яго з дапамогай камбінацыі функцый INDEX , SMALL , MATCH , ROW і ROWS .

У наступным наборы дадзеных нам трэба знайсці яго ў ячэйцы G5 .

  • Такім чынам, спачатку запішыце формулу ў G5 ячэйка такая.

=INDEX($B$5:$B$25, SMALL(IF(G$4=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

  • Паколькі гэта формула масіва, цяпер нам трэба націснуць CTRL + SHIFT + ENTER .
  • У рэшце рэшт, мы знойдзем гады, у якіх Бразілія стаў чэмпіёнам як вынік.

Цяпер, выкарыстоўваючы прыведзеную вышэй формулу, вы можаце атрымаць гады чэмпіянату любой іншай краіны.

Напрыклад , каб даведацца гады, калі Аргенціна была чэмпіёнам у Слупку H , стварыце новы слупок Аргенціна побач са слупком Бразілія і перацягніце формулу ўправа з дапамогай Рэндзля запаўнення .

Такім чынам, мы знойдзем такі вынік.

Тлумачэнне формулы

  • Тут $B$5:$B$25 гэта масіў пошуку. Шукаем гадамі. Калі ў вас ёсць што-небудзь яшчэ, выкарыстоўвайцегэта.
  • G$4=$D$5:$D$25 - гэта крытэрыі адпаведнасці. Мы хочам супаставіць змесціва ячэйкі G4 , Бразілія з змесцівам ячэек ад D5 да D25 . Вы выкарыстоўваеце свае крытэрыі.
  • Зноў жа, $D$5:$D$25 гэта адпаведны слупок. Вы карыстаецеся сваёй калонкай.

Бачыце, мы атрымалі гады, калі Аргенціна была чэмпіёнам. Год 1978 і 1986 .

Мы можам зрабіць гэта для ўсіх іншых краін.

Перш чым перайсці да наступнага раздзела, у мяне ёсць адзін маленькі пытанне для вас. Ці можаце вы даведацца гады, калі чэмпіянат свету выйгравалі краіны-гаспадары?

Так. Вы правільна здагадаліся. Формула будзе знаходзіцца ў ячэйцы H5 вось так.

=INDEX($B$5:$B$25, SMALL(IF($C$5:$C$25=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

У рэшце рэшт краіна-гаспадыня станавілася чэмпіёнам у 1930,1934,1966,1974,1978 і 1998 гадах.

2.2. Прымяненне функцыі FILTER

Калі мы не хочам выкарыстоўваць складаную формулу, як згадвалася вышэй, мы можам выканаць задачу даволі зручна, выкарыстоўваючы функцыю FILTER Excel.

Але адзіная праблема ў тым, што функцыя FILTER даступная толькі ў Office 365 .

У любым выпадку, формула ў ячэйцы G5 для сартавання будуць гады, калі Бразілія стала чэмпіёнам.

=FILTER($B$5:$B$25,$D$5:$D$25=H$4)

Тлумачэнне формулы

  • Як звычайна, $B$5:$B$25 гэта масіў пошуку . Гады у нашым выпадку. Вы карыстаецеся сваімадзін.
  • $D$5:$D$25=G$4 - крытэрыі адпаведнасці. Вы карыстаецеся сваім.

  • Па-другое, націсніце ENTER , каб атрымаць такія вынікі.

  • Цяпер, як і ў папярэднім метадзе, мы можам стварыць новы слупок Аргенціна побач з Бразілія і перацягнуць Запаўненне Ручка справа, каб атрымаць Гады , калі Аргенціна была чэмпіёнам.

У рэшце рэшт, выхад будзе так.

Больш падрабязна: Як атрымаць даныя з Excel на аснове крытэрыяў (5 спосабаў)

Падобныя чытанні

  • Як імпартаваць тэкставы файл з некалькімі падзельнікамі ў Excel (3 метады)
  • Як імпартаваць даныя з тэкставага файла ў Excel (3 метады)
  • Excel VBA: аўтаматычнае выцягванне даных з вэб-сайта (2 метады)
  • Як аўтаматычна пераўтварыць тэкставы файл у Excel (3 прыдатныя спосабы)
  • Як пераўтварыць нататнік у Excel са слупкамі (5 метадаў)

3 Вярнуць некалькі значэнняў у Excel на аснове аднаго крытэрыю ў радку

Нарэшце, калі вы хочаце , вы можаце вярнуць некалькі значэнняў на аснове крытэрыяў запар. Мы можам зрабіць гэта, выкарыстоўваючы камбінацыю IFERROR , INDEX , SMALL , IF , ROW і Калонка функцыі.

  • Каб даведацца гады, калі Бразілія была чэмпіёнам, спачатку выберыце ячэйку і ўвядзіце Бразілію. У дадзеным выпадку гэта так G5 .
  • Па-другое, запішыце гэту формулу масіва ў суседнюю ячэйку, напрыклад H5 , і націсніце CTRL + SHIFT + ENTER .

=IFERROR(INDEX($B$5:$B$25, SMALL(IF($G5=$D$5:$D$25, ROW($B$5:$B$25)-3,""), COLUMN()-7)),"")

  • Па-трэцяе, націсніце ENTER .
  • У рэшце рэшт, мы знойдзем гады розных краін, калі яны ўпершыню сталі чэмпіёнамі. Гэта будзе адбывацца аўтаматычна ў Microsoft 365 без выкарыстання Запаўняльніка .
  • Цяпер, каб знайсці іншыя гады, калі гэтыя краіны сталі чэмпіёнамі, проста выкарыстоўвайце Ручка запаўнення

  • Такім чынам, мы атрымаем наступны вынік.

Тлумачэнне формулы

  • Тут $B$5:$B$25 знаходзіцца масіў пошуку. На працягу многіх гадоў мы шукалі ў дыяпазоне B5 да B25 . Калі вы хочаце што-небудзь яшчэ, выкарыстоўвайце гэта.
  • $G5=$D$5:$D$25 гэта крытэрыі адпаведнасці. Я хачу супаставіць ячэйку G5 ( Бразілія ) са слупком Чэмпіён ( D5 да D25 ). Калі вы хочаце зрабіць што-небудзь яшчэ, зрабіце гэта.
  • Я выкарыстаў ROW($B$5:$B$25)-3 таму што гэта мой масіў пошуку і першая ячэйка гэтага масіў пачынаецца з радка нумар 4 ( B4 ). Напрыклад, калі ваш пошукавы масіў $D$6:$D$25, выкарыстоўвайце ROW($D$6:$D$25)-5.
  • На месцы з COLUMN()-7, выкарыстоўвайце нумар папярэдняга слупка, куды вы ўстаўляеце формулу. Напрыклад, калі вы ўстаўляеце формулу ў слупок G , выкарыстоўвайце COLUMN()-6.

Дадатковая інфармацыя: Як атрымаць даныя з табліцы на аснове некалькіх крытэрыяў у Excel

Папярэдняя публікацыя Як спасылацца на імя аркуша ў формуле ў Excel
Наступны пост Стварэнне выпадальнага спісу Excel з табліцы (5 прыкладаў)

Х'ю Уэст з'яўляецца вельмі дасведчаным трэнерам і аналітыкам Excel з больш чым 10-гадовым вопытам работы ў галіны. Ён мае ступень бакалаўра ў галіне бухгалтарскага ўліку і фінансаў і ступень магістра дзелавога адміністравання. Х'ю захапляецца навучаннем і распрацаваў унікальны падыход да навучання, які лёгка прытрымлівацца і зразумець. Яго экспертныя веды Excel дапамаглі тысячам студэнтаў і спецыялістаў па ўсім свеце палепшыць свае навыкі і атрымаць поспех у сваёй кар'еры. Праз свой блог Х'ю дзеліцца сваімі ведамі з усім светам, прапаноўваючы бясплатныя падручнікі па Excel і онлайн-трэнінгі, каб дапамагчы прыватным асобам і прадпрыемствам цалкам раскрыць свой патэнцыял.