Wie man die INDEX MATCH Formel in Excel verwendet (9 Beispiele)

Hugh West

16-10-2023 Excel-Formeln
  • Teile Das
Hugh West

Hin und wieder müssen wir in unserer großen Datenbank nach bestimmten Informationen suchen. Excel Arbeitsblatt, aber es ist mühsam, sie manuell zu suchen. Eine Formel, die zusammenarbeitet die Funktionen INDEX und MATCH kann die erstaunliche Arbeit der Datensuche sehr leicht erledigen. Es kann auch erweiterte Suchvorgänge durchführen. In diesem Artikel zeigen wir Ihnen die einfachen und effektiven Möglichkeiten, um Verwenden Sie die INDEX MATCH Formel in Excel.

Zur Veranschaulichung werden wir einen Beispieldatensatz als Beispiel verwenden. Der folgende Datensatz stellt beispielsweise die Verkäufer , Produkt und Nettoumsatz eines Unternehmens.

Download Arbeitsbuch Praxis

Laden Sie die folgende Arbeitsmappe herunter, um selbst zu üben.

Verwendung von INDEX-MATCH.xlsx

Einführung in die Funktion INDEX

  • Syntax

INDEX(array, zeilen_num,[spalten_num])

  • Argumente

Array: Der Bereich, aus dem die Daten abgerufen werden sollen.

zeilen_num: Die Zeilennummer der zurückzugebenden Daten.

[column_num]: Die Spaltennummer der zurückzugebenden Daten.

  • Zielsetzung

Die Funktion INDEX ruft den Zellwert oder die Referenz der Zelle ab, die sich am Schnittpunkt einer bestimmten Zeile und Spalte in einem bestimmten Bereich befindet.

Im folgenden Datensatz, Nate Sales 17000 befindet sich in der 4. Zeile und 3. Spalte im Bereich B5:D10 .

Einführung in die MATCH-Funktion

  • Syntax

MATCH(lookup_value,lookup_array,[match_type])

  • Argumente

lookup_value: Der Wert, nach dem im Datenbereich gesucht werden soll.

lookup_array Datenbereich: Der Datenbereich, in dem nach den Daten gesucht wird. lookup_value .

[match_type]: - 1/0/1 . -1 steht für einen Wert, der größer ist als die genaue Übereinstimmung, 0 für eine exakte Übereinstimmung, und 1 für den Wert, der kleiner als die genaue Übereinstimmung ist.

  • Zielsetzung

Die MATCH-Funktion gibt die relative Position des lookup_value in einem Array.

In dem unten stehenden Datensatz ist die F4 Zellwert ist Frank ( lookup_value ) und Frank befindet sich in der 3. Position im Verkäufer Abschnitt ( B5:B10 ) und liefert somit 3 .

9 Beispiele für die Verwendung der INDEX MATCH Formel in Excel

Nun werden wir eine Formel erstellen, die beide Funktionen kombiniert. Wir wissen bereits, dass die INDEX Funktion benötigt Zeilen- und Spaltennummern, um Daten abzurufen, während die MATCH Funktion gibt den Ort der Daten zurück, so dass wir ihr Argument einfach platzieren können, um die Zeilen- und Spaltennummern zu erhalten.

In dem folgenden Datensatz wird die INDEX Funktion zieht die Daten aus B5:D10 . die MATCH Funktion gibt Zeilennummer zurück 3 und wir haben die Spaltennummer angegeben. Die Formel wird also die Daten in der Spalte 3. Zeile und 3. Spalte im Bereich.

1. zweiseitige Suche mit INDEX MATCH in Excel

Zwei-Wege Lookup bedeutet, dass sowohl die Zeilennummer als auch die Spaltennummer mit Hilfe des MATCH Funktion, die für die INDEX Führen Sie daher die folgenden Schritte aus, um die Aufgabe auszuführen.

SCHRITTE:

  • Wählen Sie zunächst die Zelle F6 .
  • Geben Sie dann die Formel ein:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

  • Drücken Sie schließlich Eingabe und es wird den Wert zurückgeben.

🔎 Wie funktioniert die Formel?

  • ÜBEREINSTIMMUNG(F5,B5:B10,0)

Die MATCH Formelrenditen 3 zu INDEX als Zeilennummer.

  • MATCH(F4,B4:D4,0))

Diese MATCH Formelrenditen 3 zu INDEX als Spaltennummer.

  • INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

Schließlich ist die INDEX Funktion gibt zurück 13500 die sich in der 3. Zeile und 3. Spalte im Bereich B5:D10 .

Lesen Sie mehr: SUMPRODUCT mit INDEX und MATCH Funktionen in Excel

Der größte Vorteil des INDEX MATCH Formel ist, dass sie Daten von der linken Seite des Nachschlagewerts abrufen kann. Lernen Sie also die Schritte zur Durchführung der Operation.

SCHRITTE:

  • Wählen Sie erstens die Zelle F5 .
  • Geben Sie dann die Formel ein:
=INDEX(B5:B10,MATCH(F4,C5:C10,0))

  • Zum Schluss drücken Sie Eingabe und es wird den Wert zurückgeben.

Hier gibt die Formel den Verkäufer Name, der sich auf der linken Seite des Suchwerts befindet Kabel .

🔎 Wie funktioniert die Formel?

  • ÜBEREINSTIMMUNG(F4,C5:C10,0)

Die MATCH Formelrenditen 1 zu INDEX als Zeilennummer.

  • INDEX(B5:B10,MATCH(F4,C5:C10,0))

Schließlich ist die INDEX Funktion gibt zurück Wilham die sich in der 1. Zeile im Bereich B5:B10 .

Lesen Sie mehr: Wie man die INDEX MATCH Formel in Excel verwendet (9 Beispiele)

3. case-sensitive Suche mit INDEX MATCH Formel

Die MATCH Funktion unterscheidet standardmäßig nicht zwischen Groß- und Kleinschreibung. die EXAKTE Funktion zu suchen, die Groß- und Kleinschreibung beachtet. Folgen Sie daher dem Prozess zu Verwenden Sie die INDEX MATCH Formel aufführen Fall - Empfindliches Nachschlagen in Excel .

SCHRITTE:

  • Wählen Sie zu Beginn die Zelle F5 .
  • Geben Sie anschließend die Formel ein:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

  • Zum Schluss drücken Sie Eingabe um den Wert zurückzugeben.

🔎 Wie funktioniert die Formel?

  • GENAU(F4,B5:B10)

Die EXAKT Funktion gibt zurück WAHR nur für die ersten Daten ( B5 ) im Bereich B5:B10 und FALSCH für andere.

  • MATCH(TRUE,EXACT(F4,B5:B10),0)

Diese MATCH Formelrenditen 1 zu INDEX als Zeilennummer.

  • INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

Schließlich ist die INDEX Funktion gibt zurück 2600 die sich in der 1. Zeile im Bereich D5:D10 .

Lesen Sie mehr: Beispiele mit INDEX-MATCH Formel in Excel (8 Ansätze)

4. verwenden Sie INDEX MATCH für die engste Übereinstimmung

Manchmal kann es vorkommen, dass wir keine exakte Übereinstimmung eines Nachschlagewertes im Nachschlagearray finden. In diesem Fall wollen wir nach der nächstliegenden Übereinstimmung suchen. Das passiert vor allem bei numerischen Nachschlagewerten. Lernen Sie nun, wie Sie die Naheliegendste Übereinstimmung unter Verwendung der INDEX MATCH Formel.

SCHRITTE:

  • Zelle auswählen F5 anfangs.
  • Geben Sie dann die Formel ein:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

  • Drücken Sie abschließend Eingabe .

🔎 Wie funktioniert die Formel?

  • ABS(D5:D10-F4)

Erstens subtrahiert die Formel die F4 Zellwert aus dem Bereich D5:D10 um die Unterschiede zu erzeugen, und wir verwenden die ABS-Funktion um die negativen Ergebnisse in positive umzuwandeln.

  • MIN(ABS(D5:D10-F4))

Dann, die Funktion MIN gibt die kleinste Differenz zurück, die 500 .

  • MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)

MIN(ABS(D5:D10-F4)) Formelausgabe ist der Nachschlagewert ( 500 ) für die MATCH Funktion und das Lookup-Array ist ABS(D5:D10-F4) Formelausgaben.

  • INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

Schließlich ist die INDEX Funktion gibt zurück Router da es die nächstgelegene Nettoumsatz betragen 5000 .

5. mehrere Kriterien mit INDEX MATCH Formel nachschlagen

Eine der nützlichsten Operationen mit dem INDEX MATCH Formel ist, dass sie eine Suche auf der Grundlage mehrerer Bedingungen durchführen kann. Folgen Sie den nachstehenden Schritten, um zu sehen, wie wir die Nettoumsatz auf Grund Verkäufer Name und Produkt .

SCHRITTE:

  • Wählen Sie zunächst die Zelle F6 um die Formel einzugeben:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

  • Drücken Sie anschließend Eingabe und Sie werden das Ergebnis erhalten.

🔎 Wie funktioniert die Formel?

  • MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)

Die MATCH Formelrenditen 2 zu INDEX Hier werden die verschiedenen Kriterien durch Anwendung boolescher Logik verglichen.

  • INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

Schließlich ist die INDEX Funktion gibt zurück 11500 die sich in der 2. Zeile im Bereich D5:D10 .

Lesen Sie mehr: Verwendung der INDEX-MATCH-Formel in Excel, um mehrere Ergebnisse zu generieren

Ähnliche Lektüre

  • Mehrere Kriterien in Excel mit den Funktionen INDEX, MATCH und COUNTIF
  • Verwendung von INDEX & MATCH Arbeitsblattfunktionen in Excel VBA
  • Excel-Index Abgleich einzelner/mehrerer Kriterien mit einzelnen/mehreren Ergebnissen
  • INDEX MATCH über mehrere Tabellenblätter in Excel (mit Alternative)
  • SUMIF mit INDEX und MATCH Funktionen in Excel

6) Excel INDEX MATCH Formel mit Platzhalterzeichen

Wir können ein Sternchen verwenden ( * ), die eine Platzhalterzeichen um eine teilweise Übereinstimmung für einen Suchwert zu finden. Das folgende Beispiel zeigt, wie die Aufgabe ausgeführt wird. Wir haben Nat in der Zelle F4 Es gibt keine Verkäufer mit diesem Namen, aber wir haben Nathan was eine Teilübereinstimmung darstellt.

SCHRITTE:

  • Wählen Sie erstens die Zelle F5 .
  • Danach geben Sie die Formel ein:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

  • Zum Schluss drücken Sie Eingabe und es wird die Nettoumsatz von Nathan .

🔎 Wie funktioniert die Formel?

  • MATCH(F4& "*",B5:B10,0)

F4& "*" ist unser Nachschlagewert, wobei das Sternchen ein Platzhalterzeichen ist, das für eine beliebige Anzahl von Zeichen steht, die mit Nat Die Formel ergibt 4 .

  • INDEX(D5:D10,MATCH(F4& "*",B5:B10,0))

Schließlich ist die INDEX Funktion gibt zurück 17000 die sich in der 4. Zeile im Bereich D5:D10 .

Lesen Sie mehr: INDEX MATCH Multiple Criteria with Wildcard in Excel (Eine vollständige Anleitung)

7. INDEX MATCH für die Drei-Wege-Suche in Excel anwenden

Die fortschrittliche Nutzung des INDEX MATCH Formel geht es um die Durchführung einer Drei-Wege Eine andere Syntax der INDEX Funktion ist:

INDEX (array, row_num, [col_num], [area_num])

Wo, [area_num] ( Optional ) bedeutet: Wenn das Array-Argument aus mehreren Bereichen besteht, wählt diese Zahl die spezifische Referenz aus allen Bereichen aus.

In diesem Beispiel werden wir dieses optionale Argument verwenden, um die gewünschten Daten aus einem beliebigen Monat von Januar , Februar und März Befolgen Sie daher die folgenden Schritte, um Verwenden Sie die INDEX MATCH Formel in Excel für Drei-Wege Nachschlagen .

SCHRITTE:

  • Wählen Sie zunächst die Zelle F7 um die Formel einzugeben:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januar",1,IF(F4="Februar",2,3))))

  • Drücken Sie dann Eingabe So sehen Sie die Ausgabe.

🔎 Wie funktioniert die Formel?

  • IF(F4="Januar",1,IF(F4="Februar",2,3))

Die Funktion IF wird zurückgegeben 2 da unser gegebener Monat ist Februar . die INDEX Funktion holt den Wert aus der 2. Array d.h. Februar .

  • MATCH(F6,B5:D5,0)

Die MATCH Funktion gibt zurück 3 .

  • ÜBEREINSTIMMUNG(F5,B6:B7,0)

Diese MATCH Funktion gibt zurück 2 .

  • INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januar",1,IF(F4="Februar",2,3))))

Schließlich ist die INDEX Funktion gibt zurück 12500 die sich im Schnittpunkt der 3. Spalte und 2. Zeile des 2. Array.

Lesen Sie mehr: Wie man INDEX MATCH anstelle von VLOOKUP in Excel verwendet (3 Möglichkeiten)

8. die Werte der gesamten Zeile/Spalte mit der INDEX MATCH Formel abrufen

Eine weitere Anwendung des INDEX MATCH Formel die Daten aus der gesamten Zeile oder Spalte abruft. Lernen Sie also die Vorgehensweise zur Durchführung der Operation.

SCHRITTE:

  • Wählen Sie zu Beginn die Zelle F5 Geben Sie hier die Formel ein:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

  • Danach drücken Sie Eingabe und es werden die Daten der gesamten 3. Zeile im Bereich B5:D10 .

🔎 Wie funktioniert die Formel?

  • ÜBEREINSTIMMUNG(F4,B5:B10,0)

Die MATCH Formelrenditen 3 zu INDEX als Zeilennummer.

  • INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

Die INDEX Funktion gibt alle Werte in der Datei 3. Zeile im Bereich B5:D10 .

Lesen Sie mehr: Indexabgleich Summe mehrerer Zeilen in Excel (3 Möglichkeiten)

9. ungefähre Übereinstimmung mit INDEX MATCH finden

Die INDEX MATCH Formel ist sehr nützlich, um die ungefähre Übereinstimmung zu ermitteln. In diesem Beispiel werden wir das Produkt für eine ungefähre Nettoumsatz von 6000 Folgen Sie also dem Prozess.

SCHRITTE:

  • Klicken Sie erstens auf die Zelle F5 .
  • Geben Sie dann die Formel ein:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

  • Drücken Sie abschließend Eingabe .

HINWEIS: Die Daten sollten in Aufsteigend oder Absteigend damit diese Formel funktioniert.

🔎 Wie funktioniert die Formel?

  • ÜBEREINSTIMMUNG(F4,D5:D10,1)

Die MATCH Formel verwendet 1 als Argument für den Übereinstimmungstyp, der den größten Wert zurückgibt, der kleiner oder gleich dem Nachschlagewert ist 6000 Hier, es wird zurückkehren. 2 .

  • INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

Die INDEX Funktion gibt eine Router die sich in der 2. Zeile im Bereich C5:C10 .

Lesen Sie mehr: Verwendung von INDEX und Abgleich für einen teilweisen Abgleich (2 Möglichkeiten)

Warum ist INDEX MATCH vorteilhafter als VLOOKUP?

1 Die INDEX MATCH Formel sucht beide linken und rechten Seiten des Lookup-Wertes.

Die Funktion VLOOKUP kann keine Daten von der linken Seite des Nachschlagewerts abrufen. Aber die INDEX MATCH Formel kann es tun.

2 INDEX MATCH arbeitet mit vertikalen und horizontalen Bereichen

VLOOKUP kann nur Daten aus einem vertikalen Array abrufen, während die INDEX MATCH kann sowohl vertikale als auch horizontale Daten durchgehen.

3 VLOOKUP schlägt bei absteigenden Daten fehl

Die VLOOKUP Funktion kann nicht mit Daten in absteigender Reihenfolge umgehen, wenn es um die ungefähre Übereinstimmung geht.

4. die Formel mit INDEX MATCH ist etwas schneller

VLOOKUP ist eine etwas langsamere Funktion, wenn man mit zu vielen Zeilen und Spalten arbeitet.

5. unabhängig von der tatsächlichen Position der Säule

VLOOKUP ist nicht unabhängig von der tatsächlichen Spaltenposition. Wenn Sie also eine Spalte löschen, wird die VLOOKUP Funktion ein falsches Ergebnis liefern wird.

6 VLOOKUP ist nicht schwer zu benutzen.

Die VLOOKUP Funktion ist einfacher zu benutzen als die INDEX MATCH Und die meisten unserer Nachschlageoperationen können mit VLOOKUP leicht.

Lesen Sie mehr: INDEX MATCH vs. VLOOKUP Funktion (9 Beispiele)

Schlussfolgerung

Künftig werden Sie in der Lage sein Verwenden Sie die INDEX MATCH Formel in Excel mit den oben beschriebenen Methoden. Verwenden Sie sie weiter und lassen Sie uns wissen, ob Sie weitere Möglichkeiten haben, die Aufgabe zu erledigen. Vergessen Sie nicht, Kommentare, Vorschläge oder Fragen in den Kommentarbereich unten zu schreiben, wenn Sie welche haben.

Vorherigen Post Zählen von Zeilen mit VBA in Excel (5 Vorgehensweisen)
Nächster Beitrag Text in Excel-Bereich suchen und Zellbezug zurückgeben (3 Wege)

Hugh West ist ein äußerst erfahrener Excel-Trainer und -Analyst mit über 10 Jahren Erfahrung in der Branche. Er verfügt über einen Bachelor-Abschluss in Rechnungswesen und Finanzen sowie einen Master-Abschluss in Betriebswirtschaft. Hugh hat eine Leidenschaft für das Unterrichten und hat einen einzigartigen Lehransatz entwickelt, der leicht zu befolgen und zu verstehen ist. Seine Expertenkenntnisse in Excel haben Tausenden von Studenten und Berufstätigen auf der ganzen Welt geholfen, ihre Fähigkeiten zu verbessern und in ihrer Karriere herausragende Leistungen zu erbringen. Über seinen Blog teilt Hugh sein Wissen mit der Welt und bietet kostenlose Excel-Tutorials und Online-Schulungen an, um Einzelpersonen und Unternehmen dabei zu helfen, ihr volles Potenzial auszuschöpfen.