Съдържание
От време на време ни се налага да търсим конкретна информация в големите си Excel Но е досадно да го търсите ръчно. функциите INDEX и MATCH може много лесно да извършва невероятна работа по търсене на данни. Той може да извършва и разширени търсения. В тази статия ще ви покажем простите и ефективни начини да Използвайте на Формула INDEX MATCH в Excel.
За да илюстрираме, ще използваме примерен набор от данни като пример. Например, следният набор от данни представлява Продавач , Продукт , и Нетни продажби на дадена компания.
Изтегляне на работна тетрадка за практика
Изтеглете следната работна тетрадка, за да се упражнявате сами.
Използване на INDEX-MATCH.xlsxВъведение във функцията INDEX
- Синтаксис
INDEX(array, row_num,[column_num])
- Аргументи
масив: Диапазонът, от който ще се изтеглят данните.
row_num: Номерът на реда на данните, които се връщат.
[номер на колона]: Номерът на колоната на данните, които се връщат.
- Цел
Функцията INDEX извлича стойността на клетката или референцията на клетката, намираща се в пресечната точка на определен ред и колона в даден диапазон.
В следния набор от данни, Нейт Продажби 17000 присъства в 4. ред и 3. колона в диапазона B5:D10 .
Въведение във функцията MATCH
- Синтаксис
MATCH(lookup_value,lookup_array,[match_type])
- Аргументи
lookup_value: Стойността, която ще се търси в обхвата от данни.
lookup_array : Диапазонът от данни, в който ще се търси lookup_value .
[match_type]: - 1/0/1 . -1 означава стойност, по-голяма от точното съвпадение, 0 за точно съвпадение, и 1 за стойността, по-малка от точното съвпадение.
- Цел
Функцията MATCH връща относителната позиция на lookup_value в масив.
В набора от данни по-долу F4 стойността на клетката е Франк ( lookup_value ) и Франк присъства в 3. позиция в Продавач раздел ( B5:B10 ). Така се връща 3 .
9 примера за използване на формулата INDEX MATCH в Excel
Сега ще създадем формула, комбинираща двете функции. Вече сме наясно, че функцията INDEX се нуждае от номера на редове и колони, за да извлича данни, докато функцията MATCH Функцията връща местоположението на данните. Така че можем лесно да поставим аргумента й, за да получим номерата на редовете и колоните.
В следния набор от данни INDEX функцията ще изтегли данните от B5:D10 . MATCH функцията връща номера на реда 3 и сме посочили номера на колоната. Така формулата ще изведе данните, които се намират в 3. ред и 3. колона в обхвата.
1. Двупосочно търсене с INDEX MATCH в Excel
Двупосочен означава извличане както на номера на реда, така и на номера на колоната с помощта на MATCH функция, необходима за INDEX Затова следвайте стъпките по-долу, за да изпълните задачата.
СТЪПКИ:
- Първо, изберете клетка F6 .
- След това въведете формулата:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0)) - Накрая натиснете Въведете и ще върне стойността.
🔎 Как работи формулата?
- MATCH(F5,B5:B10,0)
Сайтът MATCH възвръщаемост на формулата 3 към INDEX като номер на реда.
- MATCH(F4,B4:D4,0))
Този MATCH възвръщаемост на формулата 3 към INDEX като номер на колоната.
- INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))
Накрая, INDEX функцията връща 13500 която е в 3. ред и 3. колона в диапазона B5:D10 .
Прочетете още: SUMPRODUCT с функциите INDEX и MATCH в Excel
2. Формула INDEX MATCH за търсене вляво
Основното предимство на INDEX MATCH формулата е, че тя може да извлича данни от лявата страна на стойността за търсене. И така, научете стъпките за извършване на операцията.
СТЪПКИ:
- Първо, изберете клетка F5 .
- След това въведете формулата:
=INDEX(B5:B10,MATCH(F4,C5:C10,0)) - Накрая натиснете Въведете и ще върне стойността.
Тук формулата връща Продажби на продавача име, което се намира от лявата страна на стойността за търсене Кабел .
🔎 Как работи формулата?
- MATCH(F4,C5:C10,0)
Сайтът MATCH възвръщаемост на формулата 1 към INDEX като номер на реда.
- INDEX(B5:B10,MATCH(F4,C5:C10,0))
Накрая, INDEX функцията връща Wilham която е в 1. ред в диапазона B5:B10 .
Прочетете още: Как да използвате формулата INDEX MATCH в Excel (9 примера)
3. Търсене с отчитане на регистрите чрез формулата INDEX MATCH
Сайтът MATCH по подразбиране не е чувствителна към големи и малки букви. ТОЧНАТА функция за търсене, което се съобразява с големите и малките букви. Следователно следвайте процеса, за да Използване на формулата INDEX MATCH да извършва Дело - Чувствително търсене в Excel .
СТЪПКИ:
- В началото изберете клетка F5 .
- След това въведете формулата:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0)) - Накрая натиснете Въведете за връщане на стойността.
🔎 Как работи формулата?
- EXACT(F4,B5:B10)
Сайтът EXACT функцията връща TRUE само за първите данни ( B5 ) в диапазона B5:B10 и FALSE за други.
- MATCH(TRUE,EXACT(F4,B5:B10),0)
Този MATCH възвръщаемост на формулата 1 към INDEX като номер на реда.
- INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))
Накрая, INDEX функцията връща 2600 която е в 1. ред в диапазона D5:D10 .
Прочетете още: Примери с формулата INDEX-MATCH в Excel (8 подхода)
4. Използвайте INDEX MATCH за най-близко съвпадение
Понякога може да не получим точното съвпадение на дадена стойност за търсене в масива за търсене. В този случай искаме да потърсим най-близкото съвпадение. Това се случва особено при цифрови стойности за търсене. Сега научете процеса за намиране на Най-близък мач като използвате INDEX MATCH формула.
СТЪПКИ:
- Изберете клетка F5 отначало.
- След това въведете формулата:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)) - Накрая натиснете Въведете .
🔎 Как работи формулата?
- ABS (D5: D10-F4)
Първо, формулата изважда F4 стойност на клетката от обхвата D5:D10 за генериране на разликите и използваме функцията ABS да превърнете отрицателните резултати в положителни.
- MIN(ABS(D5:D10-F4))
След това, функцията MIN връща най-малката разлика, която е 500 .
- MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)
MIN(ABS(D5:D10-F4)) Изходът на формулата е стойността за търсене ( 500 ) за MATCH и масивът за търсене е ABS (D5: D10-F4) изходи на формулата.
- INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))
В крайна сметка INDEX функцията връща Маршрутизатор тъй като е най-близко Нетни продажби размер на 5000 .
5. Търсене на множество критерии с формулата INDEX MATCH
Една от най-полезните операции с INDEX MATCH е, че тя може да извършва търсене въз основа на множество условия. Следвайте стъпките по-долу, за да видите как можем да получим Нетни продажби въз основа на Продавач име и Продукт .
СТЪПКИ:
- На първо място, изберете клетка F6 за да въведете формулата:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)) - Впоследствие натиснете Въведете и ще получите резултата.
🔎 Как работи формулата?
- MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)
Сайтът MATCH възвръщаемост на формулата 2 към INDEX като номер на реда. Тук сравняваме няколко критерия, като прилагаме булева логика.
- INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))
Накрая, INDEX функцията връща 11500 която е в 2. ред в диапазона D5:D10 .
Прочетете още: Как да използвате формулата INDEX-MATCH в Excel за генериране на множество резултати
Подобни четива
- Множество критерии в Excel с помощта на функциите INDEX, MATCH и COUNTIF
- Как да използвате функциите INDEX & MATCH на работния лист в Excel VBA
- Индекс на Excel Съпоставяне на единични/многобройни критерии с единични/многобройни резултати
- INDEX MATCH в множество листове в Excel (с алтернатива)
- SUMIF с функциите INDEX и MATCH в Excel
6. Формула Excel INDEX MATCH със знаци Wildcard
Можем да използваме звездичка ( * ), което е Заместващ символ , за да намерите частичното съвпадение за стойност за търсене. Вижте примера по-долу, за да изпълните задачата. Нат в клетка F4 . Няма Продавач с това име, но ние имаме Нейтън , което е частично съвпадение.
СТЪПКИ:
- Първо, изберете клетка F5 .
- След това въведете формулата:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0)) - Накрая натиснете Въведете и тя ще върне Нетни продажби на Нейтън .
🔎 Как работи формулата?
- MATCH(F4& "*",B5:B10,0)
F4& "*" е нашата стойност за търсене, където звездичката е заместващ символ, който представлява произволен брой символи, започващи с Нат . Формулата връща 4 .
- INDEX(D5:D10,MATCH(F4& "*",B5:B10,0))
Накрая, INDEX функцията връща 17000 която е в 4. ред в диапазона D5:D10 .
Прочетете още: INDEX MATCH множество критерии с Wildcard в Excel (пълно ръководство)
7. прилагане на INDEX MATCH за тристранно търсене в Excel
Усъвършенстваното използване на INDEX MATCH формулата е за извършване на Трипосочен Друг синтаксис на INDEX функция е:
INDEX (array, row_num, [col_num], [area_num])
Къде, [area_num] ( По избор ) означава Ако аргументът на масива се състои от няколко диапазона, това число ще избере конкретната референция от всички диапазони.
В този пример ще използваме този незадължителен аргумент, за да върнем желаните данни от всеки един от месеците на януари , февруари , и Март . Затова следвайте следните стъпки, за да Използвайте на Формула INDEX MATCH в Excel за Трипосочен Преглед на .
СТЪПКИ:
- На първо място, изберете клетка F7 за да въведете формулата:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Януари",1,IF(F4="Февруари",2,3)))) - След това натиснете Въведете . Така ще видите резултата.
🔎 Как работи формулата?
- IF(F4="януари",1,IF(F4="февруари",2,3))
Функцията IF ще върне 2 тъй като даденият ни месец е февруари . INDEX функцията ще извлече стойността от 2. масив, т.е. февруари .
- MATCH(F6,B5:D5,0)
Сайтът MATCH функцията връща 3 .
- MATCH(F5,B6:B7,0)
Този MATCH функцията връща 2 .
- INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Януари",1,IF(F4="Февруари",2,3))))
Накрая, INDEX функцията връща 12500 която е в пресечната точка на 3. колона и 2. ред на 2. масив.
Прочетете още: Как да използвате INDEX MATCH вместо VLOOKUP в Excel (3 начина)
8. Извличане на стойностите на целия ред/колона с формулата INDEX MATCH
Друго приложение на INDEX MATCH формулата извлича данни от целия ред или колона. Затова научете процедурата за извършване на операцията.
СТЪПКИ:
- В началото изберете клетка F5 . Тук въведете формулата:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0) - След това натиснете Въведете и ще излее данните на целия 3. ред в диапазона B5:D10 .
🔎 Как работи формулата?
- MATCH(F4,B5:B10,0)
Сайтът MATCH възвръщаемост на формулата 3 към INDEX като номер на реда.
- INDEX(B5:D10,MATCH(F4,B5:B10,0),0)
Сайтът INDEX връща всички стойности в 3. ред в диапазона B5:D10 .
Прочетете още: Индексно съвпадение на сумата на множество редове в Excel (3 начина)
9. Намиране на приблизително съвпадение чрез INDEX MATCH
Сайтът INDEX MATCH В този пример ще намерим произведението за приблизително съвпадение. Нетни продажби на 6000 . Затова следвайте процеса.
СТЪПКИ:
- Първо, щракнете върху клетката F5 .
- След това въведете формулата:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1) - Накрая натиснете Въведете .
ЗАБЕЛЕЖКА: Данните трябва да бъдат в Възходящ или Спускане за да може тази формула да работи.
🔎 Как работи формулата?
- MATCH(F4,D5:D10,1)
Сайтът MATCH формулата използва 1 като аргумент за типа на съвпадение, който ще върне най-голямата стойност, по-малка или равна на стойността за търсене. 6000 . Тук ще се върне 2 .
- INDEX(C5:C10,MATCH(F4,D5:D10,1),1)
Сайтът INDEX връща функция Маршрутизатор която е в 2. ред в диапазона C5:C10 .
Прочетете още: Как да използвате INDEX и Match за частично съвпадение (2 начина)
Защо INDEX MATCH е по-полезен от VLOOKUP?
1. Формулата INDEX MATCH търси двете леви и десни страни на стойността на търсенето
Функцията VLOOKUP не може да извлича данни от лявата страна на стойността за търсене. Но INDEX MATCH Формулата може да го направи.
2. INDEX MATCH работи с вертикални и хоризонтални диапазони
VLOOKUP може да извлича данни само от вертикален масив, докато INDEX MATCH може да преминава както през вертикални, така и през хоризонтални данни.
3. VLOOKUP се проваля при низходящи данни
Сайтът VLOOKUP Функцията не може да обработва данни в низходящ ред, когато става въпрос за приблизително съвпадение.
4. Формулата с INDEX MATCH е малко по-бърза
VLOOKUP е малко по-бавна функция при работа с твърде много редове и колони.
5. Независимо от действителната позиция на колоната
VLOOKUP не е независима от действителната позиция на колоната. Така че, когато изтриете колона. VLOOKUP ще даде грешен резултат.
6. VLOOKUP не е труден за използване
Сайтът VLOOKUP е по-лесна за използване в сравнение с функцията INDEX MATCH и повечето от операциите за търсене могат да се извършват с VLOOKUP лесно.
Прочетете още: Функцията INDEX MATCH срещу VLOOKUP (9 примера)
Заключение
Отсега нататък ще можете да Използвайте на Формула INDEX MATCH в Excel с гореописаните методи. Продължавайте да ги използвате и ни уведомете, ако имате още начини за изпълнение на задачата. Не забравяйте да пускате коментари, предложения или запитвания, ако имате такива, в раздела за коментари по-долу.
