Com calcular l'edat des de l'aniversari a Excel (8 mètodes fàcils) -

Hugh West

16-10-2023 Fórmules Excel
  • Comparteix Això
Hugh West

L'article mostra alguns mètodes sorprenents per calcular l'edat a partir d'un aniversari a Excel. Aprendràs algunes fórmules per calcular l'edat com a nombre d'anys complets, així com per obtenir edats reals en anys, mesos i dies a la data d'avui o a una data determinada. Ara, us guiarem a través d'aquests mètodes fàcils i còmodes sobre com calcular l'edat des de l'aniversari a Excel.

Baixeu el quadern de pràctiques

Podeu descarregar el següent quadern de treball d'Excel per entendre's millor i practicar-lo. .

Calcul de l'edat a partir de l'aniversari.xlsm

8 mètodes per calcular l'edat a partir de l'aniversari a Excel

“Ei, quants anys tens ? " Una pregunta molt freqüent. Des de la nostra infantesa, tots hem d'haver sentit aquesta pregunta amb freqüència. Però, què vol dir això? Normalment indica una resposta que expressa quant de temps portes viu.

Tot i que no hi ha cap funció dedicada per calcular l'edat des de l'aniversari a Excel, hi ha un poques maneres alternatives de convertir la data de naixement en edat.

Tenim una llista de Aniversaris de 10 persones.

A en aquest moment, calcularem les seves edats a Excel a partir dels aniversaris.

1. Ús de la fórmula bàsica per calcular l'edat a partir de l'aniversari a Excel

Al principi, aprendrem de la manera més tradicional. per calcular l'edat en anys a Excel. Quin és el mètode més comú per determinar l'edat d'una persona? Simplement restadata de naixement a partir de la data actual. Aquesta fórmula comuna per calcular l'edat també es pot utilitzar a Excel. Seguiu els passos amb cura.

Passos:

  • Primer , seleccioneu la cel·la D5 , introduïu la fórmula següent , i premeu ENTER .
=(TODAY()-C5)/365.25

Aquí, el C5 és la cel·la inicial del Columna Aniversari.

La funció AVUI retorna la data d'avui. Naturalment, 1 any consta de 365 dies. Però l'any de traspàs arriba cada 4 anys, de manera que dividim les diferències de dates per 365,25. Utilitzeu l'eina Emplenar mànec i arrossegueu-la cap avall per completar la columna D .

  • A continuació, si voleu mostrar els resultats en anys complets, utilitzeu el Funció INT .
=INT(D5)

Nota: Assegureu-vos que les cel·les D5:D14 tinguin el format Número o General .

Llegir més: Com calcular l'edat mitjana a Excel (7 mètodes fàcils)

2. Aplicació de la combinació de fórmules de la funció SI, ANY, MES i ARA

Aquest mètode aplica una fórmula combinant algunes funcions diferents. Les funcions IF , YEAR , MES i ARA tenen les seves pròpies operacions aquí. Si us plau, seguiu els passos següents.

Passos:

  • En primer lloc, seleccioneu la cel·la D5 i anoteu la fórmula següent i toqueu ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo")

Desglossament de la fórmula

Aquí, MES i ANY les funcions retornen el mes i l'any d'aquesta data com a nombre. Hem utilitzat la funció SI per inserir una prova lògica que, si el mes de la data actual és més gran que el mes de data de naixement , aleshores la fórmula funciona és :

YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo"

En cas contrari, la resta de la fórmula funcionarà:

YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo"

Nota: L'inconvenient d'aquest mètode és que retorna 12 mesos en lloc d'afegir 1 any. Ho podem veure en el cas de Jones .

3. Càlcul de l'edat a partir de l'any de naixement, el mes i el dia en diferents cel·les

Aquí tenim la nostra data de naixement a diferents cel·les dividint-les en Any , Mes i Dia .

A partir d'aquesta taula , volem calcular la seva edat actual. Seguiu els nostres passos de treball amb cura.

Passos:

  • En primer lloc, hem d'obtenir la data de naixement utilitzant DATA i Funcions DATEVALUE . Per fer-ho, hem utilitzat aquesta fórmula:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5)

Aquesta fórmula va fusionar els diferents anys, mesos i dies en una sola cel·la.

  • Seleccioneu la cel·la G5 i enganxeu la fórmula següent.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "&  DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days"

Llegir més: Com calcular l'edat a Excel en anys i mesos (5 maneres senzilles)

4. Implementació Funció YEARFRAC

Utilitzar la funció YEARFRAC , que retorna una fracció de l'any, també és un enfocament fiable per calcular l'edat dels aniversaris enSobresortir. Seguiu els passos següents.

Passos:

  • Seleccioneu la cel·la D5 i escriviu la fórmula següent.
=YEARFRAC(C5,TODAY(),1)

Aquesta funció calcula la diferència entre l'aniversari i la data d'avui. Aquí prenem la base com a 1, que significa real.

  • Per mostrar l'edat en anys complets, utilitzeu la funció INT .

5. Adopció de la funció DATEDIF per calcular l'edat des de l'aniversari a Excel

La funció més còmoda i utilitzable per calcular l'edat és la funció DATEDIF . Seguiu els passos a fons.

Passos:

  • Al principi, seleccioneu la cel·la D5 i enganxeu la fórmula següent i premeu ENTER .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days"

Desglossament de la fórmula

Per obtenir l'edat en anys, mesos i dies hem utilitzat els arguments “Y” , “YM” i “MD” seqüencialment a la funció DATEDIF . La fórmula anterior retorna una única cadena de text amb 3 valors (anys, mesos i dies) concatenats.

6. Combinant IF amb la funció DATEDIF per mostrar només valors diferents de zero

En el nostre anterior mètode, és possible que observeu un problema que es mostren 0 mesos i 0 dies en algunes cel·les.

Per evitar aquest problema i mostrar només valors diferents de zero, podríem fer alguna renovació a la nostra fórmula anterior combinant la funció SI . Per estar actualitzat amb la nova fórmula,observeu amb cura.

Passos:

  • Primer, seleccioneu la cel·la D5 i anoteu la fórmula de la següent manera i premeu ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days")

Aquesta fórmula és com la nostra anterior, però l'única diferència és que si hi ha un valor zero en anys, mesos o dies, aquests termes s'ometran. Utilitzant la funció SI vam aplicar aquesta condició per mostrar només valors diferents de zero.

7. Càlcul de l'edat en una data específica

En els nostres mètodes anteriors, vam aprendre com per calcular l'edat actual a partir de l'aniversari. Ara coneixerem el procediment per determinar l'edat en una data específica.

Per predir l'edat en una data específica, hem utilitzat el Funció DATEDIF de nou. A partir d'això, òbviament, podeu entendre la comoditat d'utilitzar aquesta funció. Seguiu els passos següents.

Passos:

  • Seleccioneu la cel·la E5 i escriviu la fórmula següent i premeu ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days"

La diferència amb els nostres mètodes anteriors és que allà vam calcular l'edat fins al present data. Així, hem utilitzat la funció TODAY . Però aquí treballem l'edat en una data específica, no l'edat actual. Per tant, utilitzem una altra referència de cel·la per a la Data de finalització .

Llegir més: Com calcular l'edat entre dues dates a Excel (6 mètodes útils)

8. Aplicació de VBA per calcular l'edat des de l'aniversari aExcel

Una altra manera de calcular l'edat a Excel a partir dels aniversaris és utilitzar el codi VBA. Podeu seguir els passos següents per calcular l'edat amb aquest mètode.

Pasos:

  • Feu clic amb el botó dret al Nom del full i seleccioneu Mostra el codi .

  • S'obre a l'instant la finestra de Microsoft Visual Basic per a aplicacions. Feu clic amb el botó dret a Full9 (VBA) > seleccioneu Insereix > Mòdul.

  • Obre un mòdul de codi, on enganxeu el codi següent cap avall i feu clic al botó Executar o premeu F5. 
4457
  • Ara tancant el mòdul de codi, torneu al full de treball. Podeu veure que les cel·les D5:D14 s'han omplert automàticament amb l'edat en anys. A la barra de fórmules, podem veure la funció DATEDIF que hem utilitzat al nostre codi VBA .

Esbrinar la data en què una persona arriba a una edat determinada

Diguem que la data de naixement de Robin és el 13-08-1996. Quan arribaria als 50 anys? Com ho saps això? Res de què preocupar-se si no ho sabia abans. Només cal que mireu els nostres passos amb atenció.

Passos:

  • Primer, seleccioneu la cel·la D5 i anoteu la fórmula de la següent manera i, a continuació, premeu ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5))

Aquí, acabem d'afegir 50 amb l'any de la data de naixement. Finalment, torna a la data d'assolir els 50 anysEdat .

Conclusió

Gràcies per llegir aquest article, esperem que hagi estat útil. Feu-nos-ho saber a la secció de comentaris si teniu cap consulta o suggeriment. Visiteu el nostre lloc web Exceldemy per explorar-ne més.

Publicació anterior Com fer tabulacions creuades a Excel (3 exemples adequats)
Següent post Com convertir la data a l'any a Excel (3 maneres ràpides)

Hugh West és un entrenador i analista d'Excel molt experimentat amb més de 10 anys d'experiència en el sector. És llicenciat en Comptabilitat i Finances i Màster en Administració i Direcció d'Empreses. Hugh té una passió per l'ensenyament i ha desenvolupat un enfocament pedagògic únic que és fàcil de seguir i entendre. El seu coneixement expert d'Excel ha ajudat a milers d'estudiants i professionals de tot el món a millorar les seves habilitats i a destacar en les seves carreres. A través del seu bloc, Hugh comparteix els seus coneixements amb el món, oferint tutorials d'Excel gratuïts i formació en línia per ajudar les persones i les empreses a assolir tot el seu potencial.