Enhavtabelo
La artikolo montras kelkajn mirindajn metodojn por kalkuli aĝon de naskiĝtago en Excel. Vi lernos kelkajn formulojn por kalkuli aĝon kiel nombro da kompletaj jaroj, kaj ankaŭ akiri realajn aĝojn en jaroj, monatoj kaj tagoj je la hodiaŭa dato aŭ certa dato. Nun ni gvidos vin tra tiuj facilaj kaj oportunaj metodoj pri kiel kalkuli aĝon de naskiĝtago en Excel.
Elŝutu Praktikan Laborlibron
Vi povas elŝuti la sekvan Excel-libron por pli bone kompreni kaj ekzerci vin mem. .
Kalkuli Aĝon de Naskiĝtago.xlsm8 Metodoj por Kalkuli Aĝon de Naskiĝtago en Excel
“He, kiom da aĝo vi havas ? “ Tre ofta demando. De nia infanaĝo, ni ĉiuj verŝajne aŭdis ĉi tiun demandon ofte. Sed, kion tio signifas? Ĝi kutime indikas respondon esprimanta kiom longe vi vivis.
Kvankam ne ekzistas dediĉita funkcio por kalkuli aĝon de naskiĝtago en Excel, ekzistas malmultaj alternativaj manieroj konverti la naskiĝdaton al aĝo.
Ni havas liston de Naskiĝtagoj de 10 individuoj.
Je ĉi-momente, ni kalkulos iliajn aĝojn en Excel el la naskiĝtagoj.
1. Uzante Bazan Formulon por Kalkuli Aĝon de Naskiĝtago en Excel
Unue, ni lernos la plej tradician manieron kalkuli aĝon en jaroj en Excel. Kio estas la plej ofta metodo por determini ies aĝon? Simple subtrahi lanaskiĝdato de la nuna dato. Ĉi tiu komuna formulo por kalkuli aĝon ankaŭ povas esti uzata en Excel. Sekvu la paŝojn zorge.
Paŝoj:
- Unue , elektu ĉelon D5 , enigu la suban formulon , kaj premu ENTER .
=(TODAY()-C5)/365.25 Ĉi tie, la C5 estas la komenca ĉelo de la Naskiĝtaga kolumno.
La funkcio HODIAŬ resendas la hodiaŭan daton. Nature, 1 jaro konsistas el 365 tagoj. Sed superjaro venas ĉiujn 4 jarojn, do ni dividas la datajn diferencojn per 365,25. Uzu la Plenigi Tenilon Ilon kaj trenu ĝin malsupren por kompletigi kolumnon D .
- Tiam, se vi volas montri la rezultojn en nur kompletaj jaroj, uzu la INT-funkcio .
=INT(D5) 
Noto: Certigu, ke ĉeloj D5:D14 estas formatitaj en Nombro aŭ Ĝenerala .
Legu Pli: Kiel Kalkuli Mezan Aĝon en Excel (7 Facilaj Metodoj)
2. Apliki Formula Kombinaĵon de IF, JARO, MONATO kaj NUN Funkcio
Ĉi tiu metodo aplikas formulon kombinante kelkajn apartajn funkciojn. Funkcioj IF , JARO , MONATO kaj NUN havas siajn proprajn operaciojn ĉi tie. Bonvolu sekvi la paŝojn sube.
Paŝoj:
- Unue, elektu ĉelon D5 kaj skribu la suban formulon, kaj premu ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo") 
Formula disfalo
Jen, MONATO kaj JARO funkcioj resendas la monaton kaj jaron de tiu dato kiel nombro. Ni uzis la IF-funkcion por enmeti logikan teston, ke, se la monato de la nuna dato estas pli granda ol la monato de naskiĝdato , tiam la formulo funkcias estas :
YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo" Alikaze, la resto de la formulo funkcios:
YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo" Noto: La malavantaĝo de ĉi tiu metodo estas, ke ĝi redonas 12 monatojn anstataŭ aldoni 1 jaron. Ni povas vidi tion en la kazo de Jones .
3. Kalkulado de Aĝo de Naskiĝjaro, Monato kaj Tago en Malsamaj Ĉeloj
Ĉi tie, ni ricevis nian naskiĝdaton en malsamaj ĉeloj dividante ilin en Jaro , Monato, kaj Tago .
El ĉi tiu tabelo , ni volas kalkuli ilian nunan aĝon. Sekvu niajn laborpaŝojn zorge.
Paŝoj:
- Unue, ni devas ricevi la naskiĝdaton uzante la DATO kaj DATEVALUE funkcioj. Por fari tion, ni uzis ĉi tiun formulon:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5) Tiu formulo kunfandis la malsamajn jarojn, monatojn kaj tagojn en unu ĉelon.
- Elektu ĉelon G5 kaj algluu la suban formulon.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days" 
Legu Pli: Kiel Kalkuli Aĝon en Excel en Jaroj kaj Monatoj (5 Facilaj Manieroj)
4. Efektivigo YEARFRAC-funkcio
Uzi la YEARFRAC-funkcion , kiu redonas frakcion de la jaro, ankaŭ estas fidinda aliro al kalkulo de aĝo de naskiĝtagoj enExcel. Sekvu la sekvajn paŝojn.
Paŝoj:
- Elektu ĉelon D5 kaj tajpu la suban formulon.
=YEARFRAC(C5,TODAY(),1) 
Ĉi tiu funkcio kalkulis la diferencon inter naskiĝtago kaj hodiaŭa dato. Ĉi tie ni prenas la bazon kiel 1 kiu signifas realan.
- Por montri la aĝon en kompletaj jaroj, uzu la INT-funkcion .
5. Adopti DATEDIF-Funkcion por Kalkuli Aĝon de Naskiĝtago en Excel
La plej oportuna kaj uzebla funkcio por kalkuli la aĝon estas la DATEDIF-funkcio . Sekvu la paŝojn detale.
Paŝoj:
- En la komenco, elektu ĉelon D5 kaj algluu la suban formulon, kaj premu ENIGU .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days" 
Formula disfalo
Por akiri la aĝon en jaroj, monatoj kaj tagoj ni uzis la argumentojn “Y” , “YM” , kaj “MD” sinsekve en la DATEDIF-funkcio . La ĉi-supra formulo liveras ununuran tekstan ĉenon kun 3 valoroj (jaroj, monatoj kaj tagoj) kunligitaj.
6. Kombinante IF kun DATEDIF-Funkcio por montri nur ne-nulajn valorojn
En nia antaŭa metodo, vi eble rimarkos problemon, ke estas 0 monatoj kaj 0 tagoj montrantaj en iuj ĉeloj.
Por eviti ĉi tiun problemon kaj montri nur ne-nulaj valoroj, ni povus fari iom da renovigo al nia antaŭa formulo kombinante la IF-funkcion . Por esti ĝisdatigita kun la nova formulo,observu zorge.
Paŝoj:
- Unue elektu ĉelon D5 kaj skribu la formulon jene, kaj premu ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days") 
Ĉi tiu formulo estas same kiel nia antaŭa formulo sed la nura diferenco estas tio se ekzistas iu nula valoro en jaroj, monatoj aŭ tagoj, tiuj esprimoj estos preterlasitaj. Uzante la IF-funkcion ni aplikis ĉi tiun kondiĉon por montri nur ne-nulajn valorojn.
7. Kalkulado de Aĝo ĉe Specifa Dato
En niaj antaŭaj metodoj, ni lernis kiel por kalkuli la nunan aĝon de la naskiĝtago. Nun, ni scios la proceduron de determini la aĝon en specifa dato.
Por antaŭdiri aĝon je specifa dato, ni uzis la DATEDIF-funkcio denove. De ĉi tio, vi evidente povas kompreni la oportunon uzi ĉi tiun funkcion. Sekvu la sekvajn paŝojn.
Paŝoj:
- Elektu ĉelon E5 kaj tajpu la suban formulon kaj premu ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days" 
La diferenco de niaj antaŭaj metodoj estas, ke tie ni kalkulis la aĝon ĝis la nuntempo. dato. Tiel, ni uzis la funkcion HODIAŬ . Sed ĉi tie ni ellaboras la aĝon en specifa dato, ne la nuna aĝo. Do ni uzas alian ĉelan referencon por la Findato .
Legu Pli: Kiel Kalkuli Aĝon Inter Du Datoj en Excel (6 Utilaj Metodoj)
8. Apliki VBA por Kalkuli Aĝon de Naskiĝtago enExcel
Alia maniero kalkuli aĝon en Excel el naskiĝtagoj estas uzi la VBA-kodon. Vi povas sekvi la paŝojn sube por kalkuli la aĝon per ĉi tiu metodo.
Paŝoj:
- Alklaku dekstre sur la Nomo de la foliaro kaj elektu Vidi Kodon .
- Tuj malfermiĝas la fenestro de Microsoft Visual Basic por Aplikoj. Dekstre alklaku Sheet9 (VBA) > elektu Enmeti > Modulo.
- Ĝi malfermas kodan modulon, kie algluu la suban kodon malsupren kaj alklaku la butonon Run aŭ premu F5.
6505
- Nun fermante la kodan modulon revenu reen al la laborfolio. Vi povas vidi, ke D5:D14 ĉeloj aŭtomate pleniĝis kun la aĝo en jaroj. En la formulbreto, ni povas vidi la DATEDIF-funkcion kiun ni uzis en nia VBA-kodo .
Eltrovi la Daton Kiam Persono Atingas Iun Aĝon
Ni diru, la naskiĝdato de Robin estas 13-08-1996. Kiam li atingus siajn 50 jarojn? Kiel vi scias tion? Nenio zorgi pri se vi ne sciis ĝin pli frue. Nur zorge rigardu niajn paŝojn.
Paŝoj:
- Unue elektu ĉelon D5 kaj skribu la formulon jene, poste premu ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5)) 
Jen, ni ĵus aldonis 50 kun la jaro de la naskiĝdato. Poste, ĝi revenas en la Dato de Atingo de 50 JarojAĝo .
Konkludo
Dankon pro legi ĉi tiun artikolon, ni esperas, ke tio estis helpema. Bonvolu sciigi nin en la komenta sekcio se vi havas demandojn aŭ sugestojn. Bonvolu viziti nian retejon Exceldemy por esplori pli.
