Cara Menggunakan Rumus INDEX MATCH di Excel (9 Contoh)

Hugh West

16-10-2023 Rumus Excel
  • Bagikan Ini
Hugh West

Sekarang dan kemudian, kita harus mencari informasi spesifik dalam Excel Tapi, sangat melelahkan untuk mencarinya secara manual. Sebuah rumus yang berkolaborasi fungsi INDEX dan MATCH dapat melakukan pekerjaan luar biasa dalam mencari data dengan sangat mudah. Ia juga dapat melakukan pencarian lanjutan. Dalam artikel ini, kami akan menunjukkan kepada Anda cara-cara sederhana dan efektif untuk Gunakan yang Rumus INDEX MATCH di Excel.

Untuk mengilustrasikannya, kita akan menggunakan contoh dataset sebagai contoh. Misalnya, dataset berikut ini merepresentasikan Penjual , Produk dan Penjualan Bersih dari sebuah perusahaan.

Unduh Buku Kerja Praktik

Unduh buku kerja berikut ini untuk berlatih sendiri.

Penggunaan INDEX-MATCH.xlsx

Pengenalan ke Fungsi INDEX

  • Sintaksis

INDEX(array, row_num,[column_num])

  • Argumen

susunan: Kisaran dari mana ia akan menarik data.

row_num: Nomor baris data yang akan dikembalikan.

[column_num]: Nomor kolom data yang akan dikembalikan.

  • Tujuan

Fungsi INDEX mengambil nilai sel atau referensi sel yang terletak di persimpangan baris dan kolom tertentu dalam rentang tertentu.

Dalam dataset berikut ini, Penjualan Nate 17000 hadir di dalam 4 baris dan 3 kolom dalam kisaran B5:D10 .

Pengenalan ke Fungsi MATCH

  • Sintaksis

MATCH(lookup_value, lookup_array,[match_type])

  • Argumen

lookup_value: Nilai yang akan dicari dalam rentang data.

lookup_array : Kisaran data dari tempat ia akan mencari lookup_value .

[match_type]: - 1/0/1 . -1 adalah singkatan dari nilai yang lebih besar daripada yang sama persis, 0 untuk kecocokan yang tepat, dan 1 untuk nilai yang kurang dari kecocokan persis.

  • Tujuan

Fungsi MATCH mengembalikan posisi relatif dari lookup_value dalam sebuah larik.

Dalam dataset di bawah ini, file F4 nilai sel adalah Frank ( lookup_value ) dan Frank hadir di dalam 3 posisi dalam Penjual bagian ( B5:B10 ). Jadi ia mengembalikan 3 .

9 Contoh Penggunaan Rumus INDEX MATCH di Excel

Sekarang, kita akan membuat formula yang menggabungkan kedua fungsi tersebut. Kita sudah mengetahui bahwa fungsi INDEX membutuhkan nomor baris dan kolom untuk mengambil data, sedangkan fungsi PERTANDINGAN Jadi, kita dapat dengan mudah menempatkan argumennya untuk mendapatkan nomor baris dan kolom.

Dalam dataset berikut ini, yang INDEX akan menarik data dari B5:D10 . PERTANDINGAN fungsi mengembalikan nomor baris 3 dan kita telah menentukan nomor kolomnya. Jadi rumusnya akan mengeluarkan data yang ada di kolom 3 baris dan 3 kolom dalam kisaran.

1. Pencarian Dua Arah dengan INDEX MATCH di Excel

Dua Arah lookup berarti mengambil nomor baris dan nomor kolom dengan menggunakan PERTANDINGAN diperlukan untuk fungsi INDEX Oleh karena itu, ikuti langkah-langkah di bawah ini untuk melakukan tugas tersebut.

LANGKAH-LANGKAH:

  • Pertama, pilih sel F6 .
  • Kemudian, ketikkan rumusnya:
=INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

  • Terakhir, tekan Masuk dan itu akan mengembalikan nilainya.

🔎 Bagaimana Cara Kerja Formula ini?

  • COCOKKAN (F5, B5: B10, 0)

The PERTANDINGAN pengembalian rumus 3 untuk INDEX sebagai nomor baris.

  • COCOKKAN (F4, B4: D4, 0))

Ini PERTANDINGAN pengembalian rumus 3 untuk INDEX sebagai nomor kolom.

  • INDEX(B5:D10,MATCH(F5,B5:B10,0),MATCH(F4,B4:D4,0))

Terakhir, yang INDEX fungsi mengembalikan 13500 yang ada di dalam 3 baris dan 3 kolom dalam kisaran B5:D10 .

Baca Lebih Lanjut: SUMPRODUCT dengan Fungsi INDEX dan MATCH di Excel

2. Rumus INDEX MATCH untuk Mencari Kiri

Keuntungan utama dari INDEX MATCH adalah dapat mengambil data dari sisi kiri nilai pencarian. Jadi, pelajari langkah-langkah untuk melakukan operasi.

LANGKAH-LANGKAH:

  • Pertama, pilih sel F5 .
  • Berikutnya, ketikkan rumusnya:
=INDEX(B5:B10,MATCH(F4,C5:C10,0))

  • Akhirnya, tekan Masuk dan itu akan mengembalikan nilainya.

Di sini, formula mengembalikan Salesman nama yang berada di sisi kiri dari nilai pencarian Kabel .

🔎 Bagaimana Cara Kerja Formula ini?

  • COCOKKAN (F4, C5: C10, 0)

The PERTANDINGAN pengembalian rumus 1 untuk INDEX sebagai nomor baris.

  • INDEX(B5:B10,MATCH(F4,C5:C10,0))

Terakhir, yang INDEX fungsi mengembalikan Wilham yang ada di dalam 1 baris dalam kisaran B5:B10 .

Baca selengkapnya: Cara Menggunakan Rumus INDEX MATCH di Excel (9 Contoh)

3. Pencarian Peka Huruf Menggunakan Rumus INDEX MATCH

The PERTANDINGAN tidak peka huruf besar-kecil secara default. Namun, kita bisa menerapkan fungsi yang PERSIS untuk pencarian yang menghargai huruf besar dan kecil. Oleh karena itu, ikuti proses untuk Gunakan Rumus INDEX MATCH untuk melakukan Kasus - Pencarian Sensitif di Excel .

LANGKAH-LANGKAH:

  • Pada awalnya, pilih sel F5 .
  • Setelah itu, ketikkan rumusnya:
=INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

  • Pada akhirnya, tekan Masuk untuk mengembalikan nilai.

🔎 Bagaimana Cara Kerja Formula ini?

  • TEPAT (F4, B5: B10)

The PERSIS fungsi mengembalikan BENAR hanya untuk data pertama ( B5 ) dalam kisaran B5:B10 dan SALAH untuk orang lain.

  • COCOKKAN(BENAR,PERSIS(F4,B5:B10),0)

Ini PERTANDINGAN pengembalian rumus 1 untuk INDEX sebagai nomor baris.

  • INDEX(D5:D10,MATCH(TRUE,EXACT(F4,B5:B10),0))

Terakhir, yang INDEX fungsi mengembalikan 2600 yang ada di dalam 1 baris dalam kisaran D5:D10 .

Baca selengkapnya: Contoh dengan Rumus INDEX-MATCH di Excel (8 Pendekatan)

4. Gunakan INDEX MATCH untuk Kecocokan Terdekat

Terkadang, kita mungkin tidak mendapatkan kecocokan yang tepat dari nilai pencarian dalam array pencarian. Dalam hal ini, kita ingin mencari kecocokan yang paling dekat. Hal ini terutama terjadi pada nilai pencarian numerik. Sekarang, pelajari proses untuk menemukan nilai pencarian Pertandingan Terdekat menggunakan INDEX MATCH formula.

LANGKAH-LANGKAH:

  • Pilih sel F5 pada awalnya.
  • Kemudian, ketikkan rumusnya:
=INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

  • Terakhir, tekan Masuk .

🔎 Bagaimana Cara Kerja Formula ini?

  • ABS (D5: D10-F4)

Pertama, rumus ini mengurangi F4 nilai sel dari rentang D5:D10 untuk menghasilkan perbedaan dan kami menggunakan fungsi ABS untuk mengubah hasil negatif menjadi positif.

  • MIN(ABS(D5:D10-F4))

Kemudian, fungsi MIN mengembalikan perbedaan terkecil yaitu 500 .

  • MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0)

MIN(ABS(D5:D10-F4)) keluaran rumus adalah nilai pencarian ( 500 ) untuk PERTANDINGAN dan larik pencarian adalah ABS (D5: D10-F4) keluaran rumus.

  • INDEX(C5:C10,MATCH(MIN(ABS(D5:D10-F4)),ABS(D5:D10-F4),0))

Pada akhirnya, para INDEX fungsi mengembalikan Router karena memiliki yang paling dekat Penjualan Bersih jumlah untuk 5000 .

5. Pencarian Kriteria Ganda dengan Rumus INDEX MATCH

Salah satu operasi yang paling berguna dengan INDEX MATCH adalah bahwa ia dapat melakukan pencarian berdasarkan beberapa kondisi. Ikuti langkah-langkah di bawah ini untuk melihat bagaimana kita bisa mendapatkan Penjualan Bersih berdasarkan Penjual nama dan Produk .

LANGKAH-LANGKAH:

  • Pertama-tama, pilih sel F6 untuk mengetikkan rumus:
=INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

  • Selanjutnya, tekan Masuk dan Anda akan mendapatkan hasilnya.

🔎 Bagaimana Cara Kerja Formula ini?

  • MATCH(1,(F4=B5:B10)*(F5=C5:C10),0)

The PERTANDINGAN pengembalian rumus 2 untuk INDEX sebagai nomor baris. Di sini, kita membandingkan beberapa kriteria dengan menerapkan logika boolean.

  • INDEX(D5:D10,MATCH(1,(F4=B5:B10)*(F5=C5:C10),0))

Terakhir, yang INDEX fungsi mengembalikan 11500 yang ada di dalam 2 baris dalam kisaran D5:D10 .

Baca selengkapnya: Cara Menggunakan Rumus INDEX-MATCH di Excel untuk Menghasilkan Banyak Hasil

Bacaan Serupa

  • Beberapa Kriteria di Excel Menggunakan Fungsi INDEX, MATCH, dan COUNTIF
  • Cara menggunakan INDEX &; MATCH fungsi lembar kerja di Excel VBA
  • Indeks Excel Mencocokkan kriteria tunggal / ganda dengan hasil tunggal / ganda
  • INDEX MATCH di Beberapa Lembar di Excel (Dengan Alternatif)
  • SUMIF dengan Fungsi INDEX dan MATCH di Excel

6. Rumus INDEX MATCH Excel dengan Karakter Wildcard

Kita bisa menggunakan tanda bintang ( * ), yang merupakan Karakter Wildcard untuk menemukan kecocokan parsial untuk nilai pencarian. Lihat contoh di bawah ini untuk melakukan tugas tersebut. Kita memiliki Nat di dalam sel F4 Tidak ada Penjual dengan nama itu tetapi kami memiliki Nathan yang merupakan kecocokan parsial.

LANGKAH-LANGKAH:

  • Pertama, pilih sel F5 .
  • Setelah itu, ketikkan rumusnya:
=INDEX(D5:D10,MATCH(F4&"*",B5:B10,0))

  • Akhirnya, tekan Masuk dan itu akan mengembalikan Penjualan Bersih dari Nathan .

🔎 Bagaimana Cara Kerja Formula ini?

  • MATCH(F4& "*",B5:B10,0)

F4 & amp; "*" adalah nilai pencarian kita di mana tanda bintang adalah karakter wildcard yang mewakili sejumlah karakter yang dimulai dengan Nat Rumus mengembalikan 4 .

  • INDEX(D5:D10,MATCH(F4& "*",B5:B10,0))

Terakhir, yang INDEX fungsi mengembalikan 17000 yang ada di dalam 4 baris dalam kisaran D5:D10 .

Baca selengkapnya: INDEX MATCH Beberapa Kriteria dengan Wildcard di Excel (Panduan Lengkap)

7. Terapkan INDEX MATCH untuk Pencarian Tiga Arah di Excel

Penggunaan lanjutan dari INDEX MATCH formula adalah tentang melakukan Tiga Arah sintaks lain dari INDEX fungsinya adalah:

INDEX (array, row_num, [col_num], [area_num])

Di mana, [area_num] ( Opsional ) berarti Jika argumen array terdiri dari beberapa rentang, angka ini akan memilih referensi spesifik dari semua rentang.

Dalam contoh ini, kita akan menggunakan argumen opsional ini untuk mengembalikan data yang diinginkan dari salah satu bulan dari Januari , Februari dan Maret Oleh karena itu, ikuti langkah-langkah di bawah ini untuk Gunakan yang Rumus INDEX MATCH di Excel untuk Tiga Arah Pencarian .

LANGKAH-LANGKAH:

  • Pertama-tama, pilih sel F7 untuk mengetikkan rumus:
=INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januari",1,IF(F4="Februari",2,3))))

  • Berikutnya, tekan Masuk Dengan demikian, Anda akan melihat outputnya.

🔎 Bagaimana Cara Kerja Formula ini?

  • IF(F4="Januari",1,IF(F4="Februari",2,3))

Fungsi IF akan kembali 2 karena bulan yang kita berikan adalah Februari . INDEX akan mengambil nilai dari fungsi 2 larik, yaitu Februari .

  • COCOKKAN (F6, B5: D5, 0)

The PERTANDINGAN fungsi mengembalikan 3 .

  • COCOKKAN (F5, B6: B7, 0)

Ini PERTANDINGAN fungsi mengembalikan 2 .

  • INDEX((B6:D7,B11:D12,B16:D17),MATCH(F5,B6:B7,0),MATCH(F6,B5:D5,0),(IF(F4="Januari",1,IF(F4="Februari",2,3))))

Terakhir, yang INDEX fungsi mengembalikan 12500 yang berada di persimpangan dari 3 kolom dan 2 baris dari 2 susunan.

Baca selengkapnya: Cara Menggunakan INDEX MATCH Alih-alih VLOOKUP di Excel (3 Cara)

8. Ambil Nilai Seluruh Baris / Kolom dengan Rumus INDEX MATCH

Penerapan lain dari INDEX MATCH adalah mengambil data dari seluruh baris atau kolom. Jadi, pelajari prosedur untuk melakukan operasi.

LANGKAH-LANGKAH:

  • Pada awalnya, pilih sel F5 Di sini, ketikkan rumusnya:
=INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

  • Setelah itu, tekan Masuk dan itu akan menumpahkan data dari seluruh 3 baris dalam kisaran B5:D10 .

🔎 Bagaimana Cara Kerja Formula ini?

  • COCOKKAN (F4, B5: B10, 0)

The PERTANDINGAN pengembalian rumus 3 untuk INDEX sebagai nomor baris.

  • INDEX(B5:D10,MATCH(F4,B5:B10,0),0)

The INDEX fungsi mengembalikan semua nilai di dalam 3 baris dalam kisaran B5:D10 .

Baca selengkapnya: Indeks Cocokkan Jumlahkan Beberapa Baris di Excel (3 Cara)

9. Temukan Perkiraan Kecocokan Menggunakan INDEX MATCH

The INDEX MATCH sangat berguna ketika mencari tahu perkiraan kecocokan. Dalam contoh ini, kita akan menemukan produk untuk perkiraan Penjualan Bersih dari 6000 Oleh karena itu, ikuti prosesnya.

LANGKAH-LANGKAH:

  • Pertama, klik sel F5 .
  • Kemudian, ketikkan rumusnya:
=INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

  • Terakhir, tekan Masuk .

CATATAN: Data harus dalam Naik atau Turun agar formula ini berfungsi.

🔎 Bagaimana Cara Kerja Formula ini?

  • COCOKKAN (F4, D5: D10, 1)

The PERTANDINGAN penggunaan rumus 1 sebagai argumen tipe kecocokan yang akan mengembalikan nilai terbesar yang kurang dari atau sama dengan nilai pencarian 6000 . Di sini, ia akan kembali 2 .

  • INDEX(C5:C10,MATCH(F4,D5:D10,1),1)

The INDEX fungsi mengembalikan sebuah Router yang ada di dalam 2 baris dalam kisaran C5: C10 .

Baca selengkapnya: Cara Menggunakan INDEX dan Match untuk Pencocokan Sebagian (2 Cara)

Mengapa INDEX MATCH Lebih Bermanfaat daripada VLOOKUP?

1. Rumus INDEX MATCH Melihat Kedua Sisi Kiri-Kanan dari Nilai Pencarian

Fungsi VLOOKUP tidak bisa mengambil data dari sisi kiri nilai pencarian. Tetapi INDEX MATCH formula bisa melakukannya.

2. INDEX MATCH Bekerja dengan Rentang Vertikal dan Horizontal

VLOOKUP hanya dapat mengambil data dari larik vertikal, sedangkan INDEX MATCH bisa melalui data vertikal maupun horizontal.

3. VLOOKUP Gagal dengan Data Turun

The VLOOKUP fungsi tidak dapat menangani data dengan urutan menurun ketika sampai pada perkiraan kecocokan.

4. Formula dengan INDEX MATCH Sedikit Lebih Cepat

VLOOKUP adalah fungsi yang sedikit lebih lambat ketika bekerja dengan terlalu banyak baris dan kolom.

5. Independen dari Posisi Kolom Aktual

VLOOKUP tidak independen dari posisi kolom yang sebenarnya. Jadi, kapanpun Anda menghapus kolom, maka VLOOKUP akan memberikan hasil yang salah.

6. VLOOKUP Tidak Sulit Digunakan

The VLOOKUP lebih mudah digunakan dibandingkan dengan fungsi INDEX MATCH Dan sebagian besar operasi pencarian kita dapat dilakukan dengan VLOOKUP dengan mudah.

Baca selengkapnya: Fungsi INDEX MATCH vs VLOOKUP (9 Contoh)

Kesimpulan

Untuk selanjutnya, Anda akan dapat Gunakan yang Rumus INDEX MATCH di Excel Terus gunakan metode-metode tersebut di atas dan beri tahu kami jika Anda memiliki cara lain untuk melakukan tugas tersebut. Jangan lupa untuk memberikan komentar, saran, atau pertanyaan jika Anda memilikinya di bagian komentar di bawah ini.

Postingan sebelumnya Cara Menghitung Baris dengan VBA di Excel (5 Pendekatan)
Postingan berikutnya Temukan Teks dalam Rentang Excel dan Kembalikan Referensi Sel (3 Cara)

Hugh West adalah pelatih dan analis Excel yang sangat berpengalaman dengan pengalaman lebih dari 10 tahun di industri ini. Beliau meraih gelar Sarjana di bidang Akuntansi dan Keuangan dan gelar Master di bidang Administrasi Bisnis. Hugh memiliki hasrat untuk mengajar dan telah mengembangkan pendekatan pengajaran unik yang mudah diikuti dan dipahami. Pengetahuan ahlinya tentang Excel telah membantu ribuan siswa dan profesional di seluruh dunia meningkatkan keterampilan dan unggul dalam karier mereka. Melalui blognya, Hugh membagikan pengetahuannya kepada dunia, menawarkan tutorial Excel gratis dan pelatihan online untuk membantu individu dan bisnis mencapai potensi penuh mereka.