Hoe leeftyd te berekkenjen fan jierdei yn Excel (8 maklike metoaden) -

Hugh West

16-10-2023 Excel Formules
  • Diel Dit
Hugh West

It artikel toant wat geweldige metoaden om leeftyd te berekkenjen fanôf in jierdei yn Excel. Jo sille in pear formules leare foar it berekkenjen fan leeftyd as in oantal folsleine jierren, en ek it krijen fan aktuele leeftiden yn jierren, moannen en dagen op de datum fan hjoed of in bepaalde datum. No sille wy jo troch dy maklike en handige metoaden nimme oer hoe't jo leeftyd fan 'e jierdei berekkenje kinne yn Excel.

Oefenwurkboek downloade

Jo kinne it folgjende Excel-wurkboek downloade foar better begryp en oefenje josels .

Leeftyd berekkenje fan jierdei.xlsm

8 metoaden om leeftyd fan jierdei te berekkenjen yn Excel

"Hey, hoe âld bisto ? " In heul faak stelde fraach. Fan ús bernetiid moatte wy allegear dizze fraach faaks heard hawwe. Mar, wat betsjut dat? It jout meastentiids in antwurd oan dat útdrukt hoe lang jo libje.

Hoewol't der gjin spesjale funksje is om leeftyd te berekkenjen fan 'e jierdei yn Excel, binne der in pear alternative manieren om de bertedatum te konvertearjen nei leeftyd.

Wy hawwe in list fan Birthdays fan 10 persoanen.

By op dit stuit sille wy har leeftiden yn Excel berekkenje fan 'e jierdeisdagen.

1. Basisformule brûke om leeftyd fan jierdei te berekkenjen yn Excel

Earst learje wy de meast tradisjonele manier om leeftyd yn jierren te berekkenjen yn Excel. Wat is de meast foarkommende metoade foar it bepalen fan de leeftyd fan immen? Simply subtract thebertedatum fan de hjoeddeiske datum. Dizze mienskiplike formule foar it berekkenjen fan leeftyd kin ek brûkt wurde yn Excel. Folgje de stappen foarsichtich.

Stappen:

  • Earst , selektearje sel D5 , fier de formule hjirûnder yn , en druk op ENTER .
=(TODAY()-C5)/365.25

Hjir is de C5 de startsel fan de Birthday kolom.

De funksje TODAY jout de hjoeddeiske datum werom. Natuerlik bestiet 1 jier út 365 dagen. Mar in skrikkeljier komt om de 4 jier, dus diele wy de datumferskillen troch 365,25. Brûk it ark Fillhandtak en sleep it nei ûnderen om kolom D te foltôgjen.

  • Dan, as jo de resultaten yn krekt folsleine jierren werjaan wolle, brûk dan de INT-funksje .
=INT(D5)

Opmerking: Soargje dat sellen D5:D14 opmakke binne yn Nûmer of Algemien .

Lês mear: Hoe kinne jo gemiddelde leeftyd berekkenje yn Excel (7 maklike metoaden)

2. Formulekombinaasje fan IF, YEAR, MONTH en NOW-funksje tapasse

Dizze metoade jildt in formule kombinearje guon ûnderskate funksjes. Funksjes IF , YEAR , MONTH en NO hawwe hjir har eigen operaasjes. Folgje asjebleaft de stappen hjirûnder.

Stappen:

  • Selektearje earst sel D5 en skriuw de formule hjirûnder op en tik op ENTER .
=IF(MONTH(NOW())>MONTH(C5),YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo",YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo")

Formule-ôfdieling

Hjir, MONTH en YEAR funksjes jouwe de moanne en it jier fan dy datum werom as in nûmer. Wy brûkten de IF-funksje om in logyske test yn te foegjen dat, as de moanne fan de hjoeddeistige datum grutter is as de moanne fan bertedatum , dan wurket de formule :

YEAR(NOW())-YEAR(C5)&"yr "&MONTH(NOW())-MONTH(C5)&"mo"

Oars sil de rest fan de formule wurkje:

YEAR(NOW())-(YEAR(C5)+1)&"yr "&(MONTH(NOW())+12)-MONTH(C5)&"mo"

Opmerking: It neidiel fan dizze metoade is dat it 12 moannen weromkomt ynstee fan 1 jier ta te foegjen. Wy kinne dat sjen yn Jones's gefal.

3. Leeftyd berekkenje út bertejier, moanne en dei yn ferskillende sellen

Hjir hawwe wy ús bertedatum yn ferskate sellen troch se te splitsen yn Jier , Moanne, en Dei .

Fan dizze tabel , wy wolle har hjoeddeistige leeftyd berekkenje. Folgje ús wurkstappen foarsichtich.

Stappen:

  • Earst moatte wy de bertedatum krije mei de DATE en DATEVALUE funksjes. Om dat te dwaan hawwe wy dizze formule brûkt:
=DATE(C5,MONTH(DATEVALUE(D5&"1")),E5)

Dizze formule fusearre de ferskate jierren, moannen en dagen yn ien sel.

  • Selektearje sel G5 en plak de formule hjirûnder.
=DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "y") & " Years, "& DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5),TODAY(), "ym") & " Months, "&  DATEDIF(DATE(C5, MONTH(DATEVALUE(D5&"1")), E5), TODAY(), "md") & " Days"

Lês mear: Hoe kinne jo leeftyd yn Excel berekkenje yn jierren en moannen (5 maklike manieren)

4. Implementearje YEARFRAC-funksje

It brûken fan de YEARFRAC-funksje , dy't in fraksje fan it jier werombringt, is ek in betroubere oanpak foar it berekkenjen fan leeftyd fan jierdeis ynExcel. Folgje de stappen hjirûnder.

Stappen:

  • Selektearje sel D5 en typ de formule hjirûnder.
=YEARFRAC(C5,TODAY(),1)

Dizze funksje berekkene it ferskil tusken jierdei en de datum fan hjoed. Hjir nimme wy de basis as 1 wat feitlik betsjut.

  • Om de leeftyd yn folsleine jierren te sjen, brûk de INT-funksje .

5. DATEDIF-funksje oannimme om leeftyd fan jierdei te berekkenjen yn Excel

De handichste en brûkbere funksje foar it berekkenjen fan de leeftyd is de DATEDIF-funksje . Folgje de stappen yngeand.

Stappen:

  • Selektearje yn it begjin sel D5 en plak de formule hjirûnder, en druk op ENTER .
=DATEDIF(C5,TODAY(),"Y") & " Years, " & DATEDIF(C5,TODAY(),"YM") & " Months, " & DATEDIF(C5,TODAY(),"MD") & " Days"

Formule-ûnderdieling

Om de leeftyd yn jierren, moannen en dagen te krijen hawwe wy de arguminten “Y” , “YM” en “MD” brûkt sequentially yn de DATEDIF-funksje . De formule hjirboppe jout in inkele tekststring werom mei 3 wearden (jierren, moannen en dagen) gearfoege.

6. IF kombinearje mei DATEDIF-funksje om allinich wearden net-nul wer te jaan

Yn ús foarige metoade, kinne jo in probleem fernimme dat d'r 0 moannen en 0 dagen yn guon sellen te sjen binne.

Om dit probleem te foarkommen en gewoan wearden fan net-nul wer te jaan, kinne wy ​​​​dwaan wat renovaasje fan ús foarige formule troch it kombinearjen fan de IF-funksje . Om bywurke te wurden mei de nije formule,goed observearje.

Stappen:

  • Selektearje earst sel D5 en skriuw de formule sa op, en druk op ENTER .
=IF(DATEDIF(C5, TODAY(),"y")=0,"",DATEDIF(C5, TODAY(),"y")&" years, ")& IF(DATEDIF(C5, TODAY(),"ym")=0,"",DATEDIF(C5, TODAY(),"ym")&" months, ")& IF(DATEDIF(C5, TODAY(),"md")=0,"",DATEDIF(C5, TODAY(),"md")&" days")

Dizze formule is krekt as ús foarige formule, mar it ienige ferskil is dat as der in nulwearde is yn jierren, moannen of dagen, wurde dy betingsten weilitten. Mei de IF-funksje hawwe wy dizze betingst tapast om gewoan wearden net-nul wer te jaan.

7. Leeftyd berekkenje op in spesifike datum

Yn ús eardere metoaden learden wy hoe't om de hjoeddeiske leeftyd te berekkenjen fanôf de jierdei. No witte wy de proseduere fan bepale fan de leeftyd op in spesifike datum.

Foar it foarsizzen fan leeftyd op in spesifike datum, brûkten wy de DATEDIF-funksje wer. Hjirút kinne jo fansels it gemak fan it brûken fan dizze funksje begripe. Folgje de stappen hjirûnder.

Stappen:

  • Selektearje sel E5 en typ de formule hjirûnder en druk op ENTER .
=DATEDIF(C5, D5,"Y") & " Years, "& DATEDIF(C5,D5,"YM") & " Months, "&DATEDIF(C5,D5, "MD") & " Days"

It ferskil mei ús eardere metoaden is dat wy dêr de leeftyd oant no ta berekkene hawwe datum. Sa hawwe wy de TODAY-funksje brûkt. Mar hjir wurkje wy de leeftyd út op in spesifike datum, net de hjoeddeiske leeftyd. Sa brûke wy in oare selferwizing foar de Einddatum .

Lês mear: Hoe kinne jo leeftyd tusken twa datums yn Excel berekkenje (6 nuttige metoaden)

8. VBA tapasse om leeftyd te berekkenjen fan jierdei ynExcel

In oare manier om leeftyd te berekkenjen yn Excel fan jierdei is it brûken fan de VBA-koade. Jo kinne de stappen hjirûnder folgje om de leeftyd te berekkenjen mei dizze metoade.

Stappen:

  • Rjochtsklik op de Sheetnamme en selektearje Koade besjen .

  • Daliks iepenet it Microsoft Visual Basic for Applications-finster. Rjochts-klikke op Sheet9 (VBA) > selektearje Ynfoegje > Module.

  • It iepenet in koademodule, wêrby't de ûndersteande koade plakke del en klikje op de knop Utfiere of druk op F5. 
4752
  • No it sluten fan de koademodule werom nei it wurkblêd. Jo kinne sjen dat D5:D14 sellen automatysk ynfolle binne mei de leeftyd yn jierren. Yn 'e formulebalke kinne wy ​​​​de DATEDIF-funksje sjen dy't wy hawwe brûkt yn ús VBA-koade .

De datum fine as in persoan in bepaalde leeftyd berikt

Litte wy sizze, de bertedatum fan Robin is 13-08-1996. Wannear soe hy syn 50 jier berikke? Hoe witsto dat? Neat om soargen oer as jo it net earder wisten. Sjoch gewoan ús stappen foarsichtich.

Stappen:

  • Selektearje earst sel D5 en skriuw de formule as folget op, druk dan op ENTER .
=DATE(YEAR(C5)+50,MONTH(C5),DAY(C5))

Hjir hawwe wy krekt 50 tafoege mei it jier fan de bertedatum. Uteinlik komt it werom op 'e Datum fan it berikken fan 50 jierLeeftyd .

Konklúzje

Tankewol foar it lêzen fan dit artikel, wy hoopje dat dit nuttich wie. Lit it ús asjebleaft witte yn 'e kommentaar seksje as jo fragen of suggestjes hawwe. Besykje asjebleaft ús webside Exceldemy om mear te ferkennen.

Foarige post Hoe krústabulaasje te dwaan yn Excel (3 geskikte foarbylden)
Folgjende post Hoe konvertearje datum nei jier yn Excel (3 rappe manieren)

Hugh West is in tige betûfte Excel-trainer en analist mei mear as 10 jier ûnderfining yn 'e yndustry. Hy hat in bachelorstitel yn boekhâlding en finânsjes en in masterstitel yn bedriuwsadministraasje. Hugh hat in passy foar lesjaan en hat in unike lesoanpak ûntwikkele dy't maklik te folgjen en te begripen is. Syn saakkundige kennis fan Excel hat tûzenen studinten en professionals wrâldwiid holpen har feardigens te ferbetterjen en útblinke yn har karriêre. Troch syn blog dielt Hugh syn kennis mei de wrâld, en biedt fergese Excel-tutorials en online training om partikulieren en bedriuwen te helpen har folsleine potensjeel te berikken.