Du er kommet til det rette sted, hvis du leder efter svaret eller nogle unikke tips til at matche flere kriterier fra forskellige arrays i Excel. Der er forskellige måder at matche flere kriterier fra forskellige arrays i Excel på. Denne artikel vil gå dig gennem hvert enkelt trin med passende eksempler. Som følge heraf kan du nemt bruge dem til dit formål. Lad os gå videre til artiklens hovedpunkterdiskussion.

Download arbejdsbog til øvelser

Du kan downloade den arbejdsbog, som jeg har brugt i denne artikel, nedenfor og øve dig med den selv.

Match flere kriterier fra forskellige arrays.xlsx

6 metoder til at matche flere kriterier fra forskellige arrays i Excel

I dette afsnit vil jeg vise dig 6 hurtige og nemme metoder til at matche flere kriterier fra forskellige arrays i Excel på Windows-operativsystemet. Denne artikel indeholder detaljerede forklaringer med klare illustrationer til alt. Jeg har brugt den Microsoft 365-version Du kan dog bruge en anden version, afhængigt af hvad du har til rådighed. Skriv en kommentar, hvis en del af denne artikel ikke virker i din version.

I dette datasæt har jeg forsøgt at give et eksempel fra det virkelige liv. Datasættet indeholder oplysninger om nogle tøjprodukter. Det har fire kolonner, nemlig produktets navn , den Farve , den Størrelse , og den Pris som du kan se på det følgende billede.

1. Brug af Array-formel med INDEX- og MATCH-funktionerne

Her har jeg hentet den Pris af den Produkt ( Celle B11 ) på grundlag af produktets Navn , Farve, og Størrelse.

📌 Trin:

• For at gøre dette skal du først indsætte produktnavn , farve og størrelse i celler G5 , G6 , G7
• Indsæt derefter følgende formel i celle G8 for at få den pris for det produkt, der opfylder disse kriterier:

=IFERROR(INDEX(E5:E20,MATCH(1,(G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20),0)),"No Match")

🔎 Formelfordeling:

✅ Multiplikationsoperationen :

→ (G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20) = (Skjorte = Produkt kolonne)*(Indigo = Farve kolonne)*(L = Størrelse kolonne) = {FALSK; FALSK; FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;FALSK;FALSK}*(G6=C5:C20)*(G7=D5:D20)}

Den vil søge værdierne i den respektive kolonne og returnere værdierne TRUE/FALSE i overensstemmelse hermed.

→ {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0}

Multiplikationsoperator (*) konverterer disse værdier til 0'er og 1'er og udfører derefter multiplikationsoperationen, som konverterer alle andre værdier til 0'er undtagen det ønskede output.

✅ MATCH-funktion Operation :

→ MATCH(1,(0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0),0))) → 13

Denne funktion leder efter værdien 1 i det konverterede område og returnerer positionen.

✅ INDEX-funktion Operation :

→ IFERROR(INDEX(E5:E20,13), "Ingen match") → 50

Denne funktion returnerer værdien i 13. række i den priskolonne, som er det ønskede output. I tilfælde, hvor der ikke er nogen match, vil INDEX funktion vil returnere en #N/A fejl. For at håndtere sådanne fejl og vise en menneskeligt læsbar meddelelse, skal " Ingen match ", den IFERROR-funktion anvendes her.

Læs mere: Excel INDEX MATCH med flere kriterier (4 egnede eksempler)

2. Brug af en formel for INDEX- og MATCH-funktioner, der ikke er et array

Her har jeg forsøgt at udføre den samme opgave som tidligere. Formlen er også den samme, bortset fra at der er en ekstra INDEX funktion og en udvalgt ikke-array type af den INDEX funktion.

📌 Trin:

• For at gøre dette skal du først indsætte produkt navn, farve, og størrelse i de respektive celler.
• Indsæt derefter følgende formel i celle G8 for at få prisen for det produkt, der opfylder disse kriterier:

=IFERROR(INDEX(E5:E25,MATCH(1,INDEX((G5=B5:B25)*(G6=C5:C25)*(G7=D5:D25),0,1),0)),"No Match")

🔎 Formel Forklaring:

Hovedformålet med denne nye INDEX funktionen er at konvertere den foregående array-formel til en formel, der ikke er en array-formel så den kan implementeres af en person, der ikke er fortrolig med Excel-arrayfunktioner. Den nye INDEX funktionen håndterer det returnerede array efter multiplikationen, hvilket eliminerer behovet for en arrayformel.

Læs mere: INDEX MATCH flere kriterier i Excel (uden array-formel)

Lignende læsninger

• INDEX MATCH med 3 kriterier i Excel (4 eksempler)
• SUMIF med INDEX- og MATCH-funktioner i Excel
• Indeks Match Sum flere rækker i Excel (3 måder)
• INDEX MATCH med flere kriterier i et andet ark (2 måder)
• Flere kriterier i Excel ved hjælp af INDEX-, MATCH- og COUNTIF-funktionen

3. INDEX MATCH-formel for flere kriterier fra forskellige horisontale og vertikale arrays i Excel

3.1 Opslag vertikalt i kolonner

Ud over de tidligere beskrevne måder kan du kombinere INDEX og MATCH funktioner til opslag til horisontalt og vertikalt opslag med flere kriterier. Følg nedenstående trin for at gøre dette.

📌 Trin:

• Klik i første omgang på celle C18 og indsæt følgende formel.

=INDEX(D5:D14,MATCH(1,(B5:B14=C16)*(C5:C14=C17),0))

• Tryk efterfølgende på Indtast

Som et resultat heraf kan du få det ønskede resultat for den ønskede sælger.

3.2 Opslag horisontalt i rækker

Du kan også kombinere de INDEX og MATCH funktioner til at søge efter flere kriterier horisontalt ved at følge nedenstående trin.

📌 Trin:

• Først skal du klikke på celle C10 .
• Indsæt derefter følgende formel, og tryk på Indtast

=INDEX(C6:L6,MATCH(1,(C4:L4=C8)*(C5:L5=C9),0))

På den måde kan du få fat i den ønskede persons afdeling ved hjælp af et horisontalt opslag.

4. INDEX MATCH-formel til at matche flere kriterier fra arrays i forskellige Excel-ark

Tænk på en situation, hvor du arbejder på en virksomhedsgård. Din chef har givet dig en opgave, hvor du skal finde salgsbeløbet for forskellige sælgere fra et andet regneark. Du kan nemt gøre det ved at bruge INDEX MATCH formel.

• I det følgende eksempel er "ID" , "Fornavn" , og "Salg" af arbejdstagere er givet vilkårligt. Du skal finde den "Salg" for en bestemt "ID" og en specifik "Fornavn" i et andet regneark. Regnearket hedder "Data" .

• Lav en anden tabel i et nyt regneark, der indeholder kolonner "ID" , "Fornavn" , og "Salg" I dette nye regneark skal vi finde resultatet. Navngiv dette regneark som "M01" .
• Indsæt derefter følgende formel i celle D5 i regnearket "M01" i celle D5.

=INDEX(Data!$D$5:$D$15,MATCH(1,('M01'!B5=Data!$B$5:$B$15)*('M01'!C5=Data!$C$5:$C$15),0)))

• Anvend nu den samme formel på resten af cellerne.

• Du har således brugt flere kriterier til at finde en værdi fra forskellige regneark.

5. Brug af funktionen COUNTIFS til at matche flere kriterier fra forskellige arrays

Vi kan bruge den COUNTIFS-funktion til at matche flere kriterier i Excel. I så fald skal vi bruge OG logik for kriterier i forskellige kolonner og ELLER logik for kriterier i den samme kolonne.

5.1 Brug af AND-logik for flere kriterier i flere kolonner

OG logik betyder, at alle kriterier skal matches for at få den sande værdi. Her har jeg beregnet det samlede antal rækker baseret på den Navn , Farve , og Størrelse kriterier.

📌 Trin:

• Indsæt først navnet på den produkt , farve , og størrelse i de respektive celler i intervallet F5:F7 .
• Indsæt derefter følgende formel i celle F8 for at få optællingen af de celler, der svarer til de givne kriterier:

=COUNTIFS(B5:B20,F5,C5:C20,F6,D5:D20,F7)

🔎 Formelfordeling:

=COUNTIFS(B5:B20,F5,C5:C20,F6,D5:D20,F7) → COUNTIFS(Produktkolonne, Skjorte, Farvesøjle, Indigo, Størrelsessøjle, L) → 1

• Den søger efter værdierne i de respektive kolonner og øger tallet, hvis alle kriterierne er opfyldt.
• Der er kun én kolonne, hvor alle kriterierne stemmer overens, så det er det ønskede output.

• På den måde får du optællingen af celler, der matcher de givne kriterier for forskellige arrays.

Læs mere: Indeks Match flere kriterier i rækker og kolonner i Excel

5.2 OR-logik for flere kriterier i samme kolonne

ELLER logik betyder, at hvis et kriterium passer, vil det TRUE Her har jeg beregnet det samlede antal rækker, hvor farveværdierne er " Rød " og " Gul ".

For at gøre det skal du indsætte følgende formel i celle F4 for at få optællingen af de celler, der svarer til de givne kriterier:

=SUM(COUNTIFS(C5:C20,{"Rød", "Gul"}))

🔎 Formelfordeling:

→ SUM(COUNTIFS(C11:C31,{"Rød", "Gul"})) → SUM(COUNTIFS(Kolonne farve,{"Rød", "Gul"}))

COUNTIFS-funktion søger efter værdierne i de respektive kolonner og øger tallet, hvis der er overensstemmelse med et kriterium. Da der er tre "Rød" og tre "Gul", er det derfor, at COUNTIFS funktionen giver 3,3.

→ SUM(3,3) → 6

SUM-funktion lægger de to værdier sammen og returnerer det ønskede output.

• Jeg har således beregnet den samlede mængde af røde og gule produkter.

Læs mere: Sum med INDEX-MATCH-funktioner under flere kriterier i Excel

6. Brug af FILTER-funktionen

Som navnet antyder, er det FILTER-funktion filtrerer en række celler ud fra bestemte kriterier. Du skal ikke skrive formler med flere funktioner til denne metode. Kun FILTER funktion er nok til at udføre operationen. Her har jeg hentet den Pris af den Produkt ( Celle B11 ) på grundlag af produktets Navn , Farve, og Størrelse.

📌 Trin:

• Indsæt først navnet på den produkt , farve , og størrelse i de respektive celler i intervallet F5:F7 .
• Indsæt derefter følgende formel i celle F8 for at få oplyst prisen på det produkt, der opfylder alle kriterierne.

=FILTER(E5:E20,(B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7),"No Match")

🔎 Formelfordeling:

✅ Multiplikationsoperationen:

→ (B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7) = (Produkt kolonne = Skjorte)*(Farve kolonne = Indigo)*(Størrelse kolonne = L) = {FALSK ;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;FALSK;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;SAND;FALSK;FALSK}*(C5:C20=G6)*(D5:D20=G7)}

Den vil søge værdierne i de respektive kolonner og returnere SAND/FALSK værdier i henhold til den.

→ {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0}

Multiplikationsoperator (*) konverterer disse værdier til 0'er og 1'er og udfører derefter multiplikationsoperationen, som konverterer alle andre værdier til 0'er undtagen det ønskede output.

✅ FILTER-funktionen:

→ FILTER(E14:E34,{0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0;0;0;0},”No Match”) = FILTER(PriceColumn {0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0;0;0;0; 0;0;0;0}, "Ingen match") = 50

FILTER funktionen søger i kolonnen Pris med indeksnumre og returnerer den celleværdi, hvor den tilsvarende indeksværdi er 1 (1), i dette tilfælde 50.

• Jeg har således beregnet prisen på et produkt, der opfylder de mange kriterier, der er angivet.

Bemærk:

I skrivende stund er den FILTER funktionen er kun tilgængelig i Excel 365. Så hvis du bruger andre versioner af Excel, bør du tjekke de andre metoder.

Konklusion

I denne artikel har du fundet ud af, hvordan du kan matche flere kriterier fra forskellige arrays i Excel. Jeg håber, at du kunne finde en løsning på dit problem. Efterlad venligst en kommentar, hvis du har forslag eller spørgsmål. Tak.