Содржина
Написот покажува неколку неверојатни методи за пресметување на возраст од роденден во Excel. Ќе научите неколку формули за пресметување на возраста како број на целосни години, како и добивање на вистинска возраст во години, месеци и денови на денешниот датум или одреден датум. Сега, ќе ве водиме низ оние лесни и практични методи за тоа како да ја пресметате возраста од роденден во Excel.
Преземете ја работната книга за вежбање
Можете да ја преземете следната работна книга на Excel за подобро разбирање и вежбање .
Пресметување возраст од роденден.xlsm8 методи за пресметување возраст од роденден во Excel
„Еј, колку години имаш ? „ Многу често поставувано прашање. Од нашето детство, сите сигурно сме го слушале ова прашање често. Но, што значи тоа? Обично означува одговор кој изразува колку долго сте живи.
Иако не постои посебна функција за пресметување возраст од роденден во Excel, постојат неколку алтернативни начини за претворање на датумот на раѓање во возраст.
Имаме листа на Родендени од 10 поединци.
На овој момент, ќе ги пресметаме нивните возрасти во Excel од родендените.
1. Користење на основната формула за пресметување возраст од роденден во Excel
На почетокот, ќе научиме на најтрадиционалниот начин да се пресмета возраста во години во Excel. Кој е најчестиот метод за одредување на нечија возраст? Едноставно одземете јадатум на раѓање од тековниот датум. Оваа вообичаена формула за пресметување на возраста може да се користи и во Excel. Следете ги чекорите внимателно.
Чекори:
- Прво , изберете ја ќелијата D5 , внесете ја формулата подолу , и притиснете ENTER .
=(TODAY()-C5)/365.25 Тука, C5 е почетната ќелија на Роденден колона.
Функцијата ДЕНЕС го враќа денешниот датум. Нормално, 1 година се состои од 365 дена. Но, престапната година доаѓа на секои 4 години, така што разликите во датумите ги делиме со 365,25. Користете ја алатката Рачка за пополнување и повлечете ја надолу за да ја пополните колоната D .
- Потоа, ако сакате да ги прикажете резултатите за само цели години, користете ја INT функција .
=INT(D5) 
Забелешка: Осигурете се дека ќелиите D5:D14 се форматирани во Број или Општо .
Прочитајте повеќе: Како да се пресмета просечната возраст во Excel (7 лесни методи)
2. Примена на комбинација на формули на функциите IF, YEAR, MONTH и NOW
Овој метод применува формула комбинирање на некои различни функции. Функциите АКО , ГОДИНА , МЕСЕЦ и СЕГА имаат свои операции овде. Ве молиме следете ги чекорите подолу.
Чекори:
- Прво, изберете ја ќелијата D5 и запишете ја формулата подолу и допрете ВНЕСЕТЕ .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo") 
Разложување на формулата
Еве, МЕСЕЦ и ГОДИНА функциите ги враќаат месецот и годината на тој датум како број. Ја користевме функцијата IF за да вметнеме логички тест дека, ако месецот на сегашниот датум е поголем од месецот на датумот на раѓање , тогаш формулата работи е :
YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo" Во спротивно, остатокот од формулата ќе работи:
YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo" Забелешка: Недостатокот на овој метод е што враќа 12 месеци наместо да додаде 1 година. Тоа можеме да го видиме во случајот Џонс .
3. Пресметување возраст од годината, месецот и денот на раѓање во различни ќелии
Еве, го добивме нашиот датум на раѓање во различни ќелии со делење на Година , Месец, и Ден .
Од оваа табела , сакаме да ја пресметаме нивната сегашна возраст. Следете ги нашите работни чекори внимателно.
Чекори:
- Прво, треба да го добиеме датумот на раѓање користејќи ги DATE и Функциите на DATEVALUE . За да го сториме тоа, ја користевме оваа формула:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5) Оваа формула ги спои различните години, месеци и денови во една ќелија.
0> 
- Изберете ја ќелијата G5 и залепете ја формулата подолу.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days" 
Прочитај повеќе: Како да се пресмета возраста во Excel во години и месеци (5 лесни начини)
4. Спроведување Функција YEARFRAC
Користењето на функцијата YEARFRAC , која враќа дел од годината, е исто така сигурен пристап за пресметување возраст од родендени воExcel. Следете ги чекорите подолу.
Чекори:
- Изберете ја ќелијата D5 и напишете ја формулата подолу.
=YEARFRAC(C5,TODAY(),1) 
Оваа функција ја пресмета разликата помеѓу роденденот и денешниот датум. Овде ја земаме основата како 1 што значи вистинска.
- За прикажување на возраста во цели години, користете ја функцијата INT .
5. Усвојување на функцијата DATEDIF за пресметување возраст од роденден во Excel
Најпогодната и најкорисна функција за пресметување на возраста е функцијата DATEDIF . Следете ги чекорите темелно.
Чекори:
- На почетокот, изберете ја ќелијата D5 и залепете ја формулата подолу и притиснете ВНЕСЕТЕ .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days" 
Разложување на формулата
За да ја добиеме возраста во години, месеци и денови, ги користевме аргументите „Y“ , „YM“ и „MD“ последователно во функцијата DATEDIF . Формулата погоре враќа единечна текстуална низа со 3 вредности (години, месеци и денови) споени.
6. Комбинирање на IF со функцијата DATEDIF за прикажување само не-нула вредности
Во нашите претходни метод, може да забележите проблем дека во некои ќелии се прикажуваат 0 месеци и 0 дена.
За да го избегнеме овој проблем и да прикажеме само не-нула вредности, би можеле да направиме некое обновување на нашата претходна формула со комбинирање на функцијата IF . За да се ажурирате со новата формула,набљудувајте внимателно.
Чекори:
- Прво, изберете ја ќелијата D5 и запишете ја формулата на следниов начин и притиснете ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days") 
Оваа формула е исто како и нашата претходна формула, но единствената разлика е во тоа што ако има нулта вредност во години, месеци или денови, тие термини ќе бидат испуштени. Користејќи ја функцијата IF ја применивме оваа состојба за да прикажеме само вредности кои не се нула.
7. Пресметување возраст на одреден датум
Во нашите претходни методи, научивме како да се пресмета сегашната возраст од роденденот. Сега, ќе ја знаеме постапката за одредување на возраста на одреден датум.
За претскажување возраст на одреден датум, користевме Функција DATEDIF повторно. Од ова, очигледно можете да ја разберете практичноста за користење на оваа функција. Следете ги чекорите подолу.
Чекори:
- Изберете ја ќелијата E5 и напишете ја формулата подолу и притиснете ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days" 
Разликата од нашите претходни методи е што таму ја пресметавме возраста до денес датум. Така, ја користевме функцијата ДЕНЕС . Но, овде ја разработуваме возраста на одреден датум, а не сегашната возраст. Значи, ние користиме друга референца за ќелија за Крајниот датум .
Прочитајте повеќе: Како да се пресмета возраста помеѓу два датума во Excel (6 корисни методи)
8. Примена на VBA за пресметување на возраст од роденден воExcel
Друг начин за пресметување возраст во Excel од родендени е да се користи кодот VBA. Можете да ги следите чекорите подолу за да ја пресметате возраста користејќи го овој метод.
Чекори:
- Десен-клик на Име на листот и изберете Прегледај код .
- Веднаш, се отвора прозорецот Microsoft Visual Basic за апликации. Десен-клик на Лист 9 (VBA) > изберете Вметни > Модул.
- Се отвора модул за код, каде што се залепува долунаведениот код надолу и кликнете на копчето Стартувај или притиснете F5.
3199
- Сега затворајќи го модулот за код, вратете се на работниот лист. Можете да видите дека D5:D14 клетките автоматски се пополнуваат со возраста во години. Во лентата со формула, можеме да ја видиме функцијата DATEDIF што ја користевме во нашиот VBA код .
Откривање на датумот кога едно лице ќе достигне одредена возраст
Да речеме, датумот на раѓање на Робин е 13.08.1996. Кога ќе наполни 50 години? Како го знаеш тоа? Нема што да се грижите ако не сте знаеле порано. Само внимателно следете ги нашите чекори.
Чекори:
- Прво, изберете ја ќелијата D5 и запишете ја формулата на следниов начин, а потоа притиснете ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5)) 
Еве, штотуку додадовме 50 со годината на датумот на раѓање. На крајот, се враќа на Датумот на достигнување 50 годиниВозраст .
Заклучок
Ви благодариме што ја прочитавте оваа статија, се надеваме дека ова беше корисно. Ве молиме известете не во делот за коментари доколку имате какви било прашања или предлози. Ве молиме посетете ја нашата веб-локација Exceldemy за да истражите повеќе.
