ตัวอย่างการใช้สูตร INDEX-MATCH ใน Excel (8 แนวทาง)

Hugh West

16-10-2023 สูตร Excel
  • แบ่งปันสิ่งนี้
Hugh West

สารบัญ

สำหรับการค้นหาขั้นสูงใน Excel สามารถใช้ INDEX และ MATCH แทน VLOOKUP INDEX และ MATCH จำเป็นสำหรับการค้นหาอย่างละเอียด และหลายรายการนั้นยอดเยี่ยมมาก ด้วยตัวอย่าง เราจะสอนวิธีใช้ฟังก์ชัน Excel INDEX และ MATCH ใน Excel ในบทช่วยสอนนี้

ดาวน์โหลด Practice Workbook

ดาวน์โหลดแบบฝึกหัดนี้เพื่อทำแบบฝึกหัดขณะที่คุณกำลังอ่านบทความนี้

การใช้สูตร INDEX-MATCH.xlsx

8 ตัวอย่างที่มีประสิทธิภาพของการจับคู่ INDEX สูตรใน Excel

เราจะใช้ชุดข้อมูลตัวอย่างในส่วนด้านล่างเพื่อสาธิตวิธีการใช้ ฟังก์ชัน INDEX และ MATCH ในสูตรนั้น เราจะแสดงวิธีใช้ทั้งสองฟังก์ชันใน 8 วิธีที่แตกต่างกันเพื่อค้นหาค่า

♣ไวยากรณ์:

= INDEX ( อาร์เรย์ , row_num , [ column_num ])

♣อาร์กิวเมนต์:

  • อาร์เรย์ : ช่วงของเซลล์ของค่า
  • Row_num : ส่งกลับผลลัพธ์สำหรับแถวในช่วงที่เลือก
  • column_num : ส่งกลับผลลัพธ์สำหรับคอลัมน์ในช่วงที่เลือก

♣ผลลัพธ์:

ฟังก์ชัน ดัชนี ส่งคืนค่าหรือ การอ้างอิงของเซลล์ในช่วงที่ระบุซึ่งอยู่ที่จุดตัดของแถวที่ระบุและคอลัมน์

♣ไวยากรณ์:

= MATCH ( lookup_value , lookup_array ,[ match_type ])

♣อาร์กิวเมนต์:

  • lookup_value : ค่าที่คุณต้องการค้นหาในช่วง
  • lookup_array : ช่วงที่คุณกำลังค้นหา lookup_value .
  • match_type : ระบุว่าค่าการค้นหาและค่าอาร์เรย์การค้นหาเป็นอย่างไร ตรงกันใน Excel
    • 1 = ตรงทั้งหมดหรือเล็กที่สุดถัดไป
    • 0 = ตรงทั้งหมด
    • -1 = ที่แน่นอนหรือใหญ่ที่สุดถัดไป

♣ผลลัพธ์:

ส่งกลับตำแหน่งของรายการในอาร์เรย์ในแง่ของความสัมพันธ์ ตำแหน่ง

ตัวอย่างที่ 1: การรวมพื้นฐานของฟังก์ชัน INDEX และ MATCH ใน Excel

สมมติว่า คุณต้องการค้นหา ราคา สำหรับ รหัสคำสั่งซื้อ เฉพาะ เราจะรวมฟังก์ชัน INDEX และ MATCH เข้าด้วยกัน

ขั้นตอนที่ 1:

  • ในเซลล์ G5 ให้พิมพ์สูตรต่อไปนี้
=INDEX(D5:D11, MATCH(G4,B5:B11,0))

ที่นี่

    <11 MATCH(G4,B5:B11,0) หมายถึงเซลล์ G4 เป็น lookup_value ในช่วง B5:B11 สำหรับ คู่ที่เหมาะสม. จะส่งกลับ 4 เนื่องจากค่าอยู่ในแถวหมายเลข 4 .
  • INDEX(D5:D11, MATCH(G4,B5:B11,0)) อ้างอิง D5:D11 เป็นอาร์เรย์ที่เราได้รับค่า และ row_num เป็น 4 ตามที่เราได้รับจาก MATCH <2 ไม่จำเป็น Column_num เนื่องจากเราใช้ INDEX เพียงอันเดียวคอลัมน์

ขั้นตอนที่ 2:

  • กด Enter ไปที่ผลลัพธ์

อ่านเพิ่มเติม: ตัวอย่างที่มีสูตร INDEX-MATCH ใน Excel (8 แนวทาง)

ตัวอย่างที่ 2: ใช้สูตรการจับคู่ดัชนีเพื่อค้นหาจากด้านซ้ายใน Excel

คุณยังสามารถค้นหาจากคอลัมน์หนึ่งไปยังอีกคอลัมน์หนึ่งได้อีกด้วย ค่าสำหรับคอลัมน์ C ซึ่งเป็นคอลัมน์ที่สองของ INDEX ช่วง B5:D11 จะพบได้ในตัวอย่างต่อไปนี้ ทำตามขั้นตอนด้านล่างเพื่อทำการค้นหาจากด้านซ้าย

ขั้นตอนที่ 1:

  • พิมพ์สูตรต่อไปนี้ใน เซลล์ G5 .
=INDEX($B$5:$D$11,MATCH(F5,$B$5:$B$11,0),2)

ขั้นตอนที่ 2:

  • จากนั้น กด Enter เพื่อดูผลลัพธ์

ขั้นตอนที่ 3:

  • สุดท้าย ใช้ ป้อนอัตโนมัติ เพื่อดูผลลัพธ์ทั้งหมด

อ่านเพิ่มเติม: วิธีใช้สูตร INDEX-MATCH ใน Excel เพื่อสร้างผลลัพธ์หลายรายการ

ตัวอย่างที่ 3: วิเคราะห์เงื่อนไขที่คำนึงถึงขนาดตัวพิมพ์ด้วยการรวมฟังก์ชัน INDEX และ MATCH ใน Excel

สำหรับ การวิเคราะห์ตามตัวพิมพ์เล็กและใหญ่ คุณสามารถใช้ฟังก์ชัน INDEX และ MATCH ร่วมกันได้

ในการวิเคราะห์และค้นหา ให้ทำตาม ขั้นตอนด้านล่าง

ขั้นตอนที่ 1:

  • เราต้องการหา ID ของ MARK แทนที่จะเป็น ทำเครื่องหมาย มาดูกันว่าเกิดอะไรขึ้น ป้อนเซลล์สูตรต่อไปนี้ C5 .
=INDEX(B5:B11,MATCH(TRUE,EXACT(G4,C5:C11),0))

ขั้นตอน2:

  • สุดท้าย กด Enter เพื่อค้นหา Order ID สำหรับ MARK

ดูอย่างใกล้ชิด ผลลัพธ์สำหรับการจับคู่ที่สมบูรณ์แบบด้วยอักษรตัวใหญ่ MARK ได้รับ แต่ไม่ใช่สำหรับ เครื่องหมาย

ตัวอย่างที่ 4: ค้นหาสองคอลัมน์ด้วยสูตร INDEX-MATCH ใน Excel

เป็นเรื่องที่น่าสนใจที่จะทราบว่าคุณสามารถค้นหาในหลายๆ คอลัมน์สำหรับ หลายเกณฑ์ ในเวลาเดียวกัน ตัวอย่างเช่น เราจะมองหา รหัสคำสั่งซื้อ และ ราคา ของบุคคลหนึ่งๆ ทำตามขั้นตอนด้านล่างเพื่อค้นหาสองเกณฑ์

ขั้นตอนที่ 1:

  • ขั้นแรก พิมพ์ต่อไปนี้ สูตรในเซลล์ G5 .
=INDEX(B5:B11,MATCH(TRUE,EXACT(G4,C5:C11),0))

  • จากนั้น กด Enter เพื่อ รับค่าแรกในเซลล์ G5 .

ดังนั้น คุณจะค้นหาค่าแรกในเซลล์ G5

ขั้นตอนที่ 2:

  • หากต้องการรับค่าการค้นหาที่สอง ให้พิมพ์สูตรต่อไปนี้ในเซลล์ G6 .
=INDEX(D5:D11,MATCH(G4&G5,C5:C11&B5:B11,0))

  • นี่คือฟังก์ชันอาร์เรย์ ดังนั้นเราต้องใช้ฟังก์ชันนี้โดยกด Crtl + Shift + Enter

  • ดังนั้น คุณจะได้ ค่าการค้นหาแรกในเซลล์ G6 .

อ่านเพิ่มเติม: INDEX MATCH ที่มีหลายเกณฑ์ใน แผ่นงานที่แตกต่างกัน (2 วิธี)

การอ่านที่คล้ายกัน

  • Excel INDEX MATCH เพื่อส่งคืนค่าหลายค่าในเซลล์เดียว
  • สูตร INDEX-MATCH ของ Excel เพื่อส่งคืนค่าหลายค่าในแนวนอน
  • [แก้ไขแล้ว!] INDEX MATCH ไม่ส่งคืนค่าที่ถูกต้องใน Excel ( 5 เหตุผล)
  • วิธีเลือกข้อมูลเฉพาะใน Excel (6 วิธี)
  • INDEX MATCH เทียบกับฟังก์ชัน VLOOKUP (9 ตัวอย่าง)

ตัวอย่างที่ 5: การค้นหาแบบสองทางโดยใช้สูตร INDEX-MATCH

คุณสามารถดำเนินการค้นหาแถวและคอลัมน์ใน สองทาง ทำตามขั้นตอนด้านล่างเพื่อค้นหาค่าในแถวและคอลัมน์พร้อมกัน

ขั้นตอนที่ 1:

  • ป้อนสูตรในเซลล์ G7 .
=INDEX(B4:D11,MATCH(G5,B4:B11,0),MATCH(G4,B4:D4,0))

ขั้นตอนที่ 2:

  • สุดท้าย กด Enter .

ตัวอย่างที่ 6: ค้นหา การจับคู่ที่ใกล้เคียงที่สุดใน Excel โดยการรวมฟังก์ชัน INDEX และ MATCH

ฟังก์ชัน INDEX และฟังก์ชัน MATCH มีประโยชน์ในการค้นหาหรือค้นหาการจับคู่ที่ใกล้เคียงที่สุดระหว่างช่วงต่างๆ ตัวอย่างเช่น เราต้องการพิจารณาว่าใครมีค่าใกล้เคียงกับค่าเป้าหมายของเรามากที่สุด ซึ่งในกรณีนี้คือ $15 โดยทำตามขั้นตอนด้านล่าง

ขั้นตอนที่ 1:

  • หากต้องการค้นหารายการที่ใกล้เคียงที่สุด ให้พิมพ์ สูตรต่อไปนี้
=INDEX(C5:C11,MATCH(MIN(ABS(D5:D11-G4)),ABS(D5:D11-G4),0))

ในที่นี้

ABS(D5:D11-G4) คือ ค่าสัมบูรณ์ของผลต่างที่มีค่าเป้าหมาย 15 ระหว่างช่วง D5:D11 .

MIN(ABS(D5:D11-G4) คำสั่ง เพื่อหาผลต่างต่ำสุดของค่าสัมบูรณ์ค่า

ขั้นตอนที่ 2:

  • โดยกด Ctrl + Shift + Enter เราจะใช้ฟังก์ชันนี้เป็นฟังก์ชันอาร์เรย์

อ่านเพิ่มเติม: สูตรการจับคู่ INDEX เพื่อหาค่าต่ำสุดใน Excel (4 วิธีที่เหมาะสม)

ตัวอย่างที่ 7: การค้นหาแบบสามทางโดยใช้ฟังก์ชัน INDEX และ MATCH ใน Excel

A Three-way Lookup เป็นสิ่งที่ดีที่สุดที่คุณสามารถทำได้โดยใช้ฟังก์ชัน INDEX และ MATCH การค้นหาแบบสามทาง เพิ่มมิติเพิ่มเติมของความเกี่ยวข้อง ตัวอย่างเช่น เราสามารถหาว่าเจนนี่จ่ายอะไรสำหรับสินค้าสองรายการที่แตกต่างกันในสามเดือนแยกกัน ทำตามขั้นตอนง่าย ๆ ที่ระบุไว้ด้านล่างเพื่อดำเนินการให้เสร็จสิ้น

ขั้นตอนที่ 1:

  • ดำเนินการ สาม -way Lookup ในตอนแรกให้พิมพ์สูตรด้านล่างในเซลล์ H6 .
=INDEX(($D$5:$E$7,$D$10:$E$12,$D$15:$E$17),MATCH($G$6,$C$5:$C$7,0),MATCH(H$5,$D$4:$E$4,0),(IF(H$4="Jan",1,IF(H$4="Feb",2,3))))

<3

ขั้นตอนที่ 2:

  • สุดท้าย กด Enter เพื่อรับค่าการค้นหาแรก

ขั้นตอนที่ 3:

  • จากนั้น คัดลอกสูตรสำหรับเซลล์อื่นโดยใช้ ป้อนอัตโนมัติ

ดังนั้น คุณจะได้ผลลัพธ์ดังภาพด้านล่าง

ตัวอย่างที่ 8: ใช้สูตร INDEX-MATCH กับอักขระตัวแทน

Excel ยังสามารถระบุค่า การจับคู่บางส่วน ฟังก์ชัน INDEX และ MATCH ใช้ในการดำเนินการนี้ เราจะใช้เครื่องหมายดอกจัน (*) เป็นอักขระตัวแทนเพียงทำตามคำแนะนำด้านล่างเพื่อเริ่มต้น

ขั้นตอนที่ 1:

  • ประการแรก ในเซลล์ G5 พิมพ์สูตรด้านล่าง
=INDEX($D$5:$D$11,MATCH(F5&"*",$C$5:$C$11,0),1)

ขั้นตอนที่ 2:

  • จากนั้น กดปุ่ม Enter เพื่อดูการเปลี่ยนแปลง

ขั้นตอนที่ 3:

  • เพียงใช้เครื่องมือ ป้อนอัตโนมัติ เพื่อเติมเซลล์ที่ต้องการ

ผลที่ตามมาคือ คุณจะเห็นว่ามันส่งกลับผลลัพธ์สำหรับ “ เจนนี่ ” แม้ว่าจะไม่ตรงกันก็ตาม

อ่านเพิ่มเติม: INDEX จับคู่หลายเกณฑ์ด้วยสัญลักษณ์แทนใน Excel (คู่มือฉบับสมบูรณ์)

สรุป

โดยสรุป ฉันหวังว่าบทความนี้จะสาธิตวิธีใช้ INDEX <ฟังก์ชัน 2>และ MATCH เพื่อรวมเกณฑ์ต่างๆ ดูหนังสือแบบฝึกหัดและนำสิ่งที่คุณได้เรียนรู้ไปใช้ เรายินดีที่จะคืนเงินให้กับโปรแกรมเช่นนี้เนื่องจากการสนับสนุนของคุณ

หากคุณมีคำถามใดๆ โปรดอย่าลังเลที่จะติดต่อเรา โปรดแจ้งให้เราทราบว่าคุณคิดอย่างไรในส่วนความคิดเห็นด้านล่าง

คำถามของคุณจะได้รับคำตอบโดยเร็วที่สุดโดยผู้เชี่ยวชาญ ExcelWIKI

โพสต์ก่อนหน้า วิธีการคำนวณ Root Mean Square Error ใน Excel
โพสต์ถัดไป วิธีลบ Dashes ออกจาก SSN ใน Excel (4 วิธีด่วน)

Hugh West เป็นผู้ฝึกอบรมและนักวิเคราะห์ Excel ที่มีประสบการณ์สูงและมีประสบการณ์มากกว่า 10 ปีในอุตสาหกรรมนี้ เขาสำเร็จการศึกษาระดับปริญญาตรีสาขาการบัญชีและการเงิน และปริญญาโทสาขาบริหารธุรกิจ Hugh มีความหลงใหลในการสอนและได้พัฒนาแนวทางการสอนที่เป็นเอกลักษณ์ซึ่งง่ายต่อการติดตามและเข้าใจ ความรู้ความเชี่ยวชาญของเขาเกี่ยวกับ Excel ช่วยให้นักเรียนและผู้เชี่ยวชาญหลายพันคนทั่วโลกพัฒนาทักษะและความเป็นเลิศในอาชีพการงาน ฮิวจ์แบ่งปันความรู้ของเขากับคนทั้งโลกผ่านบล็อก โดยเสนอบทช่วยสอน Excel ฟรีและการฝึกอบรมออนไลน์เพื่อช่วยให้บุคคลและธุรกิจบรรลุศักยภาพสูงสุดของตนเอง