Kako Vlookup s više podudaranja u Excelu (uz jednostavne korake)

Hugh West

18-10-2023 Excel formule
  • Podijeli Ovo
Hugh West

Jedna od najčudesnijih i najčešće korištenih funkcija programa Excel je funkcija VLOOKUP . Do sada smo naučili izvući jedno podudaranje iz niza ćelija pomoću ove funkcije. Često se možete susresti sa scenarijima u kojima morate dobiti sve podudarne vrijednosti za jedinstveni identifikator. U ovom ćemo članku pokazati kako možete izvući više podudaranja iz niza ćelija pomoću funkcije VLOOKUP u Excelu.

Preuzmite vježbovnu knjigu

Možete preuzmite sljedeću Excel radnu knjigu za bolje razumijevanje i vježbajte sami.

Izvođenje Vlookupa s višestrukim podudaranjima.xlsx

2 koraka za Vlookup s višestrukim podudaranjima u Excelu

Ovdje imamo Knjižne zapise knjižare Martin . Ovaj skup podataka sadrži Vrstu knjige , Naziv knjige i Autora nekih knjiga u stupcima B , C , i D prema tome.

Danas je naš cilj izvući sva podudaranja svake vrste knjige pomoću VLOOKUP funkcije . Ovo ćemo izvršiti u dva koraka. Dakle, istražimo ih jednu po jednu.

Ovdje smo upotrijebili verziju Microsoft Excel 365 , možete koristiti bilo koju drugu verziju kako vam odgovara.

📌 Korak 01: Stvorite jedinstveni naziv za svaku vrijednost pretraživanja

  • Na samom početku umetnite novi stupac s naslovom Pomoćni stupac lijevo od stupca pretraživanja Vrsta knjige i unesite ovu formulu u ćeliju B5 .
=C5&COUNTIF(C5:$C$25,C5) Raščlamba formule
  • COUNTIF(C5:$C$25,C5) vraća ukupan broj ćelija u rasponu C5:C25 ( Vrsta knjige ) koje sadrže vrijednost u ćeliji C5 ( Novel ). Pogledajte funkciju COUNTIF za detalje.
    • Koliko romana, jednostavnim riječima, ima. To je 7 .
  • C5&COUNTIF(C5:$C$25,C5) povezuje vrijednost u ćelija C5 ( Novel ) s njim.
    • Dakle, vraća Novel7 .

Kada povučete alat Ručka za popunjavanje , C5 povećava se jedan po jedan, kao C5 , C6 , C7 … ali C25 ostaje konstantan. Stoga se za svaku Vrstu knjige one ranije isključuju i generira se novi naziv.

Na primjer, u slučaju romana, Roman1 do <1 Generiraju se>Novel7 i slično za Poetry i druge vrste knjiga.

  • Zatim pritisnite ENTER .

  • Nakon toga pomaknite kursor udesno -donji kut ćelije B5 i izgledat će kao znak plus (+) . Zapravo, to je alat Ručka za popunjavanje .
  • Sada dvaput kliknite na njega.

Kopira ovu formulu na ostale stanice. Pronaći ćete sve vrijednosti traženja s jedinstvenim nazivom, kao što su Novel1 , Novel2…, Poetry1 , Poetry2… ,itd.

📌 Korak 02: Koristite funkciju VLOOKUP

  • Prvo, stvorite novi stupac s Zaglavljem stupca kao vrijednost pretraživanja.

  • Drugo, umetnite sljedeću formulu u ćeliju G5 koja je prva ćelija ovog stupca.
=VLOOKUP(G$4&ROW($A$1:INDIRECT("A"&COUNTIF($C$5:$C$25,G$4))),$B$5:$E$25,3,FALSE) Raščlamba formule
  • COUNTIF($C$5:$C $25,G$4) govori koliko ćelija u rasponu C5:C25 ( Vrsta knjige ) sadrži vrijednost u ćeliji G4 ( Roman ).
    • Koliko ukupno ima romana, jednostavnim riječima. To je 7 .

Upotrijebili smo apsolutnu referencu ćelije raspona C5:C25 ( $C $5:$C$25 ) jer želimo da ostane nepromijenjena ako kopiramo formulu u bilo koju ćeliju.

  • INDIRECT(“A”&COUNTIF($C$5: $C$25,G$4)) postaje INDIRECT(“A”&7) i vraća referencu ćelije A7 . Pogledajte INDIRECT funkciju za detalje.
  • ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))) sada postaje ROW(A1:A7) . Pogledajte ROW funkciju za detalje.
    • Vraća niz od 1 do 7 kao što je {1, 2, 3, 4, 5, 6, 7} .

Upotrijebili smo $A$1 jer ne želimo da se promijeni ako kopiramo formulu u drugu ćeliju.

  • G$4&ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))) sada spaja vrijednost u ćeliji G4 ( Roman ) sniz koji vraća funkcija ROW i vraća drugi niz.
    • Dakle, vraća {Novel1, Novel2, …, Novel7} .
  • VLOOKUP(G$4 &ROW($A$1:INDIRECT(“A”&COUNTIF($C$5:$C$25,G$4))),$B$5:$E$25,3,FALSE) postaje VLOOKUP({Novel1, Novel2, …, Novel7},$B$5:$E$25,3,FALSE) .

Traži svaku vrijednost niza {Novel1 , Novel2, … Novel7} u stupcu pretraživanja B .

Zatim vraća odgovarajući naziv romana iz 3. stupca (kao col_index_num je 3 ). Tako dobivamo popis svih romana.

  • Kao i obično, pritisnite tipku ENTER .

Napomena: To je formula polja. Zato ne zaboravite pritisnuti Ctrl + Shift + Enter osim ako niste u programu Excel 365 .

I za ostale vrste knjiga ,

  • Najprije umetnite njihova imena jedan pored drugog kao Zaglavlja stupaca i povucite Ručku za popunjavanje .

Pročitajte više: INDIREKTNI VLOOKUP u Excelu

Slična čitanja

  • VLOOKUP ne radi (8 razloga i rješenja)
  • Excel LOOKUP protiv VLOOKUP-a: s 3 primjera
  • Zašto se VLOOKUP vraća #N/A Kada podudaranje postoji? (5 uzroka i rješenja)
  • Koristite VLOOKUP s višestrukim kriterijima u Excelu (6 metoda + alternative)
  • Excel VLOOKUP za pronalaženje zadnje vrijednosti u stupcu (saAlternative)

Alternativni načini Vlookupa s više podudaranja u Excelu

Ako se prethodna metoda čini opasnom, ne brinite. Dostupno je više opcija.

1. Korištenje funkcije FILTER

Ovo je doista najjednostavnija metoda. Ovdje ćemo koristiti samo funkciju FILTER . Slijedite ove jednostavne korake.

📌 Koraci:

  • Prvo zapišite Vrstu knjige kao Zaglavlje stupca i unesite sljedeću formulu u ćeliju F5 .
=FILTER($C$5:$C$25,$B$5:$B$25=F$4) Raščlamba formule

Ovdje,

  • $C$5:$C$25 ( Naziv knjige ) je lookup_array . Tražimo nazive knjiga. Vi koristite svoju.
  • $B$5:$B$25 ( Vrsta knjige ) je matching_array . Želimo uskladiti vrste knjiga. U skladu s tim koristite svoj.
  • F4 ( Novel ) je matching_value . Želimo uskladiti romane. Koristite ga u skladu s tim.
  • Zatim pritisnite ENTER .

Sada, ako želite Imena knjiga svih Vrsti knjiga ,

  • Na početku umetnite njihova imena kao Zaglavlja stupaca jedan pored drugog, a zatim povucite alat Ručka za popunjavanje .

2. Primjena kombinacije INDEKSA, MALOG i REDAKA Funkcije (kompatibilne sa starijim verzijama programa Excel)

Funkcija FILTER jedostupno samo u Office 365 . Dakle, ako koristite stariju verziju Excela, ne brinite. Imamo još jedno zaobilazno rješenje za vas. Jednostavno je i lako; samo slijedite.

📌 Koraci:

  • Prvenstveno umetnite Vrstu knjige kao Zaglavlje stupca u ćeliji F4 i unesite ovu formulu u ćeliju F5 .
=IFERROR(INDEX($C$5:$C$25,(SMALL(IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS(B1:B4),""),(ROW(B5:B25)-ROWS(B1:B4))))),"") Raščlamba formule
  • ROW(B5:B25) vraća niz od {5, 6, 7, …, 25 . I ROWS(B1:B4) vraća 4 . Dakle, ROW(B5:B25)-ROWS(B1:B4) vraća niz od {1, 2, 3, …, 21} . Pogledajte funkciju ROW i ROWS za detalje.
  • IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS (B1:B4),””) vraća odgovarajući broj iz polja {1, 2, 3, …, 21} vrijednost u ćeliji F4 ( Roman ) odgovara vrijednosti u bilo kojoj ćeliji raspona B5:B25 ( Vrsta knjige ). Inače vraća praznu ćeliju. Pogledajte IF funkciju za detalje.

  • SMALL(IF($B$5:$B$25=F4 ,ROW(B5:B25)-ROWS(B1:B4),””),(ROW(B5:B25)-ROWS(B1:B4))) postaje MALO({1, …, 3 , …, 6, …, 20, …},{1, 2, 3, 4, …., 21}) i prvo vraća brojeve, a zatim greške #NUM! u prazno Stanice. Pogledajte SMALL funkciju za detalje.

  • INDEX($C$5:$C$25,(SMALL( IF($B$5:$B$25=F4,ROW(B5:B25)-ROWS(B1:B4),””),(ROW(B5:B25)-ROWS(B1:B4))))) postaje INDEX($C$5:$C$25,{1,3,6,11,…,#NUM!}) i vraća odgovarajuće Nazive knjiga (Naziv romana) i #NUM! pogreške. Pogledajte funkciju INDEX za detalje.

  • Na kraju smo formulu zamotali unutar funkcije IFERROR da biste pogreške pretvorili u prazne ćelije.
  • Nakon toga pritisnite ENTER .

  • Sada, ako želite , umetnite druge Vrste knjiga kao Zaglavlja stupaca i povucite Ručku za popunjavanje . Dobit ćete knjige drugih vrsta knjiga.

3. Vlookup s višestrukim podudaranjem i vraćanjem rezultata u nizu

U prethodnom metode, dobili smo rezultate u okomitim stupcima. Ali ako želimo dobiti vrijednosti u nizu, kako to možemo učiniti? Ovdje ćemo dobiti imena autora za različite vrste knjiga u nizu. Samo pažljivo slijedite donje korake.

📌 Koraci:

  • Prvo idite na ćeliju G5 i zapišite formulu ispod.
=IFERROR(INDEX($D$5:$D$19,SMALL(IF($F5=$B$5:$B$19,ROW($D$5:$D$19)-4,""),COLUMN()-6)),"")

Ova formula je donekle slična prethodnoj formuli. Dakle, ako imate problema s razumijevanjem ove formule, pogledajte prethodno objašnjenje .

  • Zatim dodirnite tipku ENTER .

Ali postoje i drugi autori koji imaju romane u ovom skupu podataka. Dakle, kako ih možemo dobiti?

Samo povucite Ručku za popunjavanje sve do ćelije K5 da biste dobilidrugi autori romana . Štoviše, povucite alat Fill Handle u ćeliju K7 da biste dobili imena Autora za različite vrste knjiga. Pogledajte sliku u nastavku radi pojašnjenja.

Kako Vlookupirati brojna podudaranja s nekoliko kriterija

U našim prethodnim primjerima pronašli smo vrijednosti za pojedinačne kriterije. Na primjer, dobivamo naslove knjiga za određenu vrstu knjige. Ali ovdje ćemo implicirati više kriterija. Pomoću ove metode potražit ćemo Romane Charlesa Dickensa . Pogledajmo ga na djelu.

📌 Koraci:

  • Prvo i najvažnije, odaberite ćeliju H5 i zalijepite sljedeću formulu.
=IFERROR(INDEX($C$5:$C$25,SMALL(IF(1=((--($F$5=$B$5:$B$25))*(--($G$5=$D$5:$D$25))),ROW($C$5:$C$25)-4,""),ROW()-4)),"")
  • Zatim pritisnite ENTER .

Kako Vlookupirati i vratiti više podudaranja u jednoj ćeliji

U ranijim pristupima dobivali smo vrijednosti u različitim ćelijama. Ali pokazat ćemo kako možemo dobiti rezultate u jednoj ćeliji. Dakle, bez daljnjeg odgađanja, zaronimo!

📌 Koraci:

  • Prvenstveno, idite na ćeliju G5 i unesite formulu u nastavku.
=TEXTJOIN(", ",TRUE,IF($F$5=$B$5:$B$25,C5:C25,""))

Ovdje, IF funkcija dobiva vrijednost iz raspona C5:C25 gdje odgovarajuće vrijednosti u rasponu B5:B25 odgovaraju vrijednosti u ćeliji F5 . Zatim, funkcija TEXTJOIN kombinira vrijednosti niza sa zarezom kao razdjelnikom.

  • Sekundarno, pritisnite ENTER .

Pročitajte više: INDEX MATCH nasuprot funkciji VLOOKUP (9 primjera)

Zaključak

Ovaj članak objašnjava kako Vlookup s više podudaranja u Excelu na jednostavan i koncizan način. Ne zaboravite preuzeti datoteku za vježbu. Hvala što ste pročitali ovaj članak. Nadamo se da je ovo bilo od pomoći. Javite nam u odjeljku za komentare ako imate bilo kakvih pitanja ili prijedloga. Posjetite našu web stranicu, ExcelWIKI , pružatelja rješenja za Excel na jednom mjestu, kako biste istražili više.

Prethodni post VBA INDEX MATCH Na temelju više kriterija u Excelu (3 metode)
Sljedeći post Kako napraviti kubni korijen u Excelu (3 jednostavne metode)

Hugh West vrlo je iskusan Excel trener i analitičar s više od 10 godina iskustva u industriji. Diplomirao je računovodstvo i financije te magistrirao poslovno upravljanje. Hugh ima strast za podučavanjem i razvio je jedinstveni pristup podučavanju koji je lako pratiti i razumjeti. Njegovo stručno poznavanje programa Excel pomoglo je tisućama studenata i profesionalaca diljem svijeta da poboljšaju svoje vještine i postignu uspjeh u karijeri. Putem svog bloga, Hugh dijeli svoje znanje sa svijetom, nudeći besplatne vodiče za Excel i online obuku kako bi pomogao pojedincima i tvrtkama da dostignu svoj puni potencijal.