Isi kandungan
Salah satu fungsi Excel yang paling menakjubkan dan digunakan secara meluas ialah Fungsi VLOOKUP . Setakat ini, kami telah belajar untuk mengeluarkan satu padanan daripada julat sel menggunakan fungsi ini. Anda boleh kerap menghadapi senario di mana anda perlu mendapatkan semua nilai yang sepadan untuk pengecam unik. Dalam artikel ini, kami akan menunjukkan cara anda boleh mengeluarkan berbilang padanan daripada julat sel menggunakan fungsi VLOOKUP dalam Excel.
Muat Turun Buku Kerja Amalan
Anda boleh muat turun buku kerja Excel berikut untuk memahami dan mengamalkan diri anda dengan lebih baik.
Melaksanakan Vlookup dengan Pelbagai Padanan.xlsx2 Langkah untuk Vlookup dengan Pelbagai Padanan dalam Excel
Di sini kita mempunyai Rekod Buku Kedai Buku Martin . Set data ini mengandungi Jenis Buku , Nama Buku dan Pengarang beberapa buku di bawah lajur B , C , dan D yang sepadan.
Hari ini objektif kami adalah untuk mengeluarkan semua padanan setiap jenis buku menggunakan fungsi VLOOKUP . Kami akan melaksanakan ini dalam dua langkah. Jadi, mari kita terokai satu persatu.
Di sini, kami telah menggunakan versi Microsoft Excel 365 , anda boleh menggunakan mana-mana versi lain mengikut keselesaan anda.
📌 Langkah 01: Cipta Nama Unik untuk Setiap Nilai Carian
- Pada mulanya, masukkan lajur baharu dengan tajuk Lajur Pembantu kiri ke lajur carian Jenis Buku dan masukkan formula ini dalam sel B5 .
=C5&COUNTIF(C5:$C$25,C5) Pecahan Formula- COUNTIF(C5:$C$25,C5) mengembalikan jumlah bilangan sel dalam julat C5:C25 ( Jenis Buku ) yang mengandungi nilai dalam sel C5 ( Novel ). Lihat fungsi COUNTIF untuk butiran.
- Dengan kata mudah, berapa banyak novel yang ada. Ia ialah 7 .
- C5&COUNTIF(C5:$C$25,C5) menggabungkan nilai dalam sel C5 ( Novel ) dengannya.
- Jadi ia mengembalikan Novel7 .
Apabila menyeret alat Pemegang Isi , C5 meningkat satu demi satu, seperti C5 , C6 , C7 … tetapi C25 kekal malar. Oleh itu, bagi setiap Jenis Buku , yang lebih awal akan dikecualikan dan nama baharu dijana.
Sebagai contoh, dalam kes novel, Novel1 hingga Novel7 dijana dan serupa untuk Puisi dan jenis buku lain.
- Kemudian, tekan ENTER .
- Selepas itu, bawa kursor ke kanan -sudut bawah sel B5 dan ia akan kelihatan seperti tanda tambah (+) . Sebenarnya, ia adalah alat Pemegang Isi .
- Sekarang, klik dua kali padanya.
Ia menyalin formula ini ke seluruh sel. Anda akan menemui semua nilai carian yang disediakan dengan nama unik, seperti Novel1 , Novel2…, Puisi1 , Puisi2… ,dsb.
📌 Langkah 02: Gunakan Fungsi VLOOKUP
- Pertama sekali, buat lajur baharu dengan Pengepala Lajur sebagai nilai carian.
- Kedua, masukkan formula berikut dalam sel G5 yang merupakan sel pertama lajur ini.
=VLOOKUP(G$4&ROW($A$1:INDIRECT("A"&COUNTIF($C$5:$C$25,G$4))),$B$5:$E$25,3,FALSE) Pecahan Formula- COUNTIF($C$5:$C $25,G$4) memberitahu bilangan sel dalam julat C5:C25 ( Jenis Buku ) mengandungi nilai dalam sel G4 ( Novel ).
- Dalam kata mudahnya, berapa jumlah keseluruhan novel. Ia ialah 7 .
Kami telah menggunakan rujukan sel mutlak julat C5:C25 ( $C $5:$C$25 ) kerana kami mahu formula itu kekal tidak berubah jika kami menyalin formula ke mana-mana sel.
- INDIRECT(“A”&COUNTIF($C$5: $C$25,G$4)) menjadi INDIRECT(“A”&7) dan mengembalikan rujukan sel A7 . Lihat Fungsi TIDAK LANGSUNG untuk mendapatkan butiran.
- ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))) kini menjadi ROW(A1:A7) . Lihat fungsi ROW untuk mendapatkan butiran.
- Ia mengembalikan tatasusunan daripada 1 kepada 7 seperti {1, 2, 3, 4, 5, 6, 7} .
Kami menggunakan $A$1 kerana kami tidak mahu formula itu berubah jika kami menyalin formula ke sel lain.
- G$4&ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))) kini menggabungkan nilai dalam sel G4 ( Novel ) dengantatasusunan dikembalikan oleh fungsi ROW dan mengembalikan tatasusunan lain.
- Jadi ia mengembalikan {Novel1, Novel2, …, Novel7} .
- VLOOKUP(G$4 &ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))),$B$5:$E$25,3,FALSE) menjadi VLOOKUP({Novel1, Novel2, …, Novel7},$B$5:$E$25,3,FALSE) .
Ia mencari setiap nilai tatasusunan {Novel1 , Novel2, … Novel7} dalam lajur carian B .
Kemudian ia mengembalikan nama novel yang sepadan daripada lajur 3 (sebagai col_index_num ialah 3 ). Oleh itu, kami mendapat senarai semua novel.
- Seperti biasa, tekan kekunci ENTER .
Nota: Ia adalah formula tatasusunan. Jadi jangan lupa tekan Ctrl + Shift + Enter melainkan anda berada dalam Excel 365 .
Dan untuk Jenis Buku
- Pada mulanya, masukkan nama mereka bersebelahan sebagai Pengepala Lajur dan seret Pengendalian Isi .
Baca Lagi: VLOOKUP TIDAK LANGSUNG dalam Excel
Bacaan Serupa
- VLOOKUP Tidak Berfungsi (8 Sebab & Penyelesaian)
- Excel LOOKUP vs VLOOKUP: Dengan 3 Contoh
- Mengapa VLOOKUP Kembali #N/A Bila Padanan Wujud? (5 Punca & Penyelesaian)
- Gunakan VLOOKUP dengan Berbilang Kriteria dalam Excel (6 Kaedah + Alternatif)
- Excel VLOOKUP untuk Mencari Nilai Terakhir dalam Lajur (denganAlternatif)
Cara Alternatif untuk Vlookup dengan Berbilang Padanan dalam Excel
Jika kaedah sebelumnya kelihatan berbahaya, jangan risau. Terdapat lebih banyak pilihan yang tersedia.
1. Menggunakan Fungsi FILTER
Ini sememangnya kaedah yang paling mudah. Di sini, kami hanya akan menggunakan FILTER function . Ikut langkah mudah ini.
📌 Langkah:
- Pertama sekali, tulis Jenis Buku sebagai Pengepala Lajur dan masukkan formula berikut dalam sel F5 .
=FILTER($C$5:$C$25,$B$5:$B$25=F$4) Pecahan FormulaDi sini,
- $C$5:$C$25 ( Nama Buku ) ialah tatasusunan_carian . Kami sedang mencari nama-nama buku. Anda gunakan satu anda.
- $B$5:$B$25 ( Jenis Buku ) ialah susun_padanan . Kami mahu memadankan jenis buku. Anda menggunakan yang anda sewajarnya.
- F4 ( Novel ) ialah nilai_padanan . Kami mahu memadankan novel. Anda menggunakannya dengan sewajarnya.
- Kemudian, tekan ENTER .
Sekarang, jika anda mahukan Nama Buku daripada semua Jenis Buku ,
- Pada mulanya, masukkan nama mereka sebagai Pengepala Lajur sebelah menyebelah, dan kemudian seret alat Pemegang Isian .
2. Menggunakan Gabungan INDEX, SMALL dan ROWS Fungsi (Serasi dengan Versi Excel Lama)
Fungsi FILTER ialahhanya tersedia dalam Office 365 . Jadi, jika anda menggunakan versi Excel yang lebih lama, jangan risau. Kami ada penyelesaian lain untuk anda. Ia mudah dan mudah; ikut sahaja.
📌 Langkah:
- Terutamanya, masukkan Jenis Buku sebagai Pengepala Lajur dalam sel F4 dan masukkan formula ini dalam sel F5 .
=IFERROR(INDEX($C$5:$C$25,(SMALL(IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS(B1:B4),""),(ROW(B5:B25)-ROWS(B1:B4))))),"") Pecahan Formula- ROW(B5:B25) mengembalikan tatasusunan {5, 6, 7, …, 25} . Dan ROWS(B1:B4) mengembalikan 4 . Jadi ROW(B5:B25)-ROWS(B1:B4) mengembalikan tatasusunan {1, 2, 3, …, 21} . Lihat fungsi ROW dan ROWS untuk mendapatkan butiran.
- IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS (B1:B4),””) mengembalikan nombor yang sepadan daripada tatasusunan {1, 2, 3, …, 21} nilai dalam sel F4 ( Novel ) sepadan dengan nilai dalam mana-mana sel julat B5:B25 ( Jenis Buku ). Jika tidak mengembalikan sel kosong. Lihat Fungsi IF untuk mendapatkan butiran.
- KECIL(JIKA($B$5:$B$25=F4 ,ROW(B5:B25)-ROWS(B1:B4),””),(ROW(B5:B25)-ROWS(B1:B4))) menjadi KECIL({1, …, 3 , …, 6, …, 20, …},{1, 2, 3, 4, …., 21}) dan mengembalikan nombor dahulu, kemudian #NUM! ralat di tempat kosong sel. Lihat Fungsi KECIL untuk mendapatkan butiran.
- INDEX($C$5:$C$25,(SMALL( IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS(B1:B4),””),(ROW(B5:B25)-ROWS(B1:B4))))) menjadi INDEX($C$5:$C$25,{1,3,6,11,…,#NUM!}) dan mengembalikan Nama Buku yang sepadan (Nama Novel) dan ralat #NUM! . Lihat Fungsi INDEKS untuk mendapatkan butiran.
- Akhir sekali, kami membungkus formula di dalam fungsi IFERROR untuk menukar ralat menjadi sel kosong.
- Selepas itu, tekan ENTER .
- Sekarang, jika anda mahu , masukkan Jenis Buku yang lain sebagai Pengepala Lajur dan seret Pengendalian Isi . Anda akan mendapat buku jenis buku yang lain.
3. Vlookup dengan Berbilang Padanan dan Hasil Pulangan Berturut-turut
Dalam sebelumnya kaedah, kami mendapat keputusan dalam lajur menegak. Tetapi jika kita ingin mendapatkan nilai berturut-turut, bagaimana kita boleh melakukannya? Di sini, kami akan mendapat nama Pengarang untuk Jenis Buku yang berbeza berturut-turut. Cuma ikut langkah di bawah dengan teliti.
📌 Langkah:
- Pada mulanya, pergi ke sel G5 dan tulis formula di bawah.
=IFERROR(INDEX($D$5:$D$19,SMALL(IF($F5=$B$5:$B$19,ROW($D$5:$D$19)-4,""),COLUMN()-6)),"") Formula ini serupa dengan formula sebelumnya. Jadi, jika anda menghadapi sebarang masalah memahami formula ini, sila lihat penjelasan sebelumnya .
- Kemudian, ketik kekunci ENTER .
Tetapi terdapat pengarang lain yang mempunyai novel dalam set data ini. Jadi, bagaimanakah kita boleh mendapatkannya?
Hanya seret Pemegang Isi ke kanan ke atas ke sel K5 untuk mendapatkan Pengarang lain Novel . Selain itu, seret alat Fill Handle ke sel K7 untuk mendapatkan nama Pengarang untuk jenis buku yang berbeza. Lihat imej di bawah untuk penjelasan.
Cara Mencari Banyak Padanan dengan Beberapa Kriteria
Dalam contoh kami sebelum ini, kami menemui nilai untuk kriteria tunggal. Sebagai contoh, kami memperoleh tajuk buku untuk jenis buku tertentu. Tetapi di sini, kami akan membayangkan berbilang kriteria. Kami akan mencari Novel Charles Dickens menggunakan kaedah ini. Mari lihat tindakannya.
📌 Langkah:
- Pertama sekali, pilih sel H5 dan tampal formula berikut.
=IFERROR(INDEX($C$5:$C$25,SMALL(IF(1=((--($F$5=$B$5:$B$25))*(--($G$5=$D$5:$D$25))),ROW($C$5:$C$25)-4,""),ROW()-4)),"") - Kemudian, tekan ENTER .
Cara Vlookup dan Mengembalikan Berbilang Padanan dalam Satu Sel
Dalam pendekatan terdahulu, kami mendapat nilai dalam sel yang berbeza. Tetapi kami akan menunjukkan cara kami boleh mendapatkan hasil dalam satu sel. Jadi, tanpa berlengah lagi, mari kita selami!
📌 Langkah:
- Utamanya, pergi ke sel G5 dan masukkan formula di bawah.
=TEXTJOIN(", ",TRUE,IF($F$5=$B$5:$B$25,C5:C25,"")) Di sini, fungsi IF mendapat nilai daripada julat C5:C25 di mana nilai yang sepadan dalam julat B5:B25 sepadan dengan nilai dalam sel F5 . Kemudian, Fungsi TEXTJOIN menggabungkan nilai tatasusunan dengan koma sebagai pembatas.
- Kedua, tekan MASUKKAN .
Baca Lagi: FUNGSI PADANAN INDEKS lwn VLOOKUP (9 Contoh)
Kesimpulan
Artikel ini menerangkan cara vlookup dengan berbilang padanan dalam Excel dengan cara yang mudah dan ringkas. Jangan lupa memuat turun fail Amalan. Terima kasih kerana membaca artikel ini. Kami harap ini berguna. Sila beritahu kami di bahagian komen jika anda mempunyai sebarang pertanyaan atau cadangan. Sila lawati tapak web kami, ExcelWIKI , penyedia penyelesaian Excel sehenti, untuk meneroka lebih lanjut.
