INHOUDSOPGAWE
Veranderlikes (soos kommoditeitsprys, aandeel, rentekoers, ens.) onderhewig aan datums laat algemene mense paniekerig raak, aangesien hul pryse van datums afhang. INDEX MATCH veelvuldige kriteria-datumreeks kan pryse uit 'n gegewe datumreeks onttrek.
Kom ons sê ons het sekere produkte met hul pryse stabiel vir 'n sekere tydperk. En ons wil INDEX MATCH die pryse vir die gegewe kriteria.
In hierdie artikel gebruik ons verskeie funksies om INDEX MATCH veelvuldige kriteria datumreeks.
Laai Excel-werkboek af
Veelvuldige kriteria-datumreeks.xlsx
3 maklike maniere om INDEX MATCH vir veelvuldige kriteria van datumreeks te gebruik
Metode 1: Gebruik INDEX MATCH-funksies vir veelvuldige kriteria van datumreeks
Ons wil hê om die prys vir 'n sekere produk op 'n spesifieke datum te onttrek. Gestel ons wil die prys van 'n Roomys sien op 02-10-22 ( maand-dag-jaar ). As die gegewe datum tussen die aangebied tydperk val, sal ons die prys in enige leë sel laat onttrek.
Stappe: Voeg die volgende formule in enige leë sel in (d.w.s. I5 ). As die formule in 'n skikkingsformule, Druk CTRL+SHIFT+ENTER om dit toe te pas. Die formule gee onmiddellik die Produk -prys terug as dit binne die gegewe tydperk val (d.w.s. Datum -reeks) soos hieronder uitgebeeld.
=INDEX($E$5:$E$16,MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0)) 
🔄 Formule lykskouing:
Excel INDEX -funksie vind 'n waarde van 'n gegewe ligging binne 'n gegewe reeks. In ons geval gebruik ons die MATCH -funksie wat met die INDEX -funksie geïnduseer word. Die MATCH -funksie gee sy resultaat deur as 'n rynommer vir inskrywings wat aan gegewe kriteria voldoen. Die sintaksis van 'n INDEX -funksie is
INDEX(array, row_num, [col_num]) In die formule verwys $E$5$E$16 na die skikking -argument. Binne die MATCH -funksie $B$5:$B$16=G5 , $D$5:$D$16>=H5 en $C$5:$C$16<=H5 verklaar die kriteria. Om beter identifikasie te verskaf, kleur ons onderskeie reekse in reghoeke in.
Die MATCH -funksie plaas die posisie van 'n gegewe waarde binne 'n ry, kolom of tabel. Soos ons vroeër gesê het, gee die MATCH -gedeelte die rynommer vir die INDEX -funksie deur. Die sintaksis van die MATCH -funksie is
MATCH (lookup_value, lookup_array, [match_type]) Die MATCH -gedeelte is
=MATCH(1,(($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5)),0) Die MATCH -gedeelte ken 1 toe as opsoekwaarde , ($B$5:$B$16=G5)*($D$5:$D$16>=H5)*($C$5:$C$16<=H5) as opsoek-skikking , en 0 verklaar die [passing_type] as 'n presiese passing.
Die gebruikte MATCH -formule gee 3 > soos dit Roomys in rynommer 3 vind.
In gevalle het ons verskeie produkte om hul prys uit te trek die datastel. Dit lyk soos die volgende prentjie,
Die INDEX MATCH gekombineerde formule haal Pryse op syargumente wat aan die kriteria voldoen. Andersins lei dit tot 'n #N/A -fout soos uitgebeeld in die skermkiekie hierbo.
Lees meer: VBA INDEX MATCH Gebaseer op veelvuldige kriteria in Excel ( 3 Metodes)
Metode 2: XLOOKUP-funksie om veelvuldige kriteria te hanteer
Soortgelyk aan Metode 1 , kan ons die
XLOOKUP (lookup, lookup_array, return_array, [not_found], [match_mode], [search_mode]) Stappe: Gebruik die onderstaande formule in sel I5 druk dan ENTER .
=XLOOKUP(1,(H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5),$E$5:$E$16,"NotFound") Die XLOOKUP -formule gee die gerespekteerde prys terug wat aan die gegewe kriteria voldoen (d.w.s. Produk en Datum ) soos in die prent hierbo getoon.
🔄 Formule Lykskouing:
Die XLOOKUP ken 1 toe as sy soek argument, (H5>=$C$5:$C$16)*(H5<=$D$5:$D$16)*($B$5:$B$16=G5) as soek_skikking, $E$5:$E$16 as terugkeer_skikking . Die formule vertoon ook Nie gevind nie teks ingeval inskrywings nie in die datumreeks val nie. Ons dui die toegekende kriteria aan in gekleurde reghoeke soos uitgebeeld in die volgende prent.
➤ Vir veelvuldige Produkte, jy kan die XLOOKUP -formule toepas en die pryse onttrek as jy aan die gegewe kriteria voldoen. Die formule vertoon ook Nie gevind nie as die gegewe datumkriteria nie binne die gegewe datum uitbrei niereeks.
Jy kan meer kriteria byvoeg as wat in die formule gebruik word. Ten einde eenvoudige en duidelike scenario's te gee, is minimale kriteria gebruik.
Lees meer: XLOOKUP met veelvuldige kriteria in Excel (4 maklike maniere)
Metode 3: INDEKS- en AGGREGAAT-funksies om 'n wisselvallige prys vanaf datumbereik te onttrek
Sommige produkte se pryse (d.w.s. ru-olie, geldeenheid, ens.) is so wisselvallig dat hulle fluktueer vir weke of selfs dae. Ons het pryse van 'n sekere produk in 'n week se interval. Ons wil die prys vir die gegewe datums vind. Om die prys vir 'n gegewe datumreeks te vind, kan ons die gekombineerde INDEKS AGGREGATE -funksie gebruik. Die sintaksis van die AGGREGATE -funksie is
AGGREGATE (function_num, options, ref1, ref2) Stappe: Tik die volgende formule in enige leë sel (d.w.s. , E8 ).
=IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") 
Die 1ste prys van die sekere produkdatum 02-15-22 tot 02-25-22 is $0,84 . Daar is dalk 'n 2de of 3de prys beskikbaar, maar ons hou eers by die 1ste een.
🔄 Formule Lykskouing :
In die formule verskaf =IFERROR(INDEX(C$5:C$13,AGGREGATE(15,6, ROW(B$5:B$13)/ ((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))),"") ;
AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) gedeelte die rynommer aan die INDEKS funksie. C$5:C$13 is die skikking -argument van die INDEX -funksie.
Binne die AGGREGATE -formule,
(B$5:B$13>=F$4)*(B$5:B$13<=F$5) gee 1 of 0 terug na gelang van of die datasteldatums in valdie reeks of nie.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5)) gee 'n verskeidenheid rynommers terug na gelang van die datumkriteria wat voldoen. Andersins lei dit tot foutwaardes.
ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1 as ref1 lei tot 'n skikking van rynommers wat in indeksnommers omgeskakel word, anders in foutwaardes.
RYE(E$8:E8) as verw2 ly in rynommer en dis 'n maklike manier om rynommer te kry soos jy die formule afwaarts toepas.
Die nommer 15 = funksienommer (d.w.s. KLEIN ), 6 = opsies (d.i. ignoreer foutwaardes ). Jy kan funksie_nommer kies uit 19 verskillende funksies en Opsies uit 8 verskillende opsies.
Uiteindelik, AGGREGATE(15,6,ROW(B$5:B$13)/((B$5:B$13>=F$4)*(B$5:B$13<=F$5))-ROW(B$5)+1,ROWS(E$8:E8))) slaag die nde kleinste indeksnommer van 'n ry wat aan die gegewe kriteria voldoen.
In geval enige fout voorkom, ignoreer IFERROR(INDEX...),"") alle tipe foute en verander dit in spasies.
➤ Sleep die Vulhandvatsel om ander ooreenstemmende pryse binne die kriteria-datumreeks te gaan haal. En die IFERROR -funksie lei tot leë selle as die formule enige foute teëkom.
Lees meer: VLOOKUP met Veelvuldige kriteria, insluitend datumreeks in Excel (2 maniere)
Gevolgtrekking
In hierdie artikel demonstreer ons veelvuldige maniere om INDEX MATCH veelvuldige kriteria datumreeks. Ons gebruik funksies soos INDEX , MATCH . XLOOKUP , en AGGREGATE om formules te vorm wat indekseerpas inskrywings wat aan kriteria voldoen. Hoop hierdie bogenoemde maniere help jou om jou situasie te hanteer. Lewer kommentaar indien jy verdere navrae het of iets het om by te voeg.
