Съдържание
Сайтът VLOOKUP е една от най-мощните, гъвкави и изключително полезни функции на Microsoft Excel за търсене и извличане на стойности - точно съвпадащи стойности или най-близките съвпадащи стойности - чрез търсене на съответна стойност. VLOOKUP Тази статия ще ви покаже как да направите така, че VLOOKUP чувствителни към големи и малки букви в Excel.
Изтегляне на шаблон за практика
Можете да изтеглите безплатния тренировъчен шаблон на Excel оттук и да се упражнявате сами.
VLOOKUP Case Sensitive.xlsxVLOOKUP в Excel
VLOOKUP означава Вертикално търсене '. Това е функция, която кара Excel да търси определена стойност в дадена колона, за да върне стойност от друга колона в същия ред.
Обща формула:
=VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup]) Тук,
| Аргументи | Определение |
|---|---|
| lookup_value | Стойността, която се опитвате да съпоставите |
| table_array | Обхватът на данните, в който искате да търсите стойността си |
| col_index_num | Съответна колона на lookup_value |
| range_lookup | Това е булева стойност: TRUE или FALSE. FALSE (или 0) означава точно съвпадение, а TRUE (или 1) - приблизително съвпадение. |
4 динамични метода за чувствителност на VLOOKUP към случая в Excel
Разгледайте следната съвкупност от данни за ученици. В тази съвкупност от данни има двама ученици, които имат еднакви имена, но различни фамилии и са получили различен резултат.
Искаме да извършим търсене на резултата от шоуто на Джон. Затова нека приложим общия VLOOKUP за да получите резултата.
=VLOOKUP(G3,B2:D7,3,0) 
Но както можете да видите на снимката по-горе, вместо резултата на Джон Шоу той ни даде резултата на Джон Сина. Това е така, защото VLOOKUP търси стойността за търсене в масива и връща първата получена стойност; тя не се справя с чувствителността на буквите към малки и големи букви.
Така че, за да получите чувствителен към големи и малки букви VLOOKUP , трябва да изпълните функцията по различен начин. И за да го постигнем, трябва да бъдем малко по-хитри, за да получим резултата на Джон Шоу в тази клетка. Можем да направим това, като приложим различни функции заедно, за да изпълним VLOOKUP .
В следващите раздели ще разгледаме комбинацията от функцията INDEX и функцията MATCH , комбинацията от VLOOKUP и функцията CHOOSE , функцията SUMPRODUCT и стартирайте функцията XLOOKUP за да направите чувствителен към големи и малки букви VLOOKUP в Excel.
1. използване на функциите INDEX, MATCH за разработване на чувствителна към случаите VLOOKUP в Excel
Можем да получим чувствителен към малки и големи букви VLOOKUP чрез комбиниране на INDEX и MATCH да функционират заедно.
Обща формула на комбинацията от INDEX и MATCH функция е,
=INDEX(data,MATCH(TRUE,EXACT(value,lookup_column),0),column_number) Стъпките за получаване на чувствителен към случая VLOOKUP чрез прилагане на INDEX и MATCH са дадени по-долу,
Стъпки:
- Щракнете върху клетката, в която искате да се съдържа стойността на резултата (в нашия случай клетката е G4 ).
- И запишете следната формула,
=INDEX(D2:D7,MATCH(TRUE,EXACT(G3,B2:B7),0)) 
Сега погледнете снимката по-горе, където можете да видите, че резултатът на Джон Шоу е там, а не резултатът на Джон Сина.
Разбивка на формулата:
Нека да разбием формулата, за да разберем как установихме резултата на Джон Шоу.
- EXACT(G3,B2:B7) -> EXACT функция в Excel връща TRUE ако два низа са напълно еднакви, и FALSE ако два низа не съвпадат. Тук даваме EXACT функция масив като втори аргумент и да я помолите да установи дали Клетка G3 (където съхраняваме нашата стойност за търсене, Джон) е в него или не е. Тъй като дадохме масив като вход, ще получим масив от TRUE или FALSE в изхода. И изходът се съхранява в паметта на Excel, а не в диапазон.
Изход: {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}
Това е резултатът от сравняването на стойността на G3 във всяка клетка в масива за търсене. Тъй като получихме TRUE това означава, че има точно съвпадение на стойността за търсене. Сега трябва да открием позицията (номера на реда) на тази TRUE стойност в масива.
Сайтът MATCH функция на помощ!
- MATCH(TRUE,EXACT(G3,B2:B7),0) -> станете MATCH({FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE})
Обяснение: Сайтът MATCH В този пример искахме да получим точно съвпадение, затова зададохме третия аргумент като 0 (TRUE).
Изход: 6
- INDEX(D2:D7,MATCH(TRUE,EXACT(G3,B2:B7),0)) -> става INDEX(D2:D7,6)
Обяснение: Сайтът INDEX функцията приема два аргумента и връща определена стойност в едноизмерен диапазон. Тъй като вече знаем позицията на номера на реда (6) която съдържа желаната от нас стойност, ще използваме INDEX за да извлечете стойността на тази позиция.
Изход: 22
Така че резултатът от шоуто за джон е 22.
2. комбиниране на функцията VLOOKUP & CHOOSE за извършване на чувствителна към случая VLOOKUP в Excel
Можем да приложим два начина в комбинацията от VLOOKUP и ИЗБЕРИ за създаване на функция, чувствителна към големи и малки букви VLOOKUP в Excel.
2.1 Превръщане на VLOOKUP в чувствителен към случаите с помощна колона
Вмъкването на нова колона за получаване на уникална стойност за търсене за всеки елемент в масива за търсене е друг ефективен начин за изпълнение на задачата. Това помага за разграничаване на имена с различни буквени падежи. И ние ще наречем тази нововмъкната колона като Помощна колона.
Стъпките за получаване на чувствителен към случая VLOOKUP с помощна колона са дадени по-долу,
Стъпки:
- Вмъкнете помощна колона вляво от колоната, от която искате да получите данните.
- В помощната колона въведете формулата =ROW() . Във всяка клетка ще се вмъкне номерът на реда.
- Щракнете върху клетката, в която искате да се съдържа стойността на резултата (в нашия случай клетката е H4 ).
- И запишете следната формула,
=VLOOKUP(MAX(EXACT(H3,$B$2:$B$7)*(ROW($B$2:$B$7))),$D$2:$E$7,2,0) 
Сега погледнете снимката по-горе, където можете да видите, че резултатът на Джон Шоу е там, а не резултатът на Джон Сина.
Разбивка на формулата:
Нека да разбием формулата, за да разберем как установихме резултата на Джон Шоу.
- EXACT(H3,$B$2:$B$7) -> Подобно на предишната дискусия, EXACT връща масив от TRUE и FALSE стойности, където TRUE представлява съвпадения, чувствителни към големи и малки букви, и FALSE Представлява несъвпадащите стойности. Така че в нашия случай ще върне следния масив,
Изход: {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}
- EXACT(H3,$B$2:$B$7)*(ROW($B$2:$B$7) -> става { FALSE;FALSE;FALSE;FALSE;FALSE;TRUE} * {John,Roman,Seth,Dean,Finn,john}
Обяснение: Той представлява умножение между масива от TRUE/FALSE и номера на реда на B2:B7 Винаги, когато има TRUE , той извлича номера на реда. В противен случай е FALSE .
Изход: {0;0;0;0;0;7}
- MAX(EXACT(H3,$B$2:$B$7)*(ROW($B$2:$B$7)) -> става MAX( 0;0;0;0;0;7)
Обяснение: Тя ще върне максималната стойност от масива от числа.
Изход: 7 (което е и номерът на реда, в който има точно съвпадение).
- VLOOKUP(MAX(EXACT(H3,$B$2:$B$7)*(ROW($B$2:$B$7))),$D$2:$E$7,2,0) -> става VLOOKUP(7,$D$2:$E$7,2,0)
Обяснение: Той може просто да извлече стойността за търсене от масива (D2:D7) и тъй като искаме да намерим точно съвпадение, задайте аргумента 0 (TRUE).
Изход: 22
Така че резултатът от шоуто за джон е 22.
Забележка: Можете да вмъкнете помощната колона навсякъде в набора от данни. Само се уверете, че сте я вмъкнали вляво от колоната, от която искате да изтеглите данните. След това трябва да коригирате номера на колоната в VLOOKUP съответно функция.
2.2 Превръщане на VLOOKUP в чувствителен към случаите с помощта на виртуални помощни данни
Идеята за използване на виртуални помощни данни е почти подобна на вмъкването на помощна колона, но уловката тук е, че вместо да се поставя действителна колона в работния лист, самата формула работи като колони.
Стъпките за получаване на чувствителен към случая VLOOKUP с виртуални помощни данни са дадени по-долу,
Стъпки:
- Щракнете върху клетката, в която искате да се съдържа стойността на резултата (в нашия случай клетката е I4 ).
- И запишете следната формула,
=VLOOKUP(MAX(EXACT(I3,$D$2:$D$7)*(ROW($D$2:$D$7)),CHOOSE({1,2},ROW($D$2:$D$7),$F$2:$F$7),2,0 
Сега погледнете снимката по-горе, където можете да видите, че резултатът на Джон Шоу е там, а не резултатът на Джон Сина.
Следващата част от пълната формула работи тук като помощни данни ,
=---CHOOSE({1,2},ROW($D$2:$D$7),$F$2:$F$7)--- Разбивка на формулата:
Нека да разбием формулата, за да разберем как данните на виртуалния помощник помогнаха за намирането на резултата на Джон Шоу.
- CHOOSE({1,2},ROW($D$2:$D$7),$F$2:$F$7) -> Ако илюстрирате тази формула, като я изберете и натиснете F9 , ще получите следния резултат,
Изход: {2,100;3,50;4,30;5,80;6,60;7,22}
Обяснение: Представлява масив, който ни показва номера на реда и свързаната с него стойност от дадения масив, разделена на запетая (,) . И всеки точка и запетая (;) Така че, както изглежда, са създадени две колони, състоящи се от номера на реда и колоната, в която е върната стойността на търсенето (т.е. номер на реда и колона Score в нашия случай).
- VLOOKUP(MAX(EXACT(I3,$D$2:$D$7)*(ROW($D$2:$D$7)),CHOOSE({1,2},ROW($D$2:$D$7),$F$2:$F$7),2,0 -> става VLOOKUP(7,{2,100;3,50;4,30;5,80;6,60;7,22},2,0)
Обяснение: Когато приложите VLOOKUP функцията просто търси стойността за търсене в първата колона от двете колони с виртуални данни и връща съответната стойност (т.е. Резултат ). Стойността за търсене тук е комбинацията от MAX и EXACT функция, която получихме от изчисленията в горната дискусия за помощната колона.
Изход: 22
Така че резултатът от шоуто за джон е 22.
3. Използване на функцията SUMPRODUCT, за да направите VLOOKUP чувствителен към случая в Excel
Можем да получим VLOOKUP чрез прилагане на SUMPRODUCT функция в Excel.
Генерична формула:
=SUMPRODUCT(- -( EXACT(value,lookup_column)),result_column) Стъпките за получаване на чувствителен към случая VLOOKUP чрез прилагане на SUMPRODUCT са дадени по-долу,
Стъпки:
- Щракнете върху клетката, в която искате да се съдържа стойността на резултата (в нашия случай клетката е G4 ).
- И запишете следната формула,
=SUMPRODUCT((EXACT(B2:B7,G3) * (D2:D7)) 
Погледнете снимката по-горе, където можете да видите, че резултатът на Джон Шоу е там, а не на Джон Сина.
Разбивка на формулата:
Нека да разбием формулата, за да разберем как установихме резултата на Джон Шоу.
- EXACT(B2:B7,G3) -> Подобно на предишната дискусия, EXACT връща масив от TRUE и FALSE стойности, където TRUE представлява съвпадения, чувствителни към големи и малки букви, и FALSE Представлява несъвпадащите стойности. Така че в нашия случай ще върне следния масив,
Изход: {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}
- SUMPRODUCT((EXACT(B2:B7,G3) * (D2:D7)) -> станете SUMPRODUCT({ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;ВЯРНО} * {100,50,30,80,60,22})
Обяснение: SUMPRODUCT след това просто умножава стойностите във всеки масив заедно, за да се получи крайният масив, {ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;ФАЛШИВО;22} . И след това съберете и върнете стойността.
Изход: 22
Така че резултатът от шоуто за джон е 22.
Магията на тази формула е, че FALSE единствените стойности, които оцеляват, са тези, които са били TRUE .
Така че имайте предвид че ако в масива има множество съвпадения, тогава SUMPRODUCT ще върне сумата от всички тези съвпадащи стойности. Също така, SUMPRODUCT Работи само с числови стойности, но не и с текст. Така че, ако искате да получите уникална текстова стойност, използвайте горните методи, които разгледахме.
4. Формула за извършване на VLOOKUP с чувствителност към конкретния случай в Excel
Можем да получим VLOOKUP чрез извършване на XLOOKUP функция в Excel.
Генерична формула:
=XLOOKUP(TRUE,EXACT(lookup_value, lookup_array), return_array, "Not Found") Стъпките за получаване на чувствителен към случая VLOOKUP чрез прилагане на XLOOKUP Формулата е дадена по-долу,
Стъпки:
- Щракнете върху клетката, в която искате да се съдържа стойността на резултата (в нашия случай клетката е G4 ).
- И запишете следната формула,
=XLOOKUP(TRUE, EXACT(G3, B2:B7), D2:D7, "Не е намерен") 
Сега погледнете снимката по-горе, където можете да видите, че резултатът на Джон Шоу е там, а не резултатът на Джон Сина.
Разбивка на формулата:
Нека разложим формулата, за да разберем как установихме резултата на Джон Шоу.
- EXACT(G3, B2:B7) -> Подобно на предишната дискусия, EXACT връща масив от TRUE и FALSE стойности, където TRUE представлява съвпадения, чувствителни към големи и малки букви, и FALSE представлява несъвпадащите стойности. Така че в нашия случай ще върне следния масив,
Изход: {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}
- XLOOKUP(TRUE, EXACT(G3, B2:B7), D2:D7, "Не е намерен") -> става XLOOKUP( {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}, {100,50,30,80,60,22}, "Не е намерен")
Обяснение: След това XLOOKUP търси в дадения масив (в нашия случай масивът е B2:B7 ) за TRUE и връща съвпадение от масива за връщане ( D2:D7 ).
Изход: 22
Така че резултатът от шоуто за джон е 22.
Не забравяйте, че , ако в колоната за търсене има няколко еднакви стойности (включително буквените падежи), формулата ще върне първото намерено съвпадение.
Забележка: Този XLOOKUP формулата ще работи само в Excel 365 .
Основни точки, които трябва да имате предвид
- Тъй като обхватът на масива на таблицата с данни за търсене на стойността е фиксиран, не забравяйте да поставите долар ($) пред референтния номер на клетката от таблицата на масива.
- Когато работите със стойности на масиви, не забравяйте да натиснете Ctrl + Shift + Enter на клавиатурата, докато извличате резултати. Натискането само на Въведете не работи при работа със стойности на масиви.
- След натискане на Ctrl + Shift + Enter , ще забележите, че в лентата с формули е заградена формулата в къдрави скоби {} , декларирайки го като формула за масив. Не въвеждайте тези скоби {} сами, Excel автоматично прави това за вас.
Заключение
Тази статия обяснява подробно как да направите VLOOKUP чувствителност към големи и малки букви в Excel чрез прилагане на комбинация от функции. Надявам се, че тази статия е била много полезна за вас. Не се колебайте да попитате, ако имате някакви въпроси по темата.
