Mục lục
Trong bài viết này, tôi sẽ chỉ cho bạn cách tính tổng tất cả các kết quả khớp với VLOOKUP trong Excel. Bạn sẽ tìm hiểu cách tính tổng tất cả các kết quả khớp bằng cách sử dụng hàm VLOOKUP, cùng với việc sử dụng hàm FILTER và hàm IF kết hợp với Hàm tính tổng.
Tải xuống sách bài tập thực hành
Tính tổng tất cả các kết quả khớp với VLOOKUP.xlsx
3 cách tính tổng tất cả các kết quả trùng khớp với VLOOKUP trong Excel
Ở đây chúng tôi có một tập dữ liệu với Tên, Tác giả và Giá của một số cuốn sách của hiệu sách tên là Martin Bookstore.
Hãy thử tìm tổng của tất cả các kết quả khớp với VLOOKUP từ tập dữ liệu này.
1. Sử dụng Hàm FILTER để tính tổng tất cả các kết quả khớp với VLOOKUP trong Excel (Dành cho các phiên bản Excel mới hơn)
Những người có quyền truy cập vào tài khoản Office 365 có thể sử dụng FILTER Hàm của Excel để tính tổng tất cả các kết quả trùng khớp từ bất kỳ tập dữ liệu nào.
Trong tập dữ liệu đã cho, công thức để tìm ra tổng giá của tất cả sách của Charles Dickens sẽ là:
=SUM(FILTER(D4:D13,C4:C13=F4)) 
⧪ Giải thích Công thức:
- Hàm FILTER khớp một giá trị tra cứu với tất cả các giá trị của cột tra cứu và trả về các giá trị tương ứng từ một cột khác.
- Đây F4 ( Charles Dickens ) là giá trị tra cứu của chúng ta, C4:C13 (Tác giả) là tra cứu cột và D4:D13 (Price) là cột khác.
- FILTER(D4:D13,C4:C13=F4) khớp với tất cả các giá trị của cột C4:C13 (Tác giả) với F4 ( Charles Dickens ) và trả về các giá trị tương ứng từ cột D4:D13 ( Giá ).
- Cuối cùng, SUM(FILTER(D4:D13,C4:C13=F4)) trả về tổng tất cả giá của tất cả sách được trả về bởi hàm FILTER .
- Bạn có thể thay đổi giá trị tra cứu thành bất kỳ tác giả nào khác ngoại trừ Charles Dickens trong ô F4 và nó sẽ trả về tổng giá sách của tác giả đó.
Đọc thêm: Cách tính tổng các ô đã lọc trong Excel (5 cách phù hợp)
2. Sử dụng hàm IF để tính tổng tất cả các kết quả khớp với hàm VLOOKUP trong Excel (Dành cho các phiên bản Excel cũ hơn)
Nếu bạn sử dụng phiên bản Excel cũ hơn, bạn có thể sử dụng Hàm IF của Excel để tính tổng tất cả các trận đấu từ bất kỳ tập dữ liệu nào.
Có thể tìm thấy tổng giá của tất cả các cuốn sách của Charles Dickens bằng công thức sau:
=SUM(IF(C4:C13=F4,D4:D13,"")) [ Đó là Công thức mảng . Vì vậy, hãy nhấn CTRL+SHIFT+ENTER trừ khi bạn đang ở trong Office 365 . ]
⧪ Giải thích Công thức:
- IF(C4:C13=F4,D4:D13,””) khớp với mọi giá trị của cột tra cứu C4:C13 ( Tác giả ) với giá trị tra cứu F4 ( Charles Dickens ).
- Nếu giá trị tra cứu F4 khớp với cột tra cứu C4:C13 ( Tác giả ), sau đó nó trả về giá trị tương ứng từ cột D4:D13 ( Giá ) .
- Và nếu không khớp, nó sẽ trả về một chuỗi trống “” .
- Cuối cùng, SUM(IF(C4:C13=F4, D4:D13,””)) trả về tổng của tất cả các giá trị do hàm IF trả về.
Đọc thêm: Cách Vlookup và tính tổng trên nhiều trang tính trong Excel (2 công thức)
Cách đọc tương tự
- Cách cộng nhiều ô trong Excel (6 phương pháp)
- Excel Tìm giá trị khớp trong hai cột
- Cách Vlookup và lấy giá trị khớp cuối cùng trong Excel (4 cách)
- Sao chép giá trị sang một ô khác nếu hai ô khớp nhau trong Excel: 3 phương pháp
- Cách khớp dữ liệu trong Excel từ 2 trang tính
3. Sử dụng hàm VLOOKUP để tính tổng tất cả các giá trị khớp với hàm VLOOKUP trong Excel (Dành cho các phiên bản Excel cũ hơn)
Bạn cũng có thể sử dụng Hàm VLOOKUP của Excel để tính tổng tất cả các giá trị khớp với giá trị tra cứu.
⧪ Bước 1:
➤ Chọn cột liền kề bên trái tập dữ liệu và nhập công thức này vào ô đầu tiên:
=C4&COUNTIF($C$4:C4,C4) ⧪ Lưu ý:
- Đây C4 là ô đầu tiên của mảng tra cứu ( Tác giả ). Bạn sử dụng một từ bộ dữ liệu của mình.
⧪ Bước 2:
➤ Kéo Fill Handle đến ô cuối cùng.
➤ Nó sẽtạo ra một trình tự của các tác giả cùng với các cấp bậc. Như Charles Dickens1, Charles Dickens2, Elif Shafak1, Elif Shafak2 , v.v.
[ Ký hiệu Dấu và (&)nối hai chuỗi]. 
⧪ Bước 3:
➤ Nhập giá trị tra cứu vào một ô mới.
➤ Ở đây tôi đã nhập Charles Dickens vào ô F4 .
⧪ Bước 4:
➤ Cuối cùng, nhập công thức này vào một ô khác:
=SUM(VLOOKUP(F4&ROW(A1:INDIRECT("A"&COUNTIF(C4:C13,F4))),A4:D13,4,FALSE)) [ Đó là Công thức mảng . Vì vậy, hãy nhấn CTRL+SHIFT+ENTER trừ khi bạn đang sử dụng Office 365 . ]
Hãy nhìn xem, nó trả về tổng giá của tất cả các cuốn sách của Charles Dickens, $52,00 .
⧪ Giải thích Công thức:
- COUNTIF(C4:C13,F4) trả về 3 , vì có tổng cộng 3 ô trong phạm vi C4:C13 ( Autho r) chứa giá trị tra cứu F4 ( Charles Dickens ). Xem Hàm COUNTIF để biết chi tiết.
- A1:INDIRECT(“A”&COUNTIF(C4:C13,F4)) giờ trở thành A1: A3 . Xem Hàm INDIRECT để biết chi tiết.
- ROW(A1:INDIRECT(“A”&COUNTIF(C4:C13,F4))) trở thành ROW(A1:A3) và trả về một mảng {1, 2, 3} . Xem hàm ROW để biết chi tiết.
- F4&ROW(A1:INDIRECT(“A”&COUNTIF(C4:C13,F4))) trở thành F4&{1, 2, 3} và trả về một mảng {CharlesDickens1, Charles Dickens2, Charles Dickens3} .
- VLOOKUP(F4&ROW(A1:INDIRECT(“A”&COUNTIF(C4:C13,F4))),A4:D13,4,FALSE) giờ trở thành VLOOKUP({Charles Dickens1, Charles Dickens2, Charles Dickens3},A4:D13,4,FALSE) .
- Hàm VLOOKUP khớp với giá trị tra cứu với tất cả các giá trị của cột đầu tiên của tập dữ liệu, rồi trả về các giá trị tương ứng từ một cột khác.
- Ở đây giá trị tra cứu là mảng {Charles Dickens1, Charles Dickens2, Charles Dickens3}.
- Do đó, nó khớp giá trị tra cứu với tất cả giá trị của cột đầu tiên A4:A13 và trả về giá trị tương ứng từ cột thứ 4 ( Giá ).
- Cuối cùng, hàm SUM trả về tổng của tất cả các mức giá khớp với giá trị tra cứu .
Đọc thêm: Cách sử dụng hàm VLOOKUP với hàm SUM trong Excel (6 phương pháp)
Kết luận
Sử dụng các phương pháp này, bạn có thể tính tổng tất cả các kết quả phù hợp với VLOOKUP trong Excel. Bạn có biết phương pháp nào khác không? Hay bạn có câu hỏi nào không? Hãy hỏi chúng tôi.
