Táboa de contidos
As variables (como o prezo das materias primas, a acción, o tipo de xuro, etc.) suxeitas a datas provocan pánico na xente en xeral, xa que os seus prezos dependen das datas. INDEX MATCH o intervalo de datas con varios criterios pode extraer prezos dun determinado intervalo de datas.
Digamos que temos certos produtos cos seus prezos estables durante un determinado período de tempo. E queremos COINCIDENCIAR ÍNDICE os prezos para os criterios indicados.
Neste artigo, usamos varias funcións para COINCIR ÍNDICE intervalo de datas de varios criterios.
Descargar libro de Excel
Intervalo de datas de varios criterios.xlsx
3 xeitos sinxelos de usar INDEX MATCH para varios criterios de intervalo de datas
Método 1: usar funcións INDEX MATCH para varios criterios de intervalo de datas
Queremos para extraer o prezo dun determinado produto nunha data específica. Supoñamos que queremos ver o prezo dun Xelado o 02-10-22 ( mes-día-ano ). Se a data indicada cae entre o período de tempo ofrecido, extraeremos o prezo en calquera cela en branco.
Pasos: Insira a seguinte fórmula en calquera cela en branco (é dicir, I5 ). Como fórmula nunha fórmula matricial, prema CTRL+MAIÚS+INTRO para aplicala. A fórmula devolve ao instante o prezo do Produto se cae no período de tempo indicado (é dicir, o intervalo Data ) como se mostra a continuación.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Fórmula Autopsia:A función
Excel INDEX atopa un valor dunha localización determinada dentro dun intervalo determinado. No noso caso, usamos a función MATCH inducida coa función INDEX . A función COMPARAR pasa o seu resultado como número de fila para as entradas que cumpran uns criterios determinados. A sintaxe dunha función INDEX é
INDEX(array, row_num, [col_num]) Na fórmula, $E$5$E$16 refírese a o argumento matriz . Dentro da función COMPARAR $B$5:$B$16=G5 , $D$5:$D$16>=H5 e $C$5:$C$16<=H5 declaran os criterios. Para proporcionar unha mellor identificación, coloreamos os intervalos respectivos en rectángulos.
A función COMPARAR localiza a posición dun valor determinado dentro unha fila, columna ou táboa. Como dixemos anteriormente, a parte MATCH pasa o número de fila para a función INDEX . A sintaxe da función MATCH é
MATCH (lookup_value, lookup_array, [match_type]) A parte MATCH é
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) A parte MATCH asigna 1 como lookup_value , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) como lookup_array e 0 declara o [match_type] como unha coincidencia exacta.
A fórmula MATCH usada devolve 3 xa que atopa Xeado na fila número 3 .
En casos, temos varios produtos dos que extraer o seu prezo o conxunto de datos. Parece como a seguinte imaxe,
A fórmula combinada INDEX MATCH obtén Prezos o seuargumentos que satisfagan os criterios. En caso contrario, provoca un erro #N/A como se representa na captura de pantalla anterior.
Ler máis: COINCIDENCIA DE ÍNDICE VBA en base a varios criterios en Excel ( 3 Métodos)
Método 2: función XLOOKUP para tratar con varios criterios
Semellante ao Método 1 , podemos usar o XLOOKUP (só dispoñible en Excel 365 ) para INDEX MATCH intervalo de datas con varios criterios. A sintaxe da función XLOOKUP é
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Pasos: Use a seguinte fórmula na cela I5 , a continuación, prema ENTER .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") A fórmula XLOOKUP devolve o prezo respectado que satisface os criterios indicados (é dicir, Produto e Data ) como se mostra na imaxe superior.
🔄 Fórmula Autopsia:
O XLOOKUP asigna 1 como o seu argumento de busca , (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) como matriz_busca, $E$5:$E$16 como matriz_devolución . Ademais, a fórmula mostra texto Non atopado no caso de que as entradas non entren no intervalo de datas. Indicamos os criterios asignados en rectángulos de cores como se representa na seguinte imaxe.
➤ Para varios Produtos, pode aplicar a fórmula XLOOKUP e extraer os prezos ao cumprir os criterios indicados. Ademais, a fórmula mostra Non atopado se os criterios de data indicados non se expanden dentro da data indicadaintervalo.
Podes engadir máis criterios dos que se usan na fórmula. Co fin de dar escenarios sinxelos e lúcidos, utilizáronse criterios mínimos.
Ler máis: XLOOKUP con criterios múltiples en Excel (4 xeitos sinxelos)
Método 3: funcións de ÍNDICE e AGREGADO para extraer un prezo volátil do intervalo de datas
Os prezos dalgúns produtos (por exemplo, petróleo cru, moeda, etc.) son tan volátiles que flutúan durante semanas ou incluso días. Temos prezos dun determinado produto nun intervalo dunha semana. Queremos atopar o prezo para as datas indicadas. Para atopar o prezo dun determinado intervalo de datas, podemos utilizar a función combinada INDEX AGGREGATE . A sintaxe da función AGGREGATE é
AGGREGATE (function_num, options, ref1, ref2) Pasos: Escriba a seguinte fórmula en calquera cela en branco (i.e. , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
O primeiro prezo dunha determinada data do produto 02-15-22 a 02-25-22 é de $0,84 . Pode haber un prezo de 2º ou 3º , pero ao principio seguimos o 1º .
🔄 Fórmula Autopsia :
Na fórmula, a parte =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) proporciona o número de fila ao ÍNDICE función. C$5:C$13 é o argumento matriz da función INDEX .
Dentro da fórmula AGGREGATE ,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) devolve 1 ou 0 dependendo de se as datas do conxunto de datoso intervalo ou non.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) devolve unha matriz de números de fila dependendo dos criterios de data que satisfagan. En caso contrario, dará lugar a valores de erro.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 as ref1 dá lugar a unha matriz de números de fila convertidos en números índice, noutro caso en valores de erro.
ROWS(E$8:E8) como ref2 dá como resultado o número de fila e é un xeito sinxelo de obter o número de fila mentres aplicas a fórmula cara abaixo.
O número 15 = número_función (é dicir, PEQUENO ), 6 = opcións (é dicir, ignorar os valores de erro ). Podes escoller número_función entre 19 funcións diferentes e Opcións entre 8 opcións diferentes.
Por fin, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) pasa o ésimo número de índice máis pequeno dunha fila que satisfaga os criterios indicados.
En caso de producirse algún erro, IFERROR(INDEX...),"") ignora todos os tipos de erros e transfórmaos en espazos en branco.
➤ Arrastre o Recheo para buscar outros prezos coincidentes dentro do intervalo de datas dos criterios. E a función IFERROR dá lugar a celas en branco se a fórmula atopa algún erro.
Ler máis: VLOOKUP con Varios criterios incluíndo o intervalo de datas en Excel (2 xeitos)
Conclusión
Neste artigo, demostramos varias formas de COINCIDENCIAR ÍNDICE intervalo de datas de varios criterios. Usamos funcións como INDEX , MATCH . XLOOKUP e AGGREGATE para formar fórmulas que indexencoinciden as entradas que cumpran os criterios. Espero que estas formas de saída mencionadas anteriormente che axuden a xestionar a túa situación. Comenta se tes máis preguntas ou tes algo que engadir.
