Mục lục
Đối với tra cứu nâng cao trong Excel, INDEX và MATCH có thể được sử dụng thay cho VLOOKUP . INDEX và MATCH được yêu cầu để tra cứu mở rộng và rất nhiều trong số chúng hoàn toàn tuyệt vời. Với ví dụ, chúng tôi sẽ hướng dẫn bạn cách sử dụng các hàm Excel INDEX và MATCH trong Excel trong hướng dẫn này.
Tải xuống Sách bài tập thực hành
Tải sách bài tập thực hành này xuống để thực hành trong khi bạn đang đọc bài viết này.
Công dụng của INDEX-MATCH Formula.xlsx
8 ví dụ hiệu quả về INDEX-MATCH Công thức trong Excel
Chúng tôi sẽ sử dụng tập dữ liệu mẫu trong các phần bên dưới để trình bày cách sử dụng hàm INDEX và hàm MATCH trên đó. Chúng tôi sẽ chỉ cho bạn cách áp dụng cả hai hàm theo 8 cách khác nhau để tra cứu giá trị.
♣Cú pháp:
= INDEX ( mảng , row_num , [ column_num ])
♣Đối số:
- mảng : phạm vi ô có giá trị
- Row_num : trả về kết quả cho một hàng trong phạm vi đã chọn.
- column_num : trả về kết quả cho một cột trong phạm vi đã chọn.
♣Kết quả:
Hàm Chỉ mục trả về giá trị hoặc tham chiếu của ô trong một phạm vi được chỉ định nằm ở giao điểm của một hàng cụ thể vàcột.
♣Cú pháp:
= MATCH ( lookup_value , lookup_array ,[ match_type ])
♣Đối số:
- lookup_value : Giá trị bạn muốn tìm trong phạm vi.
- lookup_array : Phạm vi mà bạn đang tìm kiếm lookup_value .
- match_type : Chỉ định cách tra cứu giá trị và tra cứu giá trị mảng được so khớp trong Excel.
- 1 = chính xác hoặc nhỏ nhất tiếp theo.
- 0 = khớp chính xác.
- -1 = chính xác hoặc lớn nhất tiếp theo.
♣Kết quả:
Trả về vị trí của một mục trong một mảng theo mức độ tương đối của nó vị trí.
Ví dụ 1: Kết hợp cơ bản Hàm INDEX và MATCH trong Excel
Giả sử bạn muốn tra cứu Giá cho một ID đơn hàng cụ thể. Chúng ta sẽ kết hợp hàm INDEX và hàm MATCH để thực hiện việc này.
Bước 1:
- Trong ô G5 , hãy nhập công thức sau.
=INDEX(D5:D11, MATCH(G4,B5:B11,0)) Tại đây,
- MATCH(G4,B5:B11,0) tham chiếu đến ô G4 dưới dạng giá trị tra cứu trong phạm vi B5:B11 cho một kết hợp chuẩn xác. Nó trả về 4 vì giá trị ở hàng số 4 .
- INDEX(D5:D11, MATCH(G4,B5:B11,0)) tham chiếu D5:D11 là một mảng mà từ đó chúng tôi nhận được giá trị và row_num là 4 như chúng tôi đã nhận được từ MATCH Column_num không bắt buộc vì chúng tôi chỉ áp dụng INDEX cho mộtcột.
Bước 2:
- Nhấn Enter đến kết quả.
Đọc thêm: Ví dụ với Công thức INDEX-MATCH trong Excel (8 cách tiếp cận)
Ví dụ 2: Sử dụng Công thức INDEX-MATCH để Tra cứu từ bên trái trong Excel
Bạn cũng có thể thực hiện tra cứu từ cột này sang cột khác. Giá trị cho cột C , cột thứ hai của phạm vi INDEX B5:D11 của chúng tôi, sẽ được tìm thấy trong ví dụ sau. Thực hiện theo các bước bên dưới để thực hiện tra cứu từ bên trái.
Bước 1:
- Nhập công thức sau vào ô G5 .
=INDEX($B$5:$D$11,MATCH(F5,$B$5:$B$11,0),2) 
Bước 2:
- Sau đó, nhấn Enter để xem kết quả.
Bước 3:
- Cuối cùng, hãy sử dụng Tự động điền để xem kết quả đầy đủ.
Đọc thêm: Cách sử dụng Công thức INDEX-MATCH trong Excel để tạo nhiều kết quả
Ví dụ 3: Phân tích Điều kiện phân biệt chữ hoa chữ thường bằng cách kết hợp Hàm INDEX và MATCH trong Excel
Dành cho Phân tích phân biệt chữ hoa chữ thường , bạn có thể áp dụng kết hợp hàm INDEX và hàm MATCH .
Để phân tích và thực hiện tra cứu, hãy làm theo hướng dẫn các bước bên dưới.
Bước 1:
- Chúng tôi muốn tìm ID của MARK thay vì Đánh dấu . Hãy xem điều gì sẽ xảy ra. Nhập ô công thức sau C5 .
=INDEX(B5:B11,MATCH(TRUE,EXACT(G4,C5:C11),0)) 
Bước2:
- Cuối cùng, nhấn Enter để tìm ID đơn hàng cho MARK .
Hãy nhìn kỹ; đã thu được kết quả khớp hoàn hảo với chữ in hoa MARK , nhưng không khớp với Mark .
Ví dụ 4: Tra cứu hai cột với Công thức INDEX-MATCH trong Excel
Thật thú vị khi lưu ý rằng bạn có thể thực hiện tra cứu trong nhiều cột cho nhiều tiêu chí cùng một lúc. Ví dụ: chúng tôi sẽ tìm ID đơn đặt hàng cũng như Giá của một người. Thực hiện theo các bước bên dưới để thực hiện tra cứu theo hai tiêu chí.
Bước 1:
- Đầu tiên, nhập nội dung sau công thức trong ô G5 .
=INDEX(B5:B11,MATCH(TRUE,EXACT(G4,C5:C11),0))
- Thứ hai, nhấn Enter để lấy giá trị đầu tiên trong ô G5 .
Do đó, bạn sẽ lấy giá trị tra cứu đầu tiên trong ô G5 .
Bước 2:
- Để lấy giá trị tra cứu thứ hai, hãy nhập công thức sau vào ô G6 .
=INDEX(D5:D11,MATCH(G4&G5,C5:C11&B5:B11,0))
- Đây là hàm mảng nên chúng ta cần áp dụng hàm này bằng cách nhấn Crtl + Shift + Enter
- Kết quả là bạn sẽ có giá trị tra cứu đầu tiên trong ô G6 .
Đọc thêm: INDEX MATCH với nhiều tiêu chí trong một Trang tính khác (2 cách)
Cách đọc tương tự
- Excel INDEX MATCH trả về nhiều giá trịtrong một ô
- Công thức INDEX-MATCH của Excel trả về nhiều giá trị theo chiều ngang
- [Đã sửa!] INDEX MATCH không trả về giá trị đúng trong Excel ( 5 lý do)
- Cách chọn dữ liệu cụ thể trong Excel (6 phương pháp)
- Hàm INDEX MATCH vs VLOOKUP (9 ví dụ)
Ví dụ 5: Tra cứu hai chiều bằng công thức INDEX-MATCH
Bạn có thể thực hiện tra cứu một hàng và một cột trong Hai chiều . Thực hiện theo các bước bên dưới để tìm giá trị trong một hàng và cột cùng một lúc.
Bước 1:
- Nhập công thức vào ô G7 .
=INDEX(B4:D11,MATCH(G5,B4:B11,0),MATCH(G4,B4:D4,0)) 
Bước 2:
- Cuối cùng, nhấn Enter .
Ví dụ 6: Tìm Khớp gần nhất trong Excel bằng cách hợp nhất các hàm INDEX và MATCH
Hàm INDEX và MATCH rất hữu ích để tìm kiếm hoặc tìm kiếm kết quả khớp gần nhất giữa các phạm vi. Ví dụ: chúng tôi muốn xác định ai có giá trị gần nhất với giá trị mục tiêu của chúng tôi, đó là $15 trong trường hợp này. Để làm như vậy, chỉ cần làm theo các bước bên dưới.
Bước 1:
- Để tìm kết quả khớp nhất, hãy nhập công thức sau.
=INDEX(C5:C11,MATCH(MIN(ABS(D5:D11-G4)),ABS(D5:D11-G4),0)) Ở đây,
ABS(D5:D11-G4) là giá trị chênh lệch tuyệt đối với giá trị mục tiêu 15 giữa các lệnh trong phạm vi D5:D11 .
MIN(ABS(D5:D11-G4) để tìm sự khác biệt nhỏ nhất của tuyệt đốigiá trị.
Bước 2:
- Bằng cách nhấn Ctrl + Shift + Enter , chúng ta sẽ áp dụng hàm này như một hàm mảng.
Đọc thêm: Công thức INDEX-MATCH để tìm giá trị nhỏ nhất trong Excel (4 cách phù hợp)
Ví dụ 7: Tra cứu ba chiều bằng hàm INDEX và MATCH trong Excel
A Tra cứu ba chiều là điều tốt nhất bạn có thể thực hiện bằng cách sử dụng chức năng INDEX và MATCH . Tra cứu ba chiều thêm một khía cạnh bổ sung về mức độ liên quan. Ví dụ: chúng ta có thể tính xem Jenny đã trả bao nhiêu cho hai mặt hàng khác nhau trong ba tháng riêng biệt. Thực hiện theo các bước đơn giản được nêu bên dưới để hoàn thành.
Bước 1:
- Thực hiện Ba -way Lookup , trước tiên hãy nhập công thức bên dưới vào ô H6 .
=INDEX(($D$5:$E$7,$D$10:$E$12,$D$15:$E$17),MATCH($G$6,$C$5:$C$7,0),MATCH(H$5,$D$4:$E$4,0),(IF(H$4="Jan",1,IF(H$4="Feb",2,3)))) 
Bước 2:
- Cuối cùng, nhấn Enter để nhận giá trị tra cứu đầu tiên.
Bước 3:
- Sau đó, sao chép công thức cho các ô khác bằng cách sử dụng Tự động điền
Do đó, bạn sẽ nhận được kết quả như trong hình bên dưới.
Ví dụ 8: Áp dụng Công thức INDEX-MATCH với Ký tự đại diện
Excel cũng có thể xác định giá trị khớp một phần . Các hàm INDEX và MATCH được sử dụng để thực hiện việc này. Để thực hiện điều này, chúng tôi sẽ sử dụng dấu hoa thị (*) làm ký tự đại diện.Chỉ cần làm theo các hướng dẫn được nêu bên dưới để bắt đầu.
Bước 1:
- Đầu tiên, trong ô G5 , nhập công thức bên dưới.
=INDEX($D$5:$D$11,MATCH(F5&"*",$C$5:$C$11,0),1) 
Bước 2:
- Sau đó, nhấn nút Enter để xem các thay đổi.
Bước 3:
- Chỉ cần sử dụng công cụ Tự động điền để điền vào các ô được yêu cầu.
Kết quả là bạn có thể thấy rằng công cụ này trả về kết quả cho “ Jenny ,” mặc dù nó không khớp chính xác.
Đọc thêm: INDEX MATCH Nhiều tiêu chí với ký tự đại diện trong Excel (Hướng dẫn đầy đủ)
Kết luận
Tóm lại, tôi hy vọng bài viết này đã trình bày cách sử dụng INDEX và MATCH để tích hợp nhiều tiêu chí. Xem qua cuốn sách thực hành và áp dụng những gì bạn đã học được. Chúng tôi sẵn sàng hoàn trả các chương trình như thế này nhờ sự hỗ trợ của bạn.
Nếu bạn có bất kỳ câu hỏi nào, vui lòng liên hệ với chúng tôi. Vui lòng cho tôi biết suy nghĩ của bạn trong phần nhận xét bên dưới.
Các câu hỏi của bạn sẽ được các chuyên gia ExcelWIKI trả lời sớm nhất có thể.
