Az INDEX MATCH formula használata az Excelben (9 példa)

Hugh West

16-10-2023 Excel képletek
  • Ossza Meg Ezt
Hugh West

Néha-néha bizonyos információkat kell keresnünk a nagyméretű Excel De fárasztó manuálisan keresni. Egy képlet együttműködő az INDEX és MATCH funkciók nagyon könnyen elvégezheti az adatok keresésének csodálatos munkáját. Fejlett kereséseket is végezhet. Ebben a cikkben megmutatjuk, hogy milyen egyszerű és hatékony módon lehet a Használja a címet. a INDEX MATCH képlet a oldalon. Excel.

A szemléltetés érdekében egy mintaadatkészletet fogunk használni példaként. Például a következő adatkészlet a Értékesítő , Termék , és Nettó értékesítés egy vállalat.

Gyakorlati munkafüzet letöltése

Töltse le az alábbi munkafüzetet, hogy saját maga gyakorolhasson.

INDEX-MATCH.xlsx használata

Bevezetés az INDEX funkcióba

  • Szintaxis

INDEX(array, row_num,[column_num])

  • Érvek

tömb: A tartomány, ahonnan az adatokat veszi.

row_num: A visszaadandó adatok sorszáma.

[column_num]: A visszaadandó adatok oszlopszáma.

  • Célkitűzés

Az INDEX funkció egy adott tartományban egy adott sor és oszlop metszéspontjában található cella értékét vagy hivatkozását kéri le.

A következő adatkészletben, Nate Sales 17000 jelen van a 4. sor és 3. oszlop a következő tartományban B5:D10 .

Bevezetés a MATCH funkcióba

  • Szintaxis

MATCH(lookup_value,lookup_array,[match_type])

  • Érvek

lookup_value: Az adattartományban keresendő érték.

lookup_array : Az adattartomány, ahonnan a keresés a lookup_value .

[match_type]: - 1/0/1 . -1 a pontos egyezésnél nagyobb értéket jelent, 0 pontos egyezés esetén, és 1 a pontos egyezésnél kisebb értékre.

  • Célkitűzés

A MATCH funkció visszaadja a relatív pozícióját a lookup_value egy tömbben.

Az alábbi adatkészletben a F4 a cella értéke Frank ( lookup_value ) és Frank jelen van a 3. pozíció a Értékesítő szakasz ( B5:B10 ). Így visszatér 3 .

9 példa az INDEX MATCH képlet használatára az Excelben

Most létrehozunk egy képletet, amely egyesíti a két függvényt. Már tudjuk, hogy a INDEX függvénynek sor- és oszlopszámokra van szüksége az adatok lekérdezéséhez, míg a MATCH függvény visszaadja az adatok helyét. Így könnyen elhelyezhetjük az argumentumukat, hogy megkapjuk a sor- és oszlopszámokat.

A következő adatkészletben a INDEX függvény az adatokat a B5:D10 . MATCH a funkció visszaadja a sorszámot 3 és megadtuk az oszlopszámot. Így a képlet ki fogja hozni az adatokat, amelyek a 3. sor és 3. oszlop a tartományban.

1. Kétirányú keresés INDEX MATCH segítségével az Excelben

Kétirányú lookup azt jelenti, hogy mind a sorszámot, mind az oszlopszámot lekérjük a MATCH funkció, amely a INDEX Ezért a feladat elvégzéséhez kövesse az alábbi lépéseket.

LÉPÉSEK:

  • Először válassza ki a cellát F6 .
  • Ezután írja be a képletet:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

  • Végül nyomja meg a Írja be a címet. és ez visszaadja az értéket.

🔎 Hogyan működik a képlet?

  • MATCH(F5,B5:B10,0)

A MATCH a képlet visszatérülése 3 a címre. INDEX mint a sorszám.

  • MATCH(F4,B4:D4,0)))

Ez a MATCH a képlet visszatérülése 3 a címre. INDEX mint oszlopszám.

  • INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

Végül, a INDEX funkció visszatér 13500 amely a 3. sor és 3. oszlop a következő tartományban B5:D10 .

További információ: SUMPRODUCT INDEX és MATCH funkciókkal az Excelben

2. INDEX MATCH képlet a bal oldali kereséshez

A fő előnye a INDEX MATCH formula az, hogy a keresési érték bal oldaláról tud adatokat lekérdezni. Tehát tanulja meg a művelet elvégzésének lépéseit.

LÉPÉSEK:

  • Először is, válassza ki a cellát F5 .
  • Ezután írja be a képletet:
=INDEX(B5:B10,MATCH(F4,C5:C10,0))

  • Végül nyomja meg a Írja be a címet. és ez visszaadja az értéket.

Itt a képlet visszaadja a Az eladó név, amely a keresési érték bal oldalán található Kábel .

🔎 Hogyan működik a képlet?

  • MATCH(F4,C5:C10,0)

A MATCH a képlet visszatérülése 1 a címre. INDEX mint a sorszám.

  • INDEX(B5:B10,MATCH(F4,C5:C10,0))

Végül, a INDEX funkció visszatér Wilham amely a 1. sor a tartományban B5:B10 .

Bővebben: Az INDEX MATCH formula használata az Excelben (9 példa)

3. Nagy- és kisbetű-érzékeny keresés INDEX MATCH képlet használatával

A MATCH függvény alapértelmezés szerint nem nagy- és kisbetű-érzékeny. Azonban alkalmazhatjuk a az EXACT funkció a kereséshez, amely tiszteletben tartja a kis- és nagybetűket. Ezért kövesse a folyamatot, hogy Az INDEX MATCH formula használata hogy elvégezze Ügy - Érzékeny keresés a oldalon. Excel .

LÉPÉSEK:

  • Az elején válassza ki a cellát F5 .
  • Ezután írja be a képletet:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

  • Végül nyomja meg a Írja be a címet. hogy visszaadja az értéket.

🔎 Hogyan működik a képlet?

  • EXACT(F4,B5:B10)

A EXACT funkció visszatér TRUE csak az első adatokra ( B5 ) a következő tartományban B5:B10 és FALSE másoknak.

  • MATCH(TRUE,EXACT(F4,B5:B10),0)

Ez a MATCH a képlet visszatérülése 1 a címre. INDEX mint a sorszám.

  • INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

Végül, a INDEX funkció visszatér 2600 amely a 1. sor a tartományban D5:D10 .

Bővebben: Példák INDEX-MATCH képlettel az Excelben (8 megközelítés)

4. Használja az INDEX MATCH-t a legközelebbi egyezéshez.

Néha előfordulhat, hogy nem kapjuk meg a keresési érték pontos egyezését a keresési tömbben. Ebben az esetben a legközelebbi egyezést akarjuk megkeresni. Ez különösen a numerikus keresési értékeknél fordul elő. Most tanuljuk meg a folyamatot, hogy megtaláljuk a(z) Legközelebbi mérkőzés a INDEX MATCH formula.

LÉPÉSEK:

  • Cella kiválasztása F5 először.
  • Ezután írja be a képletet:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

  • Végül nyomja meg a Írja be a címet. .

🔎 Hogyan működik a képlet?

  • ABS(D5:D10-F4)

Először is, a képlet kivonja a F4 cellák értéke a tartományból D5:D10 a különbségek generálásához, és a az ABS funkció hogy a negatív eredményeket pozitívvá alakítsa át.

  • MIN(ABS(D5:D10-F4))

Akkor, a MIN funkció a legkisebb különbséget adja vissza, amely 500 .

  • MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)

MIN(ABS(D5:D10-F4)) A képlet kimenete a keresési érték ( 500 ) a MATCH függvény és a keresési tömb ABS(D5:D10-F4) képlet kimenetek.

  • INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

Végül a INDEX funkció visszatér Router mivel ez áll a legközelebb Nettó értékesítés a következő összegre 5000 .

5. Több kritérium keresése INDEX MATCH képlettel

Az egyik leghasznosabb művelet a INDEX MATCH formula az, hogy több feltétel alapján is képes keresést végezni. Kövesse az alábbi lépéseket, hogy lássa, hogyan kaphatjuk meg a Nettó értékesítés a következők alapján Értékesítő név és Termék .

LÉPÉSEK:

  • Először is, válassza ki a cellát F6 a képlet beírásához:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

  • Ezt követően nyomja meg a Írja be a címet. és megkapod az eredményt.

🔎 Hogyan működik a képlet?

  • MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)

A MATCH a képlet visszatérülése 2 a címre. INDEX Itt a több kritériumot bólés logika alkalmazásával hasonlítjuk össze.

  • INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

Végül, a INDEX funkció visszatér 11500 amely a 2. sor a tartományban D5:D10 .

Bővebben: Hogyan használjuk az INDEX-MATCH képletet az Excelben több eredmény létrehozásához?

Hasonló olvasmányok

  • Több kritérium az Excelben az INDEX, MATCH és COUNTIF funkció használatával
  • Hogyan használjuk az INDEX és a MATCH munkalap függvényeket az Excel VBA-ban?
  • Excel Index Egy/több kritérium egyezésének egy/több találattal történő megfeleltetése
  • INDEX MATCH több lapon keresztül az Excelben (alternatívával)
  • SUMIF INDEX és MATCH funkciókkal az Excelben

6. Excel INDEX MATCH formula Wildcard karakterekkel

Használhatunk csillagot ( * ), amely egy Wildcard karakter , hogy megtalálja a részleges egyezést egy keresési értékhez. Az alábbi példában láthatjuk a feladat végrehajtását. A következővel rendelkezünk Nat cellában F4 . Nincs Értékesítő ezzel a névvel, de van Nathan , ami részleges egyezés.

LÉPÉSEK:

  • Először is, válassza ki a cellát F5 .
  • Ezután írja be a képletet:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

  • Végül nyomja meg a Írja be a címet. és ez visszaadja a Nettó értékesítés a Nathan .

🔎 Hogyan működik a képlet?

  • MATCH(F4& "*",B5:B10,0)

F4& "*" a keresési értékünk, ahol a csillag egy joker karakter, amely a következővel kezdődő karakterek bármelyikét jelenti Nat A képlet visszaadja 4 .

  • INDEX(D5:D10,MATCH(F4& "*",B5:B10,0))

Végül, a INDEX funkció visszatér 17000 amely a 4. sor a tartományban D5:D10 .

Bővebben: INDEX MATCH több kritériummal és Wildcarddal az Excelben (Teljes útmutató)

7. Az INDEX MATCH alkalmazása háromoldalú kereséshez az Excelben

A fejlett használat a INDEX MATCH képlet egy Háromirányú keresés. A másik szintaxis a INDEX funkció:

INDEX (array, row_num, [col_num], [area_num])

Hol, [area_num] ( Opcionális ) azt jelenti, hogy ha a tömb argumentum több tartományból áll, akkor ez a szám kiválasztja az adott hivatkozást az összes tartományból.

Ebben a példában ezt az opcionális argumentumot arra fogjuk használni, hogy a kívánt adatokat a következő hónapok bármelyikéből visszaadjuk Január , Február , és Március Ezért kövesse az alábbi lépéseket Használja a címet. a INDEX MATCH képlet a oldalon. Excel a oldalon. Háromirányú Keresés .

LÉPÉSEK:

  • Először is, válassza ki a cellát F7 a képlet beírásához:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="január",1,IF(F4="február",2,3))))

  • Ezután nyomja meg a Írja be a címet. . Így a kimenetet láthatja.

🔎 Hogyan működik a képlet?

  • IF(F4="január",1,IF(F4="február",2,3))

Az IF funkció vissza fog térni 2 mivel az adott hónapunk Február . INDEX függvény az értéket a 2. tömb, azaz. Február .

  • MATCH(F6,B5:D5,0)

A MATCH funkció visszatér 3 .

  • MATCH(F5,B6:B7,0)

Ez a MATCH funkció visszatér 2 .

  • INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Január",1,IF(F4="Február",2,3))))

Végül, a INDEX funkció visszatér 12500 amely a következő metszéspontjában van 3. oszlop és 2. sora a 2. tömb.

Bővebben: Hogyan használjuk az INDEX MATCH-ot a VLOOKUP helyett az Excelben (3 módja)

8. Az egész sor/oszlop értékeinek kinyerése INDEX MATCH képlettel

Egy másik alkalmazás a INDEX MATCH A képlet a teljes sor vagy oszlop adatainak lekérdezését jelenti. Tanulja meg tehát a művelet elvégzéséhez szükséges eljárást.

LÉPÉSEK:

  • Az elején válassza ki a cellát F5 Itt írja be a képletet:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

  • Ezután nyomja meg a Írja be a címet. és ez kiönti az adatokat az egész 3. sor a tartományban B5:D10 .

🔎 Hogyan működik a képlet?

  • MATCH(F4,B5:B10,0)

A MATCH a képlet visszatérülése 3 a címre. INDEX mint a sorszám.

  • INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

A INDEX függvény visszaadja az összes értéket a 3. sor a tartományban B5:D10 .

Bővebben: Index Match Sum több sor összege az Excelben (3 mód)

9. Közelítő egyezés keresése INDEX MATCH használatával

A INDEX MATCH képlet nagyon hasznos, amikor a közelítő egyezést keressük. Ebben a példában a közelítő termékét fogjuk megtalálni egy közelítő Nettó értékesítés a 6000 Ezért kövesse a folyamatot.

LÉPÉSEK:

  • Először kattintson a cellára F5 .
  • Ezután írja be a képletet:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

  • Végül nyomja meg a Írja be a címet. .

MEGJEGYZÉS: Az adatoknak a Felszálló vagy Leereszkedő hogy ez a képlet működjön.

🔎 Hogyan működik a képlet?

  • MATCH(F4,D5:D10,1)

A MATCH a képlet felhasználása 1 mint a match type argumentum, amely a legnagyobb értéket adja vissza, amely kisebb vagy egyenlő a keresési értékkel. 6000 . Itt, ez visszatér. 2 .

  • INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

A INDEX függvény visszatér egy Router amely a 2. sor a tartományban C5:C10 .

Bővebben: Az INDEX és a Match használata részleges egyezéshez (2 mód)

Miért előnyösebb az INDEX MATCH, mint a VLOOKUP?

1. Az INDEX MATCH formula a keresési érték mindkét bal-jobb oldalát nézi.

A VLOOKUP funkció nem tud adatokat lekérni a keresési érték bal oldaláról. De a INDEX MATCH formula képes rá.

2. INDEX MATCH függőleges és vízszintes tartományokkal működik

VLOOKUP csak egy függőleges tömbből tud adatokat lekérdezni, míg a INDEX MATCH a függőleges és a vízszintes adatokon is át tud menni.

3. VLOOKUP sikertelen csökkenő adatokkal

A VLOOKUP függvény nem tudja kezelni a csökkenő sorrendű adatokat, amikor a közelítő egyezésről van szó.

4. A formula INDEX MATCH-csal valamivel gyorsabb

VLOOKUP egy kicsit lassabb funkció, ha túl sok sorral és oszloppal dolgozik.

5. Az oszlop tényleges helyzetétől függetlenül

VLOOKUP nem független a tényleges oszloppozíciótól. Tehát, amikor törölsz egy oszlopot, a VLOOKUP függvény hibás eredményt fog adni.

6. A VLOOKUP nem nehéz használni

A VLOOKUP függvényt könnyebb használni, mint a INDEX MATCH És a legtöbb keresési műveletünket elvégezhetjük a VLOOKUP könnyedén.

Bővebben: INDEX MATCH vs VLOOKUP funkció (9 példa)

Következtetés

Mostantól kezdve Ön képes lesz arra, hogy Használja a címet. a INDEX MATCH képlet a oldalon. Excel a fent leírt módszerekkel. Használja őket továbbra is, és tudassa velünk, ha van még más módja a feladat elvégzésére. Ne felejtse el, hogy az alábbi megjegyzés rovatban tegye meg észrevételeit, javaslatait vagy kérdéseit, ha van ilyen.

Előző poszt Hogyan számolhat sorokat a VBA-val az Excelben (5 megközelítés)
Következő bejegyzés Szöveg keresése az Excel tartományban és a cellahivatkozás visszaadása (3 mód)

Hugh West nagy tapasztalattal rendelkező Excel-oktató és elemző, több mint 10 éves tapasztalattal az iparágban. Számvitel és pénzügy szakos alapdiplomát, valamint üzleti adminisztrációból mesterképzést szerzett. Hugh szenvedélye a tanítás, és egyedülálló tanítási megközelítést dolgozott ki, amely könnyen követhető és érthető. Az Excelben szerzett szakértői tudása világszerte több ezer diáknak és szakembernek segített abban, hogy készségeiket és karrierjüket kiválóan teljesítsék. Hugh blogján keresztül megosztja tudását a világgal, ingyenes Excel-oktatóanyagokat és online képzéseket kínálva, hogy segítse az egyéneket és a vállalkozásokat teljes potenciáljuk kibontakoztatásában.