Cara Mengira Umur dari Hari Lahir dalam Excel (8 Kaedah Mudah) -

Hugh West

16-10-2023 Formula Excel
  • Berkongsi Ini
Hugh West

Artikel menunjukkan beberapa kaedah yang menakjubkan untuk mengira umur daripada hari lahir dalam Excel. Anda akan mempelajari beberapa formula untuk mengira umur sebagai bilangan tahun lengkap, serta mendapatkan umur sebenar dalam tahun, bulan dan hari pada tarikh hari ini atau tarikh tertentu. Kini, kami akan membawa anda melalui kaedah yang mudah dan mudah tentang cara mengira umur dari hari lahir dalam Excel.

Muat Turun Buku Kerja Amalan

Anda boleh memuat turun buku kerja Excel berikut untuk memahami dan mengamalkan diri anda dengan lebih baik .

Mengira Umur daripada Hari Lahir.xlsm

8 Kaedah untuk Mengira Umur daripada Hari Lahir dalam Excel

“Hei, berapa umur anda ? “ Soalan yang sering ditanya. Dari zaman kanak-kanak, kita semua pasti sering mendengar soalan ini. Tetapi, apakah maksudnya? Ia biasanya menandakan respons yang menyatakan berapa lama anda telah hidup.

Walaupun tiada fungsi khusus untuk mengira umur daripada hari lahir dalam Excel, terdapat beberapa cara alternatif untuk menukar tarikh lahir kepada umur.

Kami mempunyai senarai Hari Lahir daripada 10 individu.

Pada Pada masa ini, kita akan mengira umur mereka dalam Excel daripada hari lahir.

1. Menggunakan Formula Asas untuk Mengira Umur daripada Hari Lahir dalam Excel

Pada mulanya, kita akan mempelajari cara yang paling tradisional untuk mengira umur dalam tahun dalam Excel. Apakah kaedah yang paling biasa untuk menentukan umur seseorang? Hanya tolaktarikh lahir dari tarikh semasa. Formula biasa untuk mengira umur ini juga boleh digunakan dalam Excel. Ikuti langkah dengan berhati-hati.

Langkah:

  • Pertama , pilih sel D5 , masukkan formula di bawah , dan tekan ENTER .
=(TODAY()-C5)/365.25

Di sini, C5 ialah sel permulaan Lajur Hari Lahir.

Fungsi HARI INI mengembalikan tarikh hari ini. Sememangnya, 1 tahun terdiri daripada 365 hari. Tetapi tahun lompat datang setiap 4 tahun, jadi kami membahagikan perbezaan tarikh dengan 365.25. Gunakan Alat Fill Handle dan seretnya ke bawah untuk melengkapkan lajur D .

  • Kemudian, jika anda mahu memaparkan keputusan dalam beberapa tahun sahaja, gunakan Fungsi INT .
=INT(D5)

Nota: Pastikan sel D5:D14 diformatkan dalam Nombor atau Umum .

Baca Lagi: Cara Mengira Purata Umur dalam Excel (7 Kaedah Mudah)

2. Menggunakan Formula Gabungan Fungsi IF, YEAR, MONTH dan NOW

Kaedah ini menggunakan formula menggabungkan beberapa fungsi yang berbeza. Fungsi JIKA , TAHUN , BULAN dan SEKARANG mempunyai operasi sendiri di sini. Sila ikut langkah di bawah.

Langkah:

  • Mula-mula, pilih sel D5 dan tulis formula di bawah, dan ketik MASUK .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo")

Pecahan Formula

Di sini, BULAN dan TAHUN fungsi mengembalikan bulan dan tahun tarikh itu sebagai nombor. Kami menggunakan Fungsi JIKA untuk memasukkan ujian logik bahawa, jika bulan tarikh sekarang lebih besar daripada bulan tarikh lahir , maka formula itu berfungsi :

YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo"

Jika tidak, formula yang lain akan berfungsi:

YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo"

Nota: Kelemahan kaedah ini ialah ia mengembalikan 12 bulan dan bukannya menambah 1 tahun. Kita dapat melihatnya dalam kes Jones .

3. Mengira Umur dari Tahun Lahir, Bulan dan Hari dalam Sel Berbeza

Di sini, kami mendapat tarikh lahir kami dalam sel yang berbeza dengan membahagikannya kepada Tahun , Bulan, dan Hari .

Daripada jadual ini , kami ingin mengira umur mereka sekarang. Ikuti langkah kerja kami dengan berhati-hati.

Langkah:

  • Pertama, kami perlu mendapatkan tarikh lahir menggunakan TARIKH dan DATEVALUE fungsi. Untuk berbuat demikian, kami menggunakan formula ini:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5)

Formula ini menggabungkan tahun, bulan dan hari yang berbeza ke dalam satu sel.

  • Pilih sel G5 dan tampalkan formula di bawah.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "&  DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days"

Baca Lagi: Cara Mengira Umur dalam Excel dalam Tahun dan Bulan (5 Cara Mudah)

4. Melaksanakan Fungsi YEARFRAC

Menggunakan fungsi YEARFRAC , yang mengembalikan sebahagian kecil tahun, juga merupakan pendekatan yang boleh dipercayai untuk mengira umur daripada hari lahir dalamExcel. Ikut langkah di bawah.

Langkah:

  • Pilih sel D5 dan taip formula di bawah.
=YEARFRAC(C5,TODAY(),1)

Fungsi ini mengira perbezaan antara hari lahir dan tarikh hari ini. Di sini kita mengambil asas sebagai 1 yang bermaksud sebenar.

  • Untuk menunjukkan umur dalam tahun yang lengkap, gunakan fungsi INT .

5. Mengguna pakai Fungsi DATEDIF untuk Mengira Umur daripada Hari Lahir dalam Excel

Fungsi yang paling mudah dan boleh digunakan untuk mengira umur ialah fungsi DATEDIF . Ikuti langkah-langkah dengan teliti.

Langkah:

  • Pada mulanya, pilih sel D5 dan tampalkan formula di bawah dan tekan MASUK .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days"

Pecahan Formula

Untuk mendapatkan umur dalam tahun, bulan dan hari kami telah menggunakan hujah “Y” , “YM” dan “MD” secara berurutan dalam fungsi DATEDIF . Formula di atas mengembalikan rentetan teks tunggal dengan 3 nilai (tahun, bulan dan hari) digabungkan.

6. Menggabungkan IF dengan Fungsi DATEDIF untuk Memaparkan Nilai Bukan Sifar Sahaja

Dalam sebelumnya kaedah, anda mungkin melihat masalah yang terdapat 0 bulan dan 0 hari ditunjukkan dalam beberapa sel.

Untuk mengelakkan masalah ini dan hanya memaparkan nilai bukan sifar, kami boleh lakukan beberapa pengubahsuaian kepada formula kami sebelum ini dengan menggabungkan Fungsi JIKA . Untuk dikemas kini dengan formula baharu,amati dengan teliti.

Langkah:

  • Mula-mula, pilih sel D5 dan tulis formula seperti berikut dan tekan ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days")

Formula ini sama seperti formula kami sebelum ini tetapi satu-satunya perbezaan ialah jika terdapat sebarang nilai sifar dalam tahun, bulan atau hari, syarat tersebut akan ditinggalkan. Menggunakan Fungsi IF kami menggunakan syarat ini untuk memaparkan nilai bukan sifar sahaja.

7. Mengira Umur pada Tarikh Tertentu

Dalam kaedah kami yang terdahulu, kami mempelajari cara untuk mengira umur sekarang dari hari lahir. Sekarang, kita akan mengetahui prosedur menentukan umur pada tarikh tertentu.

Untuk meramal umur pada tarikh tertentu, kami menggunakan Fungsi DATEDIF sekali lagi. Daripada ini, anda jelas dapat memahami kemudahan menggunakan fungsi ini. Ikut langkah di bawah.

Langkah:

  • Pilih sel E5 dan taip formula di bawah dan tekan ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days"

Perbezaan daripada kaedah kami sebelum ini ialah di sana kami mengira umur sehingga sekarang Tarikh. Oleh itu, kami menggunakan fungsi HARI INI . Tetapi di sini kita menentukan umur pada tarikh tertentu, bukan zaman sekarang. Jadi kami menggunakan rujukan sel lain untuk Tarikh Tamat .

Baca Lagi: Cara Mengira Umur Antara Dua Tarikh dalam Excel (6 Kaedah Berguna)

8. Menggunakan VBA untuk Mengira Umur dari Hari Lahir dalamExcel

Cara lain untuk mengira umur dalam Excel daripada hari lahir ialah menggunakan kod VBA. Anda boleh mengikuti langkah di bawah untuk mengira umur menggunakan kaedah ini.

Langkah:

  • Klik kanan pada Nama helaian dan pilih Lihat Kod .

  • Semerta, tetingkap Microsoft Visual Basic for Applications dibuka. Klik kanan pada Sheet9 (VBA) > pilih Sisipkan > Modul.

  • Ia membuka modul kod, dengan tampal kod di bawah ke bawah dan klik pada butang Jalankan atau tekan F5. 
1178
  • Sekarang tutup modul kod kembali ke lembaran kerja. Anda boleh melihat bahawa D5:D14 sel telah diisi secara automatik dengan umur dalam tahun. Dalam bar formula, kita boleh melihat Fungsi DATEDIF yang telah kami gunakan dalam kod VBA kami.

Mengetahui Tarikh Apabila Seseorang Mencapai Umur Tertentu

Katakanlah, tarikh lahir Robin ialah 13-08-1996. Bilakah dia akan mencapai umur 50 tahun? Bagaimana anda tahu bahawa? Tiada apa yang perlu dibimbangkan jika anda tidak mengetahuinya lebih awal. Hanya perhatikan langkah kami dengan teliti.

Langkah:

  • Pertama, pilih sel D5 dan tulis formula seperti berikut, kemudian tekan MASUK .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5))

Di sini, kami baru sahaja menambah 50 dengan tahun daripada tarikh lahir. Akhirnya, ia kembali pada Tarikh Mencapai 50 TahunUmur .

Kesimpulan

Terima kasih kerana membaca artikel ini, kami harap ini berguna. Sila beritahu kami di bahagian komen jika anda mempunyai sebarang pertanyaan atau cadangan. Sila lawati tapak web kami Exceldemy untuk meneroka lebih lanjut.

Catatan sebelum ini Cara Melakukan Tabulasi Silang dalam Excel (3 Contoh yang Sesuai)
Post seterusnya Cara Menukar Tarikh kepada Tahun dalam Excel (3 Cara Pantas)

Hugh West ialah jurulatih dan penganalisis Excel yang sangat berpengalaman dengan lebih 10 tahun pengalaman dalam industri. Beliau memiliki Ijazah Sarjana Muda Perakaunan dan Kewangan serta Ijazah Sarjana dalam Pentadbiran Perniagaan. Hugh mempunyai minat untuk mengajar dan telah membangunkan pendekatan pengajaran yang unik yang mudah diikuti dan difahami. Pengetahuan pakar Excel beliau telah membantu beribu-ribu pelajar dan profesional di seluruh dunia meningkatkan kemahiran mereka dan cemerlang dalam kerjaya mereka. Melalui blognya, Hugh berkongsi pengetahuannya dengan dunia, menawarkan tutorial Excel percuma dan latihan dalam talian untuk membantu individu dan perniagaan mencapai potensi penuh mereka.