Kako vratiti više vrijednosti na temelju jednog kriterija u Excelu

Hugh West

29-05-2023 Excel formule
  • Podijeli Ovo
Hugh West

Ako tražite da Excel vrati više vrijednosti na temelju jednog kriterija, onda ste na pravom mjestu. Dok koristite Excel, pronalaženje više vrijednosti na temelju različitih kriterija uobičajen je posao i ključan je za učinkovito pokretanje bilo kojeg programa. U ovom ćemo članku pokušati raspravljati o načinima vraćanja višestrukih vrijednosti na temelju jednog kriterija u programu Excel.

Preuzmite vježbovnu knjigu

Vraćanje višestrukih vrijednosti na temelju jednog kriterija .xlsx

3 načina za vraćanje višestrukih vrijednosti na temelju jednog kriterija u Excelu

Da prvo pogledamo ovaj skup podataka. Imamo popis svih FIFA Svjetskih prvenstava koja su održana od 1930 do 2018 . Imamo Godinu u Stupcu B , Zemlju domaćina u Stupcu C , Prvake zemlje u Stupac D, i Drugoplasirane zemlje u Stupac E .

Pokušajmo sada za izdvajanje više vrijednosti na temelju jednog kriterija iz ovog skupa podataka.

1. Vraćanje više vrijednosti na temelju jednog kriterija u jednoj ćeliji

Prvo, pokušajmo vratiti više vrijednosti u jednu ćeliju.

Pokušat ćemo izdvojiti imena svih zemalja prvaka u jednom stupcu i godine u kojima su postali prvaci u susjednim ćelijama.

Pretpostavimo da ćemo izdvojiti imena zemalja prvaka u Stupcu G pod nazivom Zemlja

  • Prvo,koristit ćemo JEDINSTVENU funkciju programa Excel. Unesite ovu formulu u prvu ćeliju, G5 .
=UNIQUE(D5:D25)

Ovdje se D5:D25 odnosi do Prvaka Svjetskog prvenstva.

  • Drugo, pritisnite ENTER .
  • Na kraju, pronaći ćemo sve rezultate u Stupcu G

Napomena : Dok koristite Microsoft 365 , nema potrebe koristiti Fill Handle za dobivanje svih vrijednosti. Sve vrijednosti će se automatski pojaviti kao izlazi.

1.1. Korištenje funkcija TEXTJOIN i IF

Korištenje kombinacije funkcija TEXTJOIN i IF uobičajena je primjena za pronalaženje više vrijednosti na temelju jednog kriterija. Korištenje ove dvije funkcije uglavnom pronalazi zajedničke vrijednosti osnovne vrijednosti iz dva ili više kriterija.

U sljedećem skupu podataka imamo prvake zemlje u stupcu G ponovljeno jednom. Moramo saznati Godine tih Šampionskih timova u jednoj ćeliji pojedinačno.

  • Da biste to učinili, prvo napišite formulu u H5 ćelija ovako.
=TEXTJOIN(",",TRUE,IF($D$5:$D$25=G5,$B$5:$B$25,""))

  • Drugo, pritisnite ENTER da dobijete izlaz kao 1930,1950 .
  • Treće, upotrijebite Ručku za popunjavanje povlačenjem kursora prema dolje dok držite desno dolje kut H5

  • Na kraju ćemo dobiti rezultate kaoovo.

Objašnjenje formule

  • Ovdje $B$5 :$B$25 je polje pretraživanja. Želimo pogledati gore za godinama. Ako želite nešto drugo, upotrijebite to.
  • $D$5:$D$25=G5 je kriterij koji želimo ispuniti. Želimo spojiti ćeliju G5 ( Urugvaj ) sa stupcem Prvak ( $D$5:$D$25). Ako želite nešto drugo, upotrijebite to.

1.2. Korištenje funkcija TEXTJOIN i FILTER

Također možemo pronaći isti izlaz kao i prethodni korištenjem kombinacije funkcija TEXTJOIN i FILTER .

  • Dakle, prvo napišite formulu u H5 ćeliju ovako.
=TEXTJOIN(",",TRUE,FILTER($B$5:$B$25,$D$5:$D$25=G5))

  • Drugo, pritisnite ENTER .
  • Treće, upotrijebite Ručku za punjenje .
  • Na kraju ćemo dobiti izlaz ovako.

Objašnjenje formule

  • Ovdje $ B$5:$B$25 je polje pretraživanja. Želimo pogledati gore za godinama. Ako želite nešto drugo, upotrijebite to.
  • $D$5:$D$25=G5 je kriterij koji želimo ispuniti. Želimo spojiti ćeliju G5 ( Urugvaj ) sa stupcem Prvak ( $D$5:$D$25). Ako želite nešto drugo, upotrijebite to.

Pročitajte više: Kako izvući podatke iz ćelije u Excelu (5 metoda)

2. Vrati više vrijednosti na temelju jednog kriterija u stupcu

Gore navedene funkcije dostupne su samou office 365 . Sada, ako nemate office 365 pretplatu, možete slijediti ove metode i vratiti više vrijednosti na temelju kriterija u stupcu.

2.1. Koristeći kombinaciju funkcija INDEX, SMALL, MATCH, ROW i ROWS

Pretpostavimo da moramo saznati u kojim je godinama Brazil postao prvak. Možemo ga pronaći pomoću kombinacije funkcija INDEX , SMALL , MATCH , ROW i ROWS .

U sljedećem skupu podataka, moramo ga pronaći u ćeliji G5 .

  • Dakle, prvo napišite formulu u G5 ćelija poput ove.

=INDEX($B$5:$B$25, SMALL(IF(G$4=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

  • Kako je ovo formula polja, sada moramo pritisnuti CTRL + SHIFT + ENTER .
  • Na kraju ćemo pronaći godine u kojima Brazil postao prvak kao rezultat.

Sada, pomoću gornje formule možete izdvojiti godine prvenstva bilo koje druge zemlje.

Na primjer , kako biste saznali godine kada je Argentina bila prvak u Stupcu H , stvorite novi stupac Argentina uz onaj Brazil i povucite formulu udesno pomoću Ručke za popunjavanje .

Slijedom toga, pronaći ćemo ovakav izlaz.

Objašnjenje formule

  • Ovdje je $B$5:$B$25 polje pretraživanja. Tražimo godinama. Ako imate još nešto za potražiti, upotrijebiteto.
  • G$4=$D$5:$D$25 je kriterij podudaranja. Želimo uskladiti sadržaj ćelije G4 , Brazil sa sadržajem ćelija od D5 do D25 . Vi koristite svoje kriterije.
  • Opet, $D$5:$D$25 je odgovarajući stupac. Koristite svoju kolumnu.

Vidite, dobili smo godine kada je Argentina bila prvak. Godina 1978 i 1986 .

Možemo to učiniti za sve druge zemlje.

Prije nego prijeđem na sljedeći odjeljak, imam jedan mali pitanje za tebe. Možete li saznati godine kada su Svjetsko prvenstvo osvojile zemlje domaćini?

Da. Dobro ste pogodili. Formula će biti u ćeliji H5 ovako.

=INDEX($B$5:$B$25, SMALL(IF($C$5:$C$25=$D$5:$D$25, MATCH(ROW($D$5:$D$25), ROW($D$5:$D$25)), ""), ROWS($A$1:A1)))

Na kraju, zemlja domaćin postala je prvak 1930., 1934., 1966., 1974., 1978. i 1998.

2.2. Primjena funkcije FILTER

Ako ne želimo koristiti složenu formulu kao što je gore spomenuto, zadatak možemo prilično jednostavno izvršiti pomoću FILTER funkcije programa Excel.

Ali jedini je problem što je funkcija FILTER dostupna samo u Office 365 .

U svakom slučaju, formula u ćeliji G5 da sortira godine kada je Brazil bio prvak bit će.

=FILTER($B$5:$B$25,$D$5:$D$25=H$4)

Objašnjenje formule

  • Kao i obično, $B$5:$B$25 je polje pretraživanja . Godine u našem slučaju. Vi koristite svojejedan.
  • $D$5:$D$25=G$4 je kriterij podudaranja. Vi koristite svoj.

  • Drugo, pritisnite ENTER da biste dobili ovakve rezultate.

  • Sada, kao i kod prethodne metode, možemo stvoriti novi stupac Argentina odmah pored Brazil i povući ispunu Pritisnite udesno kako biste dobili godine kada je Argentina bila prvak.

Na kraju, izlaz bit će ovako.

Pročitajte više: Kako izdvojiti podatke iz Excela na temelju kriterija (5 načina)

Slična čitanja

  • Kako uvesti tekstualnu datoteku s više graničnika u Excel (3 metode)
  • Kako uvesti podatke iz tekstualne datoteke u Excel (3 metode)
  • Excel VBA: Automatsko izvlačenje podataka s web stranice (2 metode)
  • Kako automatski pretvoriti tekstualnu datoteku u Excel (3 prikladna načina)
  • Kako pretvoriti Notepad u Excel sa stupcima (5 metoda)

3 . Vrati više vrijednosti u Excelu na temelju jednog kriterija u nizu

Na kraju, ako želite , možete vratiti više vrijednosti na temelju kriterija u nizu. To možemo učiniti korištenjem kombinacije IFERROR , INDEX , SMALL , IF , ROW i STUPAC funkcije.

  • Da biste saznali godine kada je Brazil bio prvak, prvo odaberite ćeliju i unesite Brazil. U ovom slučaju jest G5 .
  • Drugo, napišite ovu formulu polja u susjednu ćeliju, npr. H5 , i pritisnite CTRL + SHIFT + ENTER .

=IFERROR(INDEX($B$5:$B$25, SMALL(IF($G5=$D$5:$D$25, ROW($B$5:$B$25)-3,""), COLUMN()-7)),"")

  • Treće, pritisnite ENTER .
  • Na kraju ćemo pronaći godine kada su različite zemlje prve postale prvaci. To će se dogoditi automatski u Microsoft 365 bez korištenja Full Handle .
  • Sada, da biste pronašli druge godine kada su te zemlje postale prvaci, samo upotrijebite Ručka za punjenje

  • Slijedom toga, dobit ćemo ovakav izlaz.

Objašnjenje formule

  • Ovdje $B$5:$B$25 je polje pretraživanja. Godinama smo tražili u rasponu B5 do B25 . Ako želite još nešto, upotrijebite to.
  • $G5=$D$5:$D$25 je kriterij podudaranja. Želim uskladiti ćeliju G5 ( Brazil ) sa stupcem Prvak ( D5 do D25 ). Ako želite učiniti bilo što drugo, učinite to.
  • Koristio sam ROW($B$5:$B$25)-3 jer je ovo moje polje pretraživanja i prva ćelija ovog niz počinje u retku broj 4 ( B4 ). Na primjer, ako je vaš niz pretraživanja $D$6:$D$25, upotrijebite ROW($D$6:$D$25)-5.
  • Na mjestu od COLUMN()-7, koristite broj prethodnog stupca u koji umećete formulu. Na primjer, ako umećete formulu u stupac G , koristite COLUMN()-6.

Pročitajte više: Kako izdvojiti podatke iz tablice na temelju više kriterija u programu Excel

Prethodni post Kako referencirati naziv radnog lista u formuli u Excelu
Sljedeći post Stvorite Excel padajući popis iz tablice (5 primjera)

Hugh West vrlo je iskusan Excel trener i analitičar s više od 10 godina iskustva u industriji. Diplomirao je računovodstvo i financije te magistrirao poslovno upravljanje. Hugh ima strast za podučavanjem i razvio je jedinstveni pristup podučavanju koji je lako pratiti i razumjeti. Njegovo stručno poznavanje programa Excel pomoglo je tisućama studenata i profesionalaca diljem svijeta da poboljšaju svoje vještine i postignu uspjeh u karijeri. Putem svog bloga, Hugh dijeli svoje znanje sa svijetom, nudeći besplatne vodiče za Excel i online obuku kako bi pomogao pojedincima i tvrtkama da dostignu svoj puni potencijal.