Paano Magbabalik ng Maramihang Mga Halaga Batay sa Isang Pamantayan sa Excel

Hugh West

29-05-2023 Mga Formula ng Excel
  • Ibahagi Ito
Hugh West

Kung naghahanap ka ng Excel upang magbalik ng maraming halaga batay sa iisang pamantayan, nasa tamang lugar ka. Habang gumagamit ng Excel, ang paghahanap ng maramihang mga halaga batay sa iba't ibang pamantayan ay karaniwang gawain at mahalaga upang mabisang magpatakbo ng anumang programa. Sa artikulong ito, susubukan naming talakayin ang mga paraan upang magbalik ng maraming value batay sa iisang pamantayan sa Excel.

I-download ang Practice Workbook

Ibalik ang Maramihang Value Batay sa Single Criteria .xlsx

3 Paraan para Magbalik ng Maramihang Mga Halaga Batay sa Isang Pamantayan sa Excel

Tingnan muna natin ang set ng data na ito. Nasa amin ang listahan ng lahat ng FIFA World Cups na naganap mula 1930 hanggang 2018 . Mayroon kaming Taon sa Column B , ang Host Country sa Column C , ang Champion na mga bansa sa Column D, at ang Runners-up na mga bansa sa Column E .

Ngayon, subukan natin para mag-extract ng maraming value batay sa iisang criterion mula sa set ng data na ito.

1. Magbalik ng Maramihang Value Batay sa Single Criteria sa Isang Cell

Una sa lahat, subukan nating magbalik ng maramihang value sa isang solong cell.

Susubukan naming kunin ang mga pangalan ng lahat ng mga kampeong bansa sa isang column at ang mga taon kung saan sila naging mga kampeon sa mga katabing cell.

Ipagpalagay na kukunin namin ang mga pangalan ng mga kampeong bansa sa Column G na pinangalanang Bansa

  • Una,gagamitin namin ang ang NATATANGING function ng Excel. Ilagay ang formula na ito sa unang cell, G5 .
=UNIQUE(D5:D25)

Dito, ang D5:D25 ay tumutukoy sa Champion ng World Cups.

  • Pangalawa, pindutin ang ENTER .
  • Sa huli, makikita natin ang lahat ng mga output sa Column G

Tandaan : Habang ginagamit ang Microsoft 365 , hindi na kailangang gamitin ang Fill Handle para makuha ang lahat ng value. Awtomatikong lalabas ang lahat ng value bilang mga output.

1.1. Ang paggamit ng TEXTJOIN at IF Function

Ang paggamit ng kumbinasyon ng TEXTJOIN at IF na function ay isang karaniwang application upang makahanap ng maraming value batay sa iisang pamantayan. Ang paggamit ng dalawang function na ito ay pangunahing nakakaalam ng mga karaniwang value ng isang base value mula sa dalawa o higit pang pamantayan.

Sa sumusunod na dataset, mayroon kaming Champion mga bansa sa Column G inulit ng isang beses. Kailangan nating alamin ang Taon ng Champion mga koponan sa isang cell nang paisa-isa.

  • Upang gawin ito, una, isulat ang formula sa H5 cell na ganito.
=TEXTJOIN(",",TRUE,IF($D$5:$D$25=G5,$B$5:$B$25,""))

  • Pangalawa, pindutin ang ENTER upang makuha ang output bilang 1930,1950 .
  • Pangatlo, gamitin ang Fill Handle sa pamamagitan ng pag-drag pababa sa cursor habang hawak ang kanan sa ibaba sulok ng H5

  • Sa kalaunan, makukuha natin ang mga output tulad ngito.

Paliwanag ng Formula

  • Dito $B$5 :$B$25 ay ang lookup array. Gusto naming maghanap ng mga taon. Kung gusto mo ng iba pa, gamitin ang isang iyon.
  • $D$5:$D$25=G5 ay ang pamantayan na gusto naming itugma. Gusto naming itugma ang cell G5 ( Uruguay ) sa column na Champion ( $D$5:$D$25). Kung may gusto ka pa, gamitin iyon.

1.2. Paggamit ng TEXTJOIN at FILTER Function

Mahahanap din natin ang parehong output gaya ng nauna sa pamamagitan ng paggamit ng kumbinasyon ng TEXTJOIN at FILTER function.

  • Kaya, una, isulat ang formula sa H5 cell tulad nito.
=TEXTJOIN(",",TRUE,FILTER($B$5:$B$25,$D$5:$D$25=G5))

  • Pangalawa, pindutin ang ENTER .
  • Pangatlo, gamitin ang Fill Handle .
  • Sa huli, makukuha natin ang output na ganito.

Formula Explanation

  • Dito $ B$5:$B$25 ay ang lookup array. Gusto naming maghanap ng mga taon. Kung gusto mo ng iba pa, gamitin ang isang iyon.
  • $D$5:$D$25=G5 ay ang pamantayan na gusto naming itugma. Gusto naming itugma ang cell G5 ( Uruguay ) sa column na Champion ( $D$5:$D$25). Kung may gusto ka pa, gamitin iyon.

Magbasa Pa: Paano Mag-extract ng Data mula sa Cell sa Excel (5 Paraan)

2. Ibalik ang Maramihang Mga Halaga Batay sa Isang Pamantayan sa Isang Hanay

Ang mga nabanggit na function ay available lamangsa office 365 . Ngayon kung wala kang office 365 subscription, maaari mong sundin ang mga pamamaraang ito at magbalik ng maraming value batay sa isang criterion sa isang column.

2.1. Gamit ang isang Kumbinasyon ng INDEX, SMALL, MATCH, ROW, at ROWS Functions

Kumbaga, kailangan nating malaman kung saang taon Brazil naging kampeon. Mahahanap natin ito sa pamamagitan ng paggamit ng kumbinasyon ng INDEX , SMALL , MATCH , ROW , at ROWS function .

Sa sumusunod na dataset, kailangan nating hanapin ito sa cell G5 .

  • Kaya, una, isulat ang formula sa G5 cell na ganito.

=INDEX($B$5:$B$25, SMALL(IF(G$4=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

  • Dahil isa itong array formula, kailangan na nating pindutin ang CTRL + SHIFT + ENTER .
  • Sa bandang huli, mahahanap natin ang mga taon kung kailan Brazil naging kampeon bilang output.

Ngayon, gamit ang formula sa itaas maaari mong kunin ang mga taon ng kampeonato ng anumang ibang bansa.

Halimbawa , para malaman ang mga taon kung kailan naging kampeon ang Argentina sa Column H , lumikha ng bagong column Argentina na katabi ng isa Brazil , at i-drag ang formula sa kanan sa pamamagitan ng paggamit ng Fill Handle .

Dahil dito, makikita natin ang output na ganito.

Formula Explanation

  • Narito ang $B$5:$B$25 ay ang lookup array. Naghanap kami ng mga taon. Kung mayroon kang iba pang hahanapin, gamitiniyon.
  • G$4=$D$5:$D$25 ay ang pagtutugmang pamantayan. Gusto naming itugma ang nilalaman ng cell G4 , Brazil sa mga nilalaman ng mga cell mula D5 hanggang D25 . Ginagamit mo ang iyong pamantayan.
  • Muli, $D$5:$D$25 ay ang katugmang column. Gamitin mo ang iyong column.

Kita mo, nakuha natin ang mga taon kung kailan ang Argentina ay ang kampeon. Ang taon 1978 at 1986 .

Magagawa natin ito para sa lahat ng iba pang bansa.

Bago lumipat sa susunod na seksyon, mayroon akong isang maliit tanong para sayo. Maaari mo bang malaman ang mga taon kung kailan ang World Cup ay napanalunan ng mga bansang nagho-host?

Oo. Tama ang hula mo. Ang formula ay nasa H5 cell na tulad nito.

=INDEX($B$5:$B$25, SMALL(IF($C$5:$C$25=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

Sa kalaunan, naging kampeon ang host country noong 1930,1934,1966,1974,1978, at 1998.

2.2. Paglalapat ng FILTER Function

Kung hindi namin gustong gamitin ang kumplikadong formula tulad ng nabanggit sa itaas, magagawa namin ang gawain nang medyo maginhawa gamit ang FILTER function ng Excel.

Ngunit ang problema lang ay available lang ang function na FILTER sa Office 365 .

Anyway, ang formula sa cell G5 upang ayusin ang taon kung kailan ang Brazil ay naging kampeon.

=FILTER($B$5:$B$25,$D$5:$D$25=H$4)

Formula Explanation

  • Gaya ng dati, $B$5:$B$25 ay ang lookup array . Taon sa aming kaso. Ginagamit mo ang iyongisa.
  • $D$5:$D$25=G$4 ang tumutugmang pamantayan. Gamitin mo ang iyong isa.

  • Pangalawa, pindutin ang ENTER upang makuha ang mga output na tulad nito.

  • Ngayon tulad ng naunang pamamaraan, maaari tayong lumikha ng bagong column Argentina sa tabi lamang ng Brazil , at i-drag ang Fill Hawakan ang sa kanan para makuha ang Taon noong Argentina ay naging kampeon.

Sa kalaunan, ang output magiging ganito.

Magbasa Nang Higit Pa: Paano Mag-extract ng Data mula sa Excel Batay sa Pamantayan (5 Paraan)

Mga Katulad na Pagbasa

  • Paano Mag-import ng Text File na may Maramihang Delimiter sa Excel (3 Paraan)
  • Paano Mag-import ng Data mula sa Text File papunta sa Excel (3 Paraan)
  • Excel VBA: Awtomatikong Pull Data mula sa isang Website (2 Paraan)
  • Paano Awtomatikong I-convert ang Text File sa Excel (3 Angkop na Paraan)
  • Paano I-convert ang Notepad sa Excel gamit ang Mga Column (5 Paraan)

3 . Ibalik ang Maramihang Mga Halaga sa Excel Batay sa Isang Pamantayan sa Isang Hilera

Sa wakas, kung gusto mo , maaari kang magbalik ng maraming halaga batay sa magkakasunod na pamantayan. Magagawa natin ito sa pamamagitan ng paggamit ng kumbinasyon ng IFERROR , INDEX , MALIIT , IF , ROW , at COLUMN functions.

  • Upang malaman ang mga taon kung kailan naging kampeon ang Brazil , una, pumili ng cell at ipasok ang Brazil. Sa kasong ito, ito ay G5 .
  • Pangalawa, isulat ang array formula na ito sa katabing cell i.e. H5 , at pindutin ang CTRL + SHIFT + ENTER .

=IFERROR(INDEX($B$5:$B$25, SMALL(IF($G5=$D$5:$D$25, ROW($B$5:$B$25)-3,""), COLUMN()-7)),"")

  • Pangatlo, pindutin ang ENTER .
  • Sa kalaunan, makikita natin ang mga taon ng iba't ibang partikular na bansa kung kailan sila unang naging kampeon. Awtomatiko itong mangyayari sa Microsoft 365 nang hindi ginagamit ang Fill Handle .
  • Ngayon, para mahanap ang iba pang mga taon kung kailan naging kampeon ang mga bansang ito, gamitin lang ang Fill Handle

  • Dahil dito, makukuha natin ang output na ganito.

Formula Explanation

  • Narito $B$5:$B$25 ay ang lookup array. Naghanap kami ng mga taon sa hanay na B5 hanggang B25 . Kung may gusto ka pa, gamitin iyon.
  • $G5=$D$5:$D$25 ay ang tumutugmang pamantayan. Gusto kong itugma ang cell G5 ( Brazil ) sa column na Champion ( D5 hanggang D25 ). Kung may gusto kang gawin, gawin mo iyon.
  • Ginamit ko ang ROW($B$5:$B$25)-3 dahil ito ang lookup array ko at ang unang cell nito Nagsisimula ang array sa row number 4 ( B4 ). Halimbawa, kung ang iyong lookup array ay $D$6:$D$25, gamitin ang ROW($D$6:$D$25)-5.
  • Sa lugar ng COLUMN()-7, gamitin ang numero ng nakaraang column kung saan mo ipinapasok ang formula. Halimbawa, kung inilalagay mo ang formula sa column G , gamitin COLUMN()-6.

Magbasa Nang Higit Pa: Paano Mag-extract ng Data Mula sa Talahanayan Batay sa Maramihang Pamantayan sa Excel

Nakaraang post Paano Mag-refer ng Pangalan ng Worksheet sa Formula sa Excel
Susunod na post Lumikha ng Excel Drop Down List mula sa Talahanayan (5 Halimbawa)

Si Hugh West ay isang napakaraming Excel trainer at analyst na may higit sa 10 taong karanasan sa industriya. May hawak siyang Bachelor's degree sa Accounting and Finance at Master's degree sa Business Administration. Si Hugh ay may hilig sa pagtuturo at nakabuo ng kakaibang diskarte sa pagtuturo na madaling sundin at maunawaan. Ang kanyang dalubhasang kaalaman sa Excel ay nakatulong sa libu-libong mag-aaral at propesyonal sa buong mundo na mapabuti ang kanilang mga kasanayan at maging mahusay sa kanilang mga karera. Sa pamamagitan ng kanyang blog, ibinahagi ni Hugh ang kanyang kaalaman sa mundo, nag-aalok ng mga libreng Excel tutorial at online na pagsasanay upang matulungan ang mga indibidwal at negosyo na maabot ang kanilang buong potensyal.