যদি সেলে তালিকা থেকে পাঠ্য থাকে তাহলে কিভাবে Excel-এ মান ফেরত দিতে হয়

Hugh West

16-10-2023 এক্সেল সূত্র
  • এই শেয়ার করুন
Hugh West

আপনার যদি পাঠ্যের একটি তালিকা থাকে এবং আপনি কক্ষ অনুসন্ধান করতে চান এবং তালিকার উপর ভিত্তি করে মানগুলি ফেরত দিতে চান তবে আপনাকে একটি সূত্র তৈরি করতে হবে কারণ এক্সেল এটি করার জন্য একটি সহজ উপায় প্রদান করে না। এই নিবন্ধে, আমি এই সমস্যার সমাধান করেছি এবং এই অপারেশনটি সম্পাদন করার জন্য পাঁচটি ভিন্ন সূত্র প্রদান করেছি যাতে আপনি আপনার পরিস্থিতির জন্য নিখুঁত একটি চয়ন করতে পারেন, এবং যদি কক্ষে একটি তালিকা থেকে নির্দিষ্ট পাঠ্য থাকে তবে মানটি ফেরত দিতে পারেন৷

অভ্যাস ওয়ার্কবুক ডাউনলোড করুন

আপনি নিচের বোতাম থেকে এই নিবন্ধে যে ওয়ার্কবুকটি ব্যবহার করেছি তা ডাউনলোড করতে পারেন এবং নিজে নিজে অনুশীলন করতে পারেন।

যদি কক্ষে List.xlsx থেকে পাঠ্য থাকে

এই নিবন্ধে ব্যবহৃত ফাংশনগুলির ভূমিকা

আমি এখানে যে সূত্রগুলি ব্যবহার করেছি তা নিম্নলিখিত ফাংশনগুলি ব্যবহার করে:

  • COUNTIFS ফাংশন:

এই ফাংশনটি একাধিক মানদণ্ডের সাথে মেলে এমন কক্ষ গণনা করে। COUNTIFS ফাংশন এর সিনট্যাক্স নিম্নরূপ।

=COUNTIFS (পরিসীমা1, মানদণ্ড1, [রেঞ্জ2], [মাপদণ্ড2], …) <4

  • পরিসীমা1 – মূল্যায়নের জন্য ১ম ব্যাপ্তি।
  • মাপদণ্ড1 – ১ম পরিসরে ব্যবহার করার মানদণ্ড।
  • পরিসীমা2 [ঐচ্ছিক]: ২য় পরিসীমা, পরিসীমা1-এর মতো কাজ করে।
  • মাপদণ্ড2 [ঐচ্ছিক]: ব্যবহারের মানদণ্ড ২য় পরিসরে। এই ফাংশনটি সর্বাধিক 127 রেঞ্জ এবং মানদণ্ড জোড়া কে অনুমতি দেয়।
  • TEXTJOIN ফাংশন:

এই ফাংশনটি পাঠ্য যোগদান করেএকটি বিভেদক সহ মান। TEXTJOIN ফাংশন এর সিনট্যাক্স নিম্নরূপ।

=TEXTJOIN (ডিলিমিটার, ignore_empty, text1, [text2], …)

  • ডিলিমিটার: ফাংশনটি একত্রিত করতে যাচ্ছে এমন পাঠ্যগুলির মধ্যে বিভাজক৷
  • ইগনোর_এম্পটি: ফাংশনটি খালিকে উপেক্ষা করলে এই আর্গুমেন্টটি নির্দিষ্ট করে সেল বা না।
  • টেক্সট1: 1ম টেক্সট ভ্যালু (বা রেঞ্জ)।
  • টেক্সট2 [ঐচ্ছিক]: ২য় টেক্সট ভ্যালু (বা রেঞ্জ) .
  • ম্যাচ ফাংশন:

এই ফাংশনটি একটি অ্যারেতে একটি আইটেমের অবস্থান পায়। MATCH ফাংশনের সিনট্যাক্স নিম্নরূপ।

=MATCH (lookup_value, lookup_array, [match_type])

  • lookup_value: lookup_array -এ মিলবে মান।
  • lookup_array: কোন পরিসর বা একটি অ্যারে রেফারেন্স।<10
  • match_type [ঐচ্ছিক]: 1 = সঠিক বা পরবর্তী ছোট, 0 = সঠিক মিল, -1 = সঠিক বা পরবর্তী বৃহত্তম। ডিফল্টরূপে, match_type=1.
  • INDEX ফাংশন:

এই ফাংশনটি অবস্থানের উপর ভিত্তি করে একটি তালিকা বা টেবিলে মান পায় . INDEX ফাংশন এর সিনট্যাক্স নিম্নরূপ।

=INDEX (অ্যারে, row_num, [col_num], [area_num])

  • অ্যারে: কোষের পরিসর, অথবা একটি অ্যারে ধ্রুবক।
  • row_num: রেফারেন্সে সারি অবস্থান।
  • col_num [ঐচ্ছিক] : রেফারেন্সে কলামের অবস্থান।
  • ক্ষেত্র_সংখ্যা [ঐচ্ছিক]: পরিসররেফারেন্সে যেটি ব্যবহার করা উচিত৷
  • IFERROR ফাংশন:

এই ফাংশনটি ত্রুটিগুলি আটকে এবং পরিচালনা করে৷ IFERROR ফাংশন এর সিনট্যাক্স নিম্নরূপ৷

=IFERROR (মান, মান_if_error)

  • মান: একটি ত্রুটি পরীক্ষা করার জন্য মান, রেফারেন্স, বা সূত্র।
  • মান_ইফ_ত্রুটি: কোন ত্রুটি পাওয়া গেলে ফেরত দেওয়ার মান।
  • অনুসন্ধান ফাংশন:

এই ফাংশনটি একটি স্ট্রিং-এ পাঠ্যের অবস্থান পায়। SEARCH ফাংশন এর সিনট্যাক্স নিম্নরূপ।

=SEARCH (find_text, within_text, [start_num])

  • ফাইন্ড_টেক্সট : এই আর্গুমেন্টটি নির্দিষ্ট করে যে কোন টেক্সটটি খুঁজতে হবে।
  • within_text: এটি উল্লেখ করে লেখাটি কোথায় পাওয়া যাবে।
  • start_num [ঐচ্ছিক]: এর মাধ্যমে, আপনি উল্লেখ করবেন- টেক্সট স্ট্রিং-এর কোন অবস্থান থেকে আপনি নির্দিষ্ট লেখার অবস্থান গণনা করবেন। ঐচ্ছিক এবং ডিফল্ট 1 বাম থেকে।

5 এক্সেলে মান ফেরানোর সূত্র যদি একটি কক্ষে একটি তালিকা থেকে কিছু পাঠ্য থাকে

আমি উপস্থাপন করার চেষ্টা করব এই ডেটাসেটের একটি বাস্তব জীবনের উদাহরণ। কিছু পানীয় এখানে উপস্থাপন করা হয়. চিপস , কোল্ড ড্রিংকস , এবং সিরিয়ালস এই ডেটাসেটে পানীয়ের তিনটি বিভাগ। সমস্ত পণ্য নামে একটি একক কলামে, পানীয়গুলির নাম এবং বিভাগগুলি একসাথে সংযুক্ত করা হয়। এর মধ্যে দুটি বিভাগ, চিপস এবং ঠান্ডাপানীয় , এছাড়াও তালিকা কলামে রয়েছে। তালিকা কলামের উপর ভিত্তি করে, কাঙ্খিত আউটপুটটি দ্বিতীয় কলামে প্রদর্শিত হবে।

1। COUNTIF, IF & অথবা যদি একটি কক্ষে একটি তালিকা থেকে একটি টেক্সট থাকে তবে মান ফেরানোর ফাংশন

আপনি যদি ম্যাচের পরে পুরো ঘরের মান ফেরত দিতে চান তবে এটি সবচেয়ে কার্যকর সূত্র৷

এখানে, আমি পণ্যের সেল মানগুলি নিয়ে এসেছি যা তালিকা কলামের মানদণ্ডের সাথে মেলে এবং সেগুলিকে সেই তালিকার কলামের উপর ভিত্তি করে পণ্য দেখালাম৷

সূত্রটি নিম্নরূপ:

=IF(OR(COUNTIF(B5,"*"&$E$5:$E$6&"*")),B5,"")

ফর্মুলা ব্রেকডাউন:

  • =IF(OR(COUNTIF(B5,"*"&$E$5:$E$6&"*")),B5,"")

এখানে, স্টারিস্ক চিহ্ন ( * ) একটি ওয়াইল্ডকার্ড অক্ষর। এটি সেল B5 এর মধ্যে " চিপস " এবং "কোল্ড ড্রিংকস" সাবস্ট্রিং অনুসন্ধান করেছে যা " Ruffles - Chips " স্ট্রিং৷

  • =IF(OR(COUNTIF("Ruffles - Chips",*Chips*, *Cold Drinks*)), B5, "")

COUNTIF ফাংশন প্রতিটি সাবস্ট্রিং ম্যাচের জন্য একটি ফেরত দিয়েছে। যেহেতু " Chips " সেল B5 পাওয়া যায়, এটি { 1:0 } প্রদান করে।

  • =IF(OR({1;0}), B5, "")

OR ফাংশন একটি TRUE মান প্রদান করে যদি কোন আর্গুমেন্ট TRUE হয়। এই ক্ষেত্রে, একটি (1)= সত্য ।

  • =IF(TRUE, "Ruffles - Chips", "")

যেমন IF ফাংশনের মান হল TRUE , এটি প্রথম আর্গুমেন্ট প্রদান করে যা পছন্দসই আউটপুট।

ফাইনাল আউটপুট : Ruffles – চিপস

দ্রষ্টব্য:

এখানে, আমি দেখিয়েছিযে ঘরটি মিলেছে কিন্তু আপনি আপনার পছন্দসই আউটপুট দিয়ে IF ফাংশন আউটপুট পরিবর্তন করে যে কোনো আউটপুট দেখাতে পারেন।

=IF(OR(COUNTIF(B5,"*"&$E$5:$E$6&"*")),TRUE,FALSE)

আরো পড়ুন: যদি সেলে ওয়ার্ড থাকে তাহলে এক্সেলে ভ্যালু অ্যাসাইন করুন (৪টি সূত্র)

2. একাধিক শর্তের সাথে মান ফেরাতে IF-OR কম্বিনেশন SEARCH ফাংশন ব্যবহার করুন

এখানে, আমি পণ্যের সেল মানগুলি নিয়ে এসেছি যা তালিকা এর সাথে মেলে কলামের মানদণ্ড এবং সেই তালিকার উপর ভিত্তি করে পণ্য কলামে দেখানো হয়েছে।

সূত্রটি নিম্নরূপ:

=IF(OR(ISNUMBER(SEARCH($E$5,B5)),ISNUMBER(SEARCH($E$6,B5))),B5,"")

সূত্র ব্রেকডাউন:

  • =IF(OR(ISNUMBER(SEARCH($E$5,B5)),ISNUMBER(SEARCH($E$6,B5))),B5,"")

SEARCH ফাংশন Cell B5 -এ লিস্ট কলামের মান অনুসন্ধান করে। “ চিপস ” এর জন্য এটি 11 ফিরে এসেছে যা সাবস্ট্রিংয়ের শুরুর অবস্থান। কোল্ড ড্রিংকস এর জন্য, এটি একটি ত্রুটি ফিরিয়ে দিয়েছে।

  • =IF(OR(ISNUMBER(11),ISNUMBER(SEARCH(#VALUE))),B5,"")

ISNUMBER ফাংশন রূপান্তরিত হয়েছে 11 TRUE মান এবং ত্রুটি FALSE মান।

  • =IF(OR(TRUE,FALSE)),B5,"")
    • <11

    OR ফাংশনটি একটি TRUE মান প্রদান করে যদি কোন আর্গুমেন্ট TRUE হয়। যেহেতু একটি TRUE আর্গুমেন্ট আছে, এটি এই ক্ষেত্রে TRUE মানও প্রদান করে।

    • =IF(TRUE, "Ruffles - Chips","")
      • <11

      যেহেতু IF ফাংশনের মান হল TRUE , এটি প্রথম আর্গুমেন্ট প্রদান করে যা কাঙ্খিত আউটপুট।

      ফাইনাল আউটপুট: Ruffles –চিপস

      দ্রষ্টব্য:

      • এখানে, আমি যে ঘরটি মেলে তা দেখিয়েছি তবে আপনি পরিবর্তন করে আপনার পছন্দসই আউটপুট দেখাতে পারেন। IF আপনার পছন্দসই আউটপুট দিয়ে ফাংশন আউটপুট।
      =IF(OR(ISNUMBER(SEARCH($E$5,B5)),ISNUMBER(SEARCH($E$6,B5))),1,0)

      18>

      • এর প্রধান সুবিধা সূত্র হল যে এটি একটি অ্যারে সূত্র নয় কিন্তু আপনার তালিকা তে অনেকগুলি ঘর থাকলে এটি সুপারিশ করা হয় না কারণ আপনাকে লিস্ট -এর প্রতিটি ঘরে ম্যানুয়ালি প্রবেশ করতে হবে।
      • কেস-সংবেদনশীল পরিস্থিতিতে, আমরা SEARCH ফাংশনের পরিবর্তে FIND ফাংশন এর উপর ভিত্তি করে নীচের সূত্রটি ব্যবহার করতে পারি।
      =IF(OR(ISNUMBER(FIND($E$5,B5)),ISNUMBER(FIND($E$6,B5))),B5,"")

      আরো পড়ুন: Excel যদি সেলে টেক্সট থাকে তাহলে রিটার্ন ভ্যালু (8 সহজ উপায়)

      একই রকম রিডিং:

      • সেলে এক্সেলের নির্দিষ্ট টেক্সট থাকলে কিভাবে যোগ করা যায় (6 উপায়)
      • সেলে পাঠ্যের মধ্যে একটি শব্দ থাকলে VLOOKUP ব্যবহার করুন এক্সেল
      • এক্সেল পরিসরে কিভাবে পাঠ্য খুঁজে পাবেন & রিটার্ন সেল রেফারেন্স (3 উপায়)

      3. অন্য কক্ষে মান ফেরাতে TEXTJOIN সূত্রটি ব্যবহার করুন যদি একটি কক্ষে একটি তালিকা থেকে একটি পাঠ্য থাকে

      এই সূত্রটি কার্যকর যখন আপনাকে দেখাতে হবে যে তালিকা থেকে কোন স্ট্রিং বা স্ট্রিং মিলছে .

      এখানে, আমি LIST কলাম থেকে ঘরের মানগুলি নিয়ে এসেছি যেখানে সেগুলি পণ্য এর সাথে মিলেছে এবং তালিকা <থেকে মিলে যাওয়া মানের সাথে দেখালাম 4>কলাম৷

      সূত্রটি নিম্নরূপ:

      =TEXTJOIN(", ",TRUE,IF(COUNTIF(B5,"*"&$E$5:$E$6&"*"), $E$5:$E$6,""))

      সূত্রব্রেকডাউন:

      • =TEXTJOIN(", ",TRUE,IF(COUNTIF(B5,"*"&$E$5:$E$6&"*"),$E$5:$E$6,""))

      এখানে, তারকা চিহ্ন ( * ) একটি ওয়াইল্ডকার্ড চরিত্র। এটি সেল B5 এর মধ্যে " চিপস " এবং "কোল্ড ড্রিংকস" সাবস্ট্রিং অনুসন্ধান করেছে যা হল " রাফলস - চিপস " স্ট্রিং৷

      • TEXTJOIN(", ",TRUE,IF(COUNTIF("Ruffles - Chips",*Chips*, *Cold Drinks*),$E$5:$E$6,""))

      COUNTIF ফাংশন প্রতিটি সাবস্ট্রিং মিলের জন্য একটি ফেরত দিয়েছে। যেহেতু " চিপস " সেল B5 পাওয়া যায়, এটি { 1:0 } ফেরত দেয়।

      • TEXTJOIN(", ",TRUE,IF({1;0},$E$5:$E$6,""))

      IF ফাংশনটি শুধুমাত্র " চিপস " মান প্রদান করেছে কারণ এটির আর্গুমেন্টের শুধুমাত্র প্রথম মান ছিল এক = True .

      • TEXTJOIN(", ",TRUE,{"Chips";""})

      TEXTJOIN ফাংশনটি এখানে <3 থেকে শুধুমাত্র একটি মান হিসাবে কিছু করেনি>তালিকা

মিলেছে। যদি অনেকগুলি মান মিলে যায়, তবে এটি তাদের মধ্যে একটি বিভাজক হিসাবে কমা (,) সহ তাদের সকলকে ফিরিয়ে দিত৷

চূড়ান্ত আউটপুট: চিপস

আরো পড়ুন: যদি সেলে টেক্সট থাকে তাহলে এক্সেলের অন্য সেলে টেক্সট যোগ করুন

4। যদি কক্ষে নির্দিষ্ট টেক্সট থাকে

এটি TEXTJOIN সূত্রের বিকল্প। এই সূত্রটি তালিকা থেকে কোন স্ট্রিং বা স্ট্রিং মিলেছে তাও দেখায়।

এখানে, আমি LIST কলাম থেকে সেল মানগুলি নিয়ে এসেছি যেখানে তারা <3 এর সাথে মিলেছে>পণ্য এবং তালিকা কলাম থেকে মিলিত মান দেখায়।

20>

সূত্রটি নিম্নরূপ:

=IFERROR(INDEX($E$5:$E$6, MATCH(1, COUNTIF(B5, "*"&$E$5:$E$6&"*"), 0)),"")

সূত্র ব্রেকডাউন:

  • =IFERROR(INDEX($E$5:$E$6,MATCH(1,COUNTIF(B5,"*"&$E$5:$E$6&"*"),0)),"")

এখানে, স্টারিক চিহ্ন ( * ) হল একটি ওয়াইল্ডকার্ড চরিত্র। এটি সেল B5 এর মধ্যে " চিপস " এবং " কোল্ড ড্রিংকস " সাবস্ট্রিং অনুসন্ধান করেছে যা হল " Ruffles – চিপস " স্ট্রিং৷<1

  • IFERROR(INDEX($E$5:$E$6,MATCH(1,COUNTIF("Ruffles - Chips",*Chips*,*Cold Drinks*),0)),"")

COUNTIF ফাংশন প্রতিটি সাবস্ট্রিং ম্যাচের জন্য একটি রিটার্ন করেছে। যেহেতু " চিপস " সেল B5 পাওয়া যায়, এটি { 1:0 } ফেরত দেয়।

  • IFERROR(INDEX($E$5:$E$6,MATCH(1,{1;0}),0)),"")

MATCH ফাংশনটি একটি ফিরিয়ে দিয়েছে কারণ শুধুমাত্র একটি মান " চিপস " মিলেছে৷

  • IFERROR(INDEX($E$5:$E$6,1),"")

INDEX ফাংশনটি " চিপস " প্রদান করেছে কারণ এটি লিস্ট অ্যারের মান ছিল।

  • IFERROR("Chips","")

এখানে, IFERROR ফাংশনটি কোন মিল না থাকলে যে ত্রুটিটি ঘটবে তা পরিচালনা করতে ব্যবহৃত হয় .

চূড়ান্ত আউটপুট: চিপস

দ্রষ্টব্য:

এখানে, আমি মেলে এমন সেল দেখিয়েছি কিন্তু আপনি দেখাতে পারেন আপনার পছন্দসই আউটপুট দিয়ে IF ফাংশন আউটপুট পরিবর্তন করে যেকোন আউটপুট।

আরো পড়ুন: এক্সেল সূত্র যদি সেলটিতে টেক্সট থাকে তাহলে মান দিন আরেকটি কোষ

5. IF এবং TEXTJOIN এর সাথে EXACT ফাংশন প্রয়োগ করুন

এটি বিভিন্ন পরিস্থিতিতে এই সমস্যার আরেকটি সমাধান। এখানে, আমি একটি একক সদস্যের সাথে তালিকা কলাম থেকে ঘরের মান নিয়েছি। আমরা এই মানটিকে পণ্যের সাথে মেলে এবং একটি একক কক্ষে সমস্ত মিল মান দেখিয়েছি৷

সূত্রটি হলঅনুসরণ করে:

=TEXTJOIN(", ",TRUE,IF(EXACT(C5:C14,$F$5),B5:B14,""))

ফর্মুলা ব্রেকডাউন :

  • EXACT(C5:C14,$F$5)

এই অংশটি পরিসর C5:14 কোন মানগুলি সেল F5 এর সাথে মেলে তা পরীক্ষা করে এবং TRUE এবং <3 ফেরত দেয়>মিথ্যা ।

  • IF(EXACT(C5:C14,$F$5),B5:B14,"")

এই অংশটি সেই নামগুলি প্রদান করে যার জন্য আমরা TRUE পাই।

  • TEXTJOIN(", ",TRUE,IF(EXACT(C5:C14,$F$5),B5:B14,""))

অবশেষে, এটি প্রতিটি নামের পরে একটি কমা দিয়ে সমস্ত নামের সাথে যোগ দেয়।

দ্রুত নোট

এখানে এই সমস্ত সূত্র (২য়টি বাদে) অ্যারে সূত্র। তার মানে এই সূত্রটি প্রবেশ করার জন্য আপনাকে শুধুমাত্র Enter বোতাম টিপানোর পরিবর্তে Ctrl+Shift+Enter টিপতে হবে। কিন্তু আপনি যদি একজন Office 365 ব্যবহারকারী হন, তাহলে আপনি শুধুমাত্র Enter টিপে প্রয়োগ করতে পারেন।

উপসংহার

এই নিবন্ধে, যদি কোনো কক্ষে কোনো তালিকা থেকে নির্দিষ্ট পাঠ্য থাকে তাহলে আমি বিভিন্ন ক্ষেত্রে মান ফেরানোর জন্য বিভিন্ন সূত্র সংকুচিত করেছি। আমি আশা করি আপনি আপনার সমস্যার একটি সমাধান খুঁজে পেতে সক্ষম হয়েছে. আপনার কোন পরামর্শ বা প্রশ্ন থাকলে একটি মন্তব্য করুন. তাছাড়া, এই ধরনের আরো নিবন্ধের জন্য আপনি আমাদের ব্লগ দেখতে পারেন।

পূর্ববর্তী পোস্ট এক্সেলে ফর্ম্যাট ফাংশন কীভাবে ব্যবহার করবেন (উপযুক্ত উদাহরণ সহ)
পরবর্তী পোস্ট কিভাবে এক্সেলে সূত্র অনুলিপি করতে ফিল হ্যান্ডেল ব্যবহার করবেন (2টি দরকারী উদাহরণ)

Hugh West একজন অত্যন্ত অভিজ্ঞ এক্সেল প্রশিক্ষক এবং শিল্পে 10 বছরেরও বেশি অভিজ্ঞতা সহ বিশ্লেষক। তিনি অ্যাকাউন্টিং এবং ফিন্যান্সে স্নাতক ডিগ্রি এবং ব্যবসায় প্রশাসনে স্নাতকোত্তর ডিগ্রি অর্জন করেছেন। Hugh শিক্ষাদানের জন্য একটি আবেগ আছে এবং একটি অনন্য শিক্ষণ পদ্ধতি তৈরি করেছে যা অনুসরণ করা এবং বোঝা সহজ। এক্সেল সম্পর্কে তার বিশেষজ্ঞ জ্ঞান বিশ্বব্যাপী হাজার হাজার ছাত্র এবং পেশাদারদের তাদের দক্ষতা উন্নত করতে এবং তাদের কর্মজীবনে শ্রেষ্ঠত্ব অর্জন করতে সাহায্য করেছে। তার ব্লগের মাধ্যমে, Hugh তার জ্ঞান বিশ্বের সাথে ভাগ করে নেয়, বিনামূল্যে এক্সেল টিউটোরিয়াল এবং অনলাইন প্রশিক্ষণ প্রদান করে ব্যক্তি এবং ব্যবসায়িকদের তাদের পূর্ণ সম্ভাবনায় পৌঁছাতে সহায়তা করার জন্য।