Hoe om ouderdom vanaf verjaarsdag in Excel te bereken (8 maklike metodes) -

Hugh West

16-10-2023 Excel Formules
  • Deel Dit
Hugh West

Die artikel demonstreer 'n paar wonderlike metodes om ouderdom vanaf 'n verjaarsdag in Excel te bereken. Jy sal 'n paar formules leer om ouderdom as 'n aantal volledige jare te bereken, asook om werklike ouderdomme in jare, maande en dae op vandag se datum of 'n sekere datum te kry. Nou sal ons jou deur daardie maklike en gerieflike metodes neem oor hoe om ouderdom vanaf verjaarsdag in Excel te bereken.

Laai Oefenwerkboek af

Jy kan die volgende Excel-werkboek aflaai om jouself beter te verstaan ​​en te oefen .

Bereken ouderdom vanaf verjaarsdag.xlsm

8 metodes om ouderdom vanaf verjaarsdag in Excel te bereken

“Haai, hoe oud is jy ? “ 'n Baie algemene vraag. Van ons kinderdae af moes ons almal hierdie vraag gereeld gehoor het. Maar, wat beteken dit? Dit dui gewoonlik 'n antwoord aan wat uitdruk hoe lank jy nog lewe.

Alhoewel daar geen toegewyde funksie is om ouderdom vanaf verjaarsdag in Excel te bereken nie, is daar 'n min alternatiewe maniere om die geboortedatum na ouderdom om te skakel.

Ons het 'n lys van Verjaarsdae van 10 individue.

By op hierdie oomblik sal ons hul ouderdomme in Excel vanaf die verjaarsdae bereken.

1. Gebruik basiese formule om ouderdom vanaf verjaarsdag in Excel te bereken

Aanvanklik sal ons die mees tradisionele manier leer ouderdom in jare in Excel te bereken. Wat is die algemeenste metode om iemand se ouderdom te bepaal? Trek eenvoudig diegeboortedatum vanaf die huidige datum. Hierdie algemene formule vir die berekening van ouderdom kan ook in Excel gebruik word. Volg die stappe noukeurig.

Stappe:

  • Kies eers sel D5 , voer die formule hieronder in , en druk ENTER .
=(TODAY()-C5)/365.25

Hier is die C5 die beginsel van die Verjaardag kolom.

Die VANDAG-funksie gee vandag se datum terug. Natuurlik bestaan ​​1 jaar uit 365 dae. Maar skrikkeljaar kom elke 4 jaar, so ons deel die datumverskille deur 365,25. Gebruik die Vulhandvatsel -nutsding en sleep dit af om kolom D te voltooi.

  • Dan, as jy die resultate in net volledige jare wil vertoon, gebruik die INT-funksie .
=INT(D5)

Let wel: Verseker dat selle D5:D14 geformateer is in Getal of Algemeen .

Lees meer: ​​Hoe om gemiddelde ouderdom in Excel te bereken (7 maklike metodes)

2. Toepassing van formulekombinasie van IF-, JAAR-, MAAND- en NOU-funksie

Hierdie metode pas 'n formule toe 'n paar verskillende funksies te kombineer. IF , YEAR , MONTH , en NOW funksies het hul eie bedrywighede hier. Volg asseblief die stappe hieronder.

Stappe:

  • Selekteer eerstens sel D5 en skryf die formule hieronder neer, en tik op ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo")

Formule-uiteensetting

Hier, MAAND en JAAR funksies gee die maand en jaar van daardie datum as 'n getal terug. Ons het die IF-funksie gebruik om 'n logiese toets in te voeg dat, as die maand van die huidige datum groter is as die maand van geboortedatum , dan werk die formule :

YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo"

Anders sal die res van die formule werk:

YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo"

Let wel: Die nadeel van hierdie metode is dat dit 12 maande gee in plaas daarvan om 1 jaar by te voeg. Ons kan dit sien in Jones se geval.

3. Berekening van ouderdom vanaf geboortejaar, maand en dag in verskillende selle

Hier het ons ons geboortedatum gekry in verskillende selle deur hulle te verdeel in Jaar , Maand, en Dag .

Uit hierdie tabel , ons wil hul huidige ouderdom bereken. Volg ons werkstappe noukeurig.

Stappe:

  • Eerstens moet ons die geboortedatum kry deur die DATE en DATEVALUE funksies. Om dit te doen, het ons hierdie formule gebruik:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5)

Hierdie formule het die verskillende jare, maande en dae in een sel saamgevoeg.

  • Kies sel G5 en plak die formule hieronder neer.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "&  DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days"

Lees meer: Hoe om ouderdom in Excel in jare en maande te bereken (5 maklike maniere)

4. Implementering YEARFRAC-funksie

Die gebruik van die YEARFRAC-funksie , wat 'n breukdeel van die jaar gee, is ook 'n betroubare benadering tot die berekening van ouderdom vanaf verjaarsdae inExcel. Volg die stappe hieronder.

Stappe:

  • Kies sel D5 en tik die formule hieronder in.
=YEARFRAC(C5,TODAY(),1)

Hierdie funksie het die verskil tussen verjaarsdag en vandag se datum bereken. Hier neem ons die basis as 1 wat werklik beteken.

  • Om die ouderdom in volledige jare te wys, gebruik die INT-funksie .

5. Gebruik DATEDIF-funksie om ouderdom vanaf verjaarsdag in Excel te bereken

Die gerieflikste en bruikbaarste funksie vir die berekening van die ouderdom is die DATEDIF-funksie . Volg die stappe deeglik.

Stappe:

  • Selekteer aan die begin sel D5 en plak die formule hieronder neer, en druk ENTER .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days"

Formule-ontleding

Om die ouderdom in jare, maande en dae te kry, het ons die argumente “Y” , “YM” en “MD” gebruik opeenvolgend in die DATEDIF-funksie . Die formule hierbo gee 'n enkele teksstring terug met 3 waardes (jare, maande en dae) saamgevoeg.

6. Kombineer IF met DATEDIF-funksie om slegs nie-nul-waardes te vertoon

In ons vorige metode, kan jy 'n probleem opmerk dat daar 0 maande en 0 dae in sommige selle vertoon word.

Om hierdie probleem te vermy en net nie-nul waardes te vertoon, kan ons dit doen 'n bietjie opknapping aan ons vorige formule deur die IF-funksie te kombineer. Om opgedateer te word met die nuwe formule,let noukeurig op.

Stappe:

  • Selekteer eers sel D5 en skryf die formule soos volg neer, en druk ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days")

Hierdie formule is net soos ons vorige formule, maar die enigste verskil is dat indien daar enige nulwaarde in jare, maande of dae is, sal daardie terme weggelaat word. Deur die IF-funksie te gebruik, het ons hierdie voorwaarde toegepas om net nie-nul waardes te vertoon.

7. Berekening van ouderdom op 'n spesifieke datum

In ons vorige metodes het ons geleer hoe om die huidige ouderdom vanaf die verjaarsdag te bereken. Nou sal ons die prosedure van bepaling van die ouderdom op 'n spesifieke datum ken.

Om ouderdom op 'n spesifieke datum te voorspel, het ons die DATEDIF-funksie weer. Hieruit kan u natuurlik die gerief van die gebruik van hierdie funksie verstaan. Volg die stappe hieronder.

Stappe:

  • Kies sel E5 en tik die formule hieronder in en druk ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days"

Die verskil van ons vorige metodes is dat ons daar die ouderdom tot nou bereken het datum. Ons het dus die VANDAG-funksie gebruik. Maar hier werk ons ​​die ouderdom op 'n spesifieke datum uit, nie die huidige ouderdom nie. Ons gebruik dus nog 'n selverwysing vir die Einddatum .

Lees meer: Hoe om ouderdom tussen twee datums in Excel te bereken (6 nuttige metodes)

8. Pas VBA toe om ouderdom vanaf verjaarsdag in te berekenExcel

'n Ander manier om ouderdom in Excel vanaf verjaarsdae te bereken, is om die VBA-kode te gebruik. Jy kan die stappe hieronder volg om die ouderdom met hierdie metode te bereken.

Stappe:

  • Regskliek op die Veldnaam en kies Bekyk kode .

  • Onmiddellik word die Microsoft Visual Basic for Applications-venster oop. Regskliek op Sheet9 (VBA) > kies Voeg in > Module.

  • Dit maak 'n kodemodule oop, waar die onderstaande kode plak af en klik op die Run -knoppie of druk F5. 
6000
  • Keer nou terug na die werkblad. Jy kan sien dat D5:D14 selle outomaties gevul is met die ouderdom in jare. In die formulebalk kan ons die DATEDIF-funksie sien wat ons in ons VBA-kode gebruik het.

Om die datum uit te vind wanneer 'n persoon 'n gegewe ouderdom bereik

Kom ons sê, Robin se geboortedatum is 13-08-1996. Wanneer sou hy sy 50-jarige ouderdom bereik? Hoe weet jy dit? Niks om oor bekommerd te wees as jy dit nie vroeër geweet het nie. Hou net ons stappe noukeurig dop.

Stappe:

  • Selekteer eerstens sel D5 en skryf die formule soos volg neer, en druk dan ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5))

Hier het ons sopas 50 bygevoeg met die jaar van die geboortedatum. Uiteindelik keer dit terug op die datum van bereiking van 50 jaarOuderdom .

Gevolgtrekking

Dankie dat jy hierdie artikel gelees het, ons hoop dit was nuttig. Laat weet ons asseblief in die kommentaarafdeling as u enige navrae of voorstelle het. Besoek asseblief ons webwerf Exceldemy om meer te verken.

Vorige pos Hoe om kruistabulering in Excel te doen (3 gepaste voorbeelde)
Volgende plasing Hoe om datum na jaar in Excel om te skakel (3 vinnige maniere)

Hugh West is 'n hoogs ervare Excel-afrigter en ontleder met meer as 10 jaar ondervinding in die bedryf. Hy het 'n Baccalaureusgraad in Rekeningkunde en Finansies en 'n Meestersgraad in Besigheidsadministrasie. Hugh het 'n passie vir onderrig en het 'n unieke onderrigbenadering ontwikkel wat maklik is om te volg en te verstaan. Sy kundige kennis van Excel het duisende studente en professionele persone wêreldwyd gehelp om hul vaardighede te verbeter en uit te blink in hul loopbane. Deur sy blog deel Hugh sy kennis met die wêreld, en bied gratis Excel-tutoriale en aanlyn opleiding aan om individue en besighede te help om hul volle potensiaal te bereik.