Enhavtabelo
Variabloj (kiel varprezo, akcio, interezprocento, ktp.) submetataj al datoj panikigas ĝeneralajn homojn, ĉar iliaj prezoj dependas de datoj. INDEXKOMATKO multoblaj kriterioj datintervalo povas ĉerpi prezojn el difinita datintervalo.
Ni diru, ke ni havas certajn produktojn kun iliaj prezoj stabilaj dum certa tempodaŭro. Kaj ni volas INDEX MATCH la prezojn por la donitaj kriterioj.
En ĉi tiu artikolo, ni uzas plurajn funkciojn por INDEX MATCH multoblaj kriterioj datintervalo.
Elŝutu Excel-Larlibron
Multibla kriteriodatintervalo.xlsx
3 Facilaj Manieroj Uzi INDEX MATCH por Multoblaj Kriterioj de DatIntervalo
Metodo 1: Uzante INDEXMATCH-Funkciojn por Multoblaj Kriterioj de DatIntervalo
Ni volas ĉerpi la prezon por certa produkto en specifa dato. Supozu, ke ni volas vidi la prezon de Glaciaĵo je 02-10-22 ( monato-tago-jaro ). Se la donita dato falas inter la proponita tempodaŭro, ni havos la prezon ĉerpita en ajna malplena ĉelo.
Paŝoj: Enigu la sekvan formulon en ajna malplena ĉelo (t.e., I5 ). Kiel la formulo en tabelformulo, Premu CTRL+SHIFT+ENTER por apliki ĝin. Tuj la formulo liveras la prezon de Produkto se ĝi falas en la donita tempodaŭro (t.e., Dato intervalo) kiel montrite sube.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Formulo Nekropsio:
La funkcio Excel INDEX trovas valoron de difinita loko ene de difinita intervalo. En nia kazo, ni uzas la funkcion MATCH induktitan per la funkcio INDEX . La funkcio MATCH pasas sian rezulton kiel vicnumero por enskriboj kiuj kontentigas donitajn kriteriojn. La sintakso de INDEX funkcio estas
INDEX(array, row_num, [col_num]) En la formulo, $E$5$E$16 rilatas al la argumento tabelo . Ene de la funkcio MATCH $B$5:$B$16=G5 , $D$5:$D$16>=H5 , kaj $C$5:$C$16<=H5 deklaras la kriteriojn. Por havigi pli bonan identigon, ni kolorigas respektivajn intervalojn per rektanguloj.
La funkcio MATCH lokas la pozicion de donita valoro ene de vico, kolumno aŭ tabelo. Kiel ni diris pli frue, la parto MATCH pasas la vican numeron por la funkcio INDEX . La sintakso de la funkcio MATCH estas
MATCH (lookup_value, lookup_array, [match_type]) La MATCH parto estas
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) La parto MATCH asignas 1 kiel serĉa_valoro , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) kiel serĉa_tabelo , kaj 0 deklaras la [matĉo_tipo] kiel ĝusta kongruo.
La uzata formulo MATCH liveras 3 ĉar ĝi trovas Glaciaĵon en la vico numero 3 .
En kazoj, ni havas plurajn produktojn por ĉerpi ilian prezon. la datumaro. Ĝi kvazaŭ aspektas kiel la sekva bildo,
La kombinita formulo INDEX MATCH ricevas Prezojn sur ĝiaargumentoj kontentigantaj la kriteriojn. Alie rezultas #N/A eraro kiel montrite en la supra ekrankopio.
Legu Pli: VBA INDEX MATCH Bazita sur Multoblaj Kriterioj en Excel ( 3 Metodoj)
Metodo 2: XLOOKUP Funkcio por Trakti Multoblajn Kriteriojn
Simile al Metodo 1 , ni povas uzi la XLOOKUP funkcio (nur disponebla en Excel 365 ) al INDEX MATCH multoblaj kriterioj. La sintakso de la funkcio XLOOKUP estas
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Paŝoj: Uzu la suban formulon en ĉelo I5 tiam Premu ENIGU .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") La formulo XLOOKUP redonas la respektatan prezon kiu kontentigas la donitajn kriteriojn (t.e., Produkto kaj Dato ) kiel montrite en la supra bildo.
🔄 Formula Nekropsio:
La XLOOKUP asignas 1 kiel sia serĉo argumento, (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) kiel serĉo_tabelo, $E$5:$E$16 as return_array . Ankaŭ, la formulo montras Ne Trovitan tekston en la okazo ke enskriboj ne falas en la datintervalo. Ni indikas la asignitajn kriteriojn en koloraj rektanguloj kiel montrite en la sekva bildo.
➤ Por pluraj Produktoj, vi povas apliki la formulon XLOOKUP kaj ĉerpi la prezojn kontentigante la donitajn kriteriojn. Ankaŭ, la formulo montras Ne Trovita se la donitaj datkriterioj ne plivastiĝas ene de la donita datogamo.
Vi povas aldoni pli da kriterioj ol uzataj en la formulo. Por doni simplajn kaj klarajn scenarojn, oni uzis minimumajn kriteriojn.
Legu Pli: XLOOKUP kun Multoblaj Kriterioj en Excel (4 Facilaj Manieroj)
Metodo 3: INDEX kaj AGGREGAT Funkcioj por Eltiri Volatilan Prezon el Datintervalo
Kelkaj Produktaj prezoj (t.e., nafto, valuto, ktp.) estas tiom volatilaj ke ili fluktuas dum semajnoj aŭ eĉ tagoj. Ni havas prezojn de certa produkto en intervalo de semajno. Ni volas trovi la prezon por la donitaj datoj. Por trovi la prezon por difinita datintervalo, ni povas uzi la kombinitan funkcion INDEX AGGREGATE . La sintakso de la funkcio AGGREGATE estas
AGGREGATE (function_num, options, ref1, ref2) Paŝoj: Tajpu la sekvan formulon en ajna malplena ĉelo (t.e. , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
La 1a prezo de la certa produktodato 02-15-22 ĝis 02-25-22 estas $0,84 . Povas esti 2a aŭ 3a prezo disponebla sed komence ni restas al la 1a .
🔄 Formula Nekropsio :
En la formulo, =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) parto provizas la vicnumeron al la INDEX funkcio. C$5:C$13 estas la tabelo argumento de la funkcio INDEX .
En la formulo AGGREGATE ,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) liveras 1 aŭ 0 depende de ĉu la datenserio datoj enirasla intervalo aŭ ne.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) liveras tabelon de vicaj nombroj depende de la kontentigo de la datokriterio. Alie, rezultigas erarvalorojn.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 kiel ref1 rezultigas tabelon de vicnumeroj konvertitaj en indeksajn nombrojn alie en erarvalorojn.
VICJOJ(E$8:E8) kiel ref2 rezultoj en vicnumero kaj ĝi estas facila maniero akiri vicnumeron dum vi aplikas la formulon malsupren.
La nombro 15 = funkcio_num (t.e., ETA ), 6 = opcioj (t.e., ignoras erarvalorojn ). Vi povas elekti function_num el 19 malsamajn funkciojn kaj Opcioj el 8 malsamajn opciojn.
Fine, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) pasas la n-an plej malgrandan indeksan nombron de vico kiu kontentigas la donitajn kriteriojn.
Okaze okazas ia eraro, IFERROR(INDEX...),"") ignoras ĉiajn erarojn. kaj transformas ilin en vakojn.
➤ Trenu la Plenigi Tenilon por akiri aliajn kongruajn prezojn ene de la kriterio-datintervalo. Kaj la funkcio IFERARO rezultigas malplenajn ĉelojn se la formulo renkontas erarojn.
Legu Pli: VSERĈO kun Multoblaj Kriterioj Inkluzivanta Datintervalon en Excel (2 Manieroj)
Konkludo
En ĉi tiu artikolo, ni montras plurajn manierojn por INDEKSA MATCH multoblaj kriterioj datintervalo. Ni uzas funkciojn kiel INDEX , MATCH . XLOOKUP , kaj AGGREGA por formi formulojn kiuj indeksaskongruaj enskriboj kiuj kontentigas kriteriojn. Mi esperas, ke ĉi tiuj supre menciitaj eliroj helpos vin trakti vian situacion. Komentu se vi havas pliajn demandojn aŭ havas ion por aldoni.
