Talaan ng nilalaman
Ang artikulo ay nagpapakita ng ilang kamangha-manghang paraan upang makalkula ang edad mula sa isang kaarawan sa Excel. Matututuhan mo ang ilang mga formula para sa pagkalkula ng edad bilang isang bilang ng mga kumpletong taon, pati na rin ang pagkuha ng mga aktwal na edad sa mga taon, buwan, at araw sa petsa ngayon o isang partikular na petsa. Ngayon, dadalhin ka namin sa mga madali at maginhawang paraan kung paano kalkulahin ang edad mula sa kaarawan sa Excel.
I-download ang Practice Workbook
Maaari mong i-download ang sumusunod na Excel workbook para sa mas mahusay na pag-unawa at pagsasanay sa iyong sarili .
Pagkalkula ng Edad mula sa Kaarawan.xlsm8 Paraan para sa Pagkalkula ng Edad mula sa Kaarawan sa Excel
“Hey, ilang taon ka na ? “ Isang napakakaraniwang itinatanong. Mula sa ating pagkabata, dapat nating lahat ay madalas na marinig ang tanong na ito. Ngunit, ano ang ibig sabihin nito? Karaniwan itong tumutukoy sa tugon na nagpapahayag kung gaano ka na katagal nabubuhay.
Bagama't walang nakatalagang function upang kalkulahin ang edad mula sa kaarawan sa Excel, mayroong ilang alternatibong paraan upang i-convert ang petsa ng kapanganakan sa edad.
Mayroon kaming listahan ng Mga Kaarawan ng 10 indibidwal.
Sa sa sandaling ito, kakalkulahin namin ang kanilang mga edad sa Excel mula sa mga kaarawan.
1. Paggamit ng Pangunahing Formula upang Kalkulahin ang Edad mula sa Kaarawan sa Excel
Sa una, matututunan natin ang pinakatradisyunal na paraan upang kalkulahin ang edad sa mga taon sa Excel. Ano ang pinakakaraniwang paraan para sa pagtukoy ng edad ng isang tao? Ibawas lang angpetsa ng kapanganakan mula sa kasalukuyang petsa. Ang karaniwang formula na ito para sa pagkalkula ng edad ay maaari ding gamitin sa Excel. Sundin nang mabuti ang mga hakbang.
Mga Hakbang:
- Una , piliin ang cell D5 , ilagay ang formula sa ibaba , at pindutin ang ENTER .
=(TODAY()-C5)/365.25 Dito, ang C5 ay ang panimulang cell ng Birthday column.
Ang TODAY function ay nagbabalik ng petsa ngayon. Naturally, ang 1 taon ay binubuo ng 365 araw. Ngunit dumarating ang leap year tuwing 4 na taon, kaya hinahati namin ang mga pagkakaiba ng petsa sa 365.25. Gamitin ang tool na Fill Handle at i-drag ito pababa para kumpletuhin ang column D .
- Pagkatapos, kung gusto mong ipakita ang mga resulta sa mga kumpletong taon lang, gamitin ang INT function .
=INT(D5) 
Tandaan: Tiyaking naka-format ang mga cell D5:D14 sa Number o General .
Magbasa Pa: Paano Kalkulahin ang Average na Edad sa Excel (7 Madaling Paraan)
2. Paglalapat ng Formula Combination ng IF, YEAR, MONTH, at NOW Function
Ang paraang ito ay naglalapat ng formula pagsasama-sama ng ilang natatanging function. Ang IF , YEAR , MONTH , at NOW ay may sariling mga operasyon dito. Mangyaring sundin ang mga hakbang sa ibaba.
Mga Hakbang:
- Una, piliin ang cell D5 at isulat ang formula sa ibaba, at i-tap ang ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo") 
Breakdown ng Formula
Dito, MONTH at TAON ibinabalik ng mga function ang buwan at taon ng petsang iyon bilang isang numero. Ginamit namin ang IF function para maglagay ng logical test na, kung ang buwan ng kasalukuyang petsa ay mas malaki kaysa sa buwan ng birthdate , kung gayon ang formula ay :
YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo" Kung hindi, gagana ang natitirang formula:
YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo" Tandaan: Ang disbentaha ng pamamaraang ito ay nagbabalik ito ng 12 buwan sa halip na magdagdag ng 1 taon. Makikita natin iyan sa Jones's case.
3. Pagkalkula ng Edad mula sa Taon ng Kapanganakan, Buwan, at Araw sa Iba't Ibang Cells
Dito, nakuha namin ang aming petsa ng kapanganakan sa iba't ibang mga cell sa pamamagitan ng paghahati sa mga ito sa Taon , Buwan, at Araw .
Mula sa talahanayang ito , gusto naming kalkulahin ang kanilang kasalukuyang edad. Sundin nang mabuti ang aming mga hakbang sa trabaho.
Mga Hakbang:
- Una, kailangan naming makuha ang petsa ng kapanganakan gamit ang DATE at DATEVALUE mga function. Upang gawin ito, ginamit namin ang formula na ito:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5) Pinagsama-sama ng formula na ito ang iba't ibang taon, buwan, at araw sa isang cell.
- Piliin ang cell G5 at i-paste ang formula sa ibaba.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days" 
Magbasa Pa: Paano Kalkulahin ang Edad sa Excel sa Mga Taon at Buwan (5 Madaling Paraan)
4. Pagpapatupad Ang YEARFRAC Function
Ang paggamit ng YEARFRAC function , na nagbabalik ng isang bahagi ng taon, ay isa ring maaasahang diskarte sa pagkalkula ng edad mula sa mga kaarawan saExcel. Sundin ang mga hakbang sa ibaba.
Mga Hakbang:
- Piliin ang cell D5 at i-type ang formula sa ibaba.
=YEARFRAC(C5,TODAY(),1) 
Kinakalkula ng function na ito ang pagkakaiba sa pagitan ng kaarawan at petsa ngayon. Dito natin kinukuha ang basis bilang 1 na nangangahulugang aktwal.
- Para sa pagpapakita ng edad sa mga kumpletong taon, gamitin ang INT function .
5. Pag-ampon ng DATEDIF Function para Kalkulahin ang Edad mula sa Kaarawan sa Excel
Ang pinaka-maginhawa at magagamit na function para sa pagkalkula ng edad ay ang DATEDIF function . Sundin ang mga hakbang nang lubusan.
Mga Hakbang:
- Sa simula, piliin ang cell D5 at i-paste ang formula sa ibaba, at pindutin ang ENTER .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days" 
Breakdown ng Formula
Upang makuha ang edad sa mga taon, buwan, at araw na ginamit namin ang mga argumento “Y” , “YM” , at “MD” sunud-sunod sa DATEDIF function . Ang formula sa itaas ay nagbabalik ng iisang text string na may 3 value (taon, buwan, at araw) na pinagsama-sama.
6. Ang pagsasama-sama ng IF sa DATEDIF Function na Ipakita Lamang ang Non-Zero Values
Sa aming nakaraang paraan, maaari kang makapansin ng problema na mayroong 0 buwan at 0 araw na lumalabas sa ilang mga cell.
Upang maiwasan ang problemang ito at magpakita lamang ng mga hindi zero na halaga, magagawa namin ilang pagsasaayos sa aming nakaraang formula sa pamamagitan ng pagsasama-sama ng IF function . Upang ma-update gamit ang bagong formula,obserbahang mabuti.
Mga Hakbang:
- Una, piliin ang cell D5 at isulat ang formula tulad ng sumusunod, at pindutin ang ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days") 
Ang formula na ito ay katulad lang ng dati nating formula pero ang pinagkaiba lang kung mayroong anumang zero na halaga sa mga taon, buwan, o araw, aalisin ang mga tuntuning iyon. Gamit ang IF function inilapat namin ang kundisyong ito upang magpakita lamang ng mga hindi zero na halaga.
7. Pagkalkula ng Edad sa isang Partikular na Petsa
Sa aming mga nakaraang pamamaraan, natutunan namin kung paano upang kalkulahin ang kasalukuyang edad mula sa kaarawan. Ngayon, malalaman natin ang pamamaraan ng pagtukoy sa edad sa isang partikular na petsa.
Para sa paghula ng edad sa isang partikular na petsa, ginamit namin ang DATEDIF function muli. Mula dito, malinaw na mauunawaan mo ang kaginhawaan ng paggamit ng function na ito. Sundin ang mga hakbang sa ibaba.
Mga Hakbang:
- Piliin ang cell E5 at i-type ang formula sa ibaba at pindutin ang ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days" 
Ang pagkakaiba sa aming mga nakaraang pamamaraan ay doon namin kinakalkula ang edad hanggang sa kasalukuyan petsa. Kaya, ginamit namin ang TODAY function . Ngunit dito namin inaayos ang edad sa isang tiyak na petsa, hindi ang kasalukuyang edad. Kaya gumagamit kami ng isa pang cell reference para sa Petsa ng Pagtatapos .
Magbasa Nang Higit Pa: Paano Kalkulahin ang Edad sa Pagitan ng Dalawang Petsa sa Excel (6 Mga Kapaki-pakinabang na Paraan)
8. Paglalapat ng VBA upang Kalkulahin ang Edad mula sa Kaarawan saExcel
Ang isa pang paraan upang kalkulahin ang edad sa Excel mula sa mga kaarawan ay ang paggamit ng VBA code. Maaari mong sundin ang mga hakbang sa ibaba upang kalkulahin ang edad gamit ang paraang ito.
Mga Hakbang:
- I-right click sa Pangalan ng Sheet at piliin ang Tingnan ang Code .
- Agad, bubukas ang Microsoft Visual Basic for Applications window. Mag-right-click sa Sheet9 (VBA) > piliin ang Insert > Module.
- Nagbubukas ito ng module ng code, kung saan i-paste ang code sa ibaba pababa at mag-click sa button na Run o pindutin ang F5.
3182
- Ngayon, isara ang code module, bumalik sa worksheet. Makikita mo na ang D5:D14 mga cell ay awtomatikong napunan ng edad sa mga taon. Sa formula bar, makikita natin ang DATEDIF function na ginamit namin sa aming VBA code .
Pag-alam sa Petsa Kung Ang Isang Tao ay Umabot sa Ibinigay na Edad
Sabihin natin, ang petsa ng kapanganakan ni Robin ay 13-08-1996. Kailan niya mararating ang kanyang 50 taong gulang? pano mo malalaman yun? Walang dapat ipag-alala kung hindi mo alam ito nang mas maaga. Panoorin lamang nang mabuti ang aming mga hakbang.
Mga Hakbang:
- Una, piliin ang cell D5 at isulat ang formula tulad ng sumusunod, pagkatapos ay pindutin ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5)) 
Dito, nagdagdag kami ng 50 kasama ang taon ng petsa ng kapanganakan. Sa kalaunan, babalik ito sa Petsa ng Pagkamit ng 50 TaonEdad .
Konklusyon
Salamat sa pagbabasa ng artikulong ito, umaasa kaming nakatulong ito. Mangyaring ipaalam sa amin sa seksyon ng komento kung mayroon kang anumang mga katanungan o mungkahi. Pakibisita ang aming website Exceldemy para mag-explore pa.
