Paano Gamitin ang INDEX MATCH Formula sa Excel (9 na Halimbawa)

Hugh West

16-10-2023 Mga Formula ng Excel
  • Ibahagi Ito
Hugh West

Paminsan-minsan, kailangan naming maghanap ng partikular na impormasyon sa aming malaking Excel worksheet. Ngunit, nakakapagod na hanapin ito nang manu-mano. Ang isang formula na nagtutulungan ang INDEX at MATCH function ay makakagawa ng kamangha-manghang gawain ng paghahanap ng data nang napakadali. Maaari rin itong magsagawa ng mga advanced na paghahanap. Sa artikulong ito, ipapakita namin sa iyo ang mga simple at epektibong paraan upang Gamitin ang ang INDEX MATCH Formula sa Excel.

Upang ilarawan, gagamit kami ng sample na dataset bilang halimbawa. Halimbawa, kinakatawan ng sumusunod na dataset ang Salesman , Produkto , at Net Sales ng isang kumpanya.

I-download ang Practice Workbook

I-download ang sumusunod na workbook para magsanay nang mag-isa.

Paggamit ng INDEX-MATCH.xlsx

Panimula sa INDEX Function

  • Syntax

INDEX(array, row_num,[column_num])

  • Mga Argumento

array: Ang hanay kung saan ito kukuha ng data.

row_num: Ang row number ng data na ibabalik.

[column_num]: Ang column number ng data na ibabalik.

  • Layunin

Ang INDEX function ay kinukuha ang cell value o reference ng cell na matatagpuan sa intersection ng isang partikular na row at column sa isang partikular na hanay.

Sa ang sumusunod na dataset, Nate Sales 17000 ay nasa 4th row at 3rd column sa range B5:D10 .

Magbasa Nang Higit Pa: Index Match Sum Maramihang Row sa Excel (3 Ways)

9. Maghanap ng Tinatayang Tugma Gamit ang INDEX MATCH

Ang formula na INDEX MATCH ay lubhang kapaki-pakinabang kapag nalaman ang tinatayang tugma. Sa halimbawang ito, mahahanap namin ang produkto para sa tinatayang Mga Net Sales na 6000 . Kaya, sundin ang proseso.

MGA HAKBANG:

  • Una, i-click ang cell F5 .
  • Pagkatapos, i-type ang formula:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

  • Panghuli, pindutin ang Enter .

TANDAAN: Dapat nasa Pataas na o Pababang ang data para gumana ang formula na ito.

🔎 Paano Gumagana ang Formula?

  • MATCH(F4,D5:D10,1)

Gumagamit ang MATCH formula ng 1 bilang argumento ng uri ng pagtutugma na magbabalik ng pinakamalaking value na mas mababa o katumbas ng lookup value na 6000 . Dito, babalik ito ng 2 .

  • INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

Ang function na INDEX ay nagbabalik ng Router na nasa 2nd row sa range na C5:C10 .

Magbasa Nang Higit Pa: Paano Gumamit ng INDEX at Tugma para sa Bahagyang Tugma (2 Paraan)

Bakit Mas Kapaki-pakinabang ang INDEX MATCH kaysa VLOOKUP?

1. Ang INDEX MATCH Formula ay Mukhang Parehong Kaliwa-Kanang Gilid ng Lookup Value

Ang VLOOKUP function ay hindi makakuha ng data mula sa kaliwa gilid ng lookup value. Ngunit ang INDEX MATCH magagawa ito ng formula.

2. Gumagana ang INDEX MATCH sa Vertical at Horizontal Ranges

VLOOKUP maaari lang kumuha ng data mula sa vertical array, habang ang INDEX MATCH ay maaaring dumaan sa patayong data pati na rin sa pahalang.

3. Ang VLOOKUP ay Nabigo sa Pababang Data

Ang VLOOKUP function ay hindi makayanan ang data ng pababang pagkakasunod-sunod pagdating sa tinatayang tugma.

4. Ang formula na may INDEX MATCH ay Bahagyang Mas Mabilis

VLOOKUP ay medyo mas mabagal na function kapag nagtatrabaho sa masyadong maraming row at column.

5. Independent of Actual Column Position

VLOOKUP ay hindi independent sa aktwal na column position. Kaya, sa tuwing magde-delete ka ng column, ang VLOOKUP function ay magbibigay ng maling resulta.

6. Hindi Mahirap Gamitin ang VLOOKUP

Ang Ang VLOOKUP function ay mas madaling gamitin kumpara sa INDEX MATCH function. At karamihan sa aming mga operasyon sa paghahanap ay maaaring gawin sa VLOOKUP nang madali.

Magbasa Pa: INDEX MATCH vs VLOOKUP Function (9 na Halimbawa)

Konklusyon

Mula ngayon, magagawa mong Gamitin ang ang INDEX MATCH Formula sa Excel sa mga pamamaraan na inilarawan sa itaas . Patuloy na gamitin ang mga ito at ipaalam sa amin kung mayroon ka pang mga paraan para gawin ang gawain. Huwag kalimutang mag-drop ng mga komento, mungkahi, o query kung mayroon ka sa seksyon ng komento sa ibaba.

B5:D10.

Panimula sa MATCH Function

  • Syntax

MATCH(lookup_value,lookup_array,[match_type])

  • Mga Argumento

lookup_value: Ang halagang hahanapin sa hanay ng data.

lookup_array : Ang hanay ng data kung saan hahanapin nito ang lookup_value .

[match_type]: – 1/0/1 . Ang -1 ay kumakatawan sa isang value na mas malaki kaysa sa eksaktong tugma, 0 para sa eksaktong tugma, at 1 para sa value na mas mababa sa eksaktong tugma.

  • Layunin

Ibinabalik ng MATCH function ang relatibong posisyon ng lookup_value sa isang array.

Sa dataset sa ibaba, ang F4 cell value ay Frank ( lookup_value ) at Frank ay nasa ika-3 posisyon sa Salesman seksyon ( B5:B10 ). Kaya ibinabalik nito ang 3 .

9 Mga Halimbawang Gumamit ng INDEX MATCH Formula sa Excel

Ngayon, gagawa kami ng formula na pinagsasama-sama ang dalawang function. Alam na namin na ang INDEX function ay nangangailangan ng mga numero ng row at column upang makuha ang data samantalang ang MATCH function ay nagbabalik ng lokasyon ng data. Kaya, madali nating mailalagay ang kanilang argumento para makuha ang mga numero ng row at column.

Sa sumusunod na dataset, kukunin ng INDEX function ang data mula sa B5:D10 . Ang function na MATCH ay nagbabalik ng row number 3 at tinukoy namin ang column number. Kaya angIlalabas ng formula ang data na nasa 3rd row at 3rd column sa range.

1. Two-Way Ang paghahanap na may INDEX MATCH sa Excel

Two-Way lookup ay nangangahulugang pagkuha ng parehong numero ng row at numero ng column gamit ang MATCH function na kinakailangan para sa INDEX function. Samakatuwid, sundin ang mga hakbang sa ibaba upang maisagawa ang gawain.

MGA HAKBANG:

  • Una, piliin ang cell F6 .
  • Pagkatapos, i-type ang formula:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

  • Sa wakas, pindutin ang Enter at ibabalik nito ang halaga.

🔎 Paano Gumagana ang Formula?

  • MATCH(F5,B5:B10,0)

Ang MATCH formula ay nagbabalik ng 3 sa INDEX bilang row numero.

  • MATCH(F4,B4:D4,0))

Itong MATCH formula ay nagbabalik ng 3 sa INDEX bilang numero ng column.

  • INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4, B4:D4,0))

Panghuli, ang INDEX function ay nagbabalik ng 13500 na nasa 3rd row at 3rd column sa range B5:D10 .

Magbasa Pa: SUMPRODUCT na may INDEX at MATCH Function sa Excel

2. INDEX MATCH Formula to Lookup Left

Ang pangunahing bentahe ng INDEX MATCH formula ay na maaari nitong makuha ang data mula sa kaliwang bahagi ng lookup value. Kaya, alamin ang mga hakbang para isagawa ang operasyon.

MGA HAKBANG:

  • Una, piliin ang cell F5 .
  • Susunod, i-type ang formula:
=INDEX(B5:B10,MATCH(F4,C5:C10,0))

  • Sa wakas, pindutin ang Enter at ibabalik nito ang halaga.

Dito, ibinabalik ng formula ang Salesman's pangalan na nasa kaliwang bahagi ng lookup value Cable .

🔎 Paano Gumagana ang Formula?

  • MATCH(F4,C5:C10,0)

Ang MATCH formula ay nagbabalik ng 1 sa INDEX bilang ang numero ng hilera.

  • INDEX(B5:B10,MATCH(F4,C5:C10,0))

Panghuli, ang Ang INDEX function ay nagbabalik ng Wilham na nasa 1st row sa hanay na B5:B10 .

Magbasa Nang Higit Pa: Paano Gamitin ang INDEX MATCH Formula sa Excel (9 na Halimbawa)

3. Case-Sensitive Lookup Gamit ang INDEX MATCH Formula

Ang MATCH Ang function ay hindi case-sensitive bilang default. Gayunpaman, maaari naming ilapat ang EXACT function sa paghahanap na gumagalang sa upper at lower case. Kaya, sundin ang proseso upang Gamitin ang INDEX MATCH Formula upang maisagawa ang Case – Sensitive Lookup sa Excel .

STEPS:

  • Sa simula, piliin ang cell F5 .
  • Pagkatapos, i-type ang formula:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

  • Sa huli, pindutin ang Enter upang ibalik ang value.

🔎 Paano Gumagana ang Formula?

  • EXACT(F4,B5:B10)

Ang EXACT function ay nagbabalik ng TRUE para lamang sa unang data ( B5 ) sa hanay B5:B10 at FALSE para sa iba.

  • MATCH(TRUE,EXACT(F4,B5:B10),0)

Itong MATCH formula ay nagbabalik ng 1 sa INDEX bilang row number.

  • INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

Panghuli, ang INDEX function ay nagbabalik ng 2600 na nasa 1st row sa range D5:D10 .

Magbasa Nang Higit Pa: Mga Halimbawa na may INDEX -MATCH Formula sa Excel (8 Diskarte)

4. Gumamit ng INDEX MATCH para sa Pinakamalapit na Tugma

Minsan, maaaring hindi namin makuha ang eksaktong tugma ng isang lookup value sa lookup array. Kung ganoon, gusto naming hanapin ang pinakamalapit na tugma. Lalo itong nangyayari sa mga numerical lookup value. Ngayon, alamin ang proseso upang mahanap ang Pinakamalapit na Tugma gamit ang INDEX MATCH formula.

MGA HAKBANG:

  • Piliin ang cell F5 sa una.
  • Pagkatapos, i-type ang formula:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

  • Panghuli, pindutin ang Enter .

🔎 Paano Gumagana ang Formula?

  • ABS(D5:D10-F4)

Una, binabawasan ng formula ang F4 cell value mula sa range D5:D10 upang makabuo ng mga pagkakaiba at ginagamit namin ang ang ABS function upang i-convert ang mga negatibong resulta sa mga positibo.

  • MIN(ABS(D5: D10-F4))

Pagkatapos, ibinabalik ng ang MIN function ang pinakamaliit na pagkakaiba na 500 .

  • MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)

MIN(ABS(D5:D10-F4)) formula output ay ang lookup value ( 500 ) para sa MATCH function at ang lookup array ay ABS(D5:D10-F4) mga output ng formula.

  • INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)), ABS(D5:D10-F4),0))

Sa kalaunan, ang INDEX function ay nagbabalik ng Router dahil ito ang may pinakamalapit na Mga Net Sales hahalaga sa 5000 .

5. Paghahanap ng Maramihang Pamantayan gamit ang INDEX MATCH Formula

Isa sa mga pinakakapaki-pakinabang na operasyon na may INDEX MATCH formula ay maaari itong magsagawa ng paghahanap batay sa maraming kundisyon. Sundin ang mga hakbang sa ibaba para makita kung paano natin makukuha ang Net Sales batay sa Salesman pangalan at Produkto .

STEPS:

  • Una sa lahat, piliin ang cell F6 upang i-type ang formula:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

  • Pagkatapos, pindutin ang Enter at makukuha mo ang resulta.

🔎 Paano Gumagana ang Formula?

  • MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)

Ang MATCH formula ay nagbabalik ng 2 sa INDEX bilang row number. Dito, inihahambing namin ang maraming pamantayan sa pamamagitan ng paglalapat ng boolean logic.

  • INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10), 0))

Panghuli, ang INDEX function ay nagbabalik ng 11500 na nasa 2nd row sa range D5:D10 .

Magbasa Pa: PaanoGamitin ang INDEX-MATCH Formula sa Excel para Makabuo ng Maramihang Resulta

Mga Katulad na Pagbasa

  • Maramihang Pamantayan sa Excel Gamit ang INDEX, MATCH, at COUNTIF Function
  • Paano gamitin ang INDEX & Mga function ng MATCH worksheet sa Excel VBA
  • Excel Index Itugma ang isa/maraming pamantayan na may iisa/maraming resulta
  • INDEX MATCH sa Maramihang Sheet sa Excel ( May Alternatibong)
  • SUMIF na may INDEX at MATCH Function sa Excel

6. Excel INDEX MATCH Formula na may mga Wildcard na Character

Maaari kaming gumamit ng asterisk ( * ), na isang Wildcard Character , upang mahanap ang bahagyang tugma para sa isang lookup value. Tingnan ang halimbawa sa ibaba upang maisagawa ang gawain. Mayroon kaming Nat sa cell F4 . Walang Salesman na may ganoong pangalan ngunit mayroon kaming Nathan , na isang bahagyang tugma.

STEPS:

  • Una, piliin ang cell F5 .
  • Pagkatapos nito, i-type ang formula:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

  • Sa wakas, pindutin ang Enter at ibabalik nito ang Net Sales ni Nathan .

🔎 Paano Gumagana ang Formula?

  • MATCH(F4&”*”,B5:B10,0)

F4&”*” ay ang aming lookup value kung saan ang asterisk ay isang wildcard na character na kumakatawan sa anumang bilang ng mga character na nagsisimula sa Nat . Nagbabalik ang formula 4 .

  • INDEX(D5:D10,MATCH(F4&”*”,B5:B10,0))

Panghuli, ang INDEX function ay nagbabalik ng 17000 na nasa 4th row sa hanay na D5:D10 .

Magbasa Pa: INDEX MATCH Maramihang Pamantayan na may Wildcard sa Excel (Isang Kumpletong Gabay)

7. Ilapat ang INDEX MATCH para sa Three-Way Lookup sa Excel

Ang advanced na paggamit ng INDEX MATCH formula ay tungkol sa pagsasagawa ng Three-Way lookup. Ang isa pang syntax ng INDEX function ay:

INDEX (array, row_num, [col_num], [area_num])

Where, [area_num] ( Opsyonal ) ay nangangahulugang Kung ang array argument ay maraming hanay, pipiliin ng numerong ito ang partikular na sanggunian mula sa lahat ng hanay.

Sa halimbawang ito, kami' Gagamitin ang opsyonal na argumentong ito upang ibalik ang gustong data mula sa alinman sa mga buwan ng Enero , Pebrero , at Marso . Samakatuwid, sundin ang mga hakbang sa ibaba upang Gamitin ang ang INDEX MATCH Formula sa Excel para sa Three-Way Lookup .

STEPS:

  • Una sa lahat, piliin ang cell F7 upang i-type ang formula:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="January",1,IF(F4="February",2,3))))

  • Susunod, pindutin ang Enter . Kaya, makikita mo ang output.

🔎 Paano Gumagana ang Formula?

  • IF(F4=”Enero”,1,IF(F4=”Pebrero”,2,3))

Ang IF function ay magbabalik ng 2 dahil ang aming ibinigay na buwan ay Pebrero . Ang function na INDEX kukunin ang value mula sa 2nd array i.e. February .

  • MATCH(F6,B5:D5,0)

Ang function na MATCH ay nagbabalik ng 3 .

  • MATCH(F5,B6:B7,0)

Itong MATCH function ay nagbabalik ng 2 .

  • INDEX((B6:D7,B11:D12, B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4=”Enero”,1,IF(F4=”Pebrero”,2,3) )))

Panghuli, ang INDEX function ay nagbabalik ng 12500 na nasa intersection ng 3rd column at 2nd row ng 2nd array.

Read More: Paano Gamitin ang INDEX MATCH Sa halip na VLOOKUP sa Excel (3 Ways )

8. Kunin ang mga Value ng Buong Row/Column gamit ang INDEX MATCH Formula

Ang isa pang application ng INDEX MATCH formula ay ang pagkuha ng data mula sa buong row o hanay. Kaya, alamin ang pamamaraan upang maisagawa ang operasyon.

MGA HAKBANG:

  • Sa simula, piliin ang cell F5 . Dito, i-type ang formula:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

  • Pagkatapos nito, pindutin ang Enter at ito Itapon ang data ng buong 3rd row sa range B5:D10 .

🔎 Paano Gumagana ang Formula?

  • MATCH(F4,B5:B10,0)

Ang MATCH ibinabalik ng formula ang 3 sa INDEX bilang row number.

  • INDEX(B5:D10,MATCH(F4,B5:B10, 0),0)

Ibinabalik ng INDEX function ang lahat ng value sa 3rd row sa range

Nakaraang post Paano Magbilang ng Mga Hilera gamit ang VBA sa Excel (5 Diskarte)
Susunod na post Maghanap ng Text sa Excel Range at Return Cell Reference (3 Ways)

Si Hugh West ay isang napakaraming Excel trainer at analyst na may higit sa 10 taong karanasan sa industriya. May hawak siyang Bachelor's degree sa Accounting and Finance at Master's degree sa Business Administration. Si Hugh ay may hilig sa pagtuturo at nakabuo ng kakaibang diskarte sa pagtuturo na madaling sundin at maunawaan. Ang kanyang dalubhasang kaalaman sa Excel ay nakatulong sa libu-libong mag-aaral at propesyonal sa buong mundo na mapabuti ang kanilang mga kasanayan at maging mahusay sa kanilang mga karera. Sa pamamagitan ng kanyang blog, ibinahagi ni Hugh ang kanyang kaalaman sa mundo, nag-aalok ng mga libreng Excel tutorial at online na pagsasanay upang matulungan ang mga indibidwal at negosyo na maabot ang kanilang buong potensyal.