Daptar eusi
Variabel (sapertos harga komoditi, saham, suku bunga, jrrd.) anu tunduk kana tanggal nyababkeun masarakat umum panik, sabab hargana gumantung kana tanggal. INDEX MATCH sababaraha kritéria rentang tanggal bisa nimba harga tina rentang tanggal nu tangtu.
Anggap we boga produk tangtu kalawan harga maranéhanana stabil pikeun kurun waktu nu tangtu. Sareng kami hoyong INDEKS MATCH harga pikeun kriteria anu dipasihkeun.
Dina artikel ieu, kami nganggo sababaraha fungsi pikeun INDEX MATCH sababaraha kritéria rentang tanggal.
Unduh Excel Workbook
Sabaraha Kriteria Rentang Tanggal.xlsx
3 Cara Gampang Ngagunakeun INDEX MATCH pikeun Sababaraha Kriteria Rentang Tanggal
Metoda 1: Ngagunakeun Fungsi INDEX MATCH pikeun Sababaraha Kriteria Rentang Tanggal
Kami hoyong nimba harga pikeun produk tangtu dina tanggal husus. Anggap urang hoyong ningali harga És Krim dina 02-10-22 ( bulan-poé-taun ). Upami tanggal anu dipasihkeun aya di antara periode waktos anu ditawarkeun, hargana bakal diekstrak dina sél kosong mana waé.
Lengkah-léngkah: Selapkeun rumus ieu dina sél kosong mana waé (nyaéta, I5 ). Salaku rumus dina rumus array, Pencét CTRL+SHIFT+ENTER pikeun nerapkeunana. Langsung rumus ngabalikeun harga Produk upami turun dina jangka waktu anu ditangtukeun (nyaéta, Kaping rentang) sapertos anu digambarkeun di handap ieu.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Rumus Autopsi:
Excel INDEX fungsi manggihan nilai lokasi nu tangtu dina rentang nu tangtu. Dina kasus urang, kami nganggo fungsi MATCH anu diinduksi ku fungsi INDEX . Fungsi MATCH ngirimkeun hasil salaku nomer baris pikeun éntri anu nyumponan kriteria anu dipasihkeun. Sintaksis fungsi INDEX nyaéta
INDEX(array, row_num, [col_num]) Dina rumus, $E$5$E$16 nujul kana argumen array . Di jero fungsi MATCH $B$5:$B$16=G5 , $D$5:$D$16>=H5 , jeung $C$5:$C$16<=H5 nyatakeun kritéria. Pikeun masihan idéntifikasi anu langkung saé, urang ngawarnaan rentang masing-masing dina sagi opat.
Pungsi MATCH maluruh posisi nilai anu dipasihkeun dina jero baris, kolom, atawa tabel. Sakumaha urang nyarios tadi, bagian MATCH ngalangkungan nomer baris pikeun fungsi INDEX . Sintaksis fungsi MATCH nyaéta
MATCH (lookup_value, lookup_array, [match_type]) Bagian MATCH nyaéta
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) Bagian MATCH nangtukeun 1 salaku lookup_value , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) salaku lookup_array , jeung 0 ngadéklarasikeun [match_type] sabagé patandingan pasti.
Rumus MATCH anu dipaké ngabalikeun 3 sabab manggihan És Krim dina nomer baris 3 .
Dina kasus, urang boga sababaraha produk pikeun nimba harga maranéhanana. susunan data. Sigana mah gambar di handap ieu,
Rumus gabungan INDEX MATCH nyokot Harga nyaargumen satisfying kriteria. Upami teu kitu, aya kasalahan #N/A sapertos anu kagambar dina screenshot di luhur.
Baca deui: VBA INDEX MATCH Dumasar kana Sababaraha Kriteria dina Excel ( 3 Métode)
Metoda 2: Fungsi XLOOKUP Pikeun Nangtukeun Sababaraha Kriteria
Sarupa jeung Metoda 1 , urang bisa ngagunakeun XLOOKUP fungsi (ngan sadia dina Excel 365 ) nepi ka INDEX MATCH rentang tanggal sababaraha kriteria. Sintaksis fungsi XLOOKUP nyaéta
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Lengkah: Paké rumus di handap dina sél I5 teras Pencét ENTER .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") Rumus XLOOKUP ngabalikeun harga anu dihormat anu nyugemakeun kriteria anu dipasihkeun (nyaéta, Produk sareng Tanggal ) sapertos anu dipidangkeun dina gambar di luhur.
🔄 Autopsi Formula:
XLOOKUP netepkeun 1 salaku argumen lookup , (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) sakumaha lookup_array, $E$5:$E$16 as return_array . Ogé, rumus nampilkeun Teu Kapanggih téks upami éntri henteu aya dina rentang tanggal. Kami nunjukkeun kritéria anu ditugaskeun dina sagi opat warna sapertos anu digambarkeun dina gambar ieu.
➤ Pikeun sababaraha Produk, anjeun tiasa nerapkeun rumus XLOOKUP sareng nimba harga nalika nyumponan kriteria anu dipasihkeun. Ogé, rumus mintonkeun Teu Kapendak upami kriteria tanggal anu dipasihkeun henteu dilegakeun dina tanggal anu dipasihkeun.rentang.
Anjeun tiasa nambihan langkung seueur kriteria tibatan anu dianggo dina rumus. Pikeun masihan skénario anu saderhana sareng jelas, kritéria minimal parantos dianggo.
Baca deui: XLOOKUP sareng Sababaraha Kriteria dina Excel (4 Cara Gampang)
Metoda 3: INDEKS jeung AGGREGATE Berfungsi pikeun nimba harga volatil tina rentang tanggal
Sababaraha harga produk (nyaéta minyak bumi, mata uang, jsb.) jadi volatile nepi ka turun naek. pikeun minggu atawa malah poé. Kami gaduh harga produk anu tangtu dina interval saminggu. Kami hoyong mendakan harga kanggo tanggal anu dipasihkeun. Pikeun milarian harga rentang tanggal anu ditangtukeun, urang tiasa nganggo fungsi INDEX AGGREGATE . Sintaksis fungsi AGGREGATE nyaéta
AGGREGATE (function_num, options, ref1, ref2) Lengkah-lengkah: Ketik rumus ieu dina sél kosong mana waé (ie. , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
Harga ka-1 ti tanggal produk tangtu 02-15-22 nepi ka 02-25-22 nyaeta $0,84 . Bisa jadi aya harga 2nd atawa 3rd tapi mimitina urang tetep dina 1st hiji.
🔄 Formula Autopsy :
Dina rumus, =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) porsi nyadiakeun nomer baris ka INDEX fungsi. C$5:C$13 nyaéta argumen array tina fungsi INDEX .
Di jero rumus AGGREGATE ,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) mulihkeun 1 atawa 0 gumantung kana naha tanggal set data digolongkeun kanarentang atawa henteu.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) mulihkeun susunan angka baris gumantung kana kriteria tanggal nyugemakeun. Upami teu kitu, nimbulkeun niléy kasalahan.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 sakumaha ref1 nyababkeun susunan angka baris dirobah jadi angka indéks, sabalikna dina nilai kasalahan.
ROWS(E$8:E8) sakumaha ref2 ngahasilkeun nomer baris jeung éta cara gampang pikeun meunangkeun nomer baris nalika anjeun nerapkeun rumus ka handap.
Jumlah 15 = function_num (nyaéta, LEUTIK ), 6 = pilihan (nyaéta, malire nilai kasalahan ). Anjeun tiasa milih function_num tina 19 fungsi anu béda sareng Options tina 8 pilihan anu béda.
Ahirna, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) lulus nth angka indéks pangleutikna tina hiji baris nu nyugemakeun kriteria nu dibikeun.
Upami aya kasalahan, IFERROR(INDEX...),"") teu malire sagala jinis kasalahan. jeung ngarobahna jadi kosong.
➤ Séred Eusian Cecekelan pikeun nyokot harga-harga séjén nu cocog dina rentang tanggal kritéria. Sareng fungsi IFERROR nyababkeun sél kosong upami rumusna mendakan kasalahan.
Baca deui: VLOOKUP nganggo Sababaraha Kriteria Kaasup Rentang Tanggal dina Excel (2 Cara)
Kacindekan
Dina artikel ieu, urang nunjukkeun sababaraha cara INDEX MATCH rentang tanggal sababaraha kriteria. Kami nganggo fungsi sapertos INDEX , MATCH . XLOOKUP , jeung AGGREGATE pikeun ngabentuk rumus nu indékséntri cocog anu nyugemakeun kriteria. Mudah-mudahan cara-cara anu disebatkeun di luhur ngabantosan anjeun pikeun ngatasi kaayaan anjeun. Koméntar upami anjeun gaduh patarosan salajengna atanapi aya anu badé nambihan.
