Hvernig á að breyta mörgum línum í dálka í Excel (9 leiðir)

Hugh West

16-10-2023 Excel formúlur
  • Deildu Þessu
Hugh West

Ef þú ert að leita að einhverjum af auðveldustu leiðunum til að breyta mörgum línum í dálka í Excel, þá muntu finna þessa grein gagnleg. Svo, við skulum kafa ofan í aðalgreinina.

Sækja vinnubók

Umbreyting margra raða í dálka.xlsm

9 leiðir til að umbreyta Margar línur í dálka í Excel

Hér höfum við nokkrar skrár yfir sölu fyrir sumar vörurnar fyrir mánuðina frá janúar til maí . Við munum reyna að breyta línunum í dálka þannig að við getum séð færslurnar fyrir mánuðina sem dálkahausa og við munum nýta þetta gagnasafn aðallega til að sýna fram á leiðir til að breyta mörgum línum í dálka auðveldlega.

Við höfum notað Microsoft Excel 365 útgáfu hér, þú getur notað allar aðrar útgáfur eftir hentugleika.

Aðferð-1: Notkun umfærslumöguleika til að umbreyta mörgum línum í dálka í Excel

Hér munum við nota Transpose möguleikann innan Paste options til að breyta eftirfarandi mörgum línum í dálka auðveldlega.

Skref :

➤ Afritaðu allt svið gagnasafnsins með því að ýta á CTRL+C .

➤ Veldu reitinn þar sem þú vilt hafa úttakið, Hægri-smelltu á músinni og veldu Transpose valkostinn úr Paste Options .

Þá muntu geta yfirfært gögnin þín sem þýðir að breyta línunum ídálka.

Lesa meira: Excel Macro: Umbreyta mörgum línum í dálka (3 dæmi)

Aðferð-2: Umbreyting á Margar raðir í dálka með því að nota TRANSPOSE aðgerðina

Í þessum hluta ætlum við að nota fylkisfall, TRANSPOSE fallið , til að umbreyta mörgum línum eftirfarandi gagnasafns í marga dálka, og til að safna gögnunum höfum við einnig sniðið aðra töflu fyrir neðan aðalgagnagrunninn.

Skref :

➤ Sláðu inn eftirfarandi formúlu í reit B10 .

=TRANSPOSE(B3:E8)

Hér mun TRANSPOSE breyta röðum bilsins B3:E8 í dálka samtímis.

➤ Ýttu á ENTER .

Eftir það færðu umbreytingu á línurnar í dálka eins og eftirfarandi mynd.

Þú verður að ýta á CTRL+SHIFT+ENTER í stað þess að ýta á ENTER fyrir aðrar útgáfur nema fyrir Microsoft Excel 365 .

Lesa meira: Hvernig á að flytja dálk í margar raðir í Excel (6 aðferðir)

Aðferð-3: Notkun INDIRECT og ADDRESS aðgerða

Hér munum við nota INDIRECT aðgerðina , ADDRESS aðgerðina , ROW aðgerðina og COLUMN fall til að umbreyta raðir eftirfarandi gagnasafns í dálka.

Skref :

➤ Notaðu eftirfarandi formúlu í reit B10 .

=INDIRECT(ADDRESS(COLUMN(B3) - COLUMN($B$3) + ROW($B$3), ROW(B3) - ROW($B$3) + COLUMN($B$3)))

Hér er B3 upphafsreiturinn af aðalgagnasafn.

  • COLUMN(B3) → returns the column number of cell B3

    Framlag → 2
  • COLUMN($B$3) → returns the column number of cell $B$3 (the absolute referencing will fix this cell)

    Úttak → 2

  • ROW($B$3) → returns the row number of cell $B$3 (the absolute referencing will fix this cell)

    Úttak → 3

  • ROW(B3) → returns the row number of cell B3

    Úttak → 3
  • COLUMN(B3) - COLUMN($B$3) + ROW($B$3) verður

    2-2+3 → 3

  • ROW(B3) - ROW($B$3) + COLUMN($B$3) verður

    3-3+2 → 2

  • ADDRESS(COLUMN(B3) - COLUMN($B$3) + ROW($B$3), ROW(B3) - ROW($B$3) + COLUMN($B$3)) verður

    ADDRESS(3, 2) → returns the reference at the intersection point of Row 3 and Column 2

    Úttak → $B$3

  • INDIRECT(ADDRESS(COLUMN(B3) - COLUMN($B$3) + ROW($B$3), ROW(B3) - ROW($B$3) + COLUMN($B$3))) verður

    INDIRECT(“$B$3”) → skilar gildi hólfsins $B$3 .

    Úttak → mánuður

➤ Ýttu á ENTER .

➤ Dragðu Fill Handle tólið til hægri og niður.

Að lokum muntu geta breytt mörgum línum aðalgagnasettsins í marga dálka.

Lesa meira:  Excel VBA: Get Row og Dálknúmer úr hólfsfangi (4 aðferðir)

Aðferð-4: Notkun INDEX fall til að umbreyta mörgum línum í dálka

Í þessum hluta munum við nota samsetningu INDEX fallsins , COLUMN fallsins og ROW fallsins til að breyta mörgum línum í dálka auðveldlega.

Skref :

➤ Notaðu eftirfarandi formúlu í reit B10 .

=INDEX($B$3:$E$8,COLUMN(A1),ROW(A1))

Hér, $B$3:$E$8 er svið gagnasafnsins, A1 er notað til að fá fyrstu línuna og dálknúmer þessa gagnasafns.Við erum að nota dálkanúmer fyrir línunúmer rökin og línunúmer sem dálkanúmer rökin til að breyta línum í dálka auðveldlega með því að setja þessi gildi inn í INDEX aðgerðina .

➤ Ýttu á ENTER .

➤ Dragðu ENTER . 6>Fill Handle tól hægra megin og niður.

Eftir það færðu umbreytingu raðanna í dálka eins og eftirfarandi mynd.

Lesa meira:  Hvernig á að bæta við mörgum línum og dálkum í Excel (allar mögulegar leiðir)

Aðferð-5: Notkun INDEX-MATCH Formúla

Í þessum hluta ætlum við að nota INDEX aðgerðina og MATCH aðgerðina til að breyta mörgum raðir eftirfarandi gagnasafns í dálka.

Skref :

➤ Í fyrsta lagi þarftu að yfirfæra fyrsta dálkinn sem fyrstu línu nýju töflunnar handvirkt.

➤ Sláðu inn eftirfarandi formúlu í reit B11 .

=INDEX($C$3:$C$8,MATCH(B$10,$B$3:$B$8,0))

Hér, $C$3:$C$8 er annar dálkur í gagnasafnið, og $B$3:$B$8 er fyrsti dálkur gagnasafnsins.

  • MATCH(B$10,$B$3:$B$8,0) verður

    MATCH(“Month”,$B$3:$B$8,0) → skilar línuvísitölu reitsins með streng mánuði á bilinu $B$3:$B$8

    Úttak → 1

  • INDEX($C$3:$C$8,MATCH(B$10,$B$3:$B$8,0)) verður

    INDEX($C$3:$C$8,1) → skilar fyrsta gildi sviðsins $C$3:$C$8

    Úttak → Appelsínugult

➤ Ýttu á ENTER og dragðu Fill Handle tólið hægra megin.

Þá færðu seinni dálkinn í aðal gagnasafn sem önnur röð.

Á sama hátt skaltu nota eftirfarandi formúlur til að klára restina af umbreytingunni.

=INDEX($D$3:$D$8,MATCH(B$10,$B$3:$B$8,0))

=INDEX($E$3:$E$8,MATCH(B$10,$B$3:$B$8,0))

Að lokum færðu allar raðir fyrsta gagnasafnsins sem dálka í öðru gagnasafni.

Lesa meira: Hvernig á að flytja marga dálka yfir í raðir í Excel

Svipaðir lestrar

  • [Lögað!] Raðir og dálkar eru báðar tölur í Excel
  • Hvernig á að fela línur og dálka í Excel (10 leiðir)
  • Excel VBA: Stilltu bil eftir röð og dálknúmer (3 dæmi)

Aðferð-6: Notkun VLOOKUP aðgerð til að umbreyta mörgum línum í dálka

Í þessum hluta munum við nota VLOOKUP aðgerðina til að færa margar línur af eftirfarandi gagnatöflu yfir í dálka.

Skref :

➤ Í upphafi þarftu að transpo sjáðu fyrsta dálkinn sem fyrstu línu í nýja gagnasafninu handvirkt.

➤ Skrifaðu niður eftirfarandi formúlu í reit B11 .

=VLOOKUP(B$10,$B$3:$E$8,2,FALSE)

Hér, $B$3:$E$8 er svið gagnasafnsins, B$10 er uppflettingargildið og 2 er til að skoða gildið í öðrum dálki gagnasafnsins.

➤ Ýttu á ENTER og dragðu Fill Handle tól til hægrihlið.

Síðan færðu annan dálk aðalgagnasettsins sem aðra röð.

Í á sama hátt, notaðu formúlurnar hér að neðan til að klára restina af umbreytingunni.

=VLOOKUP(B$10,$B$3:$E$8,3, FALSE)

=VLOOKUP(B$10,$B$3:$E$8,4, FALSE)

Lesa meira: Hvernig á að bæta við línum og dálkum í Excel (3 auðveldar aðferðir)

Aðferð-7: Notkun Power Query

Hér munum við nota Power Query til að flytja margar raðir auðveldlega í dálka. En við verðum að bæta við auka línu í upphafi gagnasafnsins því Power Query breytir ekki fyrstu línunni sem dálki þar sem hún lítur á hana sem haus.

Skref :

➤ Farðu í Gögn flipann >> Fáðu & Umbreyta gögnum Hópur >> Frá töflu/sviði valkosti.

Eftir það, Búa til töflu hjálparforritið birtist.

➤ Veldu gagnasviðið og smelltu svo á Taflan mín hefur hausa valmöguleikann.

➤ Ýttu á OK .

Þá mun Power Query Editor glugginn birtast.

➤ Veldu alla dálka gagnasafnsins með því að ýta á CTRL og Vinstri-smella á músinni á sama tíma .

➤ Farðu í Umbreyta flipann >> Umfærsla valkostur.

Þú getur búið til fyrstu röð af gagnasafnið þitt hausinn líka.

➤ Farðu á Umbreyta flipa >> Nota fyrstu línu sem hausa Hópur >> Notaðu fyrstu línu sem hausa valkost.

Þá færðu umbreyttu dálkana úr röðum aðal gagnasafn.

➤ Til að loka þessum glugga, farðu á Heima flipann >> Loka & Hlaða Hóp >> Loka & Hlaða valkost.

Þannig verður taflan í Power Query Editor glugganum hlaðinn í a nýtt blað sem heitir Tafla5 .

Lesa meira: Hvernig á að skipta um línur og dálka í Excel (5 aðferðir)

Aðferð-8: Umbreyta mörgum línum í dálka með því að nota VBA kóða

Í þessum hluta ætlum við að nota VBA kóða til að breyta mörgum línum í dálka.

Skref :

➤ Farðu á Hönnuðar flipan >> Visual Basic Valkostur.

Þá opnast Visual Basic Editor .

➤ Farðu í Setja inn Tab >> Eining Valkostur.

Eftir það verður Eining búin til.

➤ Skrifaðu eftirfarandi kóða

4472

Hér höfum við lýst margar_raðir_svið og margar_dálkasviði sem Svið , og þau eru stillt á það bil sem við veljum í gegnum Inntaksboxin með því að nota InputBox aðferðina.

Þá munum við afrita helstu gögnin et margar_raðir_svið og límdu það síðan sem yfirfærslu í áfangahólfi margdálkasvið .

➤ Ýttu á F5 .

Þá færðu inntaksreitinn þar sem þú þarft að velja svið gagnasafnsins $B$3:$E$8 í Veldu röð lína box og ýttu á OK .

Þá mun annar inntaksreitur skjóta upp kollinum.

➤ Veldu áfangahólfi $B$10 þar sem þú vilt hafa yfirfærða gagnasafnið og ýttu síðan á OK .

Að lokum, þú mun fá umbreyttu dálkana úr mörgum línum, jafnvel með sniði aðalgagnasettsins líka eins og eftirfarandi.

Lesa meira: Hvernig á að Skiptu um línur og dálka í Excel myndriti (2 aðferðir)

Aðferð-9: Umbreyting margra raða í dálka og raðir með því að nota OFFSET aðgerð

Við höfum lista sem inniheldur nöfn nokkurra nemenda , viðfangsefni þeirra og samsvarandi merki í mörgum röðum. Nú viljum við breyta fyrstu þremur línunum í þrjá mismunandi dálka töflunnar við hliðina á þessum lista. Á sama hátt viljum við breyta restinni af röðunum sem dálkum í þrjár línur. Þannig að þú sérð að við þurfum að breyta línum í dálka og línur í einu.

Til að gera þetta ætlum við að nota OFFSET , ROW , og COLUMN aðgerðir .

Skref :

➤ Sláðu inn eftirfarandi formúlu í reit D4 .

=OFFSET($B$4,COLUMN()-4+(ROW()-4)*3,0,1,1)

Hér, $B$4 er upphafsreit listans.

  • COLUMN() → returns the column number of cell D4 where the formula is being applied.

    Output → 4

  • COLUMN()-4 verður

    4-4 → 4 is subtracted because the starting cell of the formula is in Column 4 .

    Output → 0

  • ROW() → returns the row number of cell D4 where the formula is being applied.

    Output → 4

  • (ROW()-4)*3 verður

    (4-4)*3 → 4 is subtracted because the starting cell of the formula is in Row 4 and multiplied with 3 as we want to transform 3 rows into columns each time.

    Output → 0

  • OFFSET($B$4,COLUMN()-4+(ROW()-4)*3,0,1,1) becomes

    OFFSET($B$4,0+0,0,1,1)

    OFFSET($B$4,0,0,1,1) → OFFSET will extract the range with a height and width of 1 starting from cell $B$4 .

    Output → Joseph

➤ Ýttu á ENTER .

➤ Dragðu Fill Handle tólið hægra megin og niður.

Að lokum muntu geta gert umbreyting úr mörgum línum í dálka og raðir.

Lesa meira: Færa línu/dálk í Excel án þess að skipta um núverandi gögn (3 bestu leiðirnar)

Æfingahluti

Til að æfa sjálfur höfum við veitt Æfingahluti eins og hér að neðan í blaði sem heitir Æfing . Vinsamlegast gerðu það sjálfur.

Niðurstaða

Í þessari grein reyndum við að fjalla um leiðir til að umbreyta mörgum línum í dálka í Excel auðveldlega. Vona að þér finnist það gagnlegt. Ef þú hefur einhverjar uppástungur eða spurningar skaltu ekki hika við að deila þeim í athugasemdahlutanum.

Fyrri færsla Hvernig á að finna efri og neðri mörk öryggisbils í Excel
Næsta færsla Hvernig á að fylla út sjálfkrafa frá öðru vinnublaði í Excel

Hugh West er mjög reyndur Excel þjálfari og sérfræðingur með yfir 10 ára reynslu í greininni. Hann er með BA gráðu í bókhaldi og fjármálum og meistaragráðu í viðskiptafræði. Hugh hefur ástríðu fyrir kennslu og hefur þróað einstaka kennsluaðferð sem auðvelt er að fylgja eftir og skilja. Sérfræðiþekking hans á Excel hefur hjálpað þúsundum nemenda og fagfólks um allan heim að bæta færni sína og skara fram úr í starfi. Í gegnum bloggið sitt deilir Hugh þekkingu sinni með heiminum og býður upp á ókeypis Excel námskeið og netþjálfun til að hjálpa einstaklingum og fyrirtækjum að ná fullum möguleikum.