Oft gætir þú þurft að raða hlutum úr gagnasafni út frá mörgum forsendum. Nánar tiltekið, þú verður að framkvæma þetta verkefni þegar það eru tengsl í einum dálki. Í þessari lærdómsríku lotu mun ég sýna 4 tilvik með réttri útskýringu á röðun í Excel byggt á mörgum forsendum.

Sækja æfingabók

Röðun byggt á á mörgum skilyrðum.xlsx

4 tilvik fyrir röðun byggt á mörgum skilyrðum í Excel

Við skulum kynna gagnasafn dagsins þar sem stig af nemanda í Stærðfræði og Sálfræði eru gefin í samræmi við samsvarandi hóp þeirra. Hér eru D6 og D7 frumur tengdar í dálki D . Svo skulum við nota röðunina með hliðsjón af dálki E .

1. Notkun RANK.EQ og COUNTIFS aðgerðir

Í byrjunaraðferð mun ég sýna þér samsetta notkun RANK.EQ fallsins og COUNTIFS fallsins . Til að raða á grundvelli einkunna tveggja skaltu setja inn eftirfarandi formúlu.

=RANK.EQ($C5,$C$5:$C$15)+COUNTIFS($C$5:$C$15,$C5,$D$5:$D$15,">"&$D5)

Hér, C5 og D5 eru upphafshólfið á stig (stærðfræði) þ.e. dálkur C, og stig (sálfræði) þ.e. dálkur D í sömu röð.

⧬ Skýring á formúlu:

• RANK.EQ fallið skilar stöðunúmerinu úr C5:C15 frumusvið byggt á C5 frumu. Því miður veitir það sömu stöðu fyrir afritiðstig (t.d. röð er 7 fyrir C6 , C7 og C12 frumur).
• Svo, COUNTIFS fall er úthlutað í lækkandi röð ( “>”&$D5) t o telja tvítekið stig. Til dæmis skilar fallið 1 fyrir C7 hólfið og 2 fyrir C12 hólfið.
• Hins vegar, þegar þú leggur saman tvö úttak, þ.e. úttakið RANK.EQ fallið og úttak COUNTIFS fallsins, færðu einstaka stöðunúmer fyrir alla nemendur.

Eftir að hafa ýtt á ENTER og notað Fill Handle tólið færðu eftirfarandi úttak.

Ef þú skoðar vel á myndinni hér að ofan muntu sjá að Staðan fyrir Robert Smith er 7 (horfðu á B6:E6 frumurnar) en það er 8 fyrir Jim Brown (horfðu á B7:E7 frumur).

Lesa meira: Hvernig á að búa til sjálfvirka röðunartöflu í Excel (með skjótum skrefum)

2. Röðun byggð á mörgum forsendum með því að nota COUNTIF og COUNTIFS aðgerðir

Á sama hátt geturðu notað COUNTIF fallið í stað RANK.EQ fallsins.

=COUNTIF($C$5:$C$15,"<"&$C5)+COUNTIFS($C$5:$C$15,$C5,$D$5:$D$15,"<"&$D5)+1

Hér vil ég raða stigunum í hækkandi röð ( “<“&$D5) .

⧬ Formúlaskýring:

• COUNTIF fallið telur fjölda frumna sem hafa gildi sem eru hærri en samsvarandi reit (eins og C5 fyrir James Smith, C6 fyrir Jim Brown, og svo framvegis).
• Að lokum,þú verður að bæta 1 við úttakið þar sem COUNTIF fallið skilar 0 fyrir minnstu gildin, þ.e. fyrir C13 reitinn.

Svo, úttakið verður sem hér segir.

Lesa meira: Rank IF Formula í Excel (5 dæmi)

Svipuð lestur

• Hvernig á að raða með böndum í Excel (5 einfaldar leiðir)
• Reiknið út hlutfallstölu í Excel (7 viðeigandi dæmi)
• Hvernig á að reikna út 10 efstu prósentin í Excel (4 leiðir)

3. Notkun RANK og SUMPRODUCT aðgerða

Einnig geturðu notað bæði RANK aðgerðina og SUMPRODUCT fall til að raða hlutum út frá mörgum forsendum.

Skoðaðu nú eftirfarandi gagnasafn þaðan sem þú þarft að raða út frá GRE Score (Quant) og Fjárhagsaðstoð . En frumugildin C10 og C11 eru jöfn.

Svo skaltu setja inn eftirfarandi sameinuðu formúlu.

=RANK(C5,$C$5:$C$15)+SUMPRODUCT(--($C$5:$C$15=$C5),--(D5<$D$5:$D$15))

⧬ Skýring formúlu:

• RANK fallið skilar röðunarnúmerið úr $C$5:$C$15 reitsviðinu byggt á C5 hólfinu með tvítekningargildinu í C10 og C11 frumur (staðatalan er 2 ).
• Og SUMPRODUCT fallið finnur 0 ef engin jöfn gildi eru til staðar. En það skilar 1 fyrir C10 hólfið.
• Einkum er að nefna að ( — ) rekstraraðili er notaður til að skila 1 í stað þess að fá TRUE og 0 fyrir FALSE .
• Þannig geturðu auðveldlega forðast tvítekna stöðunúmerið með þessari formúlu.

Að lokum mun úttakið líta út sem hér segir.

Í stað þess að nota RANK aðgerð, þú getur notað COUNTIF aðgerðina. En þú verður að bæta við 1 í því tilfelli.

=COUNTIF($C$5:$C$15,">"&$C5)+SUMPRODUCT(--($C$5:$C$15=$C5),--(D5<$D$5:$D$15))+1

Vissulega muntu fá sama framleiðsla.

Lesa meira: Hvernig á að stafla starfsmönnum í Excel (3 aðferðir)

4. Röðun með mörgum skilyrðum eftir hópum

Hvað ef þú ert með einhverja algenga hópa í gagnasafninu þínu? Til dæmis nær Science hópurinn yfir C5:C6 og C11:C12 frumur.

Sem betur fer , þú getur fengið einstaka stöðunúmer sem fjallar um bæði Hópur og Sigur . Við höfum aðgerðir sem geta hjálpað okkur við röðun í Excel út frá mörgum viðmiðum í hópum.

4.1. Með því að nota COUNTIFS aðgerðina

Með því að nota COUNTIFS aðgerðina geturðu auðveldlega raðað stiginu eftir úthlutaðan hóp í lækkandi röð ( “ >”&D5 ).

=COUNTIFS($C$5:$C$15,C5,$D$5:$D$15,">"&D5)+1

⧬ Formúluskýring:

• The COUNTIFS($C$5:$C$15,C5) skilar 4 þar sem það eru 4 strengir í boði, nefnilega Science .
• Og, COUNTIFS($C$5:$C$15,C5,$D$5:$D$15,">"&D5) setningafræði skilar 0 fyrir hæstu einkunn (t.d.fyrir E6 frumuna). Þess vegna þarftu að bæta við 1 .

Hér er stigunum raðað eftir hópnum sérstaklega. Til dæmis er Jim Brown ( B6 klefi) í fyrsta sæti þó að einkunn Mary Smith ( B13 klefi) sé heilsað en hann.

Lesa meira : Hvernig á að raða innan hóps í Excel (3 aðferðir)

4.2. Notkun SUMPRODUCT aðgerða

Á sama hátt geturðu notað eftirfarandi formúlu þar sem SUMPRODUCT aðgerðin er notuð (röðun í hækkandi röð).

=SUMPRODUCT((C5=$C$5:$C$15)*($D5<$D$5:$D$15))+1

⧬ Formúluskýring:

• The SUMPRODUCT((C5=$C$5:$C$15) skilar 0 .
• Að auki, SUMPRODUCT((C5=$C$5:$C$15)*($D5<$D$5:$D$15)) finnur 2 . En SUMVARA fallið skilar fyrir E7 hólf er 0 þar sem það er minnsta stigið. Þannig að þú þarft að 1 til að forðast slíkar villur.

Lesa meira: Hvernig á að raða meðaltali í Excel (4 algengar sviðsmyndir)

Niðurstaða

Þarna lýkur lotunni í dag. Svona geturðu náð að raka í Excel byggt á mörgum forsendum. Engu að síður, ef þú hefur einhverjar fyrirspurnir eða ráðleggingar, vinsamlegast deildu þeim í athugasemdahlutanum.