Bạn đã đến đúng chỗ nếu đang tìm kiếm câu trả lời hoặc một số mẹo độc đáo để đối sánh nhiều tiêu chí từ các mảng khác nhau trong Excel. Có nhiều cách khác nhau để so khớp nhiều tiêu chí từ các mảng khác nhau trong Excel. Bài viết này sẽ hướng dẫn bạn qua từng bước với các ví dụ thích hợp. Nhờ đó, bạn có thể sử dụng chúng dễ dàng cho mục đích của mình. Hãy chuyển sang nội dung thảo luận chính của bài viết.

Tải xuống Sách bài tập thực hành

Bạn có thể tải xuống sách bài tập mà tôi đã sử dụng trong bài viết này từ bên dưới và tự mình thực hành.

Khớp nhiều tiêu chí từ các mảng khác nhau.xlsx

6 phương pháp khớp nhiều tiêu chí từ các mảng khác nhau trong Excel

Trong phần này, tôi sẽ chỉ cho bạn 6 phương pháp nhanh chóng và dễ dàng để so khớp nhiều tiêu chí từ các mảng khác nhau trong Excel trên hệ điều hành Windows. Bài viết này chứa các giải thích chi tiết với hình ảnh minh họa rõ ràng cho mọi thứ. Tôi đã sử dụng Phiên bản Microsoft 365 tại đây. Tuy nhiên, bạn có thể sử dụng bất kỳ phiên bản nào khác tùy thuộc vào tình trạng sẵn có của bạn. Vui lòng để lại nhận xét nếu bất kỳ phần nào của bài viết này không hoạt động trong phiên bản của bạn.

Trong bộ dữ liệu này, tôi đã cố gắng cung cấp một ví dụ thực tế. Bộ dữ liệu chứa thông tin về một số sản phẩm quần áo. Nó có bốn cột, tên sản phẩm , Màu sắc , Kích thước và Giá như bạn có thể thấytrong hình sau.

1. Sử dụng Công thức mảng với Hàm INDEX và MATCH

Ở đây, tôi đã tìm nạp Giá của Sản phẩm ( Ô B11 ) dựa trên trên Tên , Màu sắc, và Kích thước của sản phẩm.

📌 Các bước:

• Đối với điều này, trước tiên hãy chèn tên sản phẩm , màu sắc và kích thước vào các ô G5 , G6 , G7
• Sau đó, chèn công thức sau vào ô G8 để lấy giá cho sản phẩm đáp ứng các tiêu chí đó:

=IFERROR(INDEX(E5:E20,MATCH(1,(G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20),0)),"No Match")

🔎 Phân tích công thức:

✅ Thao tác nhân :

→ (G5=B5:B20)*(G6=C5:C20)*(G7=D5:D20) = (Áo sơ mi = Cột sản phẩm)*(Chàm = Cột màu)*(L = Cột kích thước) = {FALSE; SAI;SAI;SAI;SAI;SAI;SAI;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE}*(G6=C5:C20)*(G7=D5:D20)}

Nó sẽ tìm kiếm các giá trị cho cột tương ứng và trả về các giá trị TRUE/FALSE tương ứng với cột đó.

→ {0;0;0;0;0;0;0; 0;0;0;0;0;1;0;0;0}

Toán tử nhân (*) chuyển đổi các giá trị này thành 0 và 1, sau đó thực hiện phép toán nhân chuyển đổi tất cả các giá trị khác thành 0 ngoại trừ đầu ra mong muốn.

✅ Hàm MATCH Thao tác :

→ MATCH(1 ,(0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0),0)) → 13

Đây hàm tìm kiếm giá trị 1 trong phạm vi đã chuyển đổi vàtrả về vị trí.

✅ Chức năng INDEX Thao tác :

→ IFERROR(INDEX(E5:E20,13), “No Khớp”) → 50

Hàm này trả về giá trị ở hàng thứ 13 của cột giá là đầu ra mong muốn. Đối với trường hợp không có kết quả khớp, hàm INDEX sẽ trả về lỗi #N/A . Để xử lý các lỗi như vậy và hiển thị thông báo mà con người có thể đọc được, “ Không khớp “, hàm IFERROR được sử dụng tại đây.

Đọc thêm: DẠNG CHỈ SỐ Excel với nhiều tiêu chí (4 ví dụ phù hợp)

2. Sử dụng Công thức không phải mảng của Hàm INDEX và MATCH

Ở đây, tôi đã thử thực hiện tác vụ tương tự như trước đây. Công thức cũng giống như vậy, ngoại trừ có thêm hàm INDEX và loại không phải mảng được chọn của hàm INDEX .

📌 Các bước:

• Đối với điều này, trước tiên hãy chèn tên sản phẩm , màu sắc, và kích thước vào các ô tương ứng.
• Sau đó, chèn công thức sau vào ô G8 để lấy giá cho sản phẩm đáp ứng các tiêu chí đó:

=IFERROR(INDEX(E5:E25,MATCH(1,INDEX((G5=B5:B25)*(G6=C5:C25)*(G7=D5:D25),0,1),0)),"No Match")

🔎 Giải thích về công thức:

Mục đích chính của hàm INDEX mới này là chuyển đổi công thức mảng trước đó thành công thức không phải mảng để người không quen với các hàm mảng trong Excel có thể thực hiện được. Hàm INDEX mới xử lý mảng được trả về sauphép toán nhân loại bỏ sự cần thiết của công thức mảng.

Đọc thêm: INDEX MATCH Nhiều tiêu chí trong Excel (Không có công thức mảng)

Các bài đọc tương tự

• INDEX MATCH với 3 tiêu chí trong Excel (4 ví dụ)
• SUMIF với hàm INDEX và MATCH trong Excel
• So khớp chỉ mục Tổng nhiều hàng trong Excel (3 cách)
• INDEX MATCH với nhiều tiêu chí trong một Trang tính khác nhau (2 cách)
• Nhiều tiêu chí trong Excel bằng hàm INDEX, MATCH và COUNTIF

3. Công thức INDEX MATCH cho nhiều tiêu chí từ các mảng ngang và dọc khác nhau trong Excel

3.1 Tra cứu theo chiều dọc trong cột

Ngoài các cách trước đó được mô tả ở trên, bạn có thể kết hợp INDEX và MATCH chức năng tra cứu tra cứu ngang và dọc với nhiều tiêu chí. Hãy làm theo các bước bên dưới để thực hiện việc này.

📌 Các bước:

• Đầu tiên, hãy nhấp vào ô C18 và chèn công thức sau.

=INDEX(D5:D14,MATCH(1,(B5:B14=C16)*(C5:C14=C17),0))

• Sau đó, nhấn Enter

Kết quả là bạn có thể nhận được kết quả mong muốn cho nhân viên bán hàng mong muốn của mình.

3.2 Tra cứu theo hàng ngang

Bạn cũng có thể kết hợp Hàm INDEX và MATCH để tra cứu nhiều tiêu chí theo chiều ngang bằng cách thực hiện theo các bước bên dưới.

📌 Các bước:

• Đầu tiên , nhấp chuộttrên ô C10 .
• Sau đó, hãy chèn công thức sau và nhấn Enter

=INDEX(C6:L6,MATCH(1,(C4:L4=C8)*(C5:L5=C9),0))

Do đó, bạn có thể nhận được phòng ban của người mong muốn bằng cách tra cứu theo chiều ngang.

4. Công thức INDEX MATCH để Khớp Nhiều Tiêu chí từ Mảng trong Các trang tính Excel khác nhau

Hãy xem xét một tình huống mà bạn đang làm việc tại một trang trại kinh doanh. Sếp của bạn đã giao cho bạn một nhiệm vụ trong đó bạn phải tìm số lượng bán hàng của các đại diện bán hàng khác nhau từ một bảng tính khác. Bạn có thể thực hiện dễ dàng bằng cách sử dụng công thức INDEX MATCH .

• Trong ví dụ sau, “ID” , “Tên” , và “Bán” công nhân được đưa ra một cách tùy tiện. Bạn phải tìm “Giảm giá” cho một “ID” cụ thể và “Tên” cụ thể trong một trang tính khác. Trang tính được đặt tên là “Dữ liệu” .

• Tạo một bảng khác trong trang tính mới chứa các cột “ID” , “Tên” và “Bán hàng” . Trong bảng tính mới này, chúng ta sẽ tìm thấy kết quả. Đặt tên cho trang tính này là “M01” .
• Sau đó, chèn công thức sau vào ô D5 của trang tính “M01”.

=INDEX(Data!$D$5:$D$15,MATCH(1,('M01'!B5=Data!$B$5:$B$15)*('M01'!C5=Data!$C$5:$C$15),0))

• Bây giờ, hãy áp dụng công thức tương tự cho các ô còn lại.

• Do đó, bạn đã sử dụng nhiều tiêu chí để tìm ra một giá trị từ các trang tính khác nhau.

5. Sử dụng hàm COUNTIFS để so khớp nhiều tiêu chítừ các mảng khác nhau

Chúng ta có thể sử dụng hàm COUNTIFS để so khớp nhiều tiêu chí trong Excel. Trong trường hợp đó, chúng ta phải sử dụng logic AND cho các tiêu chí trong các cột khác nhau và logic OR cho các tiêu chí trong cùng một cột.

5.1 Sử dụng AND Logic cho nhiều tiêu chí trong nhiều cột

VÀ logic có nghĩa là tất cả các tiêu chí phải được so khớp để có được giá trị thực. Ở đây, tôi đã tính tổng số hàng dựa trên các tiêu chí Tên , Màu sắc và Kích thước .

📌 Các bước :

• Đầu tiên, hãy chèn tên của sản phẩm , màu sắc và kích thước vào các ô tương ứng của phạm vi F5:F7 .
• Sau đó, chèn công thức sau vào ô F8 để lấy số ô khớp với tiêu chí đã cho:

=COUNTIFS(B5:B20,F5,C5:C20,F6,D5:D20,F7)

🔎 Phân tích công thức:

=COUNTIFS(B5 :B20,F5,C5:C20,F6,D5:D20,F7) → COUNTIFS(Cột Sản phẩm, Áo sơ mi, Cột Màu, Chàm, Cột Kích thước, L) → 1

• Nó tìm kiếm các giá trị trong các cột tương ứng và tăng số lượng nếu tất cả các tiêu chí đều phù hợp.
• Chỉ có một cột có tất cả các tiêu chí phù hợp. Vì vậy, đó là đầu ra mong muốn.

• Như vậy, bạn có số ô phù hợp với tiêu chí được đưa ra cho các mảng khác nhau.

Đọc thêm: Chỉ mục khớp với nhiều tiêu chí trong hàng và cột trong Excel

5.2 HOẶCLogic cho nhiều tiêu chí trong cùng một cột

HOẶC logic có nghĩa là nếu một tiêu chí phù hợp, giá trị TRUE sẽ được trả về. Ở đây, tôi đã tính tổng số hàng có các giá trị màu là “ Đỏ ” và “ Vàng ”.

Để làm điều đó, hãy chèn công thức sau vào ô F4 để lấy số ô khớp với tiêu chí đã cho:

=SUM(COUNTIFS(C5:C20,{"Red","Yellow"}))

🔎 Phân tích công thức:

→ SUM(COUNTIFS(C11:C31,{“Red”,“Yellow”})) → SUM( COUNTIFS(Cột màu,{“Đỏ”, ”Vàng”}))

Hàm COUNTIFS tìm kiếm các giá trị trong cột tương ứng và tăng số lượng nếu có bất kỳ tiêu chí nào phù hợp . Vì có ba “Đỏ” và ba “Vàng”, đó là lý do tại sao hàm COUNTIFS trả về 3,3.

→ SUM(3,3) → 6

Hàm SUM cộng hai giá trị và trả về kết quả mong muốn.

• Như vậy tôi đã tính được tổng số sản phẩm màu đỏ và màu vàng.

Đọc thêm: Tính tổng bằng hàm INDEX-MATCH theo nhiều tiêu chí trong Excel

6 . Sử dụng Hàm FILTER

Như tên gợi ý, Hàm FILTER lọc một dải ô dựa trên các tiêu chí nhất định. Bạn không viết công thức với nhiều chức năng cho phương pháp này. Chỉ chức năng FILTER là đủ để thực hiện thao tác. Ở đây, tôi đã lấy Giá của Sản phẩm ( Ô B11 ) dựa trên Tên , Màu sắc, và Kích thước của sản phẩm.

📌 Các bước:

• Đầu tiên, hãy nhập tên của sản phẩm , màu sắc và kích thước vào các ô tương ứng của phạm vi F5:F7 .
• Sau đó, hãy chèn công thức sau vào ô F8 để nhận giá của sản phẩm phù hợp với tất cả các tiêu chí.

=FILTER(E5:E20,(B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7),"No Match")

🔎 Phân tích công thức:

✅ Phép toán nhân:

→ (B5:B20=G5)*(C5:C20=G6)*(D5:D20=G7) = (Cột Sản phẩm = Áo sơ mi)*(Cột màu = Chàm)*(Cột cỡ = L) = {FALSE ;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE ;TRUE;FALSE;FALSE}*(C5:C20=G6)*(D5:D20=G7)}

Nó sẽ tìm kiếm các giá trị cho cột tương ứng và trả về TRUE/FALSE giá trị theo nó.

→ {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0

Toán tử nhân (*) chuyển đổi các giá trị này thành 0 và 1, sau đó thực hiện phép toán nhân chuyển tất cả các giá trị khác về 0 ngoại trừ đầu ra mong muốn.

✅ Chức năng FILTER:

→ FILTER(E14:E34,{0;0;0 ;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0;0;0;0},”Không khớp”) = FILTER(Cột giá {0;0;0;0;0;0;0;0;0;0;0;0;1;0;0;0;0;0; 0;0;0},”No Match”) = 50

Hàm FILTER tìm kiếm cột Giá bằng số chỉ mục và trả về giá trị ô nơi chỉ số tương ứnggiá trị là một (1), Trong trường hợp này là 50.

• Như vậy, tôi đã tính giá của một sản phẩm phù hợp với nhiều tiêu chí đã cho.

Lưu ý:

Tại thời điểm viết bài này, hàm FILTER chỉ khả dụng trên Excel 365. Vì vậy , nếu bạn đang sử dụng các phiên bản Excel khác thì bạn nên kiểm tra các phương pháp khác.

Kết luận

Trong bài viết này, bạn đã tìm ra cách đối sánh nhiều tiêu chí từ các mảng trong Excel. Tôi hy vọng bạn đã có thể tìm ra giải pháp cho vấn đề của mình. Vui lòng để lại nhận xét nếu bạn có bất kỳ đề xuất hoặc câu hỏi nào. Cảm ơn bạn.