Hoe om veelvuldige waardes op grond van enkele kriteria in Excel terug te gee

Hugh West

29-05-2023 Excel Formules
  • Deel Dit
Hugh West

As jy op soek is na Excel om veelvuldige waardes op grond van enkele kriteria terug te gee, dan is jy op die regte plek. Terwyl u Excel gebruik, is die vind van veelvuldige waardes gebaseer op verskillende kriteria algemene werk en is noodsaaklik om enige program effektief te laat loop. In hierdie artikel sal ons probeer om die maniere te bespreek om veelvuldige waardes op grond van enkele kriteria in Excel terug te gee.

Laai Praktykwerkboek af

Gee meervoudige waardes op grond van enkelkriteria terug. .xlsx

3 maniere om veelvuldige waardes op grond van enkele kriteria in Excel terug te gee

Kom ons kyk eers na hierdie datastel. Ons het die lys van al die FIFA Wêreldbekers wat plaasgevind het vanaf 1930 tot 2018 . Ons het die Jaar in Kolom B , die Gasheerland in Kolom C , die Kampioen -lande in Kolom D, en die Naaswenners -lande in Kolom E .

Nou, laat ons probeer om veelvuldige waardes gebaseer op enkele kriterium uit hierdie datastel te onttrek.

1. Gee veelvuldige waardes gebaseer op enkele kriteria in 'n enkele sel terug

Laat ons eerstens probeer om veelvuldige waardes in 'n enkele sel.

Ons sal probeer om die name van al die kampioenlande in een kolom te onttrek en die jare waarin hulle kampioene geword het in die aangrensende selle.

Gestel ons sal die name onttrek van die kampioenlande in Kolom G met die naam Land

  • Eerstens,ons sal die UNIEKE funksie van Excel gebruik. Tik hierdie formule in die eerste sel, G5 .
=UNIQUE(D5:D25)

Hier verwys D5:D25 na die Kampioen van Wêreldbekers.

  • Tweedens, druk ENTER .
  • Uiteindelik, ons sal al die uitsette vind in Kolom G

Nota : Terwyl jy Microsoft 365 gebruik, hoef jy nie die Vulhandvatsel te gebruik om al die waardes te kry nie. Alle waardes sal outomaties as uitsette verskyn.

1.1. Die gebruik van TEXTJOIN- en IF-funksies

Die gebruik van die kombinasie van TEXTJOIN - en IF -funksies is 'n algemene toepassing om veelvuldige waardes op grond van enkele kriteria te vind. Die gebruik van hierdie twee funksies vind hoofsaaklik uit die algemene waardes van 'n basiswaarde uit twee of meer kriteria.

In die volgende datastel het ons Kampioen lande in Kolom G een keer herhaal. Ons moet die Jaar van hierdie Kampioen spanne individueel in een sel uitvind.

  • Om dit te doen, skryf eerstens die formule in die H5 sel soos hierdie.
=TEXTJOIN(",",TRUE,IF($D$5:$D$25=G5,$B$5:$B$25,""))

  • Tweedens, druk ENTER om die afvoer as 1930,1950 te kry.
  • Derdens, gebruik die Vulhandvatsel deur die wyser af te sleep terwyl jy die regs-onder hou hoek van die H5

  • Uiteindelik sal ons die uitsette kry sooshierdie.

Formule Verduideliking

  • Hier $B$5 :$B$25 is die opsoekskikking. Ons wil opkyk vir die jare. As jy enigiets anders wil hê, gebruik daardie een.
  • $D$5:$D$25=G5 is die kriteria wat ons wil pas. Ons wil sel G5 ( Uruguay ) pas by die Champion -kolom ( $D$5:$D$25). As jy enigiets anders wil hê, gebruik daardie een.

1.2. Gebruik van TEXTJOIN- en FILTER-funksies

Ons kan ook dieselfde uitvoer as die vorige een vind deur die kombinasie van TEXTJOIN en FILTER -funksies te gebruik.

  • Dus, skryf eerstens die formule so in die H5 sel.
=TEXTJOIN(",",TRUE,FILTER($B$5:$B$25,$D$5:$D$25=G5))

  • Tweedens, druk ENTER .
  • Gebruik derdens die Vulhandvatsel .
  • Uiteindelik sal ons die uitvoer soos hierdie.

Formule Verduideliking

  • Hier $ B$5:$B$25 is die opsoekskikking. Ons wil opkyk vir die jare. As jy enigiets anders wil hê, gebruik daardie een.
  • $D$5:$D$25=G5 is die kriteria wat ons wil pas. Ons wil sel G5 ( Uruguay ) pas by die Champion -kolom ( $D$5:$D$25). As jy enigiets anders wil hê, gebruik daardie een.

Lees meer: Hoe om data uit sel in Excel te onttrek (5 metodes)

2. Gee veelvuldige waardes op grond van enkele kriteria in 'n kolom terug

Die bogenoemde funksies is slegs beskikbaarin kantoor 365 . As jy nou nie 'n office 365 intekening het nie, kan jy hierdie metodes volg en veelvuldige waardes op grond van 'n maatstaf in 'n kolom terugstuur.

2.1. Gebruik 'n kombinasie van INDEX-, SMALL-, MATCH-, ROW- en ROWS-funksies

Gestel, ons moet uitvind in watter jare Brasilië die kampioen geword het. Ons kan dit vind deur die kombinasie van INDEKS , KLEIN , MATCH , RY en RYE funksies .

In die volgende datastel moet ons dit in sel G5 vind.

  • Dus, skryf eerstens die formule in die G5 sel soos hierdie.

=INDEX($B$5:$B$25, SMALL(IF(G$4=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

  • Aangesien dit 'n skikkingsformule is, moet ons nou CTRL + SHIFT + ENTER druk.
  • Uiteindelik sal ons die jare vind waarin Brasilië kampioen geword as uitset.

Nou, deur die formule hierbo te gebruik, kan jy die jare van die kampioenskap van enige ander land onttrek.

Byvoorbeeld , om uit te vind watter jare Argentinië kampioen was in Kolom H , skep 'n nuwe kolom Argentinië langs die een Brasilië , en sleep die formule na regs deur die Vulhandvatsel te gebruik.

Gevolglik sal ons die uitvoer so vind.

Formule Verduideliking

  • Hier $B$5:$B$25 is die opsoekskikking. Ons kyk vir jare. As jy enigiets anders het om na op te soek, gebruikdit.
  • G$4=$D$5:$D$25 is die ooreenstemmende kriteria. Ons wil die inhoud van die sel G4 , Brasilië pas by die inhoud van die selle van D5 tot D25 . Jy gebruik jou kriteria.
  • Weereens, $D$5:$D$25 is die ooreenstemmende kolom. Jy gebruik jou kolom.

Sien, ons het die jare gekry toe Argentinië die kampioen was. Die jaar 1978 en 1986 .

Ons kan dit vir alle ander lande doen.

Voordat ek na die volgende afdeling gaan, het ek een klein vraag vir jou. Kan jy uitvind watter jare die Wêreldbeker deur die gasheerlande gewen is?

Ja. Jy het reg geraai. Die formule sal so in die H5 sel wees.

=INDEX($B$5:$B$25, SMALL(IF($C$5:$C$25=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

Uiteindelik het die gasheerland kampioen geword in 1930,1934,1966,1974,1978 en 1998.

2.2. Toepassing van FILTER-funksie

As ons nie die komplekse formule soos hierbo genoem wil gebruik nie, kan ons die taak redelik gerieflik uitvoer deur die FILTER funksie van Excel te gebruik.

Maar die enigste probleem is dat die FILTER -funksie slegs in Office 365 beskikbaar is.

In elk geval, die formule in sel G5 om die jaar wanneer Brasilië kampioen was, sal wees.

=FILTER($B$5:$B$25,$D$5:$D$25=H$4)

Formule Verduideliking

  • Soos gewoonlik is $B$5:$B$25 die opsoekskikking . Jaar in ons geval. Jy gebruik joueen.
  • $D$5:$D$25=G$4 is die ooreenstemmende kriteria. Jy gebruik jou een.

  • Tweedens, druk ENTER om die uitsette so te kry.

  • Nou soos die vorige metode, kan ons 'n nuwe kolom skep Argentinië net langs Brasilië , en sleep die Vul Hanteer na regs om die Jaar te kry toe Argentinië kampioen was.

Uiteindelik het die uitset sal so wees.

Lees meer: Hoe om data uit Excel te onttrek gebaseer op kriteria (5 maniere)

Soortgelyke lesings

  • Hoe om tekslêer met veelvuldige skeidingstekens in Excel in te voer (3 metodes)
  • Hoe om data van tekslêer in Excel in te voer (3 metodes)
  • Excel VBA: trek data outomaties van 'n webwerf af (2 metodes)
  • Hoe om tekslêer outomaties na Excel om te skakel (3 geskikte maniere)
  • Hoe om Notepad na Excel om te skakel met kolomme (5 metodes)

3 Gee veelvuldige waardes in Excel op grond van enkele kriteria in 'n ry terug

Laastens, as jy wil , kan jy veelvuldige waardes op grond van kriteria in 'n ry terugstuur. Ons kan dit doen deur die kombinasie van IFERROR , INDEX , KLEIN , IF , RY en KOLOM funksies.

  • Om uit te vind watter jare Brasilië kampioen was, kies eerstens 'n sel en voer Brasilië in. In hierdie geval is dit G5 .
  • Tweedens, skryf hierdie skikkingsformule in die aangrensende sel, dws H5 , en druk CTRL + SHIFT + ENTER .

=IFERROR(INDEX($B$5:$B$25, SMALL(IF($G5=$D$5:$D$25, ROW($B$5:$B$25)-3,""), COLUMN()-7)),"")

  • Derdens, druk ENTER .
  • Uiteindelik sal ons die jare van verskillende spesifieke lande vind toe hulle eerste kampioen geword het. Dit sal outomaties in Microsoft 365 gebeur sonder om die Vulhandvatsel te gebruik.
  • Nou, om die ander jare te vind toe hierdie lande kampioene geword het, gebruik net die Vul handvatsel

  • Gevolglik sal ons die uitset so kry.

Formule Verduideliking

  • Hier $B$5:$B$25 is die opsoekskikking. Ons het jare lank opgesoek in die reeks B5 tot B25 . As jy enigiets anders wil hê, gebruik dit.
  • $G5=$D$5:$D$25 is die ooreenstemmende kriteria. Ek wil sel G5 ( Brasilië ) pas by die Champion -kolom ( D5 tot D25 ). As jy enigiets anders wil doen, doen dit.
  • Ek het RY($B$5:$B$25)-3 gebruik, want dit is my opsoekskikking en die eerste sel hiervan skikking begin in ry nommer 4 ( B4 ). Byvoorbeeld, as jou opsoek skikking $D$6:$D$25 is, gebruik RY($D$6:$D$25)-5.
  • In plek van KOLOM()-7, gebruik die nommer van die vorige kolom van waar jy die formule invoeg. Byvoorbeeld, as jy die formule in kolom G invoeg, gebruik KOLOM()-6.

Lees meer: Hoe om data uit tabelle te onttrek gebaseer op veelvuldige kriteria in Excel

Vorige pos Hoe om die werkbladnaam in formule in Excel te verwys
Volgende plasing Skep Excel-aftreklys vanaf tabel (5 voorbeelde)

Hugh West is 'n hoogs ervare Excel-afrigter en ontleder met meer as 10 jaar ondervinding in die bedryf. Hy het 'n Baccalaureusgraad in Rekeningkunde en Finansies en 'n Meestersgraad in Besigheidsadministrasie. Hugh het 'n passie vir onderrig en het 'n unieke onderrigbenadering ontwikkel wat maklik is om te volg en te verstaan. Sy kundige kennis van Excel het duisende studente en professionele persone wêreldwyd gehelp om hul vaardighede te verbeter en uit te blink in hul loopbane. Deur sy blog deel Hugh sy kennis met die wêreld, en bied gratis Excel-tutoriale en aanlyn opleiding aan om individue en besighede te help om hul volle potensiaal te bereik.