جدول المحتويات
في Microsoft Excel ، تُستخدم الدالة SEQUENCE لإنشاء تسلسل من القيم الرقمية بتنسيقات مختلفة. في هذه المقالة ، ستتعلم كيف يمكنك استخدام دالة SEQUENCE هذه بكفاءة مع معايير مختلفة ومن خلال دمجها مع وظائف أخرى في Excel.
لقطة الشاشة أعلاه هي نظرة عامة من المقالة التي تمثل تطبيقًا لوظيفة SEQUENCE في Excel. ستتعرف على المزيد حول مجموعة البيانات بالإضافة إلى طرق استخدام وظيفة SEQUENCE بشكل صحيح في الأقسام التالية من هذه المقالة.
تنزيل Practice Workbook
يمكنك قم بتنزيل مصنف Excel الذي استخدمناه لإعداد هذه المقالة.
استخدام SEQUENCE Function.xlsx
مقدمة إلى دالة SEQUENCE
- هدف الوظيفة:
تُستخدم الدالة SEQUENCE لإنشاء تسلسل القيم الرقمية.
- البنية:
= SEQUENCE (الصفوف ، [الأعمدة] ، [البداية] ، [الخطوة ])
- التفسير الوسيطات:
| الوسيطة | مطلوب / اختياري | الشرح |
|---|---|---|
| صفوف | مطلوب | عدد الصفوف. |
| [أعمدة] | اختياري | عدد الأعمدة. |
| [بدء] | اختياري | رقم البداية في مجموعة الإرجاع. |
| [الخطوة] | اختياري | الشائعالأرقام ذات الأصفار البادئة في Excel إذا كنت تعرف كيف تعمل وظيفة TEXT ، فإن تنسيق سلسلة من الأرقام باستخدام الأصفار البادئة أمر سهل للغاية. على سبيل المثال ، ستحتوي جميع الأرقام في تسلسل عشوائي على 4 أرقام وستحتوي تلك التي لا تحتوي على 4 أرقام على أصفار بادئة. ستكون الصيغة ذات الصلة في الخلية B4 هي: =TEXT(SEQUENCE(10,1,5,50),"0000") 15. إنشاء ترتيب عكسي في قائمة بوظيفة التسلسلالآن دعنا نفترض أننا نريد عكس ترتيب الخلايا في القائمة. لتنفيذ الغرض ، يمكننا استخدام الدالتين INDEX و ROWS هنا جنبًا إلى جنب مع وظيفة SEQUENCE. في العمود B ، هناك بعض الأسماء العشوائية وفي العمود D ، سنعرض هذه الأسماء بترتيب عكسي. لذلك ، يجب أن تكون الصيغة المطلوبة في الخلية D5 : =INDEX(B5:B10, SEQUENCE(ROWS(B5:B10), , ROWS(B5:B10), -1)) هنا ، دالة SEQUENCE يعكس أرقام الصفوف لجميع الأسماء وتقوم الوظيفة INDEX لاحقًا باستخراج الأسماء بترتيب عكسي استنادًا إلى الوسيطة الثانية (row_num) التي تم تعديلها بواسطة الدالة SEQUENCE سابقًا. 16. تحضير قائمة بالأبجدية مع وظائف SEQUENCE و CHARفي المثال الأخير ، سنرى كيف يمكن استخدام دالة SEQUENCE لإنشاء قائمة بالحروف الأبجدية في مصفوفة. في الصورة التالية ، تم استخدام صفين منفصلين لعرض المصفوفة التي تحتوي على كل الحروف الأبجدية. المطلوبالصيغة في الخلية B4 هي: =CHAR(SEQUENCE(2,13,65)) في هذه الصيغة ، CHAR دالة تقوم بإرجاع الأحرف المحددة بواسطة Unicode. نظرًا لوجود 26 حرفًا أبجديًا باللغة الإنجليزية ، فقد استخدمنا 13 عمودًا هنا. يمكننا أيضًا تحديد رقم العمود على أنه 2 وستعيد الصيغة جميع الحروف الأبجدية في 13 صفًا وعمودين. 💡 أشياء يجب وضعها في الاعتبار🔺 دالة SEQUENCE ترجع مصفوفة بإراقة القيم في صفوف وأعمدة متعددة. لذلك ، إذا لم تتمكن أي من قيم الإرجاع في المصفوفة من العثور على خلية فارغة لتمثيل نفسها ، فستُرجع الدالة خطأ #SPILL . 🔺 SEQUENCE تتوفر حاليًا في Microsoft Office 365 فقط. 🔺 القيمة الافتراضية لجميع الوسائط الاختيارية للدالة SEQUENCE هي 1 . الكلمات الختاميةآمل أن تستفزك جميع الطرق المذكورة أعلاه لاستخدام وظيفة SEQUENCE الآن لتطبيقها في جداول بيانات Excel بشكل أكثر فعالية. إذا كان لديك أي أسئلة أو تعليقات ، فيرجى إبلاغي بذلك في قسم التعليقات. أو يمكنك الاطلاع على مقالاتنا الأخرى المتعلقة بوظائف Excel على هذا الموقع. الفرق بين قيمتين متتاليتين في تسلسل الأرقام. |
- معلمة الإرجاع:
مصفوفة تحتوي على سلسلة من الأرقام بمواصفات محددة .
16 أمثلة على استخدام دالة SEQUENCE في Excel
1. الاستخدام الأساسي لوظيفة SEQUENCE مع وسيطة واحدة فقط
الوسيطة الأولى للدالة SEQUENCE هي "الصفوف" والتي تشير إلى عدد الصفوف المراد عرضها في جدول البيانات. إذا لم تقم بإدخال أي وسيطات أخرى ، فستقوم الوظيفة بإرجاع العدد المحدد من الصفوف حيث سيحتوي الصف الأول على الرقم '1' وسيتم عرض جميع الأرقام المتسلسلة الأخرى لاحقًا في الصفوف التالية.
لذلك ، في الصورة أدناه ، تحتوي الخلية B4 على الصيغة:
=SEQUENCE(5) 
اقرأ المزيد: 51 معظم وظائف الرياضيات والمثلثات المستخدمة في Excel
2. دالة SEQUENCE مع وسيطتين في Excel
نظرًا لأن الوسيطة الثانية للدالة تشير إلى عدد الأعمدة ، فإن الجمع بين الوسيطتين الأوليين سينتج عنه مصفوفة من الصفوف والأعمدة المحددة.
في الخلية B4 ، ستكون الوظيفة SEQUENCE مع وسيطات الصفوف والأعمدة:
=SEQUENCE(5,3) 
اقرأ المزيد: 44 دالة رياضية في Excel (تنزيل ملف PDF مجاني)
3. SEQUENCE Function with Three Arguments in Excel
الآن ملفالوسيطة الثالثة للدالة هي [start] والتي تشير إلى قيمة البداية أو الرقم الذي سيتم عرضه في الخلية الأولى من الصف الأول في المصفوفة.
لذلك ، مع الوسيطات الثلاث الأولى ، ستعيد الوظيفة المصفوفة كما هو موضح في الصورة التالية. والصيغة في الخلية B4 هي:
=SEQUENCE(5,3,10) حيث تكون قيمة البداية 10 في المصفوفة التي تم تحديدها في الوسيطة الثالثة الوظيفة.
4. دالة SEQUENCE مع أربع وسيطات في Excel
تشير الوسيطة الرابعة للدالة [الخطوة] إلى الفاصل الزمني الذي يجب اتباعه بين أي قيمتين متتاليتين في المصفوفة. بافتراض أننا نريد بناء سلسلة حسابية من الأرقام الصحيحة تبدأ من 10 حيث يكون الاختلاف المشترك هو 5.
الصيغة المطلوبة في الخلية B4 ستكون:
=SEQUENCE(5,3,10,5) 
5. استخدام دالة SEQUENCE لإنشاء التواريخ أو الأشهر في Excel
i. إنشاء تواريخ متسلسلة باستخدام وظائف SEQUENCE و TODAY
تعد الوظيفة SEQUENCE مفيدة جدًا لعمل عدد من التواريخ المتتالية بدءًا من تاريخ محدد. باستخدام الوظيفة TODAY في الداخل كوسيطة ثالثة ، يمكننا تحديد التاريخ الحالي الذي سيكون تاريخ البدء. بافتراض أننا سننشئ قائمة بعشرة تواريخ متتالية تبدأ من التاريخ الحالي.
يجب أن تكون الصيغة ذات الصلة في الخلية B5 يكون:
=SEQUENCE(10,1,TODAY(),1) 
ii. إنشاء قائمة بالتواريخ الأولى للأشهر المتسلسلة باستخدام وظائف EDATE و SEQUENCE
تُستخدم وظيفة EDATE لعرض التاريخ بعد أو قبل عدد محدد من الأشهر من تاريخ معين. من خلال الجمع بين وظائف EDATE و DATE و SEQUENCE معًا ، يمكننا بسهولة إنشاء قائمة بجميع التواريخ الأولى لعدة أشهر متتالية. لنفترض أننا نريد إظهار التواريخ الأولى لجميع الأشهر في عام 2021.
لذلك ، في الإخراج الخلية B4 في الصورة التالية ، ستكون الصيغة المطلوبة:
=EDATE(DATE(2021,1,1),SEQUENCE(12,1,0)) 
iii. عمل قائمة بأسماء 12 شهرًا باستخدام دالة SEQUENCE في Excel
باستخدام وظيفة TEXT حول وظيفة SEQUENCE ، يمكننا أيضًا إعداد قائمة من اثني عشر شهرًا متتالية في السنة.
يجب أن تكون الصيغة المطلوبة في الخلية B5 :
=TEXT(EDATE(DATE(2022,1,1),SEQUENCE(12,1,0)),"mmmm") 
6. مزيج من وظائف SEQUENCE و TRANSPOSE في Excel
من خلال تطبيق وظيفة SEQUENCE مع جميع الوسائط الأربعة الموجودة في الداخل ، يمكننا إنشاء مصفوفة من بعض الأرقام المتسلسلة وسيؤدي تدفق الأرقام إلى من اليسار إلى اليمين كما في الصورة أدناه.
لنفترض أننا نريد عرض تسلسل هذه الأرقام من أعلى إلى أسفل في المصفوفة. في هذه الحالة ، يتعين علينا استخدام وظيفة TRANSPOSE والتي ستحول الصفوف إلى أعمدة وأعمدة في صفوف.
لذلك ، يجب أن تكون الصيغة المطلوبة في الإخراج الخلية B10 :
=TRANSPOSE(SEQUENCE(5,3,10,5)) 
7. إنشاء تسلسل من الأرقام الرومانية في Excel
يمكن أيضًا إنشاء قائمة بالأرقام الرومانية المتتالية بمساعدة وظائف ROMAN و SEQUENCE .
المطلوب يجب أن تكون الصيغة في أي خلية:
=ROMAN(SEQUENCE(5,3,1,1)) سيؤدي ذلك إلى إنشاء خمسة عشر رقمًا رومانيًا متتاليًا بدءًا من 'i' في مجموعة من خمسة صفوف وثلاثة أعمدة.
8. استخدام SEQUENCE مع دالة INDEX في Excel
الآن دعونا نلقي نظرة على مجموعة البيانات أدناه. تظهر كل علامة تجارية للهواتف الذكية وطرازها مرتين في الجدول: أحدهما بالسعر الفعلي والآخر بسعر مخفض. لنفترض أننا نريد إظهار صفوف جميع العلامات التجارية التي تحتوي على أسعار مخفضة فقط.
في الإخراج الخلية B18 ، ستكون الصيغة ذات الصلة:
=INDEX(B6:D15,SEQUENCE(COUNTA(B6:B15)/2,1,2,2),SEQUENCE(1,3)) بعد الضغط على Enter ، ستحصل على المصفوفة الناتجة مع جميع العلامات التجارية للهواتف الذكية وأسماء الطراز بأسعارها المخفضة فقط.
🔎 كيف تعمل الصيغة؟
➯ COUNTA تحسب الدالة العدد الإجمالي للخلايا في النطاق B6: B15 . ثم يتم تقسيم الإخراج (10) على 2 ويتم إدخال القيمة الناتجة كأول وسيط (صفوف) للدالة SEQUENCE .
➯ في الوسيطة الثانية (row_num) لوظيفة INDEX ، تحدد الدالة SEQUENCE الصفوف التي يجب استخراجها من الجدول.
➯ أخيرًا ، في الوسيطة الثالثة للدالة INDEX ، تحدد دالة SEQUENCE أخرى جميع الأعمدة التي يجب أخذها في الاعتبار لاستخراج البيانات.
قراءات مماثلة
- كيفية استخدام دالة RAND في Excel (5 أمثلة)
- دالة كبيرة في Excel
- كيفية استخدام دالة SUMPRODUCT في Excel ( 4 أمثلة)
- حل المعادلات في Excel (متعدد الحدود ، تكعيبي ، تربيعي ، & amp؛ خطي)
- كيفية استخدام دالة SUMIF في Excel ( مع 5 أمثلة سهلة)
9. إنشاء ترتيب عشوائي لمخرجات SEQUENCE
ما تعلمناه حتى الآن عن دالة SEQUENCE هو أنها ترجع بعدد محدد من القيم المتسلسلة. ولكن يمكننا أيضًا اختيار ترتيب عشوائي للتسلسل أو ترتيب الأرقام في المصفوفة الناتجة. للقيام بذلك ، يتعين علينا استخدام وظيفة SORTBY خارج دالة SEQUENCE وسيتم إجراء الفرز استنادًا إلى الوظيفة RANDARRAY حيث تُرجع الدالة RANDARRAY أرقامًا عشوائية بدون ترتيب أو تسلسل معين .
في الخلية B4 ، يجب أن تكون الصيغة ذات الصلة لإنشاء ترتيب عشوائي للأرقام المتسلسلة:
=SORTBY(SEQUENCE(10),RANDARRAY(10)) 
10. يعد إنشاء تقويم ديناميكي باستخدام وظيفة SEQUENCE في Excel
أحد أكثر الأشياءالاستخدامات الشاملة لوظائف SEQUENCE تستعد لشهر تقويمي. لنفترض أن لدينا قيمة تاريخ عشوائية في الخلية C4 وهي 01-08-2021 أو 1 أغسطس 2021 . من خلال دمج الدالتين SEQUENCE و WEEKDAY معًا ، يمكننا استخراج الشهر من ذلك التاريخ المحدد ومن ثم إظهار جميع أيام التقويم لهذا الشهر المحدد.
الصيغة المطلوبة لعرض شهر تقويمي بناءً على تاريخ في الخلية B7 ستكون:
=SEQUENCE(6,7,C4-WEEKDAY(C4)+1) 
🔎 كيف تعمل الصيغة؟
➯ في وظيفة SEQUENCE ، كان عدد الصفوف تم تحديده بواسطة 6 وعدد الأعمدة بـ 7.
➯ تم تحديد تاريخ البدء بواسطة “C4-WEEKDAY (C4) +1” . هنا تستخرج الوظيفة WEEKDAY الرقم التسلسلي ليوم الأسبوع (افتراضيًا ، 1 لـ الأحد وبالتالي على التوالي 7 لـ السبت ). يطرح التاريخ الموجود في الخلية C4 عدد أيام الأسبوع وما بعدها عن طريق إضافة '1' ، يصبح تاريخ البدء هو التاريخ الأول للشهر المحتمل.
➯ الدالة SEQUENCE ثم تعرض التواريخ المتتالية من اليسار إلى اليمين في مصفوفة من 6 صفوف و 7 أعمدة. لا تنس تخصيص تنسيق التواريخ لإظهار تسلسل الأيام فقط.
11. عمل تسلسل متكرر بمساعدة وظائف MOD و SEQUENCE
باستخدام MOD و SEQUENCEمعًا ، يمكننا إظهار تسلسل معين من الأرقام أو القيم عدة مرات في عمود أو صف أو صفيف. في لقطة الشاشة التالية ، تم عرض القيم الصحيحة من 1 إلى 4 عدة مرات في عمود.
الصيغة المطلوبة في الخلية B4 لإنشاء هذا المصفوفة هي:
=MOD(SEQUENCE(12)-1,4)+1 
🔎 كيف تعمل الصيغة؟
➯ نظرًا لأن قيم الأعداد الصحيحة من 1 إلى 4 هنا يجب عرضها عدة مرات ، يجب تعيين مضاعف 4 على أنه عدد الصفوف في دالة SEQUENCE .
➯ “SEQUENCE (12) -1” ، يُرجع هذا الجزء من الصيغة المصفوفة التالية:
{0؛ 1؛ 2؛ 3؛ 4؛ 5؛ 6؛ 7؛ 8؛ 9؛ 10؛ 11}
➯ وظيفة MOD تقسم كل من قيم الأعداد الصحيحة في المصفوفة باستخدام 4 وترجع كل الباقي في مصفوفة نهائية.
12. إنشاء أرقام متكررة في تسلسل في Excel
مزيج ROUNDUP ، بالإضافة إلى دالة SEQUENCE ، يمهد الطريق لإنشاء الأرقام المتكررة في تسلسل. في الصورة أدناه ، تم عرض قيم الأعداد الصحيحة من 1 إلى 5 مرتين متتاليتين في العمود B
الصيغة المطلوبة التي تم استخدامها لإنشاء مصفوفة الإرجاع هي:
=ROUNDUP(SEQUENCE(10, 1, 1/2, 1/2), 0) 
🔎 كيف تعمل الصيغة؟
➯ هنا تم تعيين نقطة البداية وقيمة الخطوة في دالة SEQUENCE بـ ½ في كلتا الحالتين.
➯ باستخدام الوسيطات المذكورة ، ستعيد الدالة SEQUENCE المصفوفة التالية:
{0.5؛ 1؛ 1.5؛ 2؛ 2.5؛ 3؛ 3.5؛ 4؛ 4.5؛ 5}
➯ أخيرًا ، تقوم الدالة ROUNDUP بتقريب جميع الكسور العشرية إلى الرقم الصحيح التالي.
قراءة المزيد: كيفية استخدام وظيفة ROUNDDOWN في Excel (5 طرق)
13. إنشاء قيم فارغة في تسلسل من الأرقام
إذا كنت بحاجة إلى ترك خلية فارغة أو مسافة بعد كل قيمة في سلسلة من الأرقام ، فيمكنك دمج IF و INT و SEQUENCE يعمل أيضًا للحصول على الإخراج. في الصورة التالية ، تم عرض الأرقام من 1 إلى 5 في تسلسل مع مسافة بعد كل قيمة في التسلسل.
الصيغة المطلوبة في الخلية B4 هي:
=IF(INT(SEQUENCE(10, 1, 1, 1/2))=SEQUENCE(10, 1, 1, 1/2), SEQUENCE(10, 1, 1, 1/2), "") 
🔎 كيف تعمل الصيغة؟
➯ SEQUENCE (10،1،1، ½) ، هذا الجزء المكرر من الصيغة يُرجع المصفوفة التالية:
{1؛ 1.5؛ 2 ؛ 2.5؛ 3؛ 3.5؛ 4؛ 4.5؛ 5؛ 5.5}
➯ INT (SEQUENCE (10،1،1، ½)) إرجاع مصفوفة أخرى من:
{1؛ 1؛ 2؛ 2؛ 3؛ 3؛ 4؛ 4؛ 5؛ 5}
➯ باستخدام الدالة IF ، تتحقق الصيغة مما إذا كانت القيم الموجودة في المصفوفة الثانية تتطابق مع القيم الموجودة في الصف الأول. إذا كانت القيم متطابقة ، فإن الصفوف المتطابقة ترجع مع قيم المنظور. خلاف ذلك ، تظل الصفوف فارغة والتي تعتبر خلايا فارغة في عمود الإخراج.
14. تنسيق تسلسل من
