Isi kandungan
Pembolehubah (seperti harga komoditi, bahagian, kadar faedah, dll.) tertakluk pada tarikh menyebabkan orang ramai panik, kerana harga mereka bergantung pada tarikh. PADAN INDEKS julat tarikh berbilang kriteria boleh mengeluarkan harga daripada julat tarikh tertentu.
Katakanlah kami mempunyai produk tertentu dengan harganya stabil untuk tempoh masa tertentu. Dan kami mahu INDEX MATCH harga untuk kriteria yang diberikan.
Dalam artikel ini, kami menggunakan berbilang fungsi untuk INDEX MATCH julat tarikh berbilang kriteria.
Muat turun Buku Kerja Excel
Julat Tarikh Berbilang Kriteria.xlsx
3 Cara Mudah untuk Menggunakan INDEX MATCH untuk Berbilang Kriteria Julat Tarikh
Kaedah 1: Menggunakan Fungsi INDEX MATCH untuk Berbilang Kriteria Julat Tarikh
Kami mahu untuk mengekstrak harga bagi produk tertentu pada tarikh tertentu. Katakan kita ingin melihat harga Ais Krim pada 02-10-22 ( bulan-hari-tahun ). Jika tarikh yang diberikan jatuh di antara tempoh masa yang ditawarkan, kami akan mengekstrak harga dalam mana-mana sel kosong.
Langkah: Masukkan formula berikut dalam mana-mana sel kosong (iaitu, I5 ). Sebagai formula dalam formula tatasusunan, Tekan CTRL+SHIFT+ENTER untuk menggunakannya. Dengan serta-merta formula mengembalikan harga Produk jika ia jatuh dalam tempoh masa tertentu (iaitu, julat Tarikh ) seperti yang digambarkan di bawah.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Autopsi Formula:Fungsi
Excel INDEX mencari nilai lokasi tertentu dalam julat tertentu. Dalam kes kami, kami menggunakan fungsi MATCH yang diinduksi dengan fungsi INDEX . Fungsi MATCH menghantar keputusannya sebagai nombor baris untuk entri yang memenuhi kriteria yang diberikan. Sintaks fungsi INDEX ialah
INDEX(array, row_num, [col_num]) Dalam formula, $E$5$E$16 merujuk kepada hujah array . Di dalam fungsi MATCH $B$5:$B$16=G5 , $D$5:$D$16>=H5 dan $C$5:$C$16<=H5 mengisytiharkan kriteria. Untuk memberikan pengenalan yang lebih baik, kami mewarnakan julat masing-masing dalam segi empat tepat.
Fungsi MATCH mengesan kedudukan nilai yang diberikan dalam baris, lajur atau jadual. Seperti yang kita katakan sebelum ini, bahagian MATCH melepasi nombor baris untuk fungsi INDEX . Sintaks fungsi MATCH ialah
MATCH (lookup_value, lookup_array, [match_type]) Bahagian MATCH ialah
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) Bahagian MATCH memperuntukkan 1 sebagai lookup_value , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) sebagai lookup_array dan 0 mengisytiharkan [match_type] sebagai padanan tepat.
Formula MATCH yang digunakan mengembalikan 3 kerana ia menemui Ais Krim dalam nombor baris 3 .
Dalam kes, kami mempunyai berbilang produk untuk mengeluarkan harganya daripada set data. Ia kelihatan seperti gambar berikut,
Formula gabungan INDEX MATCH mengambil Harga pada ituhujah yang memenuhi kriteria. Jika tidak mengakibatkan ralat #N/A seperti yang digambarkan dalam tangkapan skrin di atas.
Baca Lagi: PADANAN INDEX VBA Berdasarkan Berbilang Kriteria dalam Excel ( 3 Kaedah)
Kaedah 2: XLOOKUP Berfungsi untuk Menangani Pelbagai Kriteria
Serupa dengan Kaedah 1 , kita boleh menggunakan Fungsi XLOOKUP (hanya tersedia dalam Excel 365 ) kepada INDEX MATCH julat tarikh berbilang kriteria. Sintaks fungsi XLOOKUP ialah
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Langkah: Gunakan formula di bawah dalam sel I5 kemudian Tekan ENTER .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") Formula XLOOKUP mengembalikan harga yang dihormati yang memenuhi kriteria yang diberikan (iaitu, Produk dan Tarikh ) seperti yang ditunjukkan dalam gambar di atas.
🔄 Autopsi Formula:
XLOOKUP menyerahkan 1 sebagai hujah carian nya, (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) sebagai lookup_array, $E$5:$E$16 sebagai return_array . Juga, formula memaparkan teks Tidak Ditemui sekiranya entri tidak termasuk dalam julat tarikh. Kami menunjukkan kriteria yang diberikan dalam segi empat tepat berwarna seperti yang digambarkan dalam imej berikut.
➤ Untuk berbilang Produk, anda boleh menggunakan formula XLOOKUP dan mengekstrak harga apabila memenuhi kriteria yang diberikan. Juga, formula memaparkan Tidak Ditemui jika kriteria tarikh yang diberikan tidak berkembang dalam tarikh yang diberikanjulat.
Anda boleh menambah lebih banyak kriteria daripada yang digunakan dalam formula. Untuk memberikan senario yang mudah dan jelas, kriteria minimum telah digunakan.
Baca Lagi: XLOOKUP dengan Pelbagai Kriteria dalam Excel (4 Cara Mudah)
Kaedah 3: INDEKS dan AGREGAT Berfungsi untuk Mengeluarkan Harga Tidak Menentu daripada Julat Tarikh
Sesetengah harga Produk (iaitu, minyak mentah, mata wang, dll.) sangat tidak menentu sehingga turun naik berminggu-minggu malah berhari-hari. Kami mempunyai harga produk tertentu dalam selang seminggu. Kami ingin mencari harga untuk tarikh yang diberikan. Untuk mencari harga bagi julat tarikh tertentu, kita boleh menggunakan gabungan fungsi INDEX AGGREGATE . Sintaks fungsi AGGREGATE ialah
AGGREGATE (function_num, options, ref1, ref2) Langkah: Taipkan formula berikut dalam mana-mana sel kosong (iaitu. , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
Harga 1 tarikh produk tertentu 02-15-22 hingga 02-25-22 ialah $0.84 . Mungkin terdapat harga ke-2 atau ke-3 tetapi pada mulanya, kami tetap pada harga ke-1 .
🔄 Autopsi Formula :
Dalam formula, =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) bahagian memberikan nombor baris kepada INDEX fungsi. C$5:C$13 ialah hujah array bagi fungsi INDEX .
Di dalam formula AGGREGATE ,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) mengembalikan 1 atau 0 bergantung pada sama ada tarikh set data termasuk dalamjulat atau tidak.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) mengembalikan tatasusunan nombor baris bergantung pada kriteria tarikh yang memuaskan. Jika tidak, menghasilkan nilai ralat.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 sebagai ref1 menghasilkan tatasusunan nombor baris ditukar kepada nombor indeks sebaliknya dalam nilai ralat.
ROWS(E$8:E8) sebagai ref2 menghasilkan nombor baris dan ini adalah cara mudah untuk mendapatkan nombor baris semasa anda menggunakan formula ke bawah.
Nombor 15 = nombor_fungsi (iaitu, KECIL ), 6 = pilihan (iaitu, abaikan nilai ralat ). Anda boleh memilih function_num daripada 19 fungsi yang berbeza dan Options daripada 8 pilihan yang berbeza.
Akhirnya, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) melepasi nth nombor indeks terkecil baris yang memenuhi kriteria yang diberikan.
Sekiranya sebarang ralat berlaku, IFERROR(INDEX...),"") mengabaikan semua jenis ralat dan mengubahnya menjadi kosong.
➤ Seret Pemegang Isi untuk mendapatkan harga dipadankan lain dalam julat tarikh kriteria. Dan fungsi IFERROR menghasilkan sel kosong jika formula menghadapi sebarang ralat.
Baca Lagi: VLOOKUP dengan Berbilang Kriteria Termasuk Julat Tarikh dalam Excel (2 Cara)
Kesimpulan
Dalam artikel ini, kami menunjukkan pelbagai cara untuk PADAN INDEKS julat tarikh berbilang kriteria. Kami menggunakan fungsi seperti INDEX , MATCH . XLOOKUP dan AGGREGATE untuk membentuk formula yang mengindekspadankan entri yang memenuhi kriteria. Harap cara keluar yang disebutkan di atas membantu anda menangani situasi anda. Komen jika anda mempunyai pertanyaan lanjut atau ada apa-apa untuk ditambahkan.
