Innholdsfortegnelse
Når vi sammenligner bare to celler manuelt, er det ikke vanskelig. Men det er aldri lett å sammenligne hundrevis og tusenvis av tekststrenger. Heldigvis gir MS Excel oss flere funksjoner og måter å utføre dette ganske enkelt på. I denne artikkelen vil jeg demonstrere flere metoder for å sammenligne teksten til to celler i Excel.
Last ned Practice Workbook
Sammenlign To celler Text.xlsx
10 måter å sammenligne tekst fra to celler i Excel
1. Sammenlign tekst av to celler ved å bruke "Lik med" operator (uavhengig av store og små bokstaver)
La oss se hvordan du sammenligner to cellers tekst ved hjelp av en enkel formel. Her skal vi ikke vurdere det sakssensitive spørsmålet. Vår eneste bekymring er å sjekke kun verdiene. For denne metoden, la oss vurdere et datasett med frukt. I datasettet vil vi ha to-kolonne Fruktlister. Nå er oppgaven vår å matche navnene på fruktene og vise deres samsvarende resultat.
📌 Trinn:
- Skriv inn formelen i Celle D5 .
=B5=C5
- Kopier ned formelen opp til D13 .
Merk:
Som denne formelen vil ikke fungere for store og små bokstaver som er grunnen til at hvis teksten samsvarer med verdier, men de ikke er i samme bokstav, vil den vise TRUE for det.
2. Sammenlign to-cellers tekst ved å bruke EXACT-funksjonen (store og små bokstaver)
I denne delen vil vi se hvordan du sammenligner totekstceller der vi vil bli betraktet som det eksakte samsvaret ved å bruke EXACT-funksjonen . For denne metoden, la oss vurdere et datasett som er brukt tidligere. Nå er oppgaven vår å sammenligne navnene på fruktene og vise deres nøyaktige resultat.
📌 Trinn:
- Skriv inn formelen i Celle D5 .
=EXACT(B5,C5)
- Kopier ned formelen opp til D13 .
Observasjon:
Hvis du observerer resultatet, kan du se at EXAKT funksjonen returnerer resultatet TRUE hvis og bare hvis hele teksten er fullstendig samsvarende. Det skiller også mellom store og små bokstaver.
Bruk av EXACT-funksjonen med IF for å få en tekstutdata:
Her vil vi i tillegg bruk IF-funksjonen med EXACT -funksjonen for å vise de betingede resultatene. Til dette vil vi også bruke samme datasett ovenfor.
📌 Trinn:
- Skriv inn formelen i Celle D5 .
=IF(EXACT(B5,C5),"Similar","Different")
Formelforklaring:
Her vårt indre funksjonen er EXAKT som skal finne den nøyaktige matchen mellom to celler. La oss se IF-funksjonens syntaks:
=IF (logisk_test, [value_if_true], [value_if_false])
I den første delen tar den betingelsen eller kriteriene, deretter verdien som vil bli skrevet ut hvis resultatet er sant og deretter hvis resultatet er usant.
Som vi vil skrive ut Lignende hvis de toceller blir matchet og forskjellige hvis de ikke er det. Det er derfor det andre og tredje argumentet er fylt opp med denne verdien.
- Kopier ned formelen opp til D13 .
3. Sammenlign tekst av to celler ved å bruke IF-funksjonen (ikke skille mellom store og små bokstaver)
Vi kan bare bruke IF -funksjonen for å finne treff. Igjen, la oss se prosessen med det samme datasettet.
📌 Trinn:
- Skriv inn formelen i Celle D5 .
=IF(B5=C5,"Yes","No")
- Kopier ned formelen opp til D13 .
4. Sammenlign to tekster etter strenglengde med LEN-funksjonen
La oss se hvordan vi kan sjekke om teksten til de to cellene har samme strenglengde eller ikke. Vår bekymring vil være tekst av samme lengde, ikke samme tekst. Datasettet vårt vil være det samme som ovenfor.
📌 Trinn:
- Skriv inn formelen i celle D5.
=IF(LEN(B5)=LEN(C5), "Same", "Not Same")
Formelforklaring:
- Først må vi kjenne til de grunnleggende konseptene for LEN-funksjonen .
- Syntaksen til denne funksjonen er: LEN (tekst)
- Denne funksjonen brukes til å telle tegnet til enhver tekst eller streng. Når vi sender en tekst i denne funksjonen, vil den returnere antall tegn.
- LEN(B5) denne delen teller først tegnet til hver celle fra den første kolonnen og LEN(C5) for den andre.
- Hvislengden er den samme, vil den skrive ut “Same” og hvis ikke, “Not Same” .
- Kopier ned formelen opp til D13 .
5. Sammenlign tekst av to celler som har unødvendige mellomrom
La oss se hvordan vi kan sjekke om teksten til de to cellene har samme streng med unødvendige mellomrom foran, i midten eller slutten. Vår bekymring vil være å finne ut den samme teksten etter å ha fjernet mellomrom. Datasettet vårt vil være det samme som ovenfor.
📌 Trinn:
- Skriv inn formelen i celle D5.
=TRIM(B5)=TRIM(C5)
Formelforklaring:
- Først må vi kjenne til de grunnleggende konseptene for TRIM-funksjonen .
- Syntaksen til denne funksjonen er: TRIM(tekst)
- Denne funksjonen brukes til å fjerne alle mellomrom fra en tekststreng bortsett fra enkeltrom mellom ord.
- TRIM(B5) denne delen fjerner unødvendige mellomrom fra cellen forventer enkelt mellomrom mellom ord og TRIM(C5) for det andre.
- Etter å ha fjernet mellomrom hvis begge er like, vil den skrive ut “TRUE” og hvis ikke da “FALSE” .
- Kopier ned formelen opp til D13 .
6. Sammenlign tekststrenger av to celler i Excel etter forekomster av et spesifikt tegn
Noen ganger må vi kanskje sammenligne celler der det vil inneholde spesifikke tegn. I denne delen,vi vil se hvordan du sammenligner to celler etter forekomsten av en bestemt karakter. La oss vurdere et datasett med produkter med sende-ID og mottatt ID. Disse ID-ene er unike og bør matches med send- og mottaks-ID-er. Vi vil sørge for at hver rad inneholder like mange sendte og mottatte varer med den spesifikke ID-en.
📌 Trinn:
- Skriv inn formelen i celle E5.
=IF(LEN(C5)-LEN(SUBSTITUTE(C5, $B5,""))=LEN(D5)-LEN(SUBSTITUTE(D5,$B5,"")),"Same","Not Same")
Formelforklaring:
- Her har vi i tillegg brukt SKIFT-funksjonen . La oss se det grunnleggende i denne funksjonen.
- Syntaksen til denne funksjonen er: SUBSTITUTE (tekst, gammel_tekst, ny_tekst, [forekomst])
- Disse fire argumentene kan være sendt i funksjonens parameter. Blant dem er den siste valgfri.
tekst- Teksten som skal byttes.
gammel_tekst- Teksten som skal erstattes.
ny_tekst- Teksten som skal erstattes med.
forekomst- Forekomsten som skal erstattes. Hvis det ikke er gitt, erstattes alle forekomster. Dette er valgfritt.
- SUBSTITUTE(B2, character_to_count,"") ved å bruke denne delen erstatter vi den unike identifikatoren med ingenting ved å bruke SUBSTITUTE funksjonen.
- Deretter bruker du LEN(C5)-LEN(SUBSTITUTE(C5, $B5,"")) og LEN(D5)-LEN(SUBSTITUTE(D5, $B5, ””)) vi beregner hvor mange ganger den unike identifikatoren vises i hver celle. For dette, fåstrenglengde uten den unike identifikatoren og trekk den fra den totale lengden på strengen.
- Til slutt brukes IF -funksjonen for å gjøre resultatene mer meningsfulle for brukerne dine ved å vise sann eller falske resultater.
- Kopier ned formelen opp til E10 .
7. Sammenlign tekst fra to celler og marker samsvarene
I dette eksemplet vil vi se hvordan du sammenligner tekst og uthever samsvarene. Til dette vil vi også bruke samme datasett som brukes i metode 4 . For dette eksemplet trenger vi ingen kolonne for å vise resultater.
📌 Trinn:
- Velg hele datasettet.
- Gå til Betinget formatering . Du finner den under fanen Hjem .
- Velg alternativet Ny regel .
- Velg alternativet merket 1 .
- Skriv inn formelen nedenfor i den merkede boksen 2 .
=$B5=$C5
- Eller du kan bare velge de to kolonnene i datasettet.
- Deretter klikker du på Format alternativ.
- Gå til Fyll -fanen.
- Velg hvilken som helst farge.
- Trykk deretter OK .
- Klikk på OK -knappen.
- Se de samsvarende dataene uthevet.
8. Sammenlign tekst fra to celler delvis i Excel (ikke skille mellom store og små bokstaver)
Når det gjelder å sammenligne to celler,noen ganger kan vi vurdere delvis matching. I denne delen vil vi se å sammenligne to cellers tekst delvis. Det er mange funksjoner tilgjengelig i Excel for å sjekke parietale elementer. Men i dette eksemplet vil vi vurdere HØYRE-funksjonen .
La oss vurdere denne datatabellen, og vi vil finne ut om de siste 6 tegnene samsvarer med de to cellene.
📌 Trinn:
- Skriv inn formelen i Celle D5 og kopier ned formelen opp til
=RIGHT(B5,5)=RIGHT(C5,5)
9. Finn samsvar i to celler i samme rad
La oss ha et datasett med tre fruktlister. Nå vil vi sammenligne cellene med hverandre og vi får alle to celler matchet i samme rad, så vil det bli sett på som matchet.
📌 Trinn:
- Skriv inn formelen i Celle E5 og kopier ned formelen opp til
=IF(OR(B5=C5,C5=D5,B5=D5),"Yes","No")
Formelforklaring:
- Her har vi i tillegg brukt ELLER-funksjonen . La oss se syntaksen til denne funksjonen: OR (logical1, [logical2], …)
- Det kan ta to eller flere logikk i parameterne.
logical1 -> ; Det første kravet eller logiske verdien for å bestemme.
logical2 -> Dette er valgfritt. Det andre kravet eller logiske verdien som skal evalueres.
- ELLER(B5=C5, C5=D5, B5=D5)
Denne delen bestemmer om alle celler er like eller minst to er like ellerikke. Hvis ja, bestemmer HVIS-funksjonen den endelige verdien basert på ELLER funksjonens resultat.
Les mer: Excel Count-treff i to kolonner (4 enkle måter)
10. Finn de unike og matchende cellene ved å sammenligne teksten deres
Her er vår oppgave å finne fruktene som er unike og som blir matchet i samme rad. For matching vil vi vurdere minst to celler som samsvarer. Hvis minst to celler samsvarer, vil det bli ansett som Samsvar ellers Unik .
📌 Trinn:
- Skriv inn formelen i Celle E5 og kopier ned formelen opp til
=IF(COUNTIF(C5:D5,B5)+(C5=D5)=0,"Unique","Match")
Formelforklaring:
- Her brukes COUNTIF-funksjonen i tillegg.
- I denne funksjonen er begge argumentene i parameteren er obligatorisk. For det første tar det celleområdet som skal telles. Den andre delen tar kriteriene som er betingelsen. Basert på denne betingelsen vil tellingen bli utført.
- Ved å bruke COUNTIF(C5:D5,B5)+(C5=D5)=0 prøver vi å finne ut om raden har samsvarende eller unike verdier. Hvis antallet er 0, er det unikt ellers er det en samsvarende verdi.
Hvordan sammenligne én celle med en hel kolonne i Excel
Her har vi et datasett med én fruktliste og en matchende celle. Nå skal vi sammenligne den matchende cellen med fruktlisten kolonne og finn kampresultatet.
📌 Trinn:
- Skriv inn formelen i Celle E5.
=$E$5=B5:B13
- Deretter trykker du på Enter -knappen.
Når Celle E5 samsvarer med tilsvarende celler i Område B5:B13, returnerer deretter TRUE. Ellers returnerer USANN .
Konklusjon
Dette er måtene vi sammenligner teksten til to celler i Excel. Jeg har vist alle metodene med deres respektive eksempler, men det kan være mange andre iterasjoner. Jeg har også diskutert det grunnleggende om disse funksjonene og deres mest brukte formatkoder. Hvis du har en annen metode for å oppnå dette, må du gjerne dele den med oss .
