Ak hľadáte odpoveď alebo jedinečné tipy na porovnanie viacerých kritérií z rôznych polí v programe Excel, ste na správnom mieste. Existujú rôzne spôsoby, ako porovnať viacero kritérií z rôznych polí v programe Excel. Tento článok vás prevedie každým krokom s vhodnými príkladmi. Vďaka tomu ich môžete ľahko použiť na svoj účel. Prejdime k hlavnému článkudiskusia.

Stiahnite si cvičebnicu

Pracovný zošit, ktorý som použil v tomto článku, si môžete stiahnuť z nižšie uvedenej stránky a precvičiť si ho sami.

Porovnanie viacerých kritérií z rôznych polí.xlsx

6 metód na porovnanie viacerých kritérií z rôznych polí v programe Excel

V tejto časti vám ukážem 6 rýchlych a jednoduchých metód na porovnanie viacerých kritérií z rôznych polí v programe Excel v operačnom systéme Windows. Tento článok obsahuje podrobné vysvetlenia s jasnými ilustráciami pre všetko. Použil som Verzia Microsoft 365 tu. Môžete však použiť akúkoľvek inú verziu v závislosti od vašej dostupnosti. Ak niektorá časť tohto článku nefunguje vo vašej verzii, zanechajte prosím komentár.

V tomto súbore údajov som sa pokúsil poskytnúť príklad z reálneho života. Súbor údajov obsahuje informácie o niektorých odevných výrobkoch. Má štyri stĺpce, a to názov výrobku ,. Farba ,. Veľkosť a Cena ako môžete vidieť na nasledujúcom obrázku.

1. Používanie vzorca poľa s funkciami INDEX a MATCH

Tu som vyhľadal Cena z Produkt ( Bunka B11 ) na základe produktu Názov , Farba, a Veľkosť.

📌 Kroky:

• Na tento účel najprv vložte názov výrobku , farba a veľkosť v bunkách G5 , G6 , G7
• Potom do bunky vložte nasledujúci vzorec G8 získať cena pre výrobok, ktorý spĺňa tieto kritériá:

=IFERROR(INDEX(E5:E20,MATCH(1,(G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20),0)),"No Match")

🔎 Rozdelenie vzorca:

✅ Operácia násobenia :

→ (G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20) = (Košeľa = stĺpec produktu)*(Indigo = stĺpec farby)*(L = stĺpec veľkosti) = {FALSE; FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE}*(G6=C5:C20)*(G7=D5:D20)}

Vyhľadá hodnoty do príslušného stĺpca a podľa toho vráti hodnoty TRUE/FALSE.

→ {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0}

Stránka Operátor násobenia (*) prevedie tieto hodnoty na 0 a 1 a potom vykoná operáciu násobenia, ktorá prevedie všetky ostatné hodnoty na 0 okrem požadovaného výstupu.

✅ Funkcia MATCH Operácia :

→ MATCH(1,(0;0;0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0),0)) → 13

Táto funkcia hľadá hodnotu 1 v prevedenom rozsahu a vracia pozíciu.

✅ Funkcia INDEX Operácia :

→ IFERROR(INDEX(E5:E20,13), "Žiadna zhoda") → 50

Táto funkcia vracia hodnotu v 13. rad stĺpca s cenou, ktorý je požadovaným výstupom. V prípadoch, keď neexistuje žiadna zhoda, sa INDEX funkcia vráti #N/A Na spracovanie takýchto chýb a zobrazenie ľudsky čitateľnej správy sa používa " Žiadna zhoda ",. Funkcia IFERROR sa tu používa.

Prečítajte si viac: Excel INDEX MATCH s viacerými kritériami (4 vhodné príklady)

2. Použitie vzorca funkcie INDEX a MATCH, ktorý nie je poľom

Tu som sa pokúsil vykonať rovnakú úlohu ako predtým. Vzorec je tiež rovnaký, len je tu navyše INDEX a vybraný typ, ktorý nie je typom poľa INDEX funkcie.

📌 Kroky:

• Na tento účel najprv vložte produkt názov, farba, a veľkosť v príslušných bunkách.
• Potom vložte nasledujúci vzorec do bunka G8 získať cenu za výrobok, ktorý spĺňa tieto kritériá:

=IFERROR(INDEX(E5:E25,MATCH(1,INDEX((G5=B5:B25)*(G6=C5:C25)*(G7=D5:D25),0,1),0)),"No Match")

🔎 Vysvetlenie vzorca:

Hlavným cieľom tohto nového INDEX je previesť predchádzajúci vzorec poľa na vzorec, ktorý nie je vzorcom poľa aby ho mohol implementovať aj niekto, kto nepozná funkcie poľa Excelu. INDEX funkcia spracuje vrátené pole po operácii násobenia, čím sa eliminuje potreba vzorca na násobenie poľa.

Prečítajte si viac: INDEX MATCH viacerých kritérií v programe Excel (bez vzorca poľa)

Podobné čítania

• INDEX MATCH s 3 kritériami v programe Excel (4 príklady)
• SUMIF s funkciami INDEX a MATCH v programe Excel
• Indexová zhoda súčtu viacerých riadkov v programe Excel (3 spôsoby)
• INDEX MATCH s viacerými kritériami v inom hárku (2 spôsoby)
• Viacero kritérií v programe Excel pomocou funkcií INDEX, MATCH a COUNTIF

3. Vzorec INDEX MATCH pre viacero kritérií z rôznych horizontálnych a vertikálnych polí v programe Excel

3.1 Vyhľadávanie vertikálne v stĺpcoch

Okrem predchádzajúcich spôsobov opísaných vyššie môžete kombinovať INDEX a MATCH funkcie na vyhľadávanie pre horizontálne a vertikálne vyhľadávanie s viacerými kritériami. Postupujte podľa nižšie uvedených krokov.

📌 Kroky:

• Na začiatku kliknite na bunka C18 a vložte nasledujúci vzorec.

=INDEX(D5:D14,MATCH(1,(B5:B14=C16)*(C5:C14=C17),0))

• Následne stlačte tlačidlo Vstúpte na stránku

Vďaka tomu môžete získať požadovaný výsledok pre požadovaného predajcu.

3.2 Vyhľadávanie horizontálne v riadkoch

Môžete tiež kombinovať INDEX a MATCH funkcie na horizontálne vyhľadávanie viacerých kritérií podľa nasledujúcich krokov.

📌 Kroky:

• Najprv kliknite na bunka C10 .
• Následne vložte nasledujúci vzorec a stlačte tlačidlo Vstúpte na stránku

=INDEX(C6:L6,MATCH(1,(C4:L4=C8)*(C5:L5=C9),0))

Takto môžete získať oddelenie požadovanej osoby pomocou horizontálneho vyhľadávania.

4. Vzorec INDEX MATCH na porovnanie viacerých kritérií z polí v rôznych listoch programu Excel

Uvažujte o situácii, keď pracujete na obchodnej farme. Váš šéf vám dal zadanie, v ktorom máte zistiť výšku predaja rôznych obchodných zástupcov z iného pracovného hárku. Môžete to urobiť jednoducho pomocou INDEX MATCH vzorec.

• V nasledujúcom príklade "ID" , "Krstné meno" a "Predaj" pracovníkov sú dané ľubovoľne. Musíte nájsť "Predaj" pre konkrétnu "ID" a konkrétny "Krstné meno" v inom pracovnom hárku. Pracovný hárok má názov "Údaje" .

• Vytvorte ďalšiu tabuľku v novom pracovnom hárku obsahujúcom stĺpce "ID" , "Krstné meno" a "Predaj" V tomto novom pracovnom hárku nájdeme výsledok. Tento pracovný hárok pomenujte ako "M01" .
• Potom do bunky D5 pracovného hárka "M01" vložte nasledujúci vzorec.

=INDEX(Data!$D$5:$D$15,MATCH(1,("M01"!B5=Data!$B$5:$B$15)*("M01"!C5=Data!$C$5:$C$15),0))

• Teraz použite rovnaký vzorec pre ostatné bunky.

• Použili ste teda viacero kritérií na zistenie hodnoty z rôznych pracovných hárkov.

5. Použitie funkcie COUNTIFS na porovnanie viacerých kritérií z rôznych polí

Môžeme použiť Funkcia COUNTIFS na porovnanie viacerých kritérií v programe Excel. V takom prípade musíme použiť A logika pre kritériá v rôznych stĺpcoch a ALEBO logika pre kritériá v tom istom stĺpci.

5.1 Používanie logiky AND pre viacero kritérií vo viacerých stĺpcoch

A logika znamená, že na získanie skutočnej hodnoty by sa mali zhodovať všetky kritériá. Tu som vypočítal celkový počet riadkov na základe Názov , Farba a Veľkosť kritériá.

📌 Kroky:

• Najprv vložte názov produkt , farba a veľkosť v príslušných bunkách rozsahu F5:F7 .
• Potom vložte nasledujúci vzorec do bunka F8 na získanie počtu buniek, ktoré vyhovujú zadaným kritériám:

=COUNTIFS(B5:B20,F5,C5:C20,F6,D5:D20,F7)

🔎 Rozdelenie vzorca:

=COUNTIFS(B5:B20,F5,C5:C20,F6,D5:D20,F7) → COUNTIFS(Stĺpec produktu, Košeľa, Stĺpec farby, Indigo, Stĺpec veľkosti, L) → 1

• Vyhľadá hodnoty v príslušných stĺpcoch a zvýši počet, ak sú splnené všetky kritériá.
• Existuje len jeden stĺpec, v ktorom sa zhodujú všetky kritériá. Je to teda požadovaný výstup.

• Takto získate počet buniek zodpovedajúcich zadaným kritériám pre rôzne polia.

Prečítajte si viac: Indexová zhoda viacerých kritérií v riadkoch a stĺpcoch v programe Excel

5.2 Logika OR pre viacero kritérií v tom istom stĺpci

ALEBO logika znamená, že ak sa jedno kritérium zhoduje s druhým. TRUE Tu som vypočítal celkový počet riadkov, v ktorých sú hodnoty farieb " Červená " a " Žltá ".

Ak to chcete urobiť, vložte nasledujúci vzorec do bunka F4 na získanie počtu buniek, ktoré zodpovedajú zadaným kritériám:

=SUM(COUNTIFS(C5:C20,{"Červená", "Žltá"})

🔎 Rozdelenie vzorca:

→ SUM(COUNTIFS(C11:C31,{"Červená", "Žltá"}) → SUM(COUNTIFS(stĺpec Farba,{"Červená", "Žltá"})

Funkcia COUNTIFS vyhľadá hodnoty v príslušnom stĺpci a zvýši počet, ak sú splnené niektoré kritériá. Keďže existujú tri "červené" a tri "žlté", preto sa COUNTIFS funkcia vráti 3,3.

→ SUM(3,3) → 6

Stránka Funkcia SUM sčíta tieto dve hodnoty a vráti požadovaný výstup.

• Takto som vypočítal celkové množstvo červených a žltých výrobkov.

Prečítajte si viac: Súčet s funkciami INDEX-MATCH v rámci viacerých kritérií v programe Excel

6. Používanie funkcie FILTER

Ako už názov napovedá, Funkcia FILTER filtruje rozsah buniek na základe určitých kritérií. Pri tejto metóde nepíšete vzorce s viacerými funkciami. FILTER na vykonanie operácie stačí funkcia. Tu som načítal Cena z Produkt ( Bunka B11 ) na základe produktu Názov , Farba, a Veľkosť.

📌 Kroky:

• Najprv vložte názov produkt , farba a veľkosť v príslušných bunkách rozsahu F5:F7 .
• Potom do bunky vložte nasledujúci vzorec F8 získať cenu výrobku, ktorý spĺňa všetky kritériá.

=FILTER(E5:E20,(B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7),"No Match")

🔎 Rozdelenie vzorca:

✅ Operácia násobenia:

→ (B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7) = (Stĺpec produktu = Košeľa)*(Stĺpec farby = Indigo)*(Stĺpec veľkosti = L) = {FALSE ;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE}*(C5:C20=G6)*(D5:D20=G7)}

Vyhľadá hodnoty do príslušného stĺpca a vráti PRAVDA/NEPRAVDA hodnoty podľa neho.

→ {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0}

Stránka Operátor násobenia (*) prevedie tieto hodnoty na 0 a 1 a potom vykoná operáciu násobenia, ktorá prevedie všetky ostatné hodnoty na 0 okrem požadovaného výstupu.

✅ Funkcia FILTER:

→ FILTER(E14:E34,{0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0;0;0;0},”No Match”) = FILTER(PriceColumn {0;0;0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0;0;0; 0;0;0}, "No Match") = 50

Stránka FILTER funkcia vyhľadá stĺpec Cena s indexovými číslami a vráti hodnotu bunky, v ktorej je príslušná hodnota indexu rovná jednej (1), v tomto prípade 50.

• Preto som vypočítal cenu výrobku, ktorý zodpovedá viacerým zadaným kritériám.

Poznámka:

V čase písania tohto článku FILTER Funkcia je k dispozícii len v programe Excel 365. Ak používate iné verzie programu Excel, mali by ste si overiť iné metódy.

Záver

V tomto článku ste našli spôsob, ako v programe Excel porovnať viacero kritérií z rôznych polí. Dúfam, že sa vám podarilo nájsť riešenie vášho problému. Ak máte nejaké návrhy alebo otázky, zanechajte prosím komentár. Ďakujem.